data/qcsrc/gamec/cl_client.c

   1 void info_player_start (void)
   2 {
   3         self.classname = "info_player_deathmatch";
   4 }
   5
   6 void info_player_deathmatch (void)
   7 {
   8 }
   9
  10 float spawn_goodspots, spawn_badspots;
  11 entity Spawn_ClassifyPoints(entity firstspot, entity playerlist, float mindist, float goodspotnum, float badspotnum)
  12 {
  13         local entity spot, player;
  14         local float pcount;
  15         spawn_goodspots = 0;
  16         spawn_badspots = 0;
  17         spot = firstspot;
  18         while (spot)
  19         {
  20                 pcount = 0;
  21                 player = playerlist;
  22                 while (player)
  23                 {
  24                         if (player != self)
  25                         if (vlen(player.origin - spot.origin) < 100)
  26                                 pcount = pcount + 1;
  27                         player = player.chain;
  28                 }
  29                 if (pcount)
  30                 {
  31                         if (spawn_goodspots >= badspotnum)
  32                                 return spot;
  33                         spawn_badspots = spawn_badspots + 1;
  34                 }
  35                 else
  36                 {
  37                         if (spawn_goodspots >= goodspotnum)
  38                                 return spot;
  39                         spawn_goodspots = spawn_goodspots + 1;
  40                 }
  41                 spot = find(spot, classname, "info_player_deathmatch");
  42         }
  43         return firstspot;
  44 }
  45
  46 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  47 {
  48         local entity best, spot, player;
  49         local float bestrating, rating;
  50         best = world;
  51         bestrating = -1000000;
  52         spot = firstspot;
  53         while (spot)
  54         {
  55                 rating = 1000000000;
  56                 player = playerlist;
  57                 while (player)
  58                 {
  59                         if (player != self)
  60                                 rating = min(rating, vlen(player.origin - spot.origin));
  61                         player = player.chain;
  62                 }
  63                 rating = rating + random() * 16;
  64                 if (bestrating < rating)
  65                 {
  66                         best = spot;
  67                         bestrating = rating;
  68                 }
  69                 spot = find(spot, classname, "info_player_deathmatch");
  70         }
  71         return best;
  72 }
  73
  74 /*
  75 =============
  76 SelectSpawnPoint
  77
  78 Finds a point to respawn
  79 =============
  80 */
  81 entity SelectSpawnPoint (float anypoint)
  82 {
  83         local entity spot, firstspot, playerlist;
  84         string spotname;
  85
  86         spot = find (world, classname, "testplayerstart");
  87         if (spot)
  88                 return spot;
  89
  90         spotname = "info_player_deathmatch";
  91
  92         if(!anypoint && cvar("g_ctf") )
  93         {
  94                 if(self.team == 5)//4)
  95                         spotname = "info_player_team1";
  96                 if(self.team == 14)//13)
  97                         spotname = "info_player_team2";
  98                 if(self.team == 4)//3)
  99                         spotname = "info_player_team3";
 100                 if(self.team == 13)//12)
 101                         spotname = "info_player_team4";
 102         }
 103
 104         playerlist = findchain(classname, "player");
 105         firstspot = find(world, classname, spotname);
 106         Spawn_ClassifyPoints(firstspot, playerlist, 100, 1000000, 1000000);
 107         // first check if there are ANY good spots
 108         if (spawn_goodspots > 0)
 109         {
 110                 // good spots exist, there is 50/50 chance of choosing a random good
 111                 // spot or the furthest spot
 112                 // (this means that roughly every other spawn will be furthest, so you
 113                 // usually won't get fragged at spawn twice in a row)
 114                 if (random() > 0.5)
 115                         spot = Spawn_ClassifyPoints(firstspot, playerlist, 100, min(floor(random() * spawn_goodspots), spawn_goodspots - 1), 1000000);
 116                 else
 117                         spot = Spawn_FurthestPoint(firstspot, playerlist);
 118         }
 119         else
 120         {
 121                 // no good spots exist, pick a random bad spot
 122                 spot = Spawn_ClassifyPoints(firstspot, playerlist, 100, 1000000, min(floor(random() * spawn_badspots), spawn_badspots - 1));
 123         }
 124
 125         if (!spot)
 126         {
 127                 if(anypoint)
 128                         error ("PutClientInServer: no start points on level");
 129                 else // try again with deathmatch spots
 130                         spot = SelectSpawnPoint(TRUE);
 131         }
 132
 133         return spot;
 134 }
 135
 136 /*
 137 =============
 138 CheckPlayerModel
 139
 140 Checks if the argument string can be a valid playermodel.
 141 Returns a valid one in doubt.
 142 =============
 143 */
 144 string CheckPlayerModel(string plyermodel) {
 145         if( substring(plyermodel,0,14) != "models/player/") plyermodel = "models/player/marine.zym";
 146
 147         /* Possible Fixme: Check if server can open the model?
 148            This would kill custom models, however. */
 149
 150         return plyermodel;
 151 }
 152
 153 /*
 154 =============
 155 PutObserverInServer
 156
 157 putting a client as observer in the server
 158 =============
 159 */
 160 void PutObserverInServer (void)
 161 {
 162         entity  spot;
 163         spot = SelectSpawnPoint (FALSE);
 164         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 165
 166         if(self.frags == 0 && cvar("g_lms"))
 167                 bprint (strcat("^4", self.netname, "^4 has no more lives left\n"));
 168         else if(self.killcount != -666)
 169                 bprint (strcat("^4", self.netname, "^4 is spectating now\n"));
 170
 171         self.classname = "observer";
 172         self.health = 666;
 173         self.takedamage = DAMAGE_NO;
 174         self.solid = SOLID_NOT;
 175         self.movetype = MOVETYPE_NOCLIP;
 176         self.armorvalue = 666;
 177         self.effects = 0;
 178         self.armorvalue = cvar("g_balance_armor_start");
 179         self.pauserotarmor_finished = 0;
 180         self.pauserothealth_finished = 0;
 181         self.pauseregen_finished = 0;
 182         self.damageforcescale = 0;
 183         self.death_time = 0;
 184         self.dead_time = 0;
 185         self.dead_frame = 0;
 186         self.die_frame = 0;
 187         self.alpha = 0;
 188         self.scale = 0;
 189         self.fade_time = 0;
 190         self.pain_frame = 0;
 191         self.pain_finished = 0;
 192         self.strength_finished = 0;
 193         self.invincible_finished = 0;
 194         self.pushltime = 0;
 195         self.vote_finished = 0;
 196         self.think = SUB_Null;
 197         self.nextthink = 0;
 198         self.hook_time = 0;
 199         self.runes = 0;
 200         self.deadflag = DEAD_NO;
 201         self.angles = spot.angles;
 202         self.angles_z = 0;
 203         self.fixangle = TRUE;
 204         self.crouch = FALSE;
 205         self.view_ofs = PL_VIEW_OFS;
 206         setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 207         self.oldorigin = self.origin;
 208         self.items = 0;
 209         self.model = "";
 210         self.modelindex = 0;
 211         self.weapon = 0;
 212         self.weaponmodel = "";
 213         self.weaponframe = 0;
 214         self.weaponentity = world;
 215         self.killcount = -666;
 216         if(!cvar("g_lms"))
 217                 self.frags = -666;
 218         //stuffcmd(self, "set viewsize 120 \n");
 219 //      bprint (strcat("^4", self.netname, "^4 is spectating now\n"));
 220 }
 221
 222
 223 /*
 224 =============
 225 PutClientInServer
 226
 227 Called when a client spawns in the server
 228 =============
 229 */
 230 void PutClientInServer (void)
 231 {
 232         if(clienttype(self) ==  CLIENTTYPE_BOT)
 233         {
 234                 self.classname = "player";
 235         }
 236
 237         // player is dead and becomes observer
 238         if(cvar("g_lms") && self.frags < 1)
 239                 self.classname = "observer";
 240
 241         if(self.classname == "player") {
 242                 entity  spot;
 243
 244                 spot = SelectSpawnPoint (FALSE);
 245
 246                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 247
 248                 self.classname = "player";
 249                 self.iscreature = TRUE;
 250                 self.movetype = MOVETYPE_WALK;
 251                 self.solid = SOLID_SLIDEBOX;
 252                 self.flags = FL_CLIENT;
 253                 self.takedamage = DAMAGE_AIM;
 254                 self.effects = 0;
 255                 self.health = cvar("g_balance_health_start");
 256                 self.armorvalue = cvar("g_balance_armor_start");
 257                 self.pauserotarmor_finished = time + 10;
 258                 self.pauserothealth_finished = time + 10;
 259                 self.pauseregen_finished = 0;
 260                 self.damageforcescale = 2;
 261                 self.death_time = 0;
 262                 self.dead_time = 0;
 263                 self.dead_frame = 0;
 264                 self.die_frame = 0;
 265                 self.alpha = 0;
 266                 self.scale = 0;
 267                 self.fade_time = 0;
 268                 self.pain_frame = 0;
 269                 self.pain_finished = 0;
 270                 self.strength_finished = 0;
 271                 self.invincible_finished = 0;
 272                 self.pushltime = 0;
 273                 //self.speed_finished = 0;
 274                 //self.slowmo_finished = 0;
 275                 self.vote_finished = 0;
 276                 // players have no think function
 277                 self.think = SUB_Null;
 278                 self.nextthink = 0;
 279
 280                 self.hook_time = 0;
 281
 282                 self.runes = 0;
 283
 284                 self.deadflag = DEAD_NO;
 285
 286                 self.angles = spot.angles;
 287
 288                 self.angles_z = 0; // never spawn tilted even if the spot says to
 289                 self.fixangle = TRUE; // turn this way immediately
 290                 self.velocity = '0 0 0';
 291                 self.avelocity = '0 0 0';
 292                 self.punchangle = '0 0 0';
 293                 self.punchvector = '0 0 0';
 294                 self.oldvelocity = self.velocity;
 295
 296                 self.viewzoom = 0.6;
 297
 298                 if(cvar("sv_defaultcharacter") == 1) {
 299                         local string defaultmodel;
 300                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
 301
 302                         precache_model (defaultmodel);
 303                         setmodel (self, defaultmodel);
 304                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 305                 } else {
 306                         self.playermodel = CheckPlayerModel(self.playermodel);
 307
 308                         precache_model (self.playermodel);
 309                         setmodel (self, self.playermodel);
 310                         self.skin = stof(self.playerskin);
 311
 312                 }
 313
 314                 self.crouch = FALSE;
 315                 self.view_ofs = PL_VIEW_OFS;
 316                 setsize (self, PL_MIN, PL_MAX);
 317                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 318                 // don't reset back to last position, even if new position is stuck in solid
 319                 self.oldorigin = self.origin;
 320
 321                 if(cvar("g_lms"))
 322                 {
 323                         self.ammo_shells = cvar("g_lms_start_ammo_shells");
 324                         self.ammo_nails = cvar("g_lms_start_ammo_nails");
 325                         self.ammo_rockets = cvar("g_lms_start_ammo_rockets");
 326                         self.ammo_cells = cvar("g_lms_start_ammo_cells");
 327                 }
 328                 else if (cvar("g_use_ammunition")) {
 329                         self.ammo_shells = cvar("g_start_ammo_shells");
 330                         self.ammo_nails = cvar("g_start_ammo_nails");
 331                         self.ammo_rockets = cvar("g_start_ammo_rockets");
 332                         self.ammo_cells = cvar("g_start_ammo_cells");
 333                 } else {
 334                         self.ammo_shells = 999;
 335                         self.ammo_nails = 999;
 336                         self.ammo_rockets = 999;
 337                         self.ammo_cells = 999;
 338                 }
 339
 340                 self.items = 0;
 341                 if (cvar("g_start_weapon_laser") || cvar("g_lms"))
 342                 {
 343                         self.items = self.items | IT_LASER;
 344                         self.switchweapon = WEP_LASER;
 345                 }
 346                 if (cvar("g_start_weapon_shotgun") || cvar("g_lms"))
 347                 {
 348                         self.items = self.items | IT_SHOTGUN;
 349                         self.switchweapon = WEP_SHOTGUN;
 350                 }
 351                 if (cvar("g_start_weapon_uzi") || cvar("g_lms"))
 352                 {
 353                         self.items = self.items | IT_UZI;
 354                         self.switchweapon = WEP_UZI;
 355                 }
 356                 if (cvar("g_start_weapon_grenadelauncher") || cvar("g_lms"))
 357                 {
 358                         self.items = self.items | IT_GRENADE_LAUNCHER;
 359                         self.switchweapon = WEP_GRENADE_LAUNCHER;
 360                 }
 361                 if (cvar("g_start_weapon_electro") || cvar("g_lms"))
 362                 {
 363                         self.items = self.items | IT_ELECTRO;
 364                         self.switchweapon = WEP_ELECTRO;
 365                 }
 366                 if (cvar("g_start_weapon_crylink") || cvar("g_lms"))
 367                 {
 368                         self.items = self.items | IT_CRYLINK;
 369                         self.switchweapon = WEP_CRYLINK;
 370                 }
 371                 if (cvar("g_start_weapon_nex") || cvar("g_lms"))
 372                 {
 373                         self.items = self.items | IT_NEX;
 374                         self.switchweapon = WEP_NEX;
 375                 }
 376                 if (cvar("g_start_weapon_hagar") || cvar("g_lms"))
 377                 {
 378                         self.items = self.items | IT_HAGAR;
 379                         self.switchweapon = WEP_HAGAR;
 380                 }
 381                 if (cvar("g_start_weapon_rocketlauncher") || cvar("g_lms"))
 382                 {
 383                         self.items = self.items | IT_ROCKET_LAUNCHER;
 384                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 385                 }
 386
 387                 if(cvar("g_instagib"))
 388                 {
 389                         self.items = IT_NEX;
 390                         self.switchweapon = WEP_NEX;
 391                         self.ammo_cells = 999;
 392                 }
 393
 394                 if(cvar("g_rocketarena"))
 395                 {
 396                         self.items = IT_ROCKET_LAUNCHER;
 397                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 398                         self.ammo_rockets = 999;
 399                 }
 400
 401                 if(cvar("g_minstagib"))
 402                 {
 403                         self.health = 100;
 404                         self.armorvalue = 0;
 405                         self.items = IT_NEX;
 406                         self.switchweapon = WEP_NEX;
 407                         self.ammo_cells = cvar("g_minstagib_ammo_start");
 408                         self.extralives = 0;
 409                         self.jump_interval = time;
 410                 }
 411
 412                 self.event_damage = PlayerDamage;
 413
 414                 self.statdraintime = time + 5;
 415                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 416
 417                 if(self.frags == -666 && self.killcount == -666) {
 418                         self.killcount = 0;
 419                         self.frags = 0;
 420                 }
 421
 422                 /*
 423                 W_UpdateWeapon();
 424                 W_UpdateAmmo();
 425                 */
 426                 CL_SpawnWeaponentity();
 427
 428                 //stuffcmd(self, "chase_active 0");
 429                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 430         } else if(self.classname == "observer") {
 431                 PutObserverInServer ();
 432         }
 433 }
 434
 435 /*
 436 =============
 437 SetNewParms
 438 =============
 439 */
 440 void SetNewParms (void)
 441 {
 442
 443 }
 444
 445 /*
 446 =============
 447 SetChangeParms
 448 =============
 449 */
 450 void SetChangeParms (void)
 451 {
 452
 453 }
 454
 455 /*
 456 =============
 457 ClientKill
 458
 459 Called when a client types 'kill' in the console
 460 =============
 461 */
 462 void ClientKill (void)
 463 {
 464         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 465 }
 466
 467 /*
 468 =============
 469 ClientConnect
 470
 471 Called when a client connects to the server
 472 =============
 473 */
 474 string ColoredTeamName(float t);
 475 //void dom_player_join_team(entity pl);
 476 void ClientConnect (void)
 477 {
 478         self.classname = "player_joining";
 479
 480         //if(cvar("g_domination"))
 481         //      dom_player_join_team(self);
 482
 483         //JoinBestTeam(self, FALSE);
 484         if(cvar("teamplay")) stuffcmd(self,"menu_showteamselect\n");
 485
 486
 487         if(cvar("sv_spectate") == 1 && !cvar("g_lms")) {
 488                 self.classname = "observer";
 489         } else {
 490                 self.classname = "player";
 491         }
 492
 493         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 494
 495         bprint ("^4",self.netname);
 496         bprint ("^4 connected");
 497
 498         if(cvar("g_domination") || cvar("g_ctf"))
 499         {
 500                 bprint(" and joined the ");
 501                 bprint(ColoredTeamName(self.team));
 502         }
 503
 504         bprint("\n");
 505
 506         self.welcomemessage_time = time + cvar("welcome_message_time");
 507         self.welcomemessage_time2 = 0;
 508
 509         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 510         // send prediction settings to the client
 511         stuffcmd(self, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 512         stuffcmd(self, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 513         stuffcmd(self, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 514         stuffcmd(self, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 515         stuffcmd(self, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 516         stuffcmd(self, strcat("cl_movement_jumpvelocity ", ftos(cvar("g_balance_jumpheight")), "\n"));
 517         stuffcmd(self, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 518         stuffcmd(self, strcat("cl_movement_edgefriction 0\n"));
 519         // Wazat's grappling hook
 520         SetGrappleHookBindings();
 521
 522         // get autoswitch state from player
 523         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1; cmd autoswitch $1\"\n");
 524         stuffcmd(self, "cmd autoswitch $cl_autoswitch\n");
 525
 526         // get version info from player
 527         stuffcmd(self, "cmd clientversion $g_nexuizversion_major\n");
 528
 529         // set cvar for team scoreboard
 530         if(teams_matter)
 531                 stuffcmd(self, "set teamplay 1\n");
 532         else
 533                 stuffcmd(self, "set teamplay 0\n");
 534
 535         if(cvar("g_lms"))
 536         {
 537                 self.frags = cvar("fraglimit");
 538                 // no fraglimit was set, so player gets 999 lives
 539                 if(self.frags < 1)
 540                         self.frags = 999;
 541
 542                 // disallow player to join after the worst player has lost g_lms_last_join lives
 543                 // if "g_lms_join_anytime" new players spawn with same amount of lives as the worst active player
 544                 if((cvar("fraglimit") - cvar("g_lms_last_join")) > lms_lowest_lives && !cvar("g_lms_join_anytime"))
 545                 {
 546                         self.frags = -1;
 547                         lms_dead_count += 1;
 548                 }
 549                 else if(cvar("fraglimit") > lms_lowest_lives)
 550                 {
 551                         self.frags = lms_lowest_lives;
 552                 }
 553         }
 554
 555         if(clienttype(self) !=  CLIENTTYPE_BOT)
 556                 player_count += 1;
 557 }
 558
 559 /*
 560 =============
 561 ClientDisconnect
 562
 563 Called when a client disconnects from the server
 564 =============
 565 */
 566 .entity chatbubbleentity;
 567 void ClientDisconnect (void)
 568 {
 569         bprint ("^4",self.netname);
 570         bprint ("^4 disconnected\n");
 571
 572         if (self.chatbubbleentity)
 573         {
 574                 remove (self.chatbubbleentity);
 575                 self.chatbubbleentity = world;
 576         }
 577         DropAllRunes(self);
 578         // decrease player count for lms
 579         if(clienttype(self) !=  CLIENTTYPE_BOT)
 580                 player_count -= 1;
 581         // player was dead, decrease dead count
 582         if(cvar("g_lms") && self.frags < 1)
 583                 lms_dead_count -= 1;
 584         //stuffcmd(self, "set viewsize $tmpviewsize \n");
 585 }
 586
 587 .float buttonchat;
 588 void() ChatBubbleThink =
 589 {
 590         self.nextthink = time;
 591         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 592         {
 593                 remove(self);
 594                 return;
 595         }
 596         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 597         if (self.owner.buttonchat && !self.owner.deadflag)
 598                 self.model = self.mdl;
 599         else
 600                 self.model = "";
 601 };
 602
 603 void() UpdateChatBubble =
 604 {
 605         if (!self.modelindex)
 606                 return;
 607         // spawn a chatbubble entity if needed
 608         if (!self.chatbubbleentity)
 609         {
 610                 self.chatbubbleentity = spawn();
 611                 self.chatbubbleentity.owner = self;
 612                 self.chatbubbleentity.exteriormodeltoclient = self;
 613                 self.chatbubbleentity.think = ChatBubbleThink;
 614                 self.chatbubbleentity.nextthink = time;
 615                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr");
 616                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 617                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 618                 self.chatbubbleentity.model = "";
 619         }
 620 }
 621
 622 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 623 // added to the model skins
 624 /*void() UpdateColorModHack =
 625 {
 626         local float c;
 627         c = self.clientcolors & 15;
 628         // LordHavoc: only bothering to support white, green, red, yellow, blue
 629              if (teamplay == 0) self.colormod = '0 0 0';
 630         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 631         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 632         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 633         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 634         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 635         else self.colormod = '1 1 1';
 636 };*/
 637
 638 void UpdatePlayerColors () {
 639         if(self.weaponentity) {
 640                 self.weaponentity.colormap = self.colormap;
 641                 self.exteriorweaponentity.colormap = self.colormap;
 642         }
 643 }
 644 /*
 645 =============
 646 PlayerJump
 647
 648 When you press the jump key
 649 =============
 650 */
 651 void PlayerJump (void)
 652 {
 653         float mjumpheight;
 654
 655         mjumpheight = cvar("g_balance_jumpheight");
 656         if (self.waterlevel >= 2)
 657         {
 658                 if (self.watertype == CONTENT_WATER)
 659                         self.velocity_z = 200;
 660                 else if (self.watertype == CONTENT_SLIME)
 661                         self.velocity_z = 80;
 662                 else
 663                         self.velocity_z = 50;
 664
 665                 return;
 666         }
 667
 668
 669         if (!(self.flags & FL_ONGROUND))
 670                 return;
 671
 672         if (!(self.flags & FL_JUMPRELEASED))
 673                 return;
 674
 675         if(cvar("g_runematch"))
 676         {
 677                 if(self.runes & RUNE_SPEED)
 678                 {
 679                         if(self.runes & CURSE_SLOW)
 680                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
 681                         else
 682                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 683                 }
 684                 else if(self.runes & CURSE_SLOW)
 685                 {
 686                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
 687                 }
 688         }
 689
 690         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
 691         {
 692                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 693         }
 694
 695         self.velocity_z = self.velocity_z + mjumpheight;
 696         self.oldvelocity_z = self.velocity_z;
 697
 698         self.flags = self.flags - FL_ONGROUND;
 699         self.flags = self.flags - FL_JUMPRELEASED;
 700 }
 701
 702 void() CheckWaterJump =
 703 {
 704         local vector start, end;
 705
 706 // check for a jump-out-of-water
 707         makevectors (self.angles);
 708         start = self.origin;
 709         start_z = start_z + 8;
 710         v_forward_z = 0;
 711         normalize(v_forward);
 712         end = start + v_forward*24;
 713         traceline (start, end, TRUE, self);
 714         if (trace_fraction < 1)
 715         {       // solid at waist
 716                 start_z = start_z + self.maxs_z - 8;
 717                 end = start + v_forward*24;
 718                 self.movedir = trace_plane_normal * -50;
 719                 traceline (start, end, TRUE, self);
 720                 if (trace_fraction == 1)
 721                 {       // open at eye level
 722                         self.flags = self.flags | FL_WATERJUMP;
 723                         self.velocity_z = 225;
 724                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
 725                         self.teleport_time = time + 2;  // safety net
 726                         return;
 727                 }
 728         }
 729 };
 730
 731
 732 void respawn(void)
 733 {
 734         CopyBody(1);
 735         PutClientInServer();
 736 }
 737
 738 void player_powerups (void)
 739 {
 740         if (cvar("g_minstagib"))
 741         {
 742                 self.effects = EF_FULLBRIGHT;
 743                 if (self.items & IT_STRENGTH)
 744                 {
 745                         self.effects = EF_NODRAW;
 746                         if (time > self.strength_finished)
 747                         {
 748                                 self.items = self.items - (self.items & IT_STRENGTH);
 749                                 sprint(self, "^3Invisibility has worn off\n");
 750                         }
 751                 }
 752                 else
 753                 {
 754                         if (time < self.strength_finished)
 755                         {
 756                                 self.items = self.items | IT_STRENGTH;
 757                                 sprint(self, "^3You are invisible\n");
 758                         }
 759                 }
 760
 761                 if (self.items & IT_INVINCIBLE)
 762                 {
 763                         if (time > self.invincible_finished)
 764                         {
 765                                 self.items = self.items - (self.items & IT_INVINCIBLE);
 766                                 sprint(self, "^3Speed has worn off\n");
 767                         }
 768                 }
 769                 else
 770                 {
 771                         if (time < self.invincible_finished)
 772                         {
 773                                 self.items = self.items | IT_INVINCIBLE;
 774                                 sprint(self, "^3You are on speed\n");
 775                         }
 776                 }
 777                 return;
 778         }
 779
 780         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
 781         if (self.items & IT_STRENGTH)
 782         {
 783                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
 784                 if (time > self.strength_finished)
 785                 {
 786                         self.items = self.items - (self.items & IT_STRENGTH);
 787                         sprint(self, "^3Strength has worn off\n");
 788                 }
 789         }
 790         else
 791         {
 792                 if (time < self.strength_finished)
 793                 {
 794                         self.items = self.items | IT_STRENGTH;
 795                         sprint(self, "^3Strength infuses your weapons with devestating power\n");
 796                 }
 797         }
 798         if (self.items & IT_INVINCIBLE)
 799         {
 800                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
 801                 if (time > self.invincible_finished)
 802                 {
 803                         self.items = self.items - (self.items & IT_INVINCIBLE);
 804                         sprint(self, "^3Shield has worn off\n");
 805                 }
 806         }
 807         else
 808         {
 809                 if (time < self.invincible_finished)
 810                 {
 811                         self.items = self.items | IT_INVINCIBLE;
 812                         sprint(self, "^3Shield surrounds you\n");
 813                 }
 814         }
 815
 816         if (cvar("g_fullbrightplayers"))
 817                 self.effects = EF_FULLBRIGHT;
 818
 819 }
 820
 821 void player_regen (void)
 822 {
 823         float maxh, maxa, max_mod, regen_mod, rot_mod;
 824         maxh = cvar("g_balance_health_stable");
 825         maxa = cvar("g_balance_armor_stable");
 826
 827         if (cvar("g_minstagib"))
 828         {
 829                 maxh = 100;
 830                 maxa = 0;
 831                 return;
 832         }
 833
 834         if(cvar("g_runematch"))
 835         {
 836                 max_mod = regen_mod = rot_mod = 1;
 837                 if (self.runes & RUNE_REGEN)
 838                 {
 839                         if (self.runes & CURSE_VENOM) // do we have both rune/curse?
 840                         {
 841                                 regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
 842                                 max_mod = cvar("g_balance_rune_regen_combo_hpmod");
 843                         }
 844                         else
 845                         {
 846                                 regen_mod = cvar("g_balance_rune_regen_regenrate");
 847                                 max_mod = cvar("g_balance_rune_regen_hpmod");
 848                         }
 849                 }
 850                 else if (self.runes & CURSE_VENOM)
 851                 {
 852                         max_mod = cvar("g_balance_curse_venom_hpmod");
 853                         if (self.runes & RUNE_REGEN) // do we have both rune/curse?
 854                                 rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
 855                         else
 856                                 rot_mod = cvar("g_balance_curse_venom_rotrate");
 857                         //if (!self.runes & RUNE_REGEN)
 858                         //      rot_mod = cvar("g_balance_curse_venom_rotrate");
 859                 }
 860                 maxh = maxh * max_mod;
 861                 //maxa = maxa * max_mod;
 862
 863                 if (time > self.pauserotarmor_finished)
 864                 {
 865                         if (self.armorvalue > maxa)
 866                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
 867                 }
 868                 if (time > self.pauserothealth_finished)
 869                 {
 870                         if (self.health > maxh)
 871                                 self.health = bound(0, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime, 1000);
 872                 }
 873                 if (time > self.pauseregen_finished)
 874                 {
 875                         if (self.health < maxh)
 876                                 self.health = bound(0, self.health + (maxh- self.health) * regen_mod*cvar("g_balance_health_regen") * frametime, 1000);
 877                         if (self.armorvalue < maxa)
 878                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime, 1000);
 879                 }
 880         }
 881         else
 882         {
 883                 if (time > self.pauserothealth_finished)
 884                 if (self.health > maxh)
 885                         self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_rot") * frametime, 1000);
 886                 if (time > self.pauserotarmor_finished)
 887                 if (self.armorvalue > maxa)
 888                         self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
 889                 if (time > self.pauseregen_finished)
 890                 {
 891                         if (self.health < maxh)
 892                                 self.health = bound(0, self.health + (maxh- self.health) * cvar("g_balance_health_regen") * frametime, 1000);
 893                         if (self.armorvalue < maxa)
 894                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime, 1000);
 895                 }
 896         }
 897 }
 898
 899 /*
 900 ======================
 901 spectate mode routines
 902 ======================
 903 */
 904 void SpectateCopy(entity spectatee) {
 905         self.armortype = spectatee.armortype;
 906         self.armorvalue = spectatee.armorvalue;
 907         self.currentammo = spectatee.currentammo;
 908         self.effects = spectatee.effects;
 909         self.health = spectatee.health;
 910         self.impulse = 0;
 911         self.items = spectatee.items;
 912         self.punchangle = spectatee.punchangle;
 913         self.view_ofs = spectatee.view_ofs;
 914         self.v_angle = spectatee.v_angle;
 915         self.viewzoom = spectatee.viewzoom;
 916         setorigin(self, spectatee.origin);
 917         setsize(self, spectatee.mins, spectatee.maxs);
 918 }
 919
 920 void SpectateUpdate() {
 921         if (self != self.enemy) {
 922                 SpectateCopy(self.enemy);
 923                 msg_entity = self;
 924                 WriteByte(MSG_ONE, SVC_SETANGLE);
 925                 WriteAngle(MSG_ONE, self.enemy.v_angle_x);
 926                 WriteAngle(MSG_ONE, self.enemy.v_angle_y);
 927                 WriteAngle(MSG_ONE, self.enemy.v_angle_z);
 928         }
 929 }
 930
 931 float SpectateNext() {
 932         other = find(self.enemy, classname, "player");
 933         if (!other) {
 934                 other = find(other, classname, "player");
 935         }
 936         if (other) {
 937                 self.enemy = other;
 938         }
 939         if(self.enemy.classname == "player") {
 940                 msg_entity = self;
 941                 WriteByte(MSG_ONE, SVC_SETVIEW);
 942                 WriteEntity(MSG_ONE, self.enemy);
 943                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 944                 SpectateUpdate();
 945                 return 1;
 946         } else {
 947                 return 0;
 948         }
 949 }
 950
 951 /*
 952 =============
 953 PlayerPreThink
 954
 955 Called every frame for each client before the physics are run
 956 =============
 957 */
 958 void PlayerPreThink (void)
 959 {
 960         if(self.classname == "player") {
 961                 local vector m1, m2;
 962
 963 //              MauveBot_AI();
 964
 965 //              if(self.netname == "Wazat")
 966 //                      bprint(strcat(self.classname, "\n"));
 967
 968                 CheckRules_Player();
 969
 970                 if (intermission_running)
 971                 {
 972                         IntermissionThink ();   // otherwise a button could be missed between
 973                         return;                                 // the think tics
 974                 }
 975
 976                 if (self.deadflag != DEAD_NO)
 977                 {
 978                         player_anim();
 979                         weapon_freeze();
 980                         if (self.deadflag == DEAD_DYING)
 981                         {
 982                                 if (time > self.dead_time)
 983                                         self.deadflag = DEAD_DEAD;
 984                         }
 985                         else if (self.deadflag == DEAD_DEAD)
 986                         {
 987                                 if (!self.button0 && !self.button2 && !self.button3)
 988                                         self.deadflag = DEAD_RESPAWNABLE;
 989                         }
 990                         else if (self.deadflag == DEAD_RESPAWNABLE)
 991                         {
 992                                 if (self.button0  ||
 993                                     self.button2  ||
 994                                     self.button3  ||
 995                                     self.button4  ||
 996                                     cvar("g_lms") ||
 997                                     cvar("g_forced_respawn"))
 998                                         respawn();
 999                         }
1000                         return;
1001                 }
1002
1003                 if (self.button5)
1004                 {
1005                         if (!self.crouch)
1006                         {
1007                                 self.crouch = TRUE;
1008                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1009                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1010                         }
1011                 }
1012                 else
1013                 {
1014                         if (self.crouch)
1015                         {
1016                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1017                                 if (!trace_startsolid)
1018                                 {
1019                                         self.crouch = FALSE;
1020                                         self.view_ofs = PL_VIEW_OFS;
1021                                         setsize (self, PL_MIN, PL_MAX);
1022                                 }
1023                         }
1024                 }
1025
1026                 if(cvar("sv_defaultcharacter") == 1) {
1027                         local string defaultmodel;
1028                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
1029
1030                         if (defaultmodel != self.model)
1031                         {
1032                                 m1 = self.mins;
1033                                 m2 = self.maxs;
1034                                 precache_model (defaultmodel);
1035                                 setmodel (self, defaultmodel);
1036                                 setsize (self, m1, m2);
1037                         }
1038
1039                         if (self.skin != stof(cvar_string("sv_defaultplayerskin")))
1040                                 self.skin = stof(cvar_string("sv_defaultplayerskin"));
1041                 } else {
1042                         if (self.playermodel != self.model)
1043                         {
1044                                 self.playermodel = CheckPlayerModel(self.playermodel);
1045                                 m1 = self.mins;
1046                                 m2 = self.maxs;
1047                                 precache_model (self.playermodel);
1048                                 setmodel (self, self.playermodel);
1049                                 setsize (self, m1, m2);
1050                         }
1051
1052                         if (self.skin != stof(self.playerskin))
1053                                 self.skin = stof(self.playerskin);
1054                 }
1055                 // Savage: Check for nameless players
1056                 if (strlen(self.netname) < 1) {
1057                         self.netname = "Player";
1058                         stuffcmd(self, "name Player\n");
1059                 }
1060
1061                 GrapplingHookFrame();
1062
1063                 W_WeaponFrame();
1064
1065                 if (self.button4 || (self.weapon == WEP_NEX && self.button3))
1066                 {
1067                         if (cvar("g_minstagib") && self.button3)
1068                         {
1069                                 if (self.jump_interval <= (time + 0.1))
1070                                 {
1071                                         self.jump_interval = time + 1;
1072                                         weapon_doattack(laser_check, laser_check, W_Laser_Attack);
1073                                 }
1074                         }
1075                         else if (self.viewzoom > 0.4)
1076                                 self.viewzoom = max (0.4, self.viewzoom - frametime * 2);
1077                 }
1078                 else if (self.viewzoom < 1.0)
1079                         self.viewzoom = min (1.0, self.viewzoom + frametime);
1080
1081
1082                 if (self.button2)
1083                         PlayerJump ();
1084                 else
1085                         self.flags = self.flags | FL_JUMPRELEASED;
1086
1087                 player_powerups();
1088                 player_regen();
1089                 player_anim();
1090
1091                 //self.angles_y=self.v_angle_y + 90;   // temp
1092
1093                 if (self.waterlevel == 2)
1094                         CheckWaterJump ();
1095
1096                 //if (TetrisPreFrame()) return;
1097         } else if(self.classname == "observer") {
1098
1099                 if (self.flags & FL_JUMPRELEASED) {
1100                         if (self.button2) {
1101                                 if(!cvar("teamplay")) {
1102                                         self.flags = self.flags & !FL_JUMPRELEASED;
1103                                         self.classname = "player";
1104                                         if(!cvar("g_lms"))
1105                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1106                                         PutClientInServer();
1107                                         centerprint(self,"");
1108                                         return;
1109                                 } else {
1110                                         self.flags = self.flags & !FL_JUMPRELEASED;
1111                                         stuffcmd(self,"menu_showteamselect\n");
1112                                         return;
1113                                 }
1114                         } else if(self.button0) {
1115                                 self.flags = self.flags & !FL_JUMPRELEASED;
1116                                 if(SpectateNext() == 1) {
1117                                         self.classname = "spectator";
1118                                 }
1119                         }
1120                 } else {
1121                         if (!(self.button0 || self.button2)) {
1122                                 self.flags = self.flags | FL_JUMPRELEASED;
1123                         }
1124                 }
1125                 if(cvar("g_lms") && self.frags == 0)
1126                         centerprint(self, "\n\n\n^1You have no more lives left\nwait for next round\n\n\n^7press attack to spectate other players");
1127                 else if(cvar("g_lms") && self.frags == -1)
1128                         centerprint(self, "\n\n\n^1Match has already begun\nwait for next round\n\n\n^7press attack to spectate other players");
1129                 else
1130                         PrintWelcomeMessage(self);
1131                         //centerprint(self, "\n\n\npress jump to play\npress attack to spectate other players");
1132         } else if(self.classname == "spectator") {
1133
1134                 if (self.flags & FL_JUMPRELEASED) {
1135                         if(self.button0) {
1136                                 self.flags = self.flags & !FL_JUMPRELEASED;
1137                                 if(SpectateNext() == 1) {
1138                                         self.classname = "spectator";
1139                                 } else {
1140                                         self.classname = "observer";
1141                                         msg_entity = self;
1142                                         WriteByte(MSG_ONE, SVC_SETVIEW);
1143                                         WriteEntity(MSG_ONE, self);
1144                                         PutClientInServer();
1145                                 }
1146                         } else if (self.button3) {
1147                                 self.flags = self.flags & !FL_JUMPRELEASED;
1148                                 self.classname = "observer";
1149                                 msg_entity = self;
1150                                 WriteByte(MSG_ONE, SVC_SETVIEW);
1151                                 WriteEntity(MSG_ONE, self);
1152                                 PutClientInServer();
1153                         } else {
1154                                 SpectateUpdate();
1155                         }
1156         } else {
1157                 if (!(self.button0 || self.button3)) {
1158                         self.flags = self.flags | FL_JUMPRELEASED;
1159                 }
1160                 }
1161                 centerprint(self, strcat("spectating ", self.enemy.netname, "\n\n\n^7press attack for next player\npress attack2 for free fly mode"));
1162
1163         }
1164         VoteThink();
1165 }
1166
1167 /*
1168 =============
1169 PlayerPostThink
1170
1171 Called every frame for each client after the physics are run
1172 =============
1173 */
1174 void PlayerPostThink (void)
1175 {
1176         if(self.classname == "player") {
1177                 CheckRules_Player();
1178                 UpdateChatBubble();
1179                 UpdatePlayerColors();
1180                 if (self.deadflag == DEAD_NO)
1181                 if (self.impulse)
1182                         ImpulseCommands ();
1183                 if (intermission_running)
1184                         return;         // intermission or finale
1185
1186                 //PrintWelcomeMessage(self);
1187                 //if (TetrisPostFrame()) return;
1188         } else if (self.classname == "observer") {
1189                 //do nothing
1190         } else if (self.classname == "spectator") {
1191                 //do nothing
1192         }
1193 }