data/qcsrc/gamec/cl_player.c

   1 $frame die1 die2 draw duck duckwalk duckjump duckidle idle
   2 $frame jump pain1 pain2 shoot taunt run runbackwards
   3 $frame strafeleft straferight dead1 dead2 forwardright
   4 $frame forwardleft backright backleft
   5
   6 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
   7 // merged player_run and player_stand to player_anim
   8 // added death animations to player_anim
   9 // can now spawn thrown weapons from anywhere, not just from players
  10 // thrown weapons now fade out after 20 seconds
  11 // created PlayerGib function
  12 // PlayerDie no longer uses hitloc or damage
  13 // PlayerDie now supports dying animations as well as gibbing
  14 // cleaned up PlayerDie a lot
  15 // added CopyBody
  16
  17 .entity pusher;
  18 .float pushltime;
  19
  20 void CopyBody(float keepvelocity)
  21 {
  22         local entity oldself;
  23         if (self.effects & EF_NODRAW)
  24                 return;
  25         oldself = self;
  26         self = spawn();
  27         self.iscreature = oldself.iscreature;
  28         self.angles = oldself.angles;
  29         self.avelocity = oldself.avelocity;
  30         self.classname = "body";
  31         self.damageforcescale = oldself.damageforcescale;
  32         self.effects = oldself.effects;
  33         self.event_damage = oldself.event_damage;
  34         self.frame = oldself.frame;
  35         self.health = oldself.health;
  36         self.armorvalue = oldself.armorvalue;
  37         self.armortype = oldself.armortype;
  38         self.model = oldself.model;
  39         self.modelindex = oldself.modelindex;
  40         self.movetype = oldself.movetype;
  41         self.nextthink = oldself.nextthink;
  42         self.skin = oldself.skin;
  43         self.solid = oldself.solid;
  44         self.takedamage = oldself.takedamage;
  45         self.think = oldself.think;
  46         if (keepvelocity == 1)
  47                 self.velocity = oldself.velocity;
  48         self.oldvelocity = self.velocity;
  49         self.fade_time = oldself.fade_time;
  50         self.fade_rate = oldself.fade_rate;
  51         //self.weapon = oldself.weapon;
  52         setorigin(self, oldself.origin);
  53         setsize(self, oldself.mins, oldself.maxs);//'-16 -16 -24',  '16 16 5');
  54         self.oldorigin = oldself.origin;
  55         self = oldself;
  56 }
  57
  58 void player_anim (void)
  59 {
  60         if (self.deadflag != DEAD_NO)
  61         {
  62                 if (time > self.dead_time)
  63                 {
  64                         if (self.maxs_z > 5)
  65                                 setsize(self, '-16 -16 -24', '16 16 5');
  66                         self.frame = self.dead_frame;
  67                 }
  68                 else
  69                         self.frame = self.die_frame;
  70                 return;
  71         }
  72
  73
  74         if (self.crouch)
  75         {
  76                 if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
  77                         self.frame = $duckwalk;
  78                 else
  79                         self.frame = $duckidle;
  80         }
  81         else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
  82         {
  83                 if (self.movement_x > 0 && self.movement_y == 0)
  84                         self.frame = $run;
  85                 else if (self.movement_x < 0 && self.movement_y == 0)
  86                         self.frame = $runbackwards;
  87                 else if (self.movement_x == 0 && self.movement_y > 0)
  88                         self.frame = $straferight;
  89                 else if (self.movement_x == 0 && self.movement_y < 0)
  90                         self.frame = $strafeleft;
  91                 else if (self.movement_x > 0 && self.movement_y > 0)
  92                         self.frame = $forwardright;
  93                 else if (self.movement_x > 0 && self.movement_y < 0)
  94                         self.frame = $forwardleft;
  95                 else if (self.movement_x < 0 && self.movement_y > 0)
  96                         self.frame = $backright;
  97                 else if (self.movement_x < 0 && self.movement_y < 0)
  98                         self.frame = $backleft;
  99                 else
 100                         self.frame = $run;
 101         }
 102         else if (self.pain_finished > time)
 103                 self.frame = self.pain_frame;
 104         else if (self.attack_finished > time)
 105                 self.frame = $shoot;
 106         else
 107                 self.frame = $idle;
 108
 109         if (!(self.flags & FL_ONGROUND))
 110         {
 111                 if (self.crouch)
 112                         self.frame = $duckidle;         // if player is crouching while in air, show crouch frame
 113                 else
 114                         self.frame = $jump;
 115         }
 116 }
 117 //End change by Supajoe on 11:44 PM EST 11/16/03 (Subject: Player animations)
 118
 119 void SpawnThrownWeapon (vector org, float w)
 120 {
 121         local entity oldself;
 122
 123         if (!cvar("g_pickup_items"))
 124         if (!cvar("g_minstagib"))
 125                 return;
 126         if (w == IT_LASER)
 127                 return;
 128
 129         oldself = self;
 130         self = spawn();
 131         // this will cause it to be removed later
 132         self.classname = "droppedweapon";
 133
 134         setorigin(self, org);
 135         self.velocity = randomvec() * 100 + '0 0 200';
 136         SUB_SetFade(self, time + 20, 1);
 137
 138         if (w == WEP_UZI)
 139                 weapon_uzi ();
 140         else if (w == WEP_SHOTGUN)
 141                 weapon_shotgun ();
 142         else if (w == WEP_GRENADE_LAUNCHER)
 143                 weapon_grenadelauncher ();
 144         else if (w == WEP_ELECTRO)
 145                 weapon_electro ();
 146         else if (w == WEP_CRYLINK)
 147                 weapon_crylink ();
 148         else if (w == WEP_NEX)
 149                 weapon_nex ();
 150         else if (w == WEP_HAGAR)
 151                 weapon_hagar ();
 152         else if (w == WEP_ROCKET_LAUNCHER)
 153                 weapon_rocketlauncher ();
 154
 155         // making absolutely sure...
 156         self.classname = "droppedweapon";
 157
 158         self = oldself;
 159 }
 160
 161 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 162 {
 163         local float take, save;
 164         te_blood (hitloc, force, damage);
 165         // damage resistance (ignore most of the damage from a bullet or similar)
 166         damage = max(damage - 5, 1);
 167
 168         save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 169         take = bound(0, damage - save, damage);
 170
 171         if (save > 10)
 172                 sound (self, CHAN_IMPACT, "misc/armorimpact.wav", 1, ATTN_NORM);
 173         else if (take > 30)
 174                 sound (self, CHAN_IMPACT, "misc/bodyimpact2.wav", 1, ATTN_NORM);
 175         else if (take > 10)
 176                 sound (self, CHAN_IMPACT, "misc/bodyimpact1.wav", 1, ATTN_NORM);
 177
 178         if (take > 50)
 179                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 180         if (take > 100)
 181                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 182
 183         if (!(self.flags & FL_GODMODE))
 184         {
 185                 self.armorvalue = self.armorvalue - save;
 186                 self.health = self.health - take;
 187                 // pause regeneration for 5 seconds
 188                 self.pauseregen_finished = max(self.pauseregen_finished, time + 5);
 189         }
 190         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 191         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 192         self.dmg_inflictor = inflictor;
 193
 194         if (self.health <= -50)
 195         {
 196                 // don't use any animations as a gib
 197                 self.frame = 0;
 198                 self.dead_frame = 0;
 199                 self.die_frame = 0;
 200                 // view just above the floor
 201                 self.view_ofs = '0 0 4';
 202
 203                 // make a juicy mess
 204                 te_bloodshower (self.origin + self.mins, self.origin + self.maxs, 800, 1000);
 205                 te_bloodshower (self.origin + self.mins, self.origin + self.maxs, 400, 1000);
 206
 207                 // make a meaty mess
 208                 TossGib (self, "models/gibs/eye.md3", self.origin, self.velocity,0);
 209                 TossGib (world, "models/gibs/bloodyskull.md3", self.origin, '0 0 600',0);
 210
 211                 TossGib (world, "models/gibs/gib1.md3", self.origin, self.velocity,0);
 212                 TossGib (world, "models/gibs/gib2.md3", self.origin, self.velocity,0);
 213                 TossGib (world, "models/gibs/gib3.md3", self.origin, self.velocity,0);
 214                 TossGib (world, "models/gibs/gib4.md3", self.origin, self.velocity,0);
 215
 216                 // these destory on impact
 217                 TossGib (world, "models/gibs/gib5.md3", self.origin, '-500 0 450',1);
 218                 TossGib (world, "models/gibs/gib6.md3", self.origin, '0 500 450',1);
 219                 TossGib (world, "models/gibs/chunk.mdl", self.origin, '0 -500 450',1);
 220                 TossGib (world, "models/gibs/chunk.mdl", self.origin, '500 0 450',1);
 221                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity,1);
 222                 TossGib (world, "models/gibs/chunk.mdl", self.origin, '0 0 450',1);
 223
 224                 sound (trace_ent, CHAN_VOICE, "misc/gib.wav", 1, ATTN_NORM);
 225         }
 226 }
 227
 228 void DropAllRunes(entity pl);
 229
 230
 231 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 232 {
 233         local float take, save;
 234
 235         te_blood (hitloc, force, damage);
 236         if (self.pain_finished < time)          //Don't switch pain sequences like crazy
 237         {
 238                 if (random() > 0.5)
 239                         self.pain_frame = $pain1;
 240                 else
 241                         self.pain_frame = $pain2;
 242                 self.pain_finished = time + 0.5;        //Supajoe
 243         }
 244
 245         if (!cvar("g_minstagib"))
 246         {
 247                 save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 248                 take = bound(0, damage - save, damage);
 249         }
 250         else
 251         {
 252                 save = 0;
 253                 take = damage;
 254         }
 255
 256         if (save > 10)
 257                 sound (self, CHAN_IMPACT, "misc/armorimpact.wav", 1, ATTN_NORM);
 258         else if (take > 30)
 259                 sound (self, CHAN_IMPACT, "misc/bodyimpact2.wav", 1, ATTN_NORM);
 260         else if (take > 10)
 261                 sound (self, CHAN_IMPACT, "misc/bodyimpact1.wav", 1, ATTN_NORM);
 262
 263         if (take > 50)
 264                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 265         if (take > 100)
 266                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 267
 268         if (!(self.flags & FL_GODMODE))
 269         {
 270                 self.armorvalue = self.armorvalue - save;
 271                 self.health = self.health - take;
 272                 // pause regeneration for 5 seconds
 273                 self.pauseregen_finished = max(self.pauseregen_finished, time + 5);
 274         }
 275         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 276         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 277         self.dmg_inflictor = inflictor;
 278
 279         if(attacker == self)
 280         {
 281                 // don't reset pushltime for self damage as it may be an attempt to
 282                 // escape a lava pit or similar
 283                 //self.pushltime = 0;
 284         }
 285         else if(attacker.classname == "player" || attacker.classname == "gib")
 286         {
 287                 if (self.bot_type == BOT_TYPE_URREBOT || self.bot_type == BOT_TYPE_AUTOURRE)
 288                 if (!self.enemy)
 289                 if (vlen(self.origin - attacker.origin) < 1000)
 290                         self.enemy = attacker;
 291                 self.pusher = attacker;
 292                 self.pushltime = time + cvar("g_maxpushtime");
 293         }
 294         else if(time < self.pushltime)
 295         {
 296                 attacker = self.pusher;
 297                 self.pushltime = max(self.pushltime, time + 0.6);
 298         }
 299         else
 300                 self.pushltime = 0;
 301
 302         if (self.health <= 2)
 303         {
 304                 DropAllRunes(self);
 305
 306                 // throw a weapon
 307                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.weapon);
 308                 // print an obituary message
 309                 Obituary (attacker, self, deathtype);
 310                 // make the corpse upright (not tilted)
 311                 self.angles_x = 0;
 312                 self.angles_z = 0;
 313                 // don't spin
 314                 self.avelocity = '0 0 0';
 315                 // no weapon when dead
 316                 self.weaponmodel = "";
 317                 w_clear();
 318                 // view from the floor
 319                 self.view_ofs = '0 0 -8';
 320                 // toss the corpse
 321                 self.movetype = MOVETYPE_TOSS;
 322                 // shootable corpse
 323                 self.solid = SOLID_CORPSE;
 324                 // don't stick to the floor
 325                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 326                 // dying animation
 327                 self.deadflag = DEAD_DYING;
 328                 // when to allow respawn
 329                 self.death_time = time + 0.5;
 330                 // when to switch to the dead_frame
 331                 self.dead_time = time + 2;
 332                 if (random() < 0.5)
 333                 {
 334                         self.die_frame = $die1;
 335                         self.dead_frame = $dead1;
 336                 }
 337                 else
 338                 {
 339                         self.die_frame = $die2;
 340                         self.dead_frame = $dead2;
 341                 }
 342                 // start the animation
 343                 player_anim();
 344                 // set damage function to corpse damage
 345                 self.event_damage = PlayerCorpseDamage;
 346                 // call the corpse damage function just in case it wants to gib
 347                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 348                 // set up to fade out later
 349                 SUB_SetFade (self, time + 12 + random () * 4, 1);
 350         }
 351 }
 352