data/qcsrc/common/mapinfo.qc

   1 // generic string stuff
   2 float startsWith(string haystack, string needle)
   3 {
   4         return substring(haystack, 0, strlen(needle)) == needle;
   5 }
   6 float startsWithNocase(string haystack, string needle)
   7 {
   8         return strcasecmp(substring(haystack, 0, strlen(needle)), needle) == 0;
   9 }
  10 string extractRestOfLine(string haystack, string needle)
  11 {
  12         if(startsWith(haystack, needle))
  13                 return substring(haystack, strlen(needle), strlen(haystack) - strlen(needle));
  14         return string_null;
  15 }
  16 string car(string s)
  17 {
  18         float o;
  19         o = strstrofs(s, " ", 0);
  20         if(o < 0)
  21                 return s;
  22         return substring(s, 0, o);
  23 }
  24 string cdr(string s)
  25 {
  26         float o;
  27         o = strstrofs(s, " ", 0);
  28         if(o < 0)
  29                 return string_null;
  30         return substring(s, o + 1, strlen(s) - (o + 1));
  31 }
  32 float matchacl(string acl, string str)
  33 {
  34         string t, s;
  35         float r, d;
  36         r = 0;
  37         while(acl)
  38         {
  39                 t = car(acl); acl = cdr(acl);
  40                 d = 1;
  41                 if(substring(t, 0, 1) == "-")
  42                 {
  43                         d = -1;
  44                         t = substring(t, 1, strlen(t) - 1);
  45                 }
  46                 else if(substring(t, 0, 1) == "+")
  47                         t = substring(t, 1, strlen(t) - 1);
  48                 if(substring(t, -1, 1) == "*")
  49                 {
  50                         t = substring(t, 0, strlen(t) - 1);
  51                         s = substring(s, 0, strlen(t));
  52                 }
  53                 else
  54                         s = str;
  55
  56                 if(s == t)
  57                 {
  58                         r = d;
  59                 }
  60         }
  61         return r;
  62 }
  63
  64 float _MapInfo_Cache_Active;
  65 float _MapInfo_Cache_DB_NameToIndex;
  66 float _MapInfo_Cache_Buf_IndexToMapData;
  67
  68 void MapInfo_Cache_Destroy()
  69 {
  70         if(!_MapInfo_Cache_Active)
  71                 return;
  72
  73         db_close(_MapInfo_Cache_DB_NameToIndex);
  74         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
  75         _MapInfo_Cache_Active = 0;
  76 }
  77
  78 void MapInfo_Cache_Create()
  79 {
  80         MapInfo_Cache_Destroy();
  81         _MapInfo_Cache_DB_NameToIndex = db_create();
  82         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
  83         _MapInfo_Cache_Active = 1;
  84 }
  85
  86 void MapInfo_Cache_Invalidate()
  87 {
  88         if(!_MapInfo_Cache_Active)
  89                 return;
  90
  91         MapInfo_Cache_Create();
  92 }
  93
  94 void MapInfo_Cache_Store()
  95 {
  96         float i;
  97         string s;
  98         if(!_MapInfo_Cache_Active)
  99                 return;
 100
 101         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
 102         if(!s) // empty string is NOT valid here!
 103         {
 104                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
 105                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
 106         }
 107         else
 108                 i = stof(s);
 109
 110         // now store all the stuff
 111         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
 112         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
 113         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
 114         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
 115         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
 116         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
 117         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_flags));
 118 }
 119
 120 float MapInfo_Cache_Retrieve(string map)
 121 {
 122         float i;
 123         string s;
 124         if(!_MapInfo_Cache_Active)
 125                 return 0;
 126
 127         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
 128         if(!s)
 129                 return 0;
 130         i = stof(s);
 131
 132         // now retrieve all the stuff
 133         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
 134         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
 135         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
 136         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
 137         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
 138         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
 139         MapInfo_Map_flags = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
 140         return 1;
 141 }
 142
 143 // GLOB HANDLING (for all BSP files)
 144 float _MapInfo_globopen;
 145 float _MapInfo_globcount;
 146 float _MapInfo_globhandle;
 147 string _MapInfo_GlobItem(float i)
 148 {
 149         string s;
 150         s = search_getfilename(_MapInfo_globhandle, i);
 151         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
 152 }
 153
 154 void MapInfo_Enumerate()
 155 {
 156         if(_MapInfo_globopen)
 157                 search_end(_MapInfo_globhandle);
 158         MapInfo_Cache_Invalidate();
 159         _MapInfo_globhandle = search_begin("maps/*.bsp", TRUE, TRUE);
 160         _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
 161         _MapInfo_globopen = 1;
 162 }
 163
 164 // filter the info by game type mask (updates MapInfo_count)
 165 //
 166 float _MapInfo_filtered;
 167 float _MapInfo_filtered_allocated;
 168 float MapInfo_FilterList_Lookup(float i)
 169 {
 170         return stof(bufstr_get(_MapInfo_filtered, i));
 171 }
 172
 173 void _MapInfo_FilterList_swap(float i, float j, entity pass)
 174 {
 175         string h;
 176         h = bufstr_get(_MapInfo_filtered, i);
 177         bufstr_set(_MapInfo_filtered, i, bufstr_get(_MapInfo_filtered, j));
 178         bufstr_set(_MapInfo_filtered, j, h);
 179 }
 180
 181 float _MapInfo_FilterList_cmp(float i, float j, entity pass)
 182 {
 183         string a, b;
 184         a = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, i)));
 185         b = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, j)));
 186         return strcasecmp(a, b);
 187 }
 188
 189 float MapInfo_FilterGametype(float pGametype, float pFeatures, float pFlagsRequired, float pFlagsForbidden, float pAbortOnGenerate)
 190 {
 191         float i, j;
 192         if not(_MapInfo_filtered_allocated)
 193         {
 194                 _MapInfo_filtered_allocated = 1;
 195                 _MapInfo_filtered = buf_create();
 196         }
 197         MapInfo_count = 0;
 198         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
 199         {
 200                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 201                         if(pAbortOnGenerate)
 202                         {
 203                                 dprint("Autogenerated a .mapinfo, doing the rest later.\n");
 204                                 MapInfo_progress = i / _MapInfo_globcount;
 205                                 return 0;
 206                         }
 207                 if((MapInfo_Map_supportedGametypes & pGametype) != 0)
 208                 if((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures)
 209                 if((MapInfo_Map_flags & pFlagsForbidden) == 0)
 210                 if((MapInfo_Map_flags & pFlagsRequired) == pFlagsRequired)
 211                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
 212         }
 213         MapInfo_count = j + 1;
 214         MapInfo_ClearTemps();
 215
 216         // sometimes the glob isn't sorted nicely, so fix it here...
 217         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, world);
 218
 219         return 1;
 220 }
 221
 222 void MapInfo_Filter_Free()
 223 {
 224         if(_MapInfo_filtered_allocated)
 225         {
 226                 buf_del(_MapInfo_filtered);
 227                 _MapInfo_filtered_allocated = 0;
 228         }
 229 }
 230
 231 // load info about the i-th map into the MapInfo_Map_* globals
 232 string MapInfo_BSPName_ByID(float i)
 233 {
 234         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
 235 }
 236
 237 string unquote(string s)
 238 {
 239         float i, j, l;
 240         l = strlen(s);
 241         j = -1;
 242         for(i = 0; i < l; ++i)
 243         {
 244                 string ch;
 245                 ch = substring(s, i, 1);
 246                 if(ch != " ") if(ch != "\"")
 247                 {
 248                         for(j = strlen(s) - i - 1; j > 0; --j)
 249                         {
 250                                 ch = substring(s, i+j, 1);
 251                                 if(ch != " ") if(ch != "\"")
 252                                         return substring(s, i, j+1);
 253                         }
 254                         return substring(s, i, 1);
 255                 }
 256         }
 257         return "";
 258 }
 259
 260 float MapInfo_Get_ByID(float i)
 261 {
 262         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, 0))
 263                 return 1;
 264         return 0;
 265 }
 266
 267 string _MapInfo_Map_worldspawn_music;
 268
 269 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 270 {
 271         string fn;
 272         float fh;
 273         string s, k, v;
 274         vector o;
 275         float i;
 276         float inWorldspawn;
 277         float r;
 278         float twoBaseModes;
 279         float diameter, spawnpoints;
 280         float spawnplaces;
 281
 282         vector mapMins, mapMaxs;
 283
 284         r = 1;
 285         fn = strcat("maps/", pFilename, ".ent");
 286         fh = fopen(fn, FILE_READ);
 287         if(fh < 0)
 288         {
 289                 r = 2;
 290                 fn = strcat("maps/", pFilename, ".bsp");
 291                 fh = fopen(fn, FILE_READ);
 292         }
 293         if(fh < 0)
 294                 return 0;
 295         print("Analyzing ", fn, " to generate initial mapinfo; please edit that file later\n");
 296
 297         inWorldspawn = 2;
 298         MapInfo_Map_flags = 0;
 299         MapInfo_Map_supportedGametypes = 0;
 300         spawnpoints = 0;
 301         spawnplaces = 0;
 302         _MapInfo_Map_worldspawn_music = "";
 303
 304         for(;;)
 305         {
 306                 if not((s = fgets(fh)))
 307                         break;
 308                 if(inWorldspawn == 1)
 309                         if(startsWith(s, "}"))
 310                                 inWorldspawn = 0;
 311                 k = unquote(car(s));
 312                 v = unquote(cdr(s));
 313                 if(inWorldspawn)
 314                 {
 315                         if(k == "classname" && v == "worldspawn")
 316                                 inWorldspawn = 1;
 317                         else if(k == "author")
 318                                 MapInfo_Map_author = v;
 319                         else if(k == "_description")
 320                                 MapInfo_Map_description = v;
 321                         else if(k == "music")
 322                                 _MapInfo_Map_worldspawn_music = v;
 323                         else if(k == "noise")
 324                                 _MapInfo_Map_worldspawn_music = v;
 325                         else if(k == "message")
 326                         {
 327                                 i = strstrofs(v, " by ", 0);
 328                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
 329                                 {
 330                                         MapInfo_Map_title = substring(v, 0, i);
 331                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
 332                                 }
 333                                 else
 334                                         MapInfo_Map_title = v;
 335                         }
 336                 }
 337                 else
 338                 {
 339                         if(k == "origin")
 340                         {
 341                                 o = stov(strcat("'", v, "'"));
 342                                 mapMins_x = min(mapMins_x, o_x);
 343                                 mapMins_y = min(mapMins_y, o_y);
 344                                 mapMins_z = min(mapMins_z, o_z);
 345                                 mapMaxs_x = max(mapMaxs_x, o_x);
 346                                 mapMaxs_y = max(mapMaxs_y, o_y);
 347                                 mapMaxs_z = max(mapMaxs_z, o_z);
 348                         }
 349                         else if(k == "race_place")
 350                         {
 351                                 if(stof(v) > 0)
 352                                         spawnplaces = 1;
 353                         }
 354                         else if(k == "classname")
 355                         {
 356                                 if(v == "dom_controlpoint")
 357                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DOMINATION;
 358                                 else if(v == "item_flag_team2")
 359                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 360                                 else if(v == "team_CTF_blueflag")
 361                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 362                                 else if(v == "runematch_spawn_point")
 363                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RUNEMATCH;
 364                                 else if(v == "target_assault_roundend")
 365                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ASSAULT;
 366                                 else if(v == "onslaught_generator")
 367                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ONSLAUGHT;
 368                                 else if(substring(v, 0, 8) == "nexball_" || substring(v, 0, 4) == "ball")
 369                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_NEXBALL;
 370                                 else if(v == "info_player_team1")
 371                                         ++spawnpoints;
 372                                 else if(v == "info_player_team2")
 373                                         ++spawnpoints;
 374                                 else if(v == "info_player_start")
 375                                         ++spawnpoints;
 376                                 else if(v == "info_player_deathmatch")
 377                                         ++spawnpoints;
 378                                 else if(v == "trigger_race_checkpoint")
 379                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RACE;
 380                                 else if(v == "target_startTimer")
 381                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 382                                 else if(v == "weapon_nex")
 383                                         { }
 384                                 else if(v == "weapon_railgun")
 385                                         { }
 386                                 else if(startsWith(v, "weapon_"))
 387                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 388                         }
 389                 }
 390         }
 391         if(inWorldspawn)
 392         {
 393                 print(fn, " ended still in worldspawn, BUG\n");
 394                 return 0;
 395         }
 396         diameter = vlen(mapMaxs - mapMins);
 397
 398         twoBaseModes = MapInfo_Map_supportedGametypes & (MAPINFO_TYPE_CTF | MAPINFO_TYPE_ASSAULT | MAPINFO_TYPE_RACE | MAPINFO_TYPE_NEXBALL);
 399         if(twoBaseModes && (MapInfo_Map_supportedGametypes == twoBaseModes))
 400         {
 401                 // we have a CTF-only or Assault-only map. Don't add other modes then,
 402                 // as the map is too symmetric for them.
 403         }
 404         else
 405         {
 406                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DEATHMATCH;      // DM always works
 407                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RUNEMATCH;       // Rune always works
 408                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_LMS;             // LMS always works
 409
 410                 if(spawnpoints >= 8  && diameter > 4096) {
 411                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_TEAM_DEATHMATCH;
 412                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CA;
 413                 }
 414                 if(                     diameter < 4096)
 415                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ARENA;
 416                 if(spawnpoints >= 12 && diameter > 5120)
 417                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEYHUNT;
 418         }
 419
 420         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE)
 421         if(!spawnplaces)
 422         {
 423                 MapInfo_Map_supportedGametypes &~= MAPINFO_TYPE_RACE;
 424                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 425         }
 426
 427         dprint("-> diameter ",    ftos(diameter));
 428         dprint(";  spawnpoints ", ftos(spawnpoints));
 429         dprint(";  modes ",       ftos(MapInfo_Map_supportedGametypes), "\n");
 430
 431         fclose(fh);
 432
 433         return r;
 434 }
 435
 436 void _MapInfo_Map_Reset()
 437 {
 438         MapInfo_Map_title = "<TITLE>";
 439         MapInfo_Map_description = "<DESCRIPTION>";
 440         MapInfo_Map_author = "<AUTHOR>";
 441         MapInfo_Map_supportedGametypes = 0;
 442         MapInfo_Map_supportedFeatures = 0;
 443         MapInfo_Map_flags = 0;
 444         MapInfo_Map_clientstuff = "";
 445         MapInfo_Map_fog = "";
 446         MapInfo_Map_mins = '0 0 0';
 447         MapInfo_Map_maxs = '0 0 0';
 448 }
 449
 450 void _MapInfo_Map_ApplyGametype(string s, float pWantedType, float pThisType)
 451 {
 452         string sa;
 453         MapInfo_Map_supportedGametypes |= pThisType;
 454         if(!(pThisType & pWantedType))
 455                 return;
 456
 457         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_RACE || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
 458         {
 459                 cvar_set("fraglimit", "0");
 460         }
 461         else
 462         {
 463                 cvar_set("fraglimit", car(s));
 464                 s = cdr(s);
 465         }
 466
 467         cvar_set("timelimit", car(s));
 468         s = cdr(s);
 469
 470         if(pWantedType == MAPINFO_TYPE_TEAM_DEATHMATCH)
 471         {
 472                 sa = car(s); if(sa == "") sa = "2";
 473                 cvar_set("g_tdm_teams", sa);
 474                 s = cdr(s);
 475         }
 476
 477         if(pWantedType == MAPINFO_TYPE_KEYHUNT)
 478         {
 479                 sa = car(s); if(sa == "") sa = "3";
 480                 cvar_set("g_keyhunt_teams", sa);
 481                 s = cdr(s);
 482         }
 483
 484         if(pWantedType == MAPINFO_TYPE_CTF)
 485         {
 486                 sa = car(s); if(sa == "") sa = "10";
 487                 if(cvar("g_ctf_win_mode") < 2)
 488                         cvar_set("fraglimit", sa);
 489                 s = cdr(s);
 490         }
 491
 492         // rc = timelimit timelimit_qualification laps laps_teamplay
 493         if(pWantedType == MAPINFO_TYPE_RACE)
 494         {
 495                 sa = car(s); if(sa == "") sa = cvar_string("timelimit");
 496                 cvar_set("g_race_qualifying_timelimit", sa);
 497                 s = cdr(s);
 498
 499                 sa = car(s); if(sa == "") sa = "10";
 500                 if(cvar("g_race_teams") < 2)
 501                         cvar_set("fraglimit", sa);
 502                 s = cdr(s);
 503
 504                 sa = car(s); if(sa == "") sa = "20";
 505                 if(cvar("g_race_teams") >= 2)
 506                         cvar_set("fraglimit", sa);
 507                 s = cdr(s);
 508         }
 509
 510         if(pWantedType == MAPINFO_TYPE_CTS)
 511         {
 512                 sa = car(s); if(sa == "") sa = cvar_string("fraglimit");
 513                 if(cvar("g_race_teams"))
 514                         cvar_set("fraglimit", sa);
 515                 s = cdr(s);
 516         }
 517
 518         sa = car(s); if(sa == "") sa = "0";
 519         cvar_set("leadlimit", sa);
 520         s = cdr(s);
 521 }
 522
 523 float MapInfo_Type_FromString(string t)
 524 {
 525         if     (t == "dm")      return MAPINFO_TYPE_DEATHMATCH;
 526         else if(t == "tdm")     return MAPINFO_TYPE_TEAM_DEATHMATCH;
 527         else if(t == "dom")     return MAPINFO_TYPE_DOMINATION;
 528         else if(t == "ctf")     return MAPINFO_TYPE_CTF;
 529         else if(t == "rune")    return MAPINFO_TYPE_RUNEMATCH;
 530         else if(t == "lms")     return MAPINFO_TYPE_LMS;
 531         else if(t == "arena")   return MAPINFO_TYPE_ARENA;
 532         else if(t == "ca")      return MAPINFO_TYPE_CA;
 533         else if(t == "kh")      return MAPINFO_TYPE_KEYHUNT;
 534         else if(t == "as")      return MAPINFO_TYPE_ASSAULT;
 535         else if(t == "ons")     return MAPINFO_TYPE_ONSLAUGHT;
 536         else if(t == "rc")      return MAPINFO_TYPE_RACE;
 537         else if(t == "nexball") return MAPINFO_TYPE_NEXBALL;
 538         else if(t == "cts")     return MAPINFO_TYPE_CTS;
 539         else if(t == "all")     return MAPINFO_TYPE_ALL;
 540         else                    return 0;
 541 }
 542
 543 void _MapInfo_Parse_Settemp(string pFilename, string acl, float type, string s, float recurse)
 544 {
 545         string t;
 546         float fh, o;
 547         t = car(s); s = cdr(s);
 548
 549         // limited support of "" and comments
 550         //   remove trailing and leading " of t
 551         if(substring(t, 0, 1) == "\"")
 552         {
 553                 if(substring(t, -1, 1) == "\"")
 554                         t = substring(t, 1, -2);
 555         }
 556
 557         //   remove leading " of s
 558         if(substring(s, 0, 1) == "\"")
 559         {
 560                 s = substring(s, 1, -1);
 561         }
 562         //   remove trailing " of s, and all that follows (cvar description)
 563         o = strstrofs(s, "\"", 0);
 564         if(o >= 0)
 565                 s = substring(s, 0, o);
 566
 567         //   remove // comments
 568         o = strstrofs(s, "//", 0);
 569         if(o >= 0)
 570                 s = substring(s, 0, o);
 571
 572         //   remove trailing spaces
 573         while(substring(s, -1, 1) == " ")
 574                 s = substring(s, 0, -2);
 575
 576         if(t == "#include")
 577         {
 578                 if(recurse > 0)
 579                 {
 580                         fh = fopen(s, FILE_READ);
 581                         if(fh < 0)
 582                                 print("Map ", pFilename, " references not existing config file ", s, "\n");
 583                         else
 584                         {
 585                                 for(;;)
 586                                 {
 587                                         if not((s = fgets(fh)))
 588                                                 break;
 589
 590                                         // catch different sorts of comments
 591                                         if(s == "")                    // empty lines
 592                                                 continue;
 593                                         if(substring(s, 0, 1) == "#")  // UNIX style
 594                                                 continue;
 595                                         if(substring(s, 0, 2) == "//") // C++ style
 596                                                 continue;
 597                                         if(substring(s, 0, 1) == "_")  // q3map style
 598                                                 continue;
 599
 600                                         if(substring(s, 0, 4) == "set ")
 601                                                 s = substring(s, 4, -1);
 602                                         if(substring(s, 0, 5) == "seta ")
 603                                                 s = substring(s, 5, -1);
 604
 605                                         _MapInfo_Parse_Settemp(pFilename, acl, type, s, recurse - 1);
 606                                 }
 607                                 fclose(fh);
 608                         }
 609                 }
 610                 else
 611                         print("Map ", pFilename, " uses too many levels of inclusion\n");
 612         }
 613         else if not(cvar_value_issafe(t))
 614                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 615         else if not (cvar_value_issafe(s))
 616                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 617         else if(substring(t, 0, 10) == "g_mapinfo_")
 618                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 619         else if(substring(t, 0, 5) == "rcon_")
 620                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 621         else if(substring(t, 0, 8) == "settemp_")
 622                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 623         else if(substring(t, 0, 1) == "_")
 624                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 625         else if(matchacl(acl, t) <= 0)
 626                 print("Map ", pFilename, " contains a denied setting, ignored\n");
 627         else
 628         {
 629                 if(type == 0) // server set
 630                 {
 631                         dprint("Applying temporary setting ", t, " := ", s, "\n");
 632                         if(cvar("g_campaign"))
 633                                 cvar_set(t, s); // this is a wrapper and is always temporary anyway; no need to backup old values then
 634                         else
 635                                 cvar_settemp(t, s);
 636                 }
 637                 else
 638                 {
 639                         dprint("Applying temporary client setting ", t, " := ", s, "\n");
 640                         MapInfo_Map_clientstuff = strcat(
 641                                         MapInfo_Map_clientstuff, "cl_cmd settemp \"", t, "\" \"", s, "\"\n"
 642                                         );
 643                 }
 644         }
 645 }
 646
 647 // load info about a map by name into the MapInfo_Map_* globals
 648 float MapInfo_Get_ByName(string pFilename, float pAllowGenerate, float pGametypeToSet)
 649 {
 650         string fn;
 651         string s, t;
 652         float fh, fh2;
 653         float r, f, n, i;
 654         string acl;
 655
 656         acl = cvar_string("g_mapinfo_settemp_acl");
 657
 658         if(strstrofs(pFilename, "/", 0) >= 0)
 659         {
 660                 print("Invalid character in map name, ignored\n");
 661                 return 0;
 662         }
 663
 664         if(pGametypeToSet == 0)
 665                 if(MapInfo_Cache_Retrieve(pFilename))
 666                         return 1;
 667
 668         r = 1;
 669
 670         MapInfo_Map_bspname = pFilename;
 671
 672         // default all generic fields so they have "good" values in case something fails
 673         fn = strcat("maps/", pFilename, ".mapinfo");
 674         fh = fopen(fn, FILE_READ);
 675         if(fh < 0)
 676         {
 677                 if(!pAllowGenerate)
 678                         return 0;
 679                 _MapInfo_Map_Reset();
 680                 r = _MapInfo_Generate(pFilename);
 681                 if(!r)
 682                         return 0;
 683                 fh = fopen(fn, FILE_WRITE);
 684                 fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
 685                 fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
 686                 fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
 687                 if(_MapInfo_Map_worldspawn_music != "")
 688                 {
 689                         if(
 690                                 substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".wav"
 691                                 ||
 692                                 substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".ogg"
 693                         )
 694                                 fputs(fh, strcat("cdtrack ", substring(_MapInfo_Map_worldspawn_music, 0, strlen(_MapInfo_Map_worldspawn_music) - 4), "\n"));
 695                         else
 696                                 fputs(fh, strcat("cdtrack ", _MapInfo_Map_worldspawn_music, "\n"));
 697                 }
 698                 else
 699                 {
 700                         n = tokenize_console(cvar_string("g_cdtracks_remaplist"));
 701                         s = strcat(" ", cvar_string("g_cdtracks_dontusebydefault"), " ");
 702                         for(;;)
 703                         {
 704                                 i = floor(random() * n);
 705                                 if(strstrofs(s, strcat(" ", argv(i), " "), 0) < 0)
 706                                         break;
 707                         }
 708                         fputs(fh, strcat("cdtrack ", ftos(i + 1), "\n"));
 709                 }
 710                 if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)
 711                         fputs(fh, "has weapons\n");
 712                 else
 713                         fputs(fh, "// uncomment this if you added weapon pickups: has weapons\n");
 714                 if(MapInfo_Map_flags & MAPINFO_FLAG_FRUSTRATING)
 715                         fputs(fh, "frustrating\n");
 716                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DEATHMATCH)      fputs(fh, "type dm 30 20\n");
 717                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_TEAM_DEATHMATCH) fputs(fh, "type tdm 50 20 2\n");
 718                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DOMINATION)      fputs(fh, "type dom 200 20\n");
 719                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_CTF)             fputs(fh, "type ctf 300 20 10\n");
 720                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RUNEMATCH)       fputs(fh, "type rune 200 20\n");
 721                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_LMS)             fputs(fh, "type lms 9 20\n");
 722                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ARENA)           fputs(fh, "type arena 10 20\n");
 723                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_CA)              fputs(fh, "type ca 10 20\n");
 724                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_KEYHUNT)         fputs(fh, "type kh 1000 20 3\n");
 725                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ASSAULT)         fputs(fh, "type as 20\n");
 726                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE)            fputs(fh, "type rc 20 5 7 15\n");
 727                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ONSLAUGHT)       fputs(fh, "type ons 20\n");
 728                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_NEXBALL)         fputs(fh, "type nexball 5 20\n");
 729                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_CTS)             fputs(fh, "type cts 20 -1\n");
 730
 731                 fh2 = fopen(strcat("scripts/", pFilename, ".arena"), FILE_READ);
 732                 if(fh2 >= 0)
 733                 {
 734                         fclose(fh2);
 735                         fputs(fh, "settemp_for_type all sv_q3acompat_machineshotgunswap 1\n");
 736                 }
 737
 738                 fputs(fh, "// optional: fog density red green blue alpha mindist maxdist\n");
 739                 fputs(fh, "// optional: settemp_for_type (all|gametypename) cvarname value\n");
 740                 fputs(fh, "// optional: clientsettemp_for_type (all|gametypename) cvarname value\n");
 741                 fputs(fh, "// optional: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 742                 fputs(fh, "// optional: hidden\n");
 743
 744                 fclose(fh);
 745                 r = 2;
 746                 // return r;
 747                 fh = fopen(fn, FILE_READ);
 748                 if(fh < 0)
 749                         error("... but I just wrote it!");
 750         }
 751
 752         _MapInfo_Map_Reset();
 753         for(;;)
 754         {
 755                 if not((s = fgets(fh)))
 756                         break;
 757
 758                 // catch different sorts of comments
 759                 if(s == "")                    // empty lines
 760                         continue;
 761                 if(substring(s, 0, 1) == "#")  // UNIX style
 762                         continue;
 763                 if(substring(s, 0, 2) == "//") // C++ style
 764                         continue;
 765                 if(substring(s, 0, 1) == "_")  // q3map style
 766                         continue;
 767
 768                 t = car(s); s = cdr(s);
 769                 if(t == "title")
 770                         MapInfo_Map_title = s;
 771                 else if(t == "description")
 772                         MapInfo_Map_description = s;
 773                 else if(t == "author")
 774                         MapInfo_Map_author = s;
 775                 else if(t == "has")
 776                 {
 777                         t = car(s); s = cdr(s);
 778                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 779                         else
 780                                 dprint("Map ", pFilename, " supports unknown feature ", t, ", ignored\n");
 781                 }
 782                 else if(t == "hidden")
 783                 {
 784                         MapInfo_Map_flags |= MAPINFO_FLAG_HIDDEN;
 785                 }
 786                 else if(t == "forbidden")
 787                 {
 788                         MapInfo_Map_flags |= MAPINFO_FLAG_FORBIDDEN;
 789                 }
 790                 else if(t == "frustrating")
 791                 {
 792                         MapInfo_Map_flags |= MAPINFO_FLAG_FRUSTRATING;
 793                 }
 794                 else if(t == "type")
 795                 {
 796                         t = car(s); s = cdr(s);
 797                         f = MapInfo_Type_FromString(t);
 798                         if(f)
 799                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f);
 800                         else
 801                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
 802                 }
 803                 else if(t == "size")
 804                 {
 805                         float a, b, c, d, e;
 806                         t = car(s); s = cdr(s); a = stof(t);
 807                         t = car(s); s = cdr(s); b = stof(t);
 808                         t = car(s); s = cdr(s); c = stof(t);
 809                         t = car(s); s = cdr(s); d = stof(t);
 810                         t = car(s); s = cdr(s); e = stof(t);
 811                         if(s == "")
 812                                 print("Map ", pFilename, " contains an incorrect size line (not enough params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 813                         else
 814                         {
 815                                 t = car(s); s = cdr(s); f = stof(t);
 816                                 if(s != "")
 817                                         print("Map ", pFilename, " contains an incorrect size line (too many params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 818                                 else
 819                                 {
 820                                         if(a >= d || b >= e || c >= f)
 821                                                 print("Map ", pFilename, " contains an incorrect size line, mins have to be < maxs\n");
 822                                         else
 823                                         {
 824                                                 MapInfo_Map_mins_x = a;
 825                                                 MapInfo_Map_mins_y = b;
 826                                                 MapInfo_Map_mins_z = c;
 827                                                 MapInfo_Map_maxs_x = d;
 828                                                 MapInfo_Map_maxs_y = e;
 829                                                 MapInfo_Map_maxs_z = f;
 830                                         }
 831                                 }
 832                         }
 833                 }
 834                 else if(t == "settemp_for_type")
 835                 {
 836                         t = car(s); s = cdr(s);
 837                         if((f = MapInfo_Type_FromString(t)))
 838                         {
 839                                 if(f & pGametypeToSet)
 840                                 {
 841                                         _MapInfo_Parse_Settemp(pFilename, acl, 0, s, 1);
 842                                 }
 843                         }
 844                         else
 845                         {
 846                                 dprint("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored\n");
 847                         }
 848                 }
 849                 else if(t == "clientsettemp_for_type")
 850                 {
 851                         t = car(s); s = cdr(s);
 852                         if((f = MapInfo_Type_FromString(t)))
 853                         {
 854                                 if(f & pGametypeToSet)
 855                                 {
 856                                         _MapInfo_Parse_Settemp(pFilename, acl, 1, s, 1);
 857                                 }
 858                         }
 859                         else
 860                         {
 861                                 dprint("Map ", pFilename, " has a client setting for unknown game type ", t, ", ignored\n");
 862                         }
 863                 }
 864                 else if(t == "fog")
 865                 {
 866                         if not(cvar_value_issafe(t))
 867                                 print("Map ", pFilename, " contains a potentially harmful fog setting, ignored\n");
 868                         else
 869                                 MapInfo_Map_fog = s;
 870                 }
 871                 else if(t == "cdtrack")
 872                 {
 873                         if(pGametypeToSet)
 874                         {
 875                                 if not(cvar_value_issafe(t))
 876                                         print("Map ", pFilename, " contains a potentially harmful cdtrack, ignored\n");
 877                                 else
 878                                         MapInfo_Map_clientstuff = strcat(
 879                                                 MapInfo_Map_clientstuff, "cd loop \"", s, "\"\n"
 880                                         );
 881                         }
 882                 }
 883                 else
 884                         dprint("Map ", pFilename, " provides unknown info item ", t, ", ignored\n");
 885         }
 886         fclose(fh);
 887
 888         if(pGametypeToSet)
 889         {
 890                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet))
 891                 {
 892                         print("Can't select the requested game type. Trying anyway with stupid settings.\n");
 893                         _MapInfo_Map_ApplyGametype("0 0 0", pGametypeToSet, MAPINFO_TYPE_DEATHMATCH);
 894                 }
 895         }
 896
 897         MapInfo_Cache_Store();
 898         if(MapInfo_Map_supportedGametypes != 0)
 899                 return r;
 900         dprint("Map ", pFilename, " supports no game types, ignored\n");
 901         return 0;
 902 }
 903
 904 float MapInfo_FindName(string s)
 905 {
 906         // if there is exactly one map of prefix s, return it
 907         // if not, return the null string
 908         // note that DP sorts glob results... so I can use a binary search
 909         float l, r, m, cmp;
 910         l = 0;
 911         r = MapInfo_count;
 912         // invariants: r is behind s, l-1 is equal or before
 913         while(l != r)
 914         {
 915                 m = floor((l + r) / 2);
 916                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
 917                 cmp = strcasecmp(MapInfo_FindName_match, s);
 918                 if(cmp == 0)
 919                         return m; // found and good
 920                 if(cmp < 0)
 921                         l = m + 1; // l-1 is before s
 922                 else
 923                         r = m; // behind s
 924         }
 925         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
 926         MapInfo_FindName_firstResult = l;
 927         // r == l, so: l is behind s, l-1 is before
 928         // SO: if there is any, l is the one with the right prefix
 929         //     and l+1 may be one too
 930         if(l == MapInfo_count)
 931         {
 932                 MapInfo_FindName_match = string_null;
 933                 MapInfo_FindName_firstResult = -1;
 934                 return -1; // no MapInfo_FindName_match, behind last item
 935         }
 936         if(!startsWithNocase(MapInfo_FindName_match, s))
 937         {
 938                 MapInfo_FindName_match = string_null;
 939                 MapInfo_FindName_firstResult = -1;
 940                 return -1; // wrong prefix
 941         }
 942         if(l == MapInfo_count - 1)
 943                 return l; // last one, nothing can follow => unique
 944         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
 945         {
 946                 MapInfo_FindName_match = string_null;
 947                 return -1; // ambigous MapInfo_FindName_match
 948         }
 949         return l;
 950 }
 951
 952 string MapInfo_FixName(string s)
 953 {
 954         MapInfo_FindName(s);
 955         return MapInfo_FindName_match;
 956 }
 957
 958 float MapInfo_CurrentFeatures()
 959 {
 960         float req;
 961         req = 0;
 962         if(!(cvar("g_lms") || cvar("g_minstagib") || cvar("g_nixnex") || cvar("g_weaponarena") || !cvar("g_pickup_items") || cvar("g_race") || cvar("g_cts") || cvar("g_nexball")))
 963                 req |= MAPINFO_FEATURE_WEAPONS;
 964         return req;
 965 }
 966
 967 float MapInfo_CurrentGametype()
 968 {
 969         if(cvar("g_domination"))
 970                 return MAPINFO_TYPE_DOMINATION;
 971         else if(cvar("g_ctf"))
 972                 return MAPINFO_TYPE_CTF;
 973         else if(cvar("g_runematch"))
 974                 return MAPINFO_TYPE_RUNEMATCH;
 975         else if(cvar("g_tdm"))
 976                 return MAPINFO_TYPE_TEAM_DEATHMATCH;
 977         else if(cvar("g_assault"))
 978                 return MAPINFO_TYPE_ASSAULT;
 979         else if(cvar("g_lms"))
 980                 return MAPINFO_TYPE_LMS;
 981         else if(cvar("g_arena"))
 982                 return MAPINFO_TYPE_ARENA;
 983         else if(cvar("g_ca"))
 984                 return MAPINFO_TYPE_CA;
 985         else if(cvar("g_keyhunt"))
 986                 return MAPINFO_TYPE_KEYHUNT;
 987         else if(cvar("g_onslaught"))
 988                 return MAPINFO_TYPE_ONSLAUGHT;
 989         else if(cvar("g_race"))
 990                 return MAPINFO_TYPE_RACE;
 991         else if(cvar("g_nexball"))
 992                 return MAPINFO_TYPE_NEXBALL;
 993         else if(cvar("g_cts"))
 994                 return MAPINFO_TYPE_CTS;
 995         else
 996                 return MAPINFO_TYPE_DEATHMATCH;
 997 }
 998
 999 float _MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1000 {
1001         if(!MapInfo_Get_ByName(s, 1, 0))
1002                 return 0;
1003         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype()) == 0)
1004                 return 0;
1005         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
1006                 return 0;
1007         return 1;
1008 }
1009
1010 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1011 {
1012         float r;
1013         r = _MapInfo_CheckMap(s);
1014         MapInfo_ClearTemps();
1015         return r;
1016 }
1017
1018 string MapInfo_GetGameTypeCvar(float t)
1019 {
1020         switch(t)
1021         {
1022                 case MAPINFO_TYPE_DEATHMATCH: return "g_dm";
1023                 case MAPINFO_TYPE_TEAM_DEATHMATCH: return "g_tdm";
1024                 case MAPINFO_TYPE_DOMINATION: return "g_domination";
1025                 case MAPINFO_TYPE_CTF: return "g_ctf";
1026                 case MAPINFO_TYPE_RUNEMATCH: return "g_runematch";
1027                 case MAPINFO_TYPE_LMS: return "g_lms";
1028                 case MAPINFO_TYPE_ARENA: return "g_arena";
1029                 case MAPINFO_TYPE_CA: return "g_ca";
1030                 case MAPINFO_TYPE_KEYHUNT: return "g_kh";
1031                 case MAPINFO_TYPE_ASSAULT: return "g_assault";
1032                 case MAPINFO_TYPE_ONSLAUGHT: return "g_onslaught";
1033                 case MAPINFO_TYPE_RACE: return "g_race";
1034                 case MAPINFO_TYPE_NEXBALL: return "g_nexball";
1035                 case MAPINFO_TYPE_CTS: return "g_cts";
1036                 default: return "";
1037         }
1038 }
1039
1040 void MapInfo_SwitchGameType(float t)
1041 {
1042         cvar_set("gamecfg",      "0");
1043         cvar_set("g_dm",         (t == MAPINFO_TYPE_DEATHMATCH)      ? "1" : "0");
1044         cvar_set("g_tdm",        (t == MAPINFO_TYPE_TEAM_DEATHMATCH) ? "1" : "0");
1045         cvar_set("g_domination", (t == MAPINFO_TYPE_DOMINATION)      ? "1" : "0");
1046         cvar_set("g_ctf",        (t == MAPINFO_TYPE_CTF)             ? "1" : "0");
1047         cvar_set("g_runematch",  (t == MAPINFO_TYPE_RUNEMATCH)       ? "1" : "0");
1048         cvar_set("g_lms",        (t == MAPINFO_TYPE_LMS)             ? "1" : "0");
1049         cvar_set("g_arena",      (t == MAPINFO_TYPE_ARENA)           ? "1" : "0");
1050         cvar_set("g_ca",         (t == MAPINFO_TYPE_CA)              ? "1" : "0");
1051         cvar_set("g_keyhunt",    (t == MAPINFO_TYPE_KEYHUNT)         ? "1" : "0");
1052         cvar_set("g_assault",    (t == MAPINFO_TYPE_ASSAULT)         ? "1" : "0");
1053         cvar_set("g_onslaught",  (t == MAPINFO_TYPE_ONSLAUGHT)       ? "1" : "0");
1054         cvar_set("g_race",       (t == MAPINFO_TYPE_RACE)            ? "1" : "0");
1055         cvar_set("g_nexball",    (t == MAPINFO_TYPE_NEXBALL)         ? "1" : "0");
1056         cvar_set("g_cts",        (t == MAPINFO_TYPE_CTS)             ? "1" : "0");
1057 }
1058
1059 void MapInfo_LoadMap(string s)
1060 {
1061         MapInfo_Map_supportedGametypes = 0;
1062         if(!MapInfo_CheckMap(s))
1063         {
1064                 print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
1065                 MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH);
1066         }
1067         localcmd(strcat("\nsettemp_restore\nchangelevel ", s, "\n"));
1068 }
1069
1070 string MapInfo_ListAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1071 {
1072         string out;
1073         float i;
1074
1075         // to make absolutely sure:
1076         MapInfo_Enumerate();
1077         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1078
1079         out = "";
1080         for(i = 0; i < MapInfo_count; ++i)
1081                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1082         return substring(out, 1, strlen(out) - 1);
1083 }
1084
1085 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
1086 {
1087         float t, t0;
1088         if(!_MapInfo_CheckMap(s)) // with underscore, it keeps temps
1089         {
1090                 if(MapInfo_Map_supportedGametypes <= 0)
1091                         error("Mapinfo system is not functional at all. BAILED OUT.\n");
1092
1093                 t = 1;
1094                 while(!(MapInfo_Map_supportedGametypes & 1))
1095                 {
1096                         t *= 2;
1097                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes / 2);
1098                 }
1099                 // t is now a supported mode!
1100                 t0 = MapInfo_CurrentGametype();
1101                 if(cvar("g_mapinfo_allow_unsupported_modes_and_let_stuff_break"))
1102                 {
1103                         print("EMERGENCY: can't play the selected map in the given game mode. Working with only the override settings.\n");
1104                         cvar_set("timelimit", "0");
1105                         cvar_set("fraglimit", "0");
1106                         cvar_set("g_tdm_teams", "2");
1107                         cvar_set("g_keyhunt_teams", "3");
1108                         cvar_set("g_race_qualifying_timelimit", "0");
1109                         cvar_set("leadlimit", "0");
1110                 }
1111                 else
1112                 {
1113                         print("EMERGENCY: can't play the selected map in the given game mode. Falling back to a supported mode.\n");
1114                         MapInfo_SwitchGameType(t);
1115                 }
1116         }
1117         cvar_settemp_restore();
1118         MapInfo_Get_ByName(s, 1, MapInfo_CurrentGametype());
1119 }
1120
1121 void MapInfo_ClearTemps()
1122 {
1123         MapInfo_Map_bspname = string_null;
1124         MapInfo_Map_title = string_null;
1125         MapInfo_Map_description = string_null;
1126         MapInfo_Map_author = string_null;
1127         MapInfo_Map_clientstuff = string_null;
1128         MapInfo_Map_supportedGametypes = 0;
1129         MapInfo_Map_supportedFeatures = 0;
1130 }
1131
1132 void MapInfo_Shutdown()
1133 {
1134         MapInfo_ClearTemps();
1135         MapInfo_Filter_Free();
1136         MapInfo_Cache_Destroy();
1137         if(_MapInfo_globopen)
1138         {
1139                 search_end(_MapInfo_globhandle);
1140                 _MapInfo_globhandle = -1;
1141                 _MapInfo_globopen = FALSE;
1142         }
1143 }
1144
1145 float MapInfo_ForbiddenFlags()
1146 {
1147         float f;
1148         f = MAPINFO_FLAG_FORBIDDEN;
1149
1150 #ifndef MENUQC
1151         if not(cvar("g_maplist_allow_hidden"))
1152 #endif
1153                 f |= MAPINFO_FLAG_HIDDEN;
1154
1155         if not(cvar("g_maplist_allow_frustrating"))
1156                 f |= MAPINFO_FLAG_FRUSTRATING;
1157
1158         return f;
1159 }
1160
1161 float MapInfo_RequiredFlags()
1162 {
1163         float f;
1164         f = 0;
1165
1166         if(cvar("g_maplist_allow_frustrating") > 1)
1167                 f |= MAPINFO_FLAG_FRUSTRATING;
1168
1169         return f;
1170 }