data/qcsrc/common/util.qc

   1 string wordwrap_buffer;
   2
   3 void wordwrap_buffer_put(string s)
   4 {
   5         wordwrap_buffer = strcat(wordwrap_buffer, s);
   6 }
   7
   8 string wordwrap(string s, float l)
   9 {
  10         string r;
  11         wordwrap_buffer = "";
  12         wordwrap_cb(s, l, wordwrap_buffer_put);
  13         r = wordwrap_buffer;
  14         wordwrap_buffer = "";
  15         return r;
  16 }
  17
  18 #ifndef MENUQC
  19 #ifndef CSQC
  20 void wordwrap_buffer_sprint(string s)
  21 {
  22         wordwrap_buffer = strcat(wordwrap_buffer, s);
  23         if(s == "\n")
  24         {
  25                 sprint(self, wordwrap_buffer);
  26                 wordwrap_buffer = "";
  27         }
  28 }
  29
  30 void wordwrap_sprint(string s, float l)
  31 {
  32         wordwrap_buffer = "";
  33         wordwrap_cb(s, l, wordwrap_buffer_sprint);
  34         if(wordwrap_buffer != "")
  35                 sprint(self, strcat(wordwrap_buffer, "\n"));
  36         wordwrap_buffer = "";
  37         return;
  38 }
  39 #endif
  40 #endif
  41
  42 string unescape(string in)
  43 {
  44         local float i, len;
  45         local string str, s;
  46
  47         // but it doesn't seem to be necessary in my tests at least
  48         in = strzone(in);
  49
  50         len = strlen(in);
  51         str = "";
  52         for(i = 0; i < len; ++i)
  53         {
  54                 s = substring(in, i, 1);
  55                 if(s == "\\")
  56                 {
  57                         s = substring(in, i+1, 1);
  58                         if(s == "n")
  59                                 str = strcat(str, "\n");
  60                         else if(s == "\\")
  61                                 str = strcat(str, "\\");
  62                         else
  63                                 str = strcat(str, substring(in, i, 2));
  64                         ++i;
  65                 } else
  66                         str = strcat(str, s);
  67         }
  68
  69         strunzone(in);
  70         return str;
  71 }
  72
  73 void wordwrap_cb(string s, float l, void(string) callback)
  74 {
  75         local string c;
  76         local float lleft, i, j, wlen;
  77
  78         s = strzone(s);
  79         lleft = l;
  80         for (i = 0;i < strlen(s);++i)
  81         {
  82                 if (substring(s, i, 2) == "\\n")
  83                 {
  84                         callback("\n");
  85                         lleft = l;
  86                         ++i;
  87                 }
  88                 else if (substring(s, i, 1) == "\n")
  89                 {
  90                         callback("\n");
  91                         lleft = l;
  92                 }
  93                 else if (substring(s, i, 1) == " ")
  94                 {
  95                         if (lleft > 0)
  96                         {
  97                                 callback(" ");
  98                                 lleft = lleft - 1;
  99                         }
 100                 }
 101                 else
 102                 {
 103                         for (j = i+1;j < strlen(s);++j)
 104                                 //    ^^ this skips over the first character of a word, which
 105                                 //       is ALWAYS part of the word
 106                                 //       this is safe since if i+1 == strlen(s), i will become
 107                                 //       strlen(s)-1 at the end of this block and the function
 108                                 //       will terminate. A space can't be the first character we
 109                                 //       read here, and neither can a \n be the start, since these
 110                                 //       two cases have been handled above.
 111                         {
 112                                 c = substring(s, j, 1);
 113                                 if (c == " ")
 114                                         break;
 115                                 if (c == "\\")
 116                                         break;
 117                                 if (c == "\n")
 118                                         break;
 119                                 // we need to keep this tempstring alive even if substring is
 120                                 // called repeatedly, so call strcat even though we're not
 121                                 // doing anything
 122                                 callback("");
 123                         }
 124                         wlen = j - i;
 125                         if (lleft < wlen)
 126                         {
 127                                 callback("\n");
 128                                 lleft = l;
 129                         }
 130                         callback(substring(s, i, wlen));
 131                         lleft = lleft - wlen;
 132                         i = j - 1;
 133                 }
 134         }
 135         strunzone(s);
 136 }
 137
 138 float dist_point_line(vector p, vector l0, vector ldir)
 139 {
 140         ldir = normalize(ldir);
 141
 142         // remove the component in line direction
 143         p = p - (p * ldir) * ldir;
 144
 145         // vlen of the remaining vector
 146         return vlen(p);
 147 }
 148
 149 void depthfirst(entity start, .entity up, .entity downleft, .entity right, void(entity, entity) funcPre, void(entity, entity) funcPost, entity pass)
 150 {
 151         entity e;
 152         e = start;
 153         funcPre(pass, e);
 154         while(e.downleft)
 155         {
 156                 e = e.downleft;
 157                 funcPre(pass, e);
 158         }
 159         funcPost(pass, e);
 160         while(e != start)
 161         {
 162                 if(e.right)
 163                 {
 164                         e = e.right;
 165                         funcPre(pass, e);
 166                         while(e.downleft)
 167                         {
 168                                 e = e.downleft;
 169                                 funcPre(pass, e);
 170                         }
 171                 }
 172                 else
 173                         e = e.up;
 174                 funcPost(pass, e);
 175         }
 176 }
 177
 178 float median(float a, float b, float c)
 179 {
 180         if(a < c)
 181                 return bound(a, b, c);
 182         return bound(c, b, a);
 183 }
 184
 185 // converts a number to a string with the indicated number of decimals
 186 // works for up to 10 decimals!
 187 string ftos_decimals(float number, float decimals)
 188 {
 189         string result;
 190         string tmp;
 191         float len;
 192
 193         // if negative, cut off the sign first
 194         if(number < 0)
 195                 return strcat("-", ftos_decimals(-number, decimals));
 196         // it now is always positive!
 197
 198         // 3.516 -> 352
 199         number = floor(number * pow(10, decimals) + 0.5);
 200
 201         // 352 -> "352"
 202         result = ftos(number);
 203         len = strlen(result);
 204         // does it have a decimal point (should not happen)? If there is one, it is always at len-7)
 205                 // if ftos had messed it up, which should never happen: "34278.000000"
 206         if(len >= 7)
 207                 if(substring(result, len - 7, 1) == ".")
 208                 {
 209                         dprint("ftos(integer) has comma? Can't be. Affected result: ", result, "\n");
 210                         result = substring(result, 0, len - 7);
 211                         len -= 7;
 212                 }
 213                 // "34278"
 214         if(decimals == 0)
 215                 return result; // don't insert a point for zero decimals
 216         // is it too short? If yes, insert leading zeroes
 217         if(len <= decimals)
 218         {
 219                 result = strcat(substring("0000000000", 0, decimals - len + 1), result);
 220                 len = decimals + 1;
 221         }
 222         // and now... INSERT THE POINT!
 223         tmp = substring(result, len - decimals, decimals);
 224         result = strcat(substring(result, 0, len - decimals), ".", tmp);
 225         return result;
 226 }
 227
 228 float time;
 229 vector colormapPaletteColor(float c, float isPants)
 230 {
 231         switch(c)
 232         {
 233                 case  0: return '0.800000 0.800000 0.800000';
 234                 case  1: return '0.600000 0.400000 0.000000';
 235                 case  2: return '0.000000 1.000000 0.501961';
 236                 case  3: return '0.000000 1.000000 0.000000';
 237                 case  4: return '1.000000 0.000000 0.000000';
 238                 case  5: return '0.000000 0.501961 1.000000';
 239                 case  6: return '0.000000 1.000000 1.000000';
 240                 case  7: return '0.501961 1.000000 0.000000';
 241                 case  8: return '0.501961 0.000000 1.000000';
 242                 case  9: return '1.000000 0.000000 1.000000';
 243                 case 10: return '1.000000 0.000000 0.501961';
 244                 case 11: return '0.600000 0.600000 0.600000';
 245                 case 12: return '1.000000 1.000000 0.000000';
 246                 case 13: return '0.000000 0.000000 1.000000';
 247                 case 14: return '1.000000 0.501961 0.000000';
 248                 case 15:
 249                         if(isPants)
 250                                 return
 251                                           '1 0 0' * (0.502 + 0.498 * sin(time / 2.7182818285 + 0.0000000000))
 252                                         + '0 1 0' * (0.502 + 0.498 * sin(time / 2.7182818285 + 2.0943951024))
 253                                         + '0 0 1' * (0.502 + 0.498 * sin(time / 2.7182818285 + 4.1887902048));
 254                         else
 255                                 return
 256                                           '1 0 0' * (0.502 + 0.498 * sin(time / 3.1415926536 + 5.2359877560))
 257                                         + '0 1 0' * (0.502 + 0.498 * sin(time / 3.1415926536 + 3.1415926536))
 258                                         + '0 0 1' * (0.502 + 0.498 * sin(time / 3.1415926536 + 1.0471975512));
 259                 default: return '0.000 0.000 0.000';
 260         }
 261 }
 262
 263 // unzone the string, and return it as tempstring. Safe to be called on string_null
 264 string fstrunzone(string s)
 265 {
 266         string sc;
 267         if not(s)
 268                 return s;
 269         sc = strcat(s, "");
 270         strunzone(s);
 271         return sc;
 272 }
 273
 274 // Databases (hash tables)
 275 #define DB_BUCKETS 8192
 276 void db_save(float db, string pFilename)
 277 {
 278         float fh, i, n;
 279         fh = fopen(pFilename, FILE_WRITE);
 280         if(fh < 0)
 281         {
 282                 print(strcat("^1Can't write DB to ", pFilename));
 283                 return;
 284         }
 285         n = buf_getsize(db);
 286         fputs(fh, strcat(ftos(DB_BUCKETS), "\n"));
 287         for(i = 0; i < n; ++i)
 288                 fputs(fh, strcat(bufstr_get(db, i), "\n"));
 289         fclose(fh);
 290 }
 291
 292 float db_create()
 293 {
 294         return buf_create();
 295 }
 296
 297 float db_load(string pFilename)
 298 {
 299         float db, fh, i, j, n;
 300         string l;
 301         db = buf_create();
 302         if(db < 0)
 303                 return -1;
 304         fh = fopen(pFilename, FILE_READ);
 305         if(fh < 0)
 306                 return db;
 307         if(stof(fgets(fh)) == DB_BUCKETS)
 308         {
 309                 i = 0;
 310                 while((l = fgets(fh)))
 311                 {
 312                         if(l != "")
 313                                 bufstr_set(db, i, l);
 314                         ++i;
 315                 }
 316         }
 317         else
 318         {
 319                 // different count of buckets?
 320                 // need to reorganize the database then (SLOW)
 321                 while((l = fgets(fh)))
 322                 {
 323                         n = tokenizebyseparator(l, "\\");
 324                         for(j = 2; j < n; j += 2)
 325                                 db_put(db, argv(j-1), uri_unescape(argv(j)));
 326                 }
 327         }
 328         fclose(fh);
 329         return db;
 330 }
 331
 332 void db_dump(float db, string pFilename)
 333 {
 334         float fh, i, j, n, m;
 335         fh = fopen(pFilename, FILE_WRITE);
 336         if(fh < 0)
 337                 error(strcat("Can't dump DB to ", pFilename));
 338         n = buf_getsize(db);
 339         fputs(fh, "0\n");
 340         for(i = 0; i < n; ++i)
 341         {
 342                 m = tokenizebyseparator(bufstr_get(db, i), "\\");
 343                 for(j = 2; j < m; j += 2)
 344                         fputs(fh, strcat("\\", argv(j-1), "\\", argv(j), "\n"));
 345         }
 346         fclose(fh);
 347 }
 348
 349 void db_close(float db)
 350 {
 351         buf_del(db);
 352 }
 353
 354 string db_get(float db, string pKey)
 355 {
 356         float h;
 357         h = mod(crc16(FALSE, pKey), DB_BUCKETS);
 358         return uri_unescape(infoget(bufstr_get(db, h), pKey));
 359 }
 360
 361 void db_put(float db, string pKey, string pValue)
 362 {
 363         float h;
 364         h = mod(crc16(FALSE, pKey), DB_BUCKETS);
 365         bufstr_set(db, h, infoadd(bufstr_get(db, h), pKey, uri_escape(pValue)));
 366 }
 367
 368 void db_test()
 369 {
 370         float db, i;
 371         print("LOAD...\n");
 372         db = db_load("foo.db");
 373         print("LOADED. FILL...\n");
 374         for(i = 0; i < DB_BUCKETS; ++i)
 375                 db_put(db, ftos(random()), "X");
 376         print("FILLED. SAVE...\n");
 377         db_save(db, "foo.db");
 378         print("SAVED. CLOSE...\n");
 379         db_close(db);
 380         print("CLOSED.\n");
 381 }
 382
 383 // Multiline text file buffers
 384 float buf_load(string pFilename)
 385 {
 386         float buf, fh, i;
 387         string l;
 388         buf = buf_create();
 389         if(buf < 0)
 390                 return -1;
 391         fh = fopen(pFilename, FILE_READ);
 392         if(fh < 0)
 393                 return buf;
 394         i = 0;
 395         while((l = fgets(fh)))
 396         {
 397                 bufstr_set(buf, i, l);
 398                 ++i;
 399         }
 400         fclose(fh);
 401         return buf;
 402 }
 403
 404 void buf_save(float buf, string pFilename)
 405 {
 406         float fh, i, n;
 407         fh = fopen(pFilename, FILE_WRITE);
 408         if(fh < 0)
 409                 error(strcat("Can't write buf to ", pFilename));
 410         n = buf_getsize(buf);
 411         for(i = 0; i < n; ++i)
 412                 fputs(fh, strcat(bufstr_get(buf, i), "\n"));
 413         fclose(fh);
 414 }
 415
 416 string GametypeNameFromType(float g)
 417 {
 418         if      (g == GAME_DEATHMATCH) return "dm";
 419         else if (g == GAME_TEAM_DEATHMATCH) return "tdm";
 420         else if (g == GAME_DOMINATION) return "dom";
 421         else if (g == GAME_CTF) return "ctf";
 422         else if (g == GAME_RUNEMATCH) return "rune";
 423         else if (g == GAME_LMS) return "lms";
 424         else if (g == GAME_ARENA) return "arena";
 425         else if (g == GAME_KEYHUNT) return "kh";
 426         else if (g == GAME_ONSLAUGHT) return "ons";
 427         else if (g == GAME_ASSAULT) return "as";
 428         else if (g == GAME_RACE) return "race";
 429         else if (g == GAME_NEXBALL) return "nexball";
 430         return "dm";
 431 }
 432
 433 string mmsss(float tenths)
 434 {
 435         float minutes;
 436         string s;
 437         tenths = floor(tenths + 0.5);
 438         minutes = floor(tenths / 600);
 439         tenths -= minutes * 600;
 440         s = ftos(1000 + tenths);
 441         return strcat(ftos(minutes), ":", substring(s, 1, 2), ".", substring(s, 3, 1));
 442 }
 443
 444 string ScoreString(float pFlags, float pValue)
 445 {
 446         string valstr;
 447         float l;
 448
 449         pValue = floor(pValue + 0.5); // round
 450
 451         if((pValue == 0) && (pFlags & (SFL_HIDE_ZERO | SFL_RANK | SFL_TIME)))
 452                 valstr = "";
 453         else if(pFlags & SFL_RANK)
 454         {
 455                 valstr = ftos(pValue);
 456                 l = strlen(valstr);
 457                 if((l >= 2) && (substring(valstr, l - 2, 1) == "1"))
 458                         valstr = strcat(valstr, "th");
 459                 else if(substring(valstr, l - 1, 1) == "1")
 460                         valstr = strcat(valstr, "st");
 461                 else if(substring(valstr, l - 1, 1) == "2")
 462                         valstr = strcat(valstr, "nd");
 463                 else if(substring(valstr, l - 1, 1) == "3")
 464                         valstr = strcat(valstr, "rd");
 465                 else
 466                         valstr = strcat(valstr, "th");
 467         }
 468         else if(pFlags & SFL_TIME)
 469                 valstr = mmsss(pValue);
 470         else
 471                 valstr = ftos(pValue);
 472
 473         return valstr;
 474 }
 475
 476 vector cross(vector a, vector b)
 477 {
 478         return
 479                 '1 0 0' * (a_y * b_z - a_z * b_y)
 480         +       '0 1 0' * (a_z * b_x - a_x * b_z)
 481         +       '0 0 1' * (a_x * b_y - a_y * b_x);
 482 }
 483
 484 // compressed vector format:
 485 // like MD3, just even shorter
 486 //   4 bit pitch (16 angles), 0 is -90, 8 is 0, 16 would be 90
 487 //   5 bit yaw (32 angles), 0=0, 8=90, 16=180, 24=270
 488 //   7 bit length (logarithmic encoding), 1/8 .. about 7844
 489 //     length = 2^(length_encoded/8) / 8
 490 // if pitch is 90, yaw does nothing and therefore indicates the sign (yaw is then either 11111 or 11110); 11111 is pointing DOWN
 491 // thus, valid values are from 0000.11110.0000000 to 1111.11111.1111111
 492 // the special value 0 indicates the zero vector
 493
 494 float lengthLogTable[128];
 495
 496 float invertLengthLog(float x)
 497 {
 498         float l, r, m, lerr, rerr;
 499
 500         if(x >= lengthLogTable[127])
 501                 return 127;
 502         if(x <= lengthLogTable[0])
 503                 return 0;
 504
 505         l = 0;
 506         r = 127;
 507
 508         while(r - l > 1)
 509         {
 510                 m = floor((l + r) / 2);
 511                 if(lengthLogTable[m] < x)
 512                         l = m;
 513                 else
 514                         r = m;
 515         }
 516
 517         // now: r is >=, l is <
 518         lerr = (x - lengthLogTable[l]);
 519         rerr = (lengthLogTable[r] - x);
 520         if(lerr < rerr)
 521                 return l;
 522         return r;
 523 }
 524
 525 vector decompressShortVector(float data)
 526 {
 527         vector out;
 528         float pitch, yaw, len;
 529         if(data == 0)
 530                 return '0 0 0';
 531         pitch = (data & 0xF000) / 0x1000;
 532         yaw =   (data & 0x0F80) / 0x80;
 533         len =   (data & 0x007F);
 534
 535         //print("\ndecompress: pitch ", ftos(pitch)); print("yaw ", ftos(yaw)); print("len ", ftos(len), "\n");
 536
 537         if(pitch == 0)
 538         {
 539                 out_x = 0;
 540                 out_y = 0;
 541                 if(yaw == 31)
 542                         out_z = -1;
 543                 else
 544                         out_z = +1;
 545         }
 546         else
 547         {
 548                 yaw   = .19634954084936207740 * yaw;
 549                 pitch = .19634954084936207740 * pitch - 1.57079632679489661922;
 550                 out_x = cos(yaw) *  cos(pitch);
 551                 out_y = sin(yaw) *  cos(pitch);
 552                 out_z =            -sin(pitch);
 553         }
 554
 555         //print("decompressed: ", vtos(out), "\n");
 556
 557         return out * lengthLogTable[len];
 558 }
 559
 560 float compressShortVector(vector vec)
 561 {
 562         vector ang;
 563         float pitch, yaw, len;
 564         if(vlen(vec) == 0)
 565                 return 0;
 566         //print("compress: ", vtos(vec), "\n");
 567         ang = vectoangles(vec);
 568         ang_x = -ang_x;
 569         if(ang_x < -90)
 570                 ang_x += 360;
 571         if(ang_x < -90 && ang_x > +90)
 572                 error("BOGUS vectoangles");
 573         //print("angles: ", vtos(ang), "\n");
 574
 575         pitch = floor(0.5 + (ang_x + 90) * 16 / 180) & 15; // -90..90 to 0..14
 576         if(pitch == 0)
 577         {
 578                 if(vec_z < 0)
 579                         yaw = 31;
 580                 else
 581                         yaw = 30;
 582         }
 583         else
 584                 yaw = floor(0.5 + ang_y * 32 / 360)          & 31; // 0..360 to 0..32
 585         len = invertLengthLog(vlen(vec));
 586
 587         //print("compressed: pitch ", ftos(pitch)); print("yaw ", ftos(yaw)); print("len ", ftos(len), "\n");
 588
 589         return (pitch * 0x1000) + (yaw * 0x80) + len;
 590 }
 591
 592 void compressShortVector_init()
 593 {
 594         float l, f, i;
 595         l = 1;
 596         f = pow(2, 1/8);
 597         for(i = 0; i < 128; ++i)
 598         {
 599                 lengthLogTable[i] = l;
 600                 l *= f;
 601         }
 602
 603         if(cvar("developer"))
 604         {
 605                 print("Verifying vector compression table...\n");
 606                 for(i = 0x0F00; i < 0xFFFF; ++i)
 607                         if(i != compressShortVector(decompressShortVector(i)))
 608                         {
 609                                 print("BROKEN vector compression: ", ftos(i));
 610                                 print(" -> ", vtos(decompressShortVector(i)));
 611                                 print(" -> ", ftos(compressShortVector(decompressShortVector(i))));
 612                                 print("\n");
 613                                 error("b0rk");
 614                         }
 615                 print("Done.\n");
 616         }
 617 }
 618
 619 #ifndef MENUQC
 620 float CheckWireframeBox(entity forent, vector v0, vector dvx, vector dvy, vector dvz)
 621 {
 622         traceline(v0, v0 + dvx, TRUE, forent); if(trace_fraction < 1) return 0;
 623         traceline(v0, v0 + dvy, TRUE, forent); if(trace_fraction < 1) return 0;
 624         traceline(v0, v0 + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 625         traceline(v0 + dvx, v0 + dvx + dvy, TRUE, forent); if(trace_fraction < 1) return 0;
 626         traceline(v0 + dvx, v0 + dvx + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 627         traceline(v0 + dvy, v0 + dvy + dvx, TRUE, forent); if(trace_fraction < 1) return 0;
 628         traceline(v0 + dvy, v0 + dvy + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 629         traceline(v0 + dvz, v0 + dvz + dvx, TRUE, forent); if(trace_fraction < 1) return 0;
 630         traceline(v0 + dvz, v0 + dvz + dvy, TRUE, forent); if(trace_fraction < 1) return 0;
 631         traceline(v0 + dvx + dvy, v0 + dvx + dvy + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 632         traceline(v0 + dvx + dvz, v0 + dvx + dvy + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 633         traceline(v0 + dvy + dvz, v0 + dvx + dvy + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 634         return 1;
 635 }
 636
 637 void fixedmakevectors(vector a)
 638 {
 639         // a makevectors that actually inverts vectoangles
 640         a_x = -a_x;
 641         makevectors(a);
 642 }
 643 #endif
 644
 645 string fixPriorityList(string order, float from, float to, float subtract, float complete)
 646 {
 647         string neworder;
 648         float i, n, w;
 649
 650         n = tokenize_console(order);
 651         for(i = 0; i < n; ++i)
 652         {
 653                 w = stof(argv(i));
 654                 if(w == floor(w))
 655                 {
 656                         if(w >= from && w <= to)
 657                                 neworder = strcat(neworder, ftos(w), " ");
 658                         else
 659                         {
 660                                 w -= subtract;
 661                                 if(w >= from && w <= to)
 662                                         neworder = strcat(neworder, ftos(w), " ");
 663                         }
 664                 }
 665         }
 666
 667         if(complete)
 668         {
 669                 n = tokenize_console(neworder);
 670                 for(w = to; w >= from; --w)
 671                 {
 672                         for(i = 0; i < n; ++i)
 673                                 if(stof(argv(i)) == w)
 674                                         break;
 675                         if(i == n) // not found
 676                                 neworder = strcat(neworder, ftos(w), " ");
 677                 }
 678         }
 679
 680         return substring(neworder, 0, strlen(neworder) - 1);
 681 }
 682
 683 string swapInPriorityList(string order, float i, float j)
 684 {
 685         string s;
 686         float w, n;
 687
 688         n = tokenize_console(order);
 689
 690         if(i >= 0 && i < n && j >= 0 && j < n && i != j)
 691         {
 692                 s = "";
 693                 for(w = 0; w < n; ++w)
 694                 {
 695                         if(w == i)
 696                                 s = strcat(s, argv(j), " ");
 697                         else if(w == j)
 698                                 s = strcat(s, argv(i), " ");
 699                         else
 700                                 s = strcat(s, argv(w), " ");
 701                 }
 702                 return substring(s, 0, strlen(s) - 1);
 703         }
 704
 705         return order;
 706 }
 707
 708 float cvar_value_issafe(string s)
 709 {
 710         if(strstrofs(s, "\"", 0) >= 0)
 711                 return 0;
 712         if(strstrofs(s, "\\", 0) >= 0)
 713                 return 0;
 714         if(strstrofs(s, ";", 0) >= 0)
 715                 return 0;
 716         if(strstrofs(s, "$", 0) >= 0)
 717                 return 0;
 718         if(strstrofs(s, "\r", 0) >= 0)
 719                 return 0;
 720         if(strstrofs(s, "\n", 0) >= 0)
 721                 return 0;
 722         return 1;
 723 }
 724
 725 #ifndef MENUQC
 726 void get_mi_min_max(float mode)
 727 {
 728         vector mi, ma;
 729
 730         if(mi_shortname)
 731                 strunzone(mi_shortname);
 732         mi_shortname = mapname;
 733         if(!strcasecmp(substring(mi_shortname, 0, 5), "maps/"))
 734                 mi_shortname = substring(mi_shortname, 5, strlen(mi_shortname) - 5);
 735         if(!strcasecmp(substring(mi_shortname, strlen(mi_shortname) - 4, 4), ".bsp"))
 736                 mi_shortname = substring(mi_shortname, 0, strlen(mi_shortname) - 4);
 737         mi_shortname = strzone(mi_shortname);
 738
 739 #ifdef CSQC
 740         mi = world.mins;
 741         ma = world.maxs;
 742 #else
 743         mi = world.absmin;
 744         ma = world.absmax;
 745 #endif
 746
 747         mi_min = mi;
 748         mi_max = ma;
 749         MapInfo_Get_ByName(mi_shortname, 0, 0);
 750         if(MapInfo_Map_mins_x < MapInfo_Map_maxs_x)
 751         {
 752                 mi_min = MapInfo_Map_mins;
 753                 mi_max = MapInfo_Map_maxs;
 754         }
 755         else
 756         {
 757                 // not specified
 758                 if(mode)
 759                 {
 760                         // be clever
 761                         tracebox('1 0 0' * mi_x,
 762                                          '0 1 0' * mi_y + '0 0 1' * mi_z,
 763                                          '0 1 0' * ma_y + '0 0 1' * ma_z,
 764                                          '1 0 0' * ma_x,
 765                                          MOVE_WORLDONLY,
 766                                          world);
 767                         if(!trace_startsolid)
 768                                 mi_min_x = trace_endpos_x;
 769
 770                         tracebox('0 1 0' * mi_y,
 771                                          '1 0 0' * mi_x + '0 0 1' * mi_z,
 772                                          '1 0 0' * ma_x + '0 0 1' * ma_z,
 773                                          '0 1 0' * ma_y,
 774                                          MOVE_WORLDONLY,
 775                                          world);
 776                         if(!trace_startsolid)
 777                                 mi_min_y = trace_endpos_y;
 778
 779                         tracebox('0 0 1' * mi_z,
 780                                          '1 0 0' * mi_x + '0 1 0' * mi_y,
 781                                          '1 0 0' * ma_x + '0 1 0' * ma_y,
 782                                          '0 0 1' * ma_z,
 783                                          MOVE_WORLDONLY,
 784                                          world);
 785                         if(!trace_startsolid)
 786                                 mi_min_z = trace_endpos_z;
 787
 788                         tracebox('1 0 0' * ma_x,
 789                                          '0 1 0' * mi_y + '0 0 1' * mi_z,
 790                                          '0 1 0' * ma_y + '0 0 1' * ma_z,
 791                                          '1 0 0' * mi_x,
 792                                          MOVE_WORLDONLY,
 793                                          world);
 794                         if(!trace_startsolid)
 795                                 mi_max_x = trace_endpos_x;
 796
 797                         tracebox('0 1 0' * ma_y,
 798                                          '1 0 0' * mi_x + '0 0 1' * mi_z,
 799                                          '1 0 0' * ma_x + '0 0 1' * ma_z,
 800                                          '0 1 0' * mi_y,
 801                                          MOVE_WORLDONLY,
 802                                          world);
 803                         if(!trace_startsolid)
 804                                 mi_max_y = trace_endpos_y;
 805
 806                         tracebox('0 0 1' * ma_z,
 807                                          '1 0 0' * mi_x + '0 1 0' * mi_y,
 808                                          '1 0 0' * ma_x + '0 1 0' * ma_y,
 809                                          '0 0 1' * mi_z,
 810                                          MOVE_WORLDONLY,
 811                                          world);
 812                         if(!trace_startsolid)
 813                                 mi_max_z = trace_endpos_z;
 814                 }
 815         }
 816 }
 817
 818 void get_mi_min_max_texcoords(float mode)
 819 {
 820         vector extend;
 821
 822         get_mi_min_max(mode);
 823
 824         mi_picmin = mi_min;
 825         mi_picmax = mi_max;
 826
 827         // extend mi_picmax to get a square aspect ratio
 828         // center the map in that area
 829         extend = mi_picmax - mi_picmin;
 830         if(extend_y > extend_x)
 831         {
 832                 mi_picmin_x -= (extend_y - extend_x) * 0.5;
 833                 mi_picmax_x += (extend_y - extend_x) * 0.5;
 834         }
 835         else
 836         {
 837                 mi_picmin_y -= (extend_x - extend_y) * 0.5;
 838                 mi_picmax_y += (extend_x - extend_y) * 0.5;
 839         }
 840
 841         // add another some percent
 842         extend = (mi_picmax - mi_picmin) * (1 / 64.0);
 843         mi_picmin -= extend;
 844         mi_picmax += extend;
 845
 846         // calculate the texcoords
 847         mi_pictexcoord0 = mi_pictexcoord1 = mi_pictexcoord2 = mi_pictexcoord3 = '0 0 0';
 848         // first the two corners of the origin
 849         mi_pictexcoord0_x = (mi_min_x - mi_picmin_x) / (mi_picmax_x - mi_picmin_x);
 850         mi_pictexcoord0_y = (mi_min_y - mi_picmin_y) / (mi_picmax_y - mi_picmin_y);
 851         mi_pictexcoord2_x = (mi_max_x - mi_picmin_x) / (mi_picmax_x - mi_picmin_x);
 852         mi_pictexcoord2_y = (mi_max_y - mi_picmin_y) / (mi_picmax_y - mi_picmin_y);
 853         // then the other corners
 854         mi_pictexcoord1_x = mi_pictexcoord0_x;
 855         mi_pictexcoord1_y = mi_pictexcoord2_y;
 856         mi_pictexcoord3_x = mi_pictexcoord2_x;
 857         mi_pictexcoord3_y = mi_pictexcoord0_y;
 858 }
 859 #endif
 860
 861 #ifdef CSQC
 862 void cvar_settemp(string pKey, string pValue)
 863 {
 864         error("cvar_settemp called from CSQC - use cvar_clientsettemp instead!");
 865 }
 866 void cvar_settemp_restore()
 867 {
 868         error("cvar_settemp_restore called from CSQC - use cvar_clientsettemp instead!");
 869 }
 870 #else
 871 void cvar_settemp(string pKey, string pValue)
 872 {
 873         cvar_set("settemp_list", strcat("1 ", pKey, " ", cvar_string("settemp_var"), " ", cvar_string("settemp_list")));
 874 #ifdef MENUQC
 875         registercvar(cvar_string("settemp_var"), "", 0);
 876 #else
 877         registercvar(cvar_string("settemp_var"), "");
 878 #endif
 879         cvar_set(cvar_string("settemp_var"), cvar_string(pKey));
 880         cvar_set("settemp_var", strcat(cvar_string("settemp_var"), "x"));
 881         cvar_set(pKey, pValue);
 882 }
 883
 884 void cvar_settemp_restore()
 885 {
 886         // undo what cvar_settemp did
 887         float n, i;
 888         n = tokenize_console(cvar_string("settemp_list"));
 889         for(i = 0; i < n - 3; i += 3)
 890                 cvar_set(argv(i + 1), cvar_string(argv(i + 2)));
 891         cvar_set("settemp_list", "0");
 892 }
 893 #endif
 894
 895 float almost_equals(float a, float b)
 896 {
 897         float eps;
 898         eps = (max(a, -a) + max(b, -b)) * 0.001;
 899         if(a - b < eps && b - a < eps)
 900                 return TRUE;
 901         return FALSE;
 902 }
 903
 904 float almost_in_bounds(float a, float b, float c)
 905 {
 906         float eps;
 907         eps = (max(a, -a) + max(c, -c)) * 0.001;
 908         return b == median(a - eps, b, c + eps);
 909 }
 910
 911 float power2of(float e)
 912 {
 913         return pow(2, e);
 914 }
 915 float log2of(float x)
 916 {
 917         // NOTE: generated code
 918         if(x > 2048)
 919                 if(x > 131072)
 920                         if(x > 1048576)
 921                                 if(x > 4194304)
 922                                         return 23;
 923                                 else
 924                                         if(x > 2097152)
 925                                                 return 22;
 926                                         else
 927                                                 return 21;
 928                         else
 929                                 if(x > 524288)
 930                                         return 20;
 931                                 else
 932                                         if(x > 262144)
 933                                                 return 19;
 934                                         else
 935                                                 return 18;
 936                 else
 937                         if(x > 16384)
 938                                 if(x > 65536)
 939                                         return 17;
 940                                 else
 941                                         if(x > 32768)
 942                                                 return 16;
 943                                         else
 944                                                 return 15;
 945                         else
 946                                 if(x > 8192)
 947                                         return 14;
 948                                 else
 949                                         if(x > 4096)
 950                                                 return 13;
 951                                         else
 952                                                 return 12;
 953         else
 954                 if(x > 32)
 955                         if(x > 256)
 956                                 if(x > 1024)
 957                                         return 11;
 958                                 else
 959                                         if(x > 512)
 960                                                 return 10;
 961                                         else
 962                                                 return 9;
 963                         else
 964                                 if(x > 128)
 965                                         return 8;
 966                                 else
 967                                         if(x > 64)
 968                                                 return 7;
 969                                         else
 970                                                 return 6;
 971                 else
 972                         if(x > 4)
 973                                 if(x > 16)
 974                                         return 5;
 975                                 else
 976                                         if(x > 8)
 977                                                 return 4;
 978                                         else
 979                                                 return 3;
 980                         else
 981                                 if(x > 2)
 982                                         return 2;
 983                                 else
 984                                         if(x > 1)
 985                                                 return 1;
 986                                         else
 987                                                 return 0;
 988 }
 989
 990 float rgb_mi_ma_to_hue(vector rgb, float mi, float ma)
 991 {
 992         if(mi == ma)
 993                 return 0;
 994         else if(ma == rgb_x)
 995         {
 996                 if(rgb_y >= rgb_z)
 997                         return (rgb_y - rgb_z) / (ma - mi);
 998                 else
 999                         return (rgb_y - rgb_z) / (ma - mi) + 6;
1000         }
1001         else if(ma == rgb_y)
1002                 return (rgb_z - rgb_x) / (ma - mi) + 2;
1003         else // if(ma == rgb_z)
1004                 return (rgb_x - rgb_y) / (ma - mi) + 4;
1005 }
1006
1007 vector hue_mi_ma_to_rgb(float hue, float mi, float ma)
1008 {
1009         vector rgb;
1010
1011         hue -= 6 * floor(hue / 6);
1012
1013         //else if(ma == rgb_x)
1014         //      hue = 60 * (rgb_y - rgb_z) / (ma - mi);
1015         if(hue <= 1)
1016         {
1017                 rgb_x = ma;
1018                 rgb_y = hue * (ma - mi) + mi;
1019                 rgb_z = mi;
1020         }
1021         //else if(ma == rgb_y)
1022         //      hue = 60 * (rgb_z - rgb_x) / (ma - mi) + 120;
1023         else if(hue <= 2)
1024         {
1025                 rgb_x = (2 - hue) * (ma - mi) + mi;
1026                 rgb_y = ma;
1027                 rgb_z = mi;
1028         }
1029         else if(hue <= 3)
1030         {
1031                 rgb_x = mi;
1032                 rgb_y = ma;
1033                 rgb_z = (hue - 2) * (ma - mi) + mi;
1034         }
1035         //else // if(ma == rgb_z)
1036         //      hue = 60 * (rgb_x - rgb_y) / (ma - mi) + 240;
1037         else if(hue <= 4)
1038         {
1039                 rgb_x = mi;
1040                 rgb_y = (4 - hue) * (ma - mi) + mi;
1041                 rgb_z = ma;
1042         }
1043         else if(hue <= 5)
1044         {
1045                 rgb_x = (hue - 4) * (ma - mi) + mi;
1046                 rgb_y = mi;
1047                 rgb_z = ma;
1048         }
1049         //else if(ma == rgb_x)
1050         //      hue = 60 * (rgb_y - rgb_z) / (ma - mi);
1051         else // if(hue <= 6)
1052         {
1053                 rgb_x = ma;
1054                 rgb_y = mi;
1055                 rgb_z = (6 - hue) * (ma - mi) + mi;
1056         }
1057
1058         return rgb;
1059 }
1060
1061 vector rgb_to_hsv(vector rgb)
1062 {
1063         float mi, ma;
1064         vector hsv;
1065
1066         mi = min3(rgb_x, rgb_y, rgb_z);
1067         ma = max3(rgb_x, rgb_y, rgb_z);
1068
1069         hsv_x = rgb_mi_ma_to_hue(rgb, mi, ma);
1070         hsv_z = ma;
1071
1072         if(ma == 0)
1073                 hsv_y = 0;
1074         else
1075                 hsv_y = 1 - mi/ma;
1076
1077         return hsv;
1078 }
1079
1080 vector hsv_to_rgb(vector hsv)
1081 {
1082         return hue_mi_ma_to_rgb(hsv_x, hsv_z * (1 - hsv_y), hsv_z);
1083 }
1084
1085 vector rgb_to_hsl(vector rgb)
1086 {
1087         float mi, ma;
1088         vector hsl;
1089
1090         mi = min3(rgb_x, rgb_y, rgb_z);
1091         ma = max3(rgb_x, rgb_y, rgb_z);
1092
1093         hsl_x = rgb_mi_ma_to_hue(rgb, mi, ma);
1094
1095         hsl_z = 0.5 * (mi + ma);
1096         if(mi == ma)
1097                 hsl_y = 0;
1098         else if(hsl_z <= 0.5)
1099                 hsl_y = (ma - mi) / (2*hsl_z);
1100         else // if(hsl_z > 0.5)
1101                 hsl_y = (ma - mi) / (2 - 2*hsl_z);
1102
1103         return hsl;
1104 }
1105
1106 vector hsl_to_rgb(vector hsl)
1107 {
1108         float mi, ma, maminusmi;
1109
1110         if(hsl_z <= 0.5)
1111                 maminusmi = hsl_y * 2 * hsl_z;
1112         else
1113                 maminusmi = hsl_y * (2 - 2 * hsl_z);
1114
1115         // hsl_z     = 0.5 * mi + 0.5 * ma
1116         // maminusmi =     - mi +       ma
1117         mi = hsl_z - 0.5 * maminusmi;
1118         ma = hsl_z + 0.5 * maminusmi;
1119
1120         return hue_mi_ma_to_rgb(hsl_x, mi, ma);
1121 }
1122
1123 string rgb_to_hexcolor(vector rgb)
1124 {
1125         return
1126                 strcat(
1127                         "^x",
1128                         DEC_TO_HEXDIGIT(floor(rgb_x * 15 + 0.5)),
1129                         DEC_TO_HEXDIGIT(floor(rgb_y * 15 + 0.5)),
1130                         DEC_TO_HEXDIGIT(floor(rgb_z * 15 + 0.5))
1131                 );
1132 }
1133
1134 // requires that m2>m1 in all coordinates, and that m4>m3
1135 float boxesoverlap(vector m1, vector m2, vector m3, vector m4) {return m2_x >= m3_x && m1_x <= m4_x && m2_y >= m3_y && m1_y <= m4_y && m2_z >= m3_z && m1_z <= m4_z;};
1136
1137 // requires the same, but is a stronger condition
1138 float boxinsidebox(vector smins, vector smaxs, vector bmins, vector bmaxs) {return smins_x >= bmins_x && smaxs_x <= bmaxs_x && smins_y >= bmins_y && smaxs_y <= bmaxs_y && smins_z >= bmins_z && smaxs_z <= bmaxs_z;};
1139
1140 #ifndef MENUQC
1141 // angles transforms
1142 // angles in fixedmakevectors/fixedvectoangles space
1143 vector AnglesTransform_Apply(vector transform, vector v)
1144 {
1145         fixedmakevectors(transform);
1146         return v_forward * v_x
1147              + v_right   * (-v_y)
1148                  + v_up      * v_z;
1149 }
1150
1151 vector AnglesTransform_Multiply(vector t1, vector t2)
1152 {
1153         vector m_forward, m_up;
1154         fixedmakevectors(t2); m_forward = v_forward; m_up = v_up;
1155         m_forward = AnglesTransform_Apply(t1, m_forward); m_up = AnglesTransform_Apply(t1, m_up);
1156         return fixedvectoangles2(m_forward, m_up);
1157 }
1158
1159 vector AnglesTransform_Invert(vector transform)
1160 {
1161         vector i_forward, i_up;
1162         fixedmakevectors(transform);
1163         // we want angles that turn v_forward into '1 0 0', v_right into '0 1 0' and v_up into '0 0 1'
1164         // but these are orthogonal unit vectors!
1165         // so to invert, we can simply fixedvectoangles the TRANSPOSED matrix
1166         // TODO is this always -transform?
1167         i_forward_x = v_forward_x;
1168         i_forward_y = -v_right_x;
1169         i_forward_z = v_up_x;
1170         i_up_x = v_forward_z;
1171         i_up_y = -v_right_z;
1172         i_up_z = v_up_z;
1173         return fixedvectoangles2(i_forward, i_up);
1174 }
1175
1176 vector AnglesTransform_TurnDirection(vector transform)
1177 {
1178         // turn 180 degrees around v_up
1179         // changes in-direction to out-direction
1180         fixedmakevectors(transform);
1181         return fixedvectoangles2(-1 * v_forward, 1 * v_up);
1182 }
1183
1184 vector AnglesTransform_Divide(vector to_transform, vector from_transform)
1185 {
1186         return AnglesTransform_Multiply(to_transform, AnglesTransform_Invert(from_transform));
1187 }
1188 #endif
1189
1190 float textLengthUpToWidth(string theText, float maxWidth, textLengthUpToWidth_widthFunction_t w)
1191 {
1192         float ICanHasKallerz;
1193
1194         // detect color codes support in the width function
1195         ICanHasKallerz = (w("^7") == 0);
1196
1197         // STOP.
1198         // The following function is SLOW.
1199         // For your safety and for the protection of those around you...
1200         // DO NOT CALL THIS AT HOME.
1201         // No really, don't.
1202         if(w(theText) <= maxWidth)
1203                 return strlen(theText); // yeah!
1204
1205         // binary search for right place to cut string
1206         float ch;
1207         float left, right, middle; // this always works
1208         left = 0;
1209         right = strlen(theText); // this always fails
1210         do
1211         {
1212                 middle = floor((left + right) / 2);
1213                 if(w(substring(theText, 0, middle)) <= maxWidth)
1214                         left = middle;
1215                 else
1216                         right = middle;
1217         }
1218         while(left < right - 1);
1219
1220         if(ICanHasKallerz)
1221         {
1222                 // NOTE: when color codes are involved, this binary search is,
1223                 // mathematically, BROKEN. However, it is obviously guaranteed to
1224                 // terminate, as the range still halves each time - but nevertheless, it is
1225                 // guaranteed that it finds ONE valid cutoff place (where "left" is in
1226                 // range, and "right" is outside).
1227
1228                 // terencehill: the following code detects truncated ^xrgb tags (e.g. ^x or ^x4)
1229                 // and decrease left on the basis of the chars detected of the truncated tag
1230                 // Even if the ^xrgb tag is not complete/correct, left is decreased
1231                 // (sometimes too much but with a correct result)
1232                 // it fixes also ^[0-9]
1233                 while(left >= 1 && substring(theText, left-1, 1) == "^")
1234                         left-=1;
1235
1236                 if (left >= 2 && substring(theText, left-2, 2) == "^x") // ^x/
1237                         left-=2;
1238                 else if (left >= 3 && substring(theText, left-3, 2) == "^x")
1239                         {
1240                                 ch = str2chr(theText, left-1);
1241                                 if( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') ) // ^xr/
1242                                         left-=3;
1243                         }
1244                 else if (left >= 4 && substring(theText, left-4, 2) == "^x")
1245                         {
1246                                 ch = str2chr(theText, left-2);
1247                                 if ( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') )
1248                                 {
1249                                         ch = str2chr(theText, left-1);
1250                                         if ( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') ) // ^xrg/
1251                                                 left-=4;
1252                                 }
1253                         }
1254         }
1255
1256         return left;
1257 }
1258
1259 string getWrappedLine(float w, textLengthUpToWidth_widthFunction_t tw)
1260 {
1261         float cantake;
1262         float take;
1263         string s;
1264
1265         s = getWrappedLine_remaining;
1266
1267         cantake = textLengthUpToWidth(s, w, tw);
1268         if(cantake > 0 && cantake < strlen(s))
1269         {
1270                 take = cantake - 1;
1271                 while(take > 0 && substring(s, take, 1) != " ")
1272                         --take;
1273                 if(take == 0)
1274                 {
1275                         getWrappedLine_remaining = substring(s, cantake, strlen(s) - cantake);
1276                         if(getWrappedLine_remaining == "")
1277                                 getWrappedLine_remaining = string_null;
1278                         return substring(s, 0, cantake);
1279                 }
1280                 else
1281                 {
1282                         getWrappedLine_remaining = substring(s, take + 1, strlen(s) - take);
1283                         if(getWrappedLine_remaining == "")
1284                                 getWrappedLine_remaining = string_null;
1285                         return substring(s, 0, take);
1286                 }
1287         }
1288         else
1289         {
1290                 getWrappedLine_remaining = string_null;
1291                 return s;
1292         }
1293 }
1294
1295 string textShortenToWidth(string theText, float maxWidth, textLengthUpToWidth_widthFunction_t tw)
1296 {
1297         if(tw(theText) <= maxWidth)
1298                 return theText;
1299         else
1300                 return strcat(substring(theText, 0, textLengthUpToWidth(theText, maxWidth - tw("..."), tw)), "...");
1301 }
1302
1303 float isGametypeInFilter(float gt, float tp, string pattern)
1304 {
1305         string subpattern, subpattern2;
1306         subpattern = strcat(",", GametypeNameFromType(gt), ",");
1307         if(tp)
1308                 subpattern2 = ",teams,";
1309         else
1310                 subpattern2 = ",noteams,";
1311
1312         if(substring(pattern, 0, 1) == "-")
1313         {
1314                 pattern = substring(pattern, 1, strlen(pattern) - 1);
1315                 if(strstrofs(strcat(",", pattern, ","), subpattern, 0) >= 0)
1316                         return 0;
1317                 if(strstrofs(strcat(",", pattern, ","), subpattern2, 0) >= 0)
1318                         return 0;
1319         }
1320         else
1321         {
1322                 if(substring(pattern, 0, 1) == "+")
1323                         pattern = substring(pattern, 1, strlen(pattern) - 1);
1324                 if(strstrofs(strcat(",", pattern, ","), subpattern, 0) < 0)
1325                 if(strstrofs(strcat(",", pattern, ","), subpattern2, 0) < 0)
1326                         return 0;
1327         }
1328         return 1;
1329 }
1330
1331 void shuffle(float n, swapfunc_t swap, entity pass)
1332 {
1333         float i, j;
1334         for(i = 1; i < n; ++i)
1335         {
1336                 // swap i-th item at a random position from 0 to i
1337                 // proof for even distribution:
1338                 //   n = 1: obvious
1339                 //   n -> n+1:
1340                 //     item n+1 gets at any position with chance 1/(n+1)
1341                 //     all others will get their 1/n chance reduced by factor n/(n+1)
1342                 //     to be on place n+1, their chance will be 1/(n+1)
1343                 //     1/n * n/(n+1) = 1/(n+1)
1344                 //     q.e.d.
1345                 j = floor(random() * (i + 1));
1346                 if(j != i)
1347                         swap(j, i, pass);
1348         }
1349 }
1350
1351 string substring_range(string s, float b, float e)
1352 {
1353         return substring(s, b, e - b);
1354 }
1355
1356 string swapwords(string str, float i, float j)
1357 {
1358         float n;
1359         string s1, s2, s3, s4, s5;
1360         float si, ei, sj, ej, s0, en;
1361         n = tokenizebyseparator(str, " "); // must match g_maplist processing in ShuffleMaplist and "shuffle"
1362         si = argv_start_index(i);
1363         sj = argv_start_index(j);
1364         ei = argv_end_index(i);
1365         ej = argv_end_index(j);
1366         s0 = argv_start_index(0);
1367         en = argv_end_index(n-1);
1368         s1 = substring_range(str, s0, si);
1369         s2 = substring_range(str, si, ei);
1370         s3 = substring_range(str, ei, sj);
1371         s4 = substring_range(str, sj, ej);
1372         s5 = substring_range(str, ej, en);
1373         return strcat(s1, s4, s3, s2, s5);
1374 }
1375
1376 string _shufflewords_str;
1377 void _shufflewords_swapfunc(float i, float j, entity pass)
1378 {
1379         _shufflewords_str = swapwords(_shufflewords_str, i, j);
1380 }
1381 string shufflewords(string str)
1382 {
1383         float n;
1384         _shufflewords_str = str;
1385         n = tokenizebyseparator(str, " ");
1386         shuffle(n, _shufflewords_swapfunc, world);
1387         str = _shufflewords_str;
1388         _shufflewords_str = string_null;
1389         return str;
1390 }
1391
1392 vector solve_quadratic(float a, float b, float c) // ax^2 + bx + c = 0
1393 {
1394         vector v;
1395         float D;
1396         v = '0 0 0';
1397         if(a == 0)
1398         {
1399                 if(b != 0)
1400                 {
1401                         v_x = v_y = -c / b;
1402                         v_z = 1;
1403                 }
1404                 else
1405                 {
1406                         if(c == 0)
1407                         {
1408                                 // actually, every number solves the equation!
1409                                 v_z = 1;
1410                         }
1411                 }
1412         }
1413         else
1414         {
1415                 D = b*b - 4*a*c;
1416                 if(D >= 0)
1417                 {
1418                         D = sqrt(D);
1419                         if(a > 0) // put the smaller solution first
1420                         {
1421                                 v_x = ((-b)-D) / (2*a);
1422                                 v_y = ((-b)+D) / (2*a);
1423                         }
1424                         else
1425                         {
1426                                 v_x = (-b+D) / (2*a);
1427                                 v_y = (-b-D) / (2*a);
1428                         }
1429                         v_z = 1;
1430                 }
1431                 else
1432                 {
1433                         // complex solutions!
1434                         D = sqrt(-D);
1435                         v_x = -b / (2*a);
1436                         if(a > 0)
1437                                 v_y =  D / (2*a);
1438                         else
1439                                 v_y = -D / (2*a);
1440                         v_z = 0;
1441                 }
1442         }
1443         return v;
1444 }
1445
1446
1447 float _unacceptable_compiler_bug_1_a(float b, float c) { return b == c; }
1448 float _unacceptable_compiler_bug_1_b() { return 1; }
1449 float _unacceptable_compiler_bug_1_c(float d) { return 2 * d; }
1450 float _unacceptable_compiler_bug_1_d() { return 1; }
1451
1452 void check_unacceptable_compiler_bugs()
1453 {
1454         if(cvar("_allow_unacceptable_compiler_bugs"))
1455                 return;
1456         tokenize_console("foo bar");
1457         if(strcat(argv(0), substring("foo bar", 4, 7 - argv_start_index(1))) == "barbar")
1458                 error("fteqcc bug introduced with revision 3178 detected. Please upgrade fteqcc to a later revision, downgrade fteqcc to revision 3177, or pester Spike until he fixes it. You can set _allow_unacceptable_compiler_bugs 1 to skip this check, but expect stuff to be horribly broken then.");
1459 }
1460
1461 float compressShotOrigin(vector v)
1462 {
1463         float x, y, z;
1464         x = rint(v_x * 2);
1465         y = rint(v_y * 4) + 128;
1466         z = rint(v_z * 4) + 128;
1467         if(x > 255 || x < 0)
1468                 error("shot origin x out of bounds");
1469         if(y > 255 || y < 0)
1470                 error("shot origin y out of bounds");
1471         if(z > 255 || z < 0)
1472                 error("shot origin z out of bounds");
1473         return x * 0x10000 + y * 0x100 + z;
1474 }
1475 vector decompressShotOrigin(float f)
1476 {
1477         vector v;
1478         v_x = ((f & 0xFF0000) / 0x10000) / 2;
1479         v_y = ((f & 0xFF00) / 0x100 - 128) / 4;
1480         v_z = ((f & 0xFF) - 128) / 4;
1481         return v;
1482 }
1483
1484 void heapsort(float n, swapfunc_t swap, comparefunc_t cmp, entity pass)
1485 {
1486         float start, end, root, child;
1487
1488         // heapify
1489         start = floor((n - 2) / 2);
1490         while(start >= 0)
1491         {
1492                 // siftdown(start, count-1);
1493                 root = start;
1494                 while(root * 2 + 1 <= n-1)
1495                 {
1496                         child = root * 2 + 1;
1497                         if(child < n-1)
1498                                 if(cmp(child, child+1, pass) < 0)
1499                                         ++child;
1500                         if(cmp(root, child, pass) < 0)
1501                         {
1502                                 swap(root, child, pass);
1503                                 root = child;
1504                         }
1505                         else
1506                                 break;
1507                 }
1508                 // end of siftdown
1509                 --start;
1510         }
1511
1512         // extract
1513         end = n - 1;
1514         while(end > 0)
1515         {
1516                 swap(0, end, pass);
1517                 --end;
1518                 // siftdown(0, end);
1519                 root = 0;
1520                 while(root * 2 + 1 <= end)
1521                 {
1522                         child = root * 2 + 1;
1523                         if(child < end && cmp(child, child+1, pass) < 0)
1524                                 ++child;
1525                         if(cmp(root, child, pass) < 0)
1526                         {
1527                                 swap(root, child, pass);
1528                                 root = child;
1529                         }
1530                         else
1531                                 break;
1532                 }
1533                 // end of siftdown
1534         }
1535 }
1536
1537 void RandomSelection_Init()
1538 {
1539         RandomSelection_totalweight = 0;
1540         RandomSelection_chosen_ent = world;
1541         RandomSelection_chosen_float = 0;
1542         RandomSelection_chosen_string = string_null;
1543         RandomSelection_best_priority = -1;
1544 }
1545 void RandomSelection_Add(entity e, float f, string s, float weight, float priority)
1546 {
1547         if(priority > RandomSelection_best_priority)
1548         {
1549                 RandomSelection_best_priority = priority;
1550                 RandomSelection_chosen_ent = e;
1551                 RandomSelection_chosen_float = f;
1552                 RandomSelection_chosen_string = s;
1553                 RandomSelection_totalweight = weight;
1554         }
1555         else if(priority == RandomSelection_best_priority)
1556         {
1557                 RandomSelection_totalweight += weight;
1558                 if(random() * RandomSelection_totalweight <= weight)
1559                 {
1560                         RandomSelection_chosen_ent = e;
1561                         RandomSelection_chosen_float = f;
1562                         RandomSelection_chosen_string = s;
1563                 }
1564         }
1565 }
1566