data/qcsrc/common/mapinfo.qc

   1 #ifdef HSOI
   2 // HUGE SET - stored in a string
   3 string HugeSetOfIntegers_empty()
   4 {
   5         return "";
   6 }
   7 float HugeSetOfIntegers_get(string pArr, float i)
   8 {
   9         return stof(substring(pArr, i * 4, 4));
  10 }
  11 float HugeSetOfIntegers_length(string pArr)
  12 {
  13         return strlen(pArr) / 4;
  14 }
  15 string HugeSetOfIntegers_concat(string a1, string a2)
  16 {
  17         return strcat(a1, a2);
  18 }
  19 string HugeSetOfIntegers_insert(string a1, float n, string a2)
  20         // special concat function to build up large lists in less time by binary concatenation
  21 {
  22         string s;
  23         s = strcat("    ", ftos(n));
  24         return strcat(a1, substring(s, strlen(s) - 4, 4), a2);
  25 }
  26 #endif
  27
  28 // generic string stuff
  29 float startsWith(string haystack, string needle)
  30 {
  31         return substring(haystack, 0, strlen(needle)) == needle;
  32 }
  33 float startsWithNocase(string haystack, string needle)
  34 {
  35         return strcasecmp(substring(haystack, 0, strlen(needle)), needle) == 0;
  36 }
  37 string extractRestOfLine(string haystack, string needle)
  38 {
  39         if(startsWith(haystack, needle))
  40                 return substring(haystack, strlen(needle), strlen(haystack) - strlen(needle));
  41         return string_null;
  42 }
  43 string car(string s)
  44 {
  45         float o;
  46         o = strstrofs(s, " ", 0);
  47         if(o < 0)
  48                 return s;
  49         return substring(s, 0, o);
  50 }
  51 string cdr(string s)
  52 {
  53         float o;
  54         o = strstrofs(s, " ", 0);
  55         if(o < 0)
  56                 return string_null;
  57         return substring(s, o + 1, strlen(s) - (o + 1));
  58 }
  59
  60 float _MapInfo_Cache_Active;
  61 float _MapInfo_Cache_DB_NameToIndex;
  62 float _MapInfo_Cache_Buf_IndexToMapData;
  63
  64 void MapInfo_Cache_Destroy()
  65 {
  66         if(!_MapInfo_Cache_Active)
  67                 return;
  68
  69         db_close(_MapInfo_Cache_DB_NameToIndex);
  70         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
  71         _MapInfo_Cache_Active = 0;
  72 }
  73
  74 void MapInfo_Cache_Create()
  75 {
  76         MapInfo_Cache_Destroy();
  77         _MapInfo_Cache_DB_NameToIndex = db_create();
  78         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
  79         _MapInfo_Cache_Active = 1;
  80 }
  81
  82 void MapInfo_Cache_Invalidate()
  83 {
  84         if(!_MapInfo_Cache_Active)
  85                 return;
  86
  87         MapInfo_Cache_Create();
  88 }
  89
  90 void MapInfo_Cache_Store()
  91 {
  92         float i;
  93         string s;
  94         if(!_MapInfo_Cache_Active)
  95                 return;
  96
  97         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
  98         if(!s) // empty string is NOT valid here!
  99         {
 100                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
 101                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
 102         }
 103         else
 104                 i = stof(s);
 105
 106         // now store all the stuff
 107         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
 108         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
 109         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
 110         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
 111         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
 112         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
 113         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_flags));
 114 }
 115
 116 float MapInfo_Cache_Retrieve(string map)
 117 {
 118         float i;
 119         string s;
 120         if(!_MapInfo_Cache_Active)
 121                 return 0;
 122
 123         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
 124         if(!s)
 125                 return 0;
 126         i = stof(s);
 127
 128         // now retrieve all the stuff
 129         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
 130         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
 131         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
 132         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
 133         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
 134         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
 135         MapInfo_Map_flags = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
 136         return 1;
 137 }
 138
 139 // GLOB HANDLING (for all BSP files)
 140 float _MapInfo_globopen;
 141 float _MapInfo_globcount;
 142 float _MapInfo_globhandle;
 143 string _MapInfo_GlobItem(float i)
 144 {
 145         string s;
 146         s = search_getfilename(_MapInfo_globhandle, i);
 147         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
 148 }
 149
 150 void MapInfo_Enumerate()
 151 {
 152         if(_MapInfo_globopen)
 153                 search_end(_MapInfo_globhandle);
 154         MapInfo_Cache_Invalidate();
 155         _MapInfo_globhandle = search_begin("maps/*.bsp", TRUE, TRUE);
 156         _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
 157         _MapInfo_globopen = 1;
 158 }
 159
 160 // filter the info by game type mask (updates MapInfo_count)
 161 //
 162 #ifdef HSOI
 163 string _MapInfo_filtered;
 164 float MapInfo_FilterList_Lookup(float i)
 165 {
 166         return MapInfo_FilterList_Lookup(i);
 167 }
 168
 169 string MapInfo_FilterGametype_Recursive(float pGametype, float pFeatures, float pFlagsRequired, float pFlagsForbidden, float pBegin, float pEnd, float pAbortOnGenerate)
 170 {
 171         float m, valid;
 172         string l, r;
 173
 174         if(pBegin == pEnd)
 175                 return HugeSetOfIntegers_empty();
 176
 177         m = floor((pBegin + pEnd) / 2);
 178
 179         l = MapInfo_FilterGametype_Recursive(pGametype, pFeatures, pBegin, m, pAbortOnGenerate);
 180         if not(l)
 181                 return string_null; // BAIL OUT
 182         if(MapInfo_Get_ByName(_MapInfo_GlobItem(m), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 183                 if(pAbortOnGenerate)
 184                 {
 185                         MapInfo_progress = m / _MapInfo_globcount;
 186                         return string_null; // BAIL OUT
 187                 }
 188         valid = (((MapInfo_Map_supportedGametypes & pGametype) != 0);
 189         valid = valid && ((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures));
 190         valid = valid && (MapInfo_Map_flags & pFlagsForbidden == 0);
 191         valid = valid && (MapInfo_Map_flags & pFlagsRequired == pFlagsRequired);
 192         r = MapInfo_FilterGametype_Recursive(pGametype, pFeatures, pFlagsRequired, pFlagsForbidden, m + 1, pEnd, pAbortOnGenerate);
 193         if not(r)
 194                 return string_null; // BAIL OUT
 195
 196         if(valid)
 197                 return HugeSetOfIntegers_insert(l, m, r);
 198         else
 199                 return HugeSetOfIntegers_concat(l, r);
 200 }
 201
 202 float MapInfo_FilterGametype(float pGametype, float pFeatures, pFlagsRequired, pFlagsForbidden, float pAbortOnGenerate)
 203 {
 204         if(_MapInfo_filtered)
 205                 strunzone(_MapInfo_filtered);
 206         _MapInfo_filtered = MapInfo_FilterGametype_Recursive(pGametype, pFeatures, pFlagsRequired, pFlagsForbidden, 0, _MapInfo_globcount, pAbortOnGenerate);
 207         if not(_MapInfo_filtered)
 208         {
 209                 dprint("Autogenerated a .mapinfo, doing the rest later.\n");
 210                 return 0;
 211         }
 212         _MapInfo_filtered = strzone(_MapInfo_filtered);
 213         MapInfo_count = HugeSetOfIntegers_length(_MapInfo_filtered);
 214         MapInfo_ClearTemps();
 215         return 1;
 216 }
 217
 218 void MapInfo_Filter_Free()
 219 {
 220         if(_MapInfo_filtered)
 221         {
 222                 strunzone(_MapInfo_filtered);
 223                 _MapInfo_filtered = string_null;
 224         }
 225 }
 226 #else
 227 float _MapInfo_filtered;
 228 float _MapInfo_filtered_allocated;
 229 float MapInfo_FilterList_Lookup(float i)
 230 {
 231         return stof(bufstr_get(_MapInfo_filtered, i));
 232 }
 233
 234 float MapInfo_FilterGametype(float pGametype, float pFeatures, float pFlagsRequired, float pFlagsForbidden, float pAbortOnGenerate)
 235 {
 236         float i, j;
 237         if not(_MapInfo_filtered_allocated)
 238         {
 239                 _MapInfo_filtered_allocated = 1;
 240                 _MapInfo_filtered = buf_create();
 241         }
 242         MapInfo_count = 0;
 243         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
 244         {
 245                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 246                         if(pAbortOnGenerate)
 247                         {
 248                                 dprint("Autogenerated a .mapinfo, doing the rest later.\n");
 249                                 MapInfo_progress = i / _MapInfo_globcount;
 250                                 return 0;
 251                         }
 252                 if((MapInfo_Map_supportedGametypes & pGametype) != 0)
 253                 if((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures)
 254                 if((MapInfo_Map_flags & pFlagsForbidden) == 0)
 255                 if((MapInfo_Map_flags & pFlagsRequired) == pFlagsRequired)
 256                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
 257         }
 258         MapInfo_count = j + 1;
 259         MapInfo_ClearTemps();
 260         return 1;
 261 }
 262
 263 void MapInfo_Filter_Free()
 264 {
 265         if(_MapInfo_filtered_allocated)
 266         {
 267                 buf_del(_MapInfo_filtered);
 268                 _MapInfo_filtered_allocated = 0;
 269         }
 270 }
 271 #endif
 272
 273 // load info about the i-th map into the MapInfo_Map_* globals
 274 string MapInfo_BSPName_ByID(float i)
 275 {
 276         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
 277 }
 278
 279 string unquote(string s)
 280 {
 281         float i, j, l;
 282         l = strlen(s);
 283         j = -1;
 284         for(i = 0; i < l; ++i)
 285         {
 286                 string ch;
 287                 ch = substring(s, i, 1);
 288                 if(ch != " ") if(ch != "\"")
 289                 {
 290                         for(j = strlen(s) - i - 1; j > 0; --j)
 291                         {
 292                                 ch = substring(s, i+j, 1);
 293                                 if(ch != " ") if(ch != "\"")
 294                                         return substring(s, i, j+1);
 295                         }
 296                         return substring(s, i, 1);
 297                 }
 298         }
 299         return "";
 300 }
 301
 302 float MapInfo_Get_ByID(float i)
 303 {
 304         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, 0))
 305                 return 1;
 306         return 0;
 307 }
 308
 309 string _MapInfo_Map_worldspawn_music;
 310
 311 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 312 {
 313         string fn;
 314         float fh;
 315         string s, k, v;
 316         vector o;
 317         float i;
 318         float inWorldspawn;
 319         float r;
 320         float twoBaseModes;
 321         float diameter, spawnpoints;
 322
 323         vector mapMins, mapMaxs;
 324
 325         r = 1;
 326         fn = strcat("maps/", pFilename, ".ent");
 327         fh = fopen(fn, FILE_READ);
 328         if(fh < 0)
 329         {
 330                 r = 2;
 331                 fn = strcat("maps/", pFilename, ".bsp");
 332                 fh = fopen(fn, FILE_READ);
 333         }
 334         if(fh < 0)
 335                 return 0;
 336         print("Analyzing ", fn, " to generate initial mapinfo; please edit that file later\n");
 337
 338         inWorldspawn = 2;
 339         MapInfo_Map_supportedGametypes = 0;
 340         spawnpoints = 0;
 341         _MapInfo_Map_worldspawn_music = "";
 342
 343         for(;;)
 344         {
 345                 if not((s = fgets(fh)))
 346                         break;
 347                 if(inWorldspawn == 1)
 348                         if(startsWith(s, "}"))
 349                                 inWorldspawn = 0;
 350                 k = unquote(car(s));
 351                 v = unquote(cdr(s));
 352                 if(inWorldspawn)
 353                 {
 354                         if(k == "classname" && v == "worldspawn")
 355                                 inWorldspawn = 1;
 356                         else if(k == "author")
 357                                 MapInfo_Map_author = v;
 358                         else if(k == "_description")
 359                                 MapInfo_Map_description = v;
 360                         else if(k == "music")
 361                                 _MapInfo_Map_worldspawn_music = v;
 362                         else if(k == "noise")
 363                                 _MapInfo_Map_worldspawn_music = v;
 364                         else if(k == "message")
 365                         {
 366                                 i = strstrofs(v, " by ", 0);
 367                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
 368                                 {
 369                                         MapInfo_Map_title = substring(v, 0, i);
 370                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
 371                                 }
 372                                 else
 373                                         MapInfo_Map_title = v;
 374                         }
 375                 }
 376                 else
 377                 {
 378                         if(k == "origin")
 379                         {
 380                                 o = stov(strcat("'", v, "'"));
 381                                 mapMins_x = min(mapMins_x, o_x);
 382                                 mapMins_y = min(mapMins_y, o_y);
 383                                 mapMins_z = min(mapMins_z, o_z);
 384                                 mapMaxs_x = max(mapMaxs_x, o_x);
 385                                 mapMaxs_y = max(mapMaxs_y, o_y);
 386                                 mapMaxs_z = max(mapMaxs_z, o_z);
 387                         }
 388                         else if(k == "classname")
 389                         {
 390                                 if(v == "dom_controlpoint")
 391                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DOMINATION;
 392                                 else if(v == "item_flag_team2")
 393                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 394                                 else if(v == "team_CTF_blueflag")
 395                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 396                                 else if(v == "runematch_spawn_point")
 397                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RUNEMATCH;
 398                                 else if(v == "target_assault_roundend")
 399                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ASSAULT;
 400                                 else if(v == "onslaught_generator")
 401                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ONSLAUGHT;
 402                                 else if(v == "info_player_team1")
 403                                         ++spawnpoints;
 404                                 else if(v == "info_player_team2")
 405                                         ++spawnpoints;
 406                                 else if(v == "info_player_start")
 407                                         ++spawnpoints;
 408                                 else if(v == "info_player_deathmatch")
 409                                         ++spawnpoints;
 410                                 else if(v == "trigger_race_checkpoint")
 411                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RACE;
 412                                 else if(v == "weapon_nex")
 413                                         { }
 414                                 else if(v == "weapon_railgun")
 415                                         { }
 416                                 else if(startsWith(v, "weapon_"))
 417                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 418                         }
 419                 }
 420         }
 421         if(inWorldspawn)
 422         {
 423                 print(fn, " ended still in worldspawn, BUG\n");
 424                 return 0;
 425         }
 426         diameter = vlen(mapMaxs - mapMins);
 427
 428         twoBaseModes = MapInfo_Map_supportedGametypes & (MAPINFO_TYPE_CTF | MAPINFO_TYPE_ASSAULT | MAPINFO_TYPE_RACE);
 429         if(twoBaseModes && (MapInfo_Map_supportedGametypes == twoBaseModes))
 430         {
 431                 // we have a CTF-only or Assault-only map. Don't add other modes then,
 432                 // as the map is too symmetric for them.
 433         }
 434         else
 435         {
 436                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DEATHMATCH;      // DM always works
 437                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_LMS;             // LMS always works
 438
 439                 if(spawnpoints >= 8  && diameter > 4096)
 440                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_TEAM_DEATHMATCH;
 441                 if(                     diameter < 4096)
 442                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ARENA;
 443                 if(spawnpoints >= 12 && diameter > 5120)
 444                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEYHUNT;
 445         }
 446
 447         dprint("-> diameter ",    ftos(diameter));
 448         dprint(";  spawnpoints ", ftos(spawnpoints));
 449         dprint(";  modes ",       ftos(MapInfo_Map_supportedGametypes), "\n");
 450
 451         fclose(fh);
 452
 453         return r;
 454 }
 455
 456 void _MapInfo_Map_Reset()
 457 {
 458         MapInfo_Map_title = "<TITLE>";
 459         MapInfo_Map_description = "<DESCRIPTION>";
 460         MapInfo_Map_author = "<AUTHOR>";
 461         MapInfo_Map_supportedGametypes = 0;
 462         MapInfo_Map_supportedFeatures = 0;
 463         MapInfo_Map_flags = 0;
 464         MapInfo_Map_clientstuff = "";
 465         MapInfo_Map_fog = "";
 466         MapInfo_Map_mins = '0 0 0';
 467         MapInfo_Map_maxs = '0 0 0';
 468 }
 469
 470 void _MapInfo_Map_ApplyGametype(string s, float pWantedType, float pThisType)
 471 {
 472         string sa;
 473         MapInfo_Map_supportedGametypes |= pThisType;
 474         if(!(pThisType & pWantedType))
 475                 return;
 476
 477         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT) // these modes don't use fraglimit
 478         {
 479                 cvar_set("fraglimit", "0");
 480         }
 481         else
 482         {
 483                 cvar_set("fraglimit", car(s));
 484                 s = cdr(s);
 485         }
 486
 487         cvar_set("timelimit", car(s));
 488         s = cdr(s);
 489
 490         if(pWantedType == MAPINFO_TYPE_TEAM_DEATHMATCH)
 491         {
 492                 sa = car(s); if(sa == "") sa = "2";
 493                 cvar_set("g_tdm_teams", sa);
 494                 s = cdr(s);
 495         }
 496
 497         if(pWantedType == MAPINFO_TYPE_KEYHUNT)
 498         {
 499                 sa = car(s); if(sa == "") sa = "3";
 500                 cvar_set("g_keyhunt_teams", sa);
 501                 s = cdr(s);
 502         }
 503
 504         if(pWantedType == MAPINFO_TYPE_CTF)
 505         {
 506                 sa = car(s); if(sa == "") sa = "10";
 507                 if(cvar("g_ctf_win_mode") < 2)
 508                         cvar_set("fraglimit", sa);
 509                 s = cdr(s);
 510         }
 511
 512         if(pWantedType == MAPINFO_TYPE_RACE)
 513         {
 514                 sa = car(s); if(sa == "") sa = cvar_string("fraglimit");
 515                 if(cvar("g_race_teams"))
 516                         cvar_set("fraglimit", sa);
 517                 s = cdr(s);
 518         }
 519 }
 520
 521 float MapInfo_Type_FromString(string t)
 522 {
 523         if     (t == "dm")    return MAPINFO_TYPE_DEATHMATCH;
 524         else if(t == "tdm")   return MAPINFO_TYPE_TEAM_DEATHMATCH;
 525         else if(t == "dom")   return MAPINFO_TYPE_DOMINATION;
 526         else if(t == "ctf")   return MAPINFO_TYPE_CTF;
 527         else if(t == "rune")  return MAPINFO_TYPE_RUNEMATCH;
 528         else if(t == "lms")   return MAPINFO_TYPE_LMS;
 529         else if(t == "arena") return MAPINFO_TYPE_ARENA;
 530         else if(t == "kh")    return MAPINFO_TYPE_KEYHUNT;
 531         else if(t == "as")    return MAPINFO_TYPE_ASSAULT;
 532         else if(t == "ons")   return MAPINFO_TYPE_ONSLAUGHT;
 533         else if(t == "race")  return MAPINFO_TYPE_RACE;
 534         else if(t == "all")   return MAPINFO_TYPE_ALL;
 535         else                  return 0;
 536 }
 537
 538 // load info about a map by name into the MapInfo_Map_* globals
 539 float MapInfo_Get_ByName(string pFilename, float pAllowGenerate, float pGametypeToSet)
 540 {
 541         string fn;
 542         string s, t;
 543         float fh, fh2;
 544         float r, f;
 545
 546         if(pGametypeToSet == 0)
 547                 if(MapInfo_Cache_Retrieve(pFilename))
 548                         return 1;
 549
 550         r = 1;
 551
 552         MapInfo_Map_bspname = pFilename;
 553
 554         // default all generic fields so they have "good" values in case something fails
 555         fn = strcat("maps/", pFilename, ".mapinfo");
 556         fh = fopen(fn, FILE_READ);
 557         if(fh < 0)
 558         {
 559                 if(!pAllowGenerate)
 560                         return 0;
 561                 _MapInfo_Map_Reset();
 562                 r = _MapInfo_Generate(pFilename);
 563                 if(!r)
 564                         return 0;
 565                 fh = fopen(fn, FILE_WRITE);
 566                 fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
 567                 fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
 568                 fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
 569                 if(_MapInfo_Map_worldspawn_music != "")
 570                 {
 571                         if(
 572                                 substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".wav"
 573                                 ||
 574                                 substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".ogg"
 575                         )
 576                                 fputs(fh, strcat("cdtrack ", substring(_MapInfo_Map_worldspawn_music, 0, strlen(_MapInfo_Map_worldspawn_music) - 4), "\n"));
 577                         else
 578                                 fputs(fh, strcat("cdtrack ", _MapInfo_Map_worldspawn_music, "\n"));
 579                 }
 580                 else
 581                         fputs(fh, strcat("cdtrack ", ftos(floor(random() * 9 + 2)), "\n")); // track from 2 to 10
 582                 if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)       fputs(fh, "has weapons\n");
 583                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DEATHMATCH)      fputs(fh, "type dm 30 20\n");
 584                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_TEAM_DEATHMATCH) fputs(fh, "type tdm 50 20 2\n");
 585                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DOMINATION)      fputs(fh, "type dom 200 20\n");
 586                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_CTF)             fputs(fh, "type ctf 300 20 10\n");
 587                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RUNEMATCH)       fputs(fh, "type rune 200 20\n");
 588                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_LMS)             fputs(fh, "type lms 9 20\n");
 589                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ARENA)           fputs(fh, "type arena 10 20\n");
 590                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_KEYHUNT)         fputs(fh, "type kh 1000 20 3\n");
 591                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ASSAULT)         fputs(fh, "type as 20\n");
 592                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE)            fputs(fh, "type race 5 20 15\n");
 593                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ONSLAUGHT)       fputs(fh, "type ons 20\n");
 594
 595                 fh2 = fopen(strcat("scripts/", pFilename, ".arena"), FILE_READ);
 596                 if(fh2 >= 0)
 597                 {
 598                         fclose(fh2);
 599                         fputs(fh, "settemp_for_type all sv_q3acompat_machineshotgunswap 1\n");
 600                 }
 601
 602                 fputs(fh, "// optional: fog density red green blue alpha mindist maxdist\n");
 603                 fputs(fh, "// optional: settemp_for_type (all|gametypename) cvarname value\n");
 604                 fputs(fh, "// optional: clientsettemp_for_type (all|gametypename) cvarname value\n");
 605                 fputs(fh, "// optional: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 606                 fputs(fh, "// optional: hidden\n");
 607
 608                 fclose(fh);
 609                 r = 2;
 610                 // return r;
 611                 fh = fopen(fn, FILE_READ);
 612                 if(fh < 0)
 613                         error("... but I just wrote it!");
 614         }
 615
 616         _MapInfo_Map_Reset();
 617         for(;;)
 618         {
 619                 if not((s = fgets(fh)))
 620                         break;
 621
 622                 // catch different sorts of comments
 623                 if(s == "")                    // empty lines
 624                         continue;
 625                 if(substring(s, 0, 1) == "#")  // UNIX style
 626                         continue;
 627                 if(substring(s, 0, 2) == "//") // C++ style
 628                         continue;
 629                 if(substring(s, 0, 1) == "_")  // q3map style
 630                         continue;
 631
 632                 t = car(s); s = cdr(s);
 633                 if(t == "title")
 634                         MapInfo_Map_title = s;
 635                 else if(t == "description")
 636                         MapInfo_Map_description = s;
 637                 else if(t == "author")
 638                         MapInfo_Map_author = s;
 639                 else if(t == "has")
 640                 {
 641                         t = car(s); s = cdr(s);
 642                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 643                         else
 644                                 dprint("Map ", pFilename, " supports unknown feature ", t, ", ignored\n");
 645                 }
 646                 else if(t == "hidden")
 647                 {
 648                         MapInfo_Map_flags |= MAPINFO_FLAG_HIDDEN;
 649                 }
 650                 else if(t == "type")
 651                 {
 652                         t = car(s); s = cdr(s);
 653                         f = MapInfo_Type_FromString(t);
 654                         if(f)
 655                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f);
 656                         else
 657                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
 658                 }
 659                 else if(t == "size")
 660                 {
 661                         float a, b, c, d, e;
 662                         t = car(s); s = cdr(s); a = stof(t);
 663                         t = car(s); s = cdr(s); b = stof(t);
 664                         t = car(s); s = cdr(s); c = stof(t);
 665                         t = car(s); s = cdr(s); d = stof(t);
 666                         t = car(s); s = cdr(s); e = stof(t);
 667                         if(s == "")
 668                                 print("Map ", pFilename, " contains an incorrect size line (not enough params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 669                         else
 670                         {
 671                                 t = car(s); s = cdr(s); f = stof(t);
 672                                 if(s != "")
 673                                         print("Map ", pFilename, " contains an incorrect size line (too many params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 674                                 else
 675                                 {
 676                                         if(a >= d || b >= e || c >= f)
 677                                                 print("Map ", pFilename, " contains an incorrect size line, mins have to be < maxs\n");
 678                                         else
 679                                         {
 680                                                 MapInfo_Map_mins_x = a;
 681                                                 MapInfo_Map_mins_y = b;
 682                                                 MapInfo_Map_mins_z = c;
 683                                                 MapInfo_Map_maxs_x = d;
 684                                                 MapInfo_Map_maxs_y = e;
 685                                                 MapInfo_Map_maxs_z = f;
 686                                         }
 687                                 }
 688                         }
 689                 }
 690                 else if(t == "settemp_for_type")
 691                 {
 692                         t = car(s); s = cdr(s);
 693                         if((f = MapInfo_Type_FromString(t)))
 694                         {
 695                                 if(f & pGametypeToSet)
 696                                 {
 697                                         t = car(s); s = cdr(s);
 698                                         if not(cvar_value_issafe(t))
 699                                                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 700                                         else if not (cvar_value_issafe(s))
 701                                                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 702                                         else
 703                                         {
 704                                                 dprint("Applying temporary setting ", t, " := ", s, "\n");
 705                                                 cvar_settemp(t, s);
 706                                         }
 707                                 }
 708                         }
 709                         else
 710                         {
 711                                 dprint("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored\n");
 712                         }
 713                 }
 714                 else if(t == "clientsettemp_for_type")
 715                 {
 716                         t = car(s); s = cdr(s);
 717                         if((f = MapInfo_Type_FromString(t)))
 718                         {
 719                                 if(f & pGametypeToSet)
 720                                 {
 721                                         t = car(s); s = cdr(s);
 722                                         if not(cvar_value_issafe(t))
 723                                                 print("Map ", pFilename, " contains a potentially harmful client setting, ignored\n");
 724                                         else if not (cvar_value_issafe(s))
 725                                                 print("Map ", pFilename, " contains a potentially harmful client setting, ignored\n");
 726                                         else
 727                                         {
 728                                                 dprint("Applying temporary client setting ", t, " := ", s, "\n");
 729                                                 MapInfo_Map_clientstuff = strcat(
 730                                                         MapInfo_Map_clientstuff, "cl_cmd settemp \"", t, "\" \"", s, "\"\n"
 731                                                 );
 732                                         }
 733                                 }
 734                         }
 735                         else
 736                         {
 737                                 dprint("Map ", pFilename, " has a client setting for unknown game type ", t, ", ignored\n");
 738                         }
 739                 }
 740                 else if(t == "fog")
 741                 {
 742                         if not(cvar_value_issafe(t))
 743                                 print("Map ", pFilename, " contains a potentially harmful fog setting, ignored\n");
 744                         else
 745                                 MapInfo_Map_fog = s;
 746                 }
 747                 else if(t == "cdtrack")
 748                 {
 749                         if(pGametypeToSet)
 750                         {
 751                                 if not(cvar_value_issafe(t))
 752                                         print("Map ", pFilename, " contains a potentially harmful cdtrack, ignored\n");
 753                                 else
 754                                         MapInfo_Map_clientstuff = strcat(
 755                                                 MapInfo_Map_clientstuff, "cd loop \"", s, "\"\n"
 756                                         );
 757                         }
 758                 }
 759                 else
 760                         dprint("Map ", pFilename, " provides unknown info item ", t, ", ignored\n");
 761         }
 762         fclose(fh);
 763         if(pGametypeToSet)
 764                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet))
 765                         error("Can't select the requested game type. Bailing out.");
 766         MapInfo_Cache_Store();
 767         if(MapInfo_Map_supportedGametypes != 0)
 768                 return r;
 769         dprint("Map ", pFilename, " supports no game types, ignored\n");
 770         return 0;
 771 }
 772
 773 float MapInfo_FindName(string s)
 774 {
 775         // if there is exactly one map of prefix s, return it
 776         // if not, return the null string
 777         // note that DP sorts glob results... so I can use a binary search
 778         float l, r, m, cmp;
 779         l = 0;
 780         r = MapInfo_count;
 781         // invariants: r is behind s, l-1 is equal or before
 782         while(l != r)
 783         {
 784                 m = floor((l + r) / 2);
 785                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
 786                 cmp = strcasecmp(MapInfo_FindName_match, s);
 787                 if(cmp == 0)
 788                         return m; // found and good
 789                 if(cmp < 0)
 790                         l = m + 1; // l-1 is before s
 791                 else
 792                         r = m; // behind s
 793         }
 794         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
 795         MapInfo_FindName_firstResult = l;
 796         // r == l, so: l is behind s, l-1 is before
 797         // SO: if there is any, l is the one with the right prefix
 798         //     and l+1 may be one too
 799         if(l == MapInfo_count)
 800         {
 801                 MapInfo_FindName_match = string_null;
 802                 MapInfo_FindName_firstResult = -1;
 803                 return -1; // no MapInfo_FindName_match, behind last item
 804         }
 805         if(!startsWithNocase(MapInfo_FindName_match, s))
 806         {
 807                 MapInfo_FindName_match = string_null;
 808                 MapInfo_FindName_firstResult = -1;
 809                 return -1; // wrong prefix
 810         }
 811         if(l == MapInfo_count - 1)
 812                 return l; // last one, nothing can follow => unique
 813         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
 814         {
 815                 MapInfo_FindName_match = string_null;
 816                 return -1; // ambigous MapInfo_FindName_match
 817         }
 818         return l;
 819 }
 820
 821 string MapInfo_FixName(string s)
 822 {
 823         MapInfo_FindName(s);
 824         return MapInfo_FindName_match;
 825 }
 826
 827 float MapInfo_CurrentFeatures()
 828 {
 829         float req;
 830         req = 0;
 831         if(!(cvar("g_lms") || cvar("g_instagib") || cvar("g_minstagib") || cvar("g_nixnex") || cvar("g_rocketarena") || !cvar("g_pickup_items") || cvar("g_race")))
 832                 req |= MAPINFO_FEATURE_WEAPONS;
 833         return req;
 834 }
 835
 836 float MapInfo_CurrentGametype()
 837 {
 838         if(cvar("g_domination"))
 839                 return MAPINFO_TYPE_DOMINATION;
 840         else if(cvar("g_ctf"))
 841                 return MAPINFO_TYPE_CTF;
 842         else if(cvar("g_runematch"))
 843                 return MAPINFO_TYPE_RUNEMATCH;
 844         else if(cvar("g_tdm"))
 845                 return MAPINFO_TYPE_TEAM_DEATHMATCH;
 846         else if(cvar("g_assault"))
 847                 return MAPINFO_TYPE_ASSAULT;
 848         else if(cvar("g_lms"))
 849                 return MAPINFO_TYPE_LMS;
 850         else if(cvar("g_arena"))
 851                 return MAPINFO_TYPE_ARENA;
 852         else if(cvar("g_keyhunt"))
 853                 return MAPINFO_TYPE_KEYHUNT;
 854         else if(cvar("g_onslaught"))
 855                 return MAPINFO_TYPE_ONSLAUGHT;
 856         else if(cvar("g_race"))
 857                 return MAPINFO_TYPE_RACE;
 858         else
 859                 return MAPINFO_TYPE_DEATHMATCH;
 860 }
 861
 862 float _MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
 863 {
 864         if(!MapInfo_Get_ByName(s, 1, 0))
 865                 return 0;
 866         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype()) == 0)
 867                 return 0;
 868         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
 869                 return 0;
 870         return 1;
 871 }
 872
 873 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
 874 {
 875         float r;
 876         r = _MapInfo_CheckMap(s);
 877         MapInfo_ClearTemps();
 878         return r;
 879 }
 880
 881 void MapInfo_SwitchGameType(float t)
 882 {
 883         cvar_set("gamecfg",      "0");
 884         cvar_set("g_dm",         (t == MAPINFO_TYPE_DEATHMATCH)      ? "1" : "0");
 885         cvar_set("g_tdm",        (t == MAPINFO_TYPE_TEAM_DEATHMATCH) ? "1" : "0");
 886         cvar_set("g_domination", (t == MAPINFO_TYPE_DOMINATION)      ? "1" : "0");
 887         cvar_set("g_ctf",        (t == MAPINFO_TYPE_CTF)             ? "1" : "0");
 888         cvar_set("g_runematch",  (t == MAPINFO_TYPE_RUNEMATCH)       ? "1" : "0");
 889         cvar_set("g_lms",        (t == MAPINFO_TYPE_LMS)             ? "1" : "0");
 890         cvar_set("g_arena",      (t == MAPINFO_TYPE_ARENA)           ? "1" : "0");
 891         cvar_set("g_keyhunt",    (t == MAPINFO_TYPE_KEYHUNT)         ? "1" : "0");
 892         cvar_set("g_assault",    (t == MAPINFO_TYPE_ASSAULT)         ? "1" : "0");
 893         cvar_set("g_onslaught",  (t == MAPINFO_TYPE_ONSLAUGHT)       ? "1" : "0");
 894         cvar_set("g_race",       (t == MAPINFO_TYPE_RACE)            ? "1" : "0");
 895 }
 896
 897 void MapInfo_LoadMap(string s)
 898 {
 899         MapInfo_Map_supportedGametypes = 0;
 900         if(!MapInfo_CheckMap(s))
 901         {
 902                 print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
 903                 MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH);
 904         }
 905         localcmd(strcat("\nsettemp_restore\nchangelevel ", s, "\n"));
 906 }
 907
 908 string MapInfo_ListAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
 909 {
 910         string out;
 911         float i;
 912
 913         // to make absolutely sure:
 914         MapInfo_Enumerate();
 915         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
 916
 917         out = "";
 918         for(i = 0; i < MapInfo_count; ++i)
 919                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
 920         return substring(out, 1, strlen(out) - 1);
 921 }
 922
 923 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
 924 {
 925         float t;
 926         if(!_MapInfo_CheckMap(s)) // with underscore, it keeps temps
 927         {
 928                 if(MapInfo_Map_supportedGametypes <= 0)
 929                         error("Mapinfo system is not functional at all. BAILED OUT.\n");
 930
 931                 t = 1;
 932                 while(!(MapInfo_Map_supportedGametypes & 1))
 933                 {
 934                         t *= 2;
 935                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes / 2);
 936                 }
 937                 // t is now a supported mode!
 938                 print("EMERGENCY: can't play the selected map in the given game mode. Falling back to a supported mode.\n");
 939                 MapInfo_SwitchGameType(t);
 940         }
 941         cvar_settemp_restore();
 942         MapInfo_Get_ByName(s, 1, MapInfo_CurrentGametype());
 943 }
 944
 945 void MapInfo_ClearTemps()
 946 {
 947         MapInfo_Map_bspname = string_null;
 948         MapInfo_Map_title = string_null;
 949         MapInfo_Map_description = string_null;
 950         MapInfo_Map_author = string_null;
 951         MapInfo_Map_clientstuff = string_null;
 952         MapInfo_Map_supportedGametypes = 0;
 953         MapInfo_Map_supportedFeatures = 0;
 954 }
 955
 956 void MapInfo_Shutdown()
 957 {
 958         MapInfo_ClearTemps();
 959         MapInfo_Filter_Free();
 960         MapInfo_Cache_Destroy();
 961         if(_MapInfo_globopen)
 962         {
 963                 search_end(_MapInfo_globhandle);
 964                 _MapInfo_globhandle = -1;
 965                 _MapInfo_globopen = FALSE;
 966         }
 967 }