data/qcsrc/common/gamecommand.qc

   1 #define MAX_RPN_STACK 16
   2 float rpn_db;
   3 float rpn_error;
   4 float rpn_sp;
   5 string rpn_stack[MAX_RPN_STACK];
   6 string rpn_pop() {
   7         if(rpn_sp > 0) {
   8                 --rpn_sp;
   9                 return rpn_stack[rpn_sp];
  10         } else {
  11                 print("rpn: stack underflow\n");
  12                 rpn_error = TRUE;
  13                 return "";
  14         }
  15 }
  16 void rpn_push(string s) {
  17         if(rpn_sp < MAX_RPN_STACK) {
  18                 rpn_stack[rpn_sp] = s;
  19                 ++rpn_sp;
  20         } else {
  21                 print("rpn: stack overflow\n");
  22                 rpn_error = TRUE;
  23         }
  24 }
  25 string rpn_get() {
  26         if(rpn_sp > 0) {
  27                 return rpn_stack[rpn_sp - 1];
  28         } else {
  29                 print("rpn: empty stack\n");
  30                 rpn_error = TRUE;
  31                 return "";
  32         }
  33 }
  34 void rpn_set(string s) {
  35         if(rpn_sp > 0) {
  36                 rpn_stack[rpn_sp - 1] = s;
  37         } else {
  38                 print("rpn: empty stack\n");
  39                 rpn_error = TRUE;
  40         }
  41 }
  42 float rpn_getf() { return stof(rpn_get()); }
  43 float rpn_popf() { return stof(rpn_pop()); }
  44 void rpn_pushf(float f) { return rpn_push(ftos(f)); }
  45 void rpn_setf(float f) { return rpn_set(ftos(f)); }
  46
  47 float GameCommand_Generic(string command)
  48 {
  49         float argc;
  50         float i, j, f, n;
  51         string s, s2;
  52         argc = tokenize_sane(command);
  53         if(argv(0) == "help")
  54         {
  55                 print("  rpn EXPRESSION... - a RPN calculator.\n");
  56                 print("    Operator description (x: string, s: set, f: float):\n");
  57                 print("    x pop ----------------------------->     : removes the top\n");
  58                 print("    x dup -----------------------------> x x : duplicates the top\n");
  59                 print("    x x exch --------------------------> x x : swap the top two\n");
  60                 print("    /cvarname load --------------------> x   : loads a cvar\n");
  61                 print("    /cvarname x def ------------------->     : writes to a cvar\n");
  62                 print("    f f add|sub|mul|div|mod|max|min ---> f   : adds/... two numbers\n");
  63                 print("    f f eq|ne|gt|ge|lt|le -------------> f   : compares two numbers\n");
  64                 print("    f neg|abs|sgn|rand|floor|ceil------> f   : negates/... a number\n");
  65                 print("    f f f bound -----------------------> f   : bounds the middle number\n");
  66                 print("    f1 f2 b when ----------------------> f   : f1 if b, f2 otherwise\n");
  67                 print("    s s union|intersection|difference -> s   : set operations\n");
  68                 print("    s shuffle -------------------------> s   : randomly arrange elements\n");
  69                 print("    x dbpush -------------------------->     : pushes the top onto the database\n");
  70                 print("    dbpop|dbget -----------------------> x   : removes/reads DB's top\n");
  71                 print("    dblen|dbat ------------------------> f   : gets the DB's size/cursor pos\n");
  72                 print("    dbclr ----------------------------->     : clear the DB\n");
  73                 print("    s dbsave|dbload-------------------->     : save/load the DB to/from a file\n");
  74                 print("    x dbins --------------------------->     : moves the top into the DB\n");
  75                 print("    dbext|dbread ----------------------> x   : extract/get from the DB's cursor\n");
  76                 print("    f dbmov|dbgoto -------------------->     : move or set the DB's cursor\n");
  77                 print("    Set operations operate on 'such''strings'.\n");
  78                 print("    Unknown tokens insert their cvar value.\n");
  79                 print("  maplist add map\n");
  80                 print("  maplist remove map\n");
  81                 print("  maplist shuffle\n");
  82                 print("  suggestmap map\n");
  83                 return TRUE;
  84         }
  85
  86         if(argv(0) == "maplist")
  87         {
  88                 if(argv(1) == "add" && argc == 3)
  89                 {
  90                         f = fopen(strcat("maps/", argv(2), ".bsp"), FILE_READ);
  91                         if(f != -1)
  92                                 fclose(f);
  93                         else {
  94                                 print("maplist: ERROR: ", argv(2), " does not exist!\n");
  95                                 return TRUE;
  96                         }
  97                         if(cvar_string("g_maplist") == "")
  98                                 cvar_set("g_maplist", argv(2));
  99                         else
 100                                 cvar_set("g_maplist", strcat(argv(2), " ", cvar_string("g_maplist")));
 101                         return TRUE;
 102                 }
 103                 else if(argv(1) == "remove" && argc == 3)
 104                 {
 105                         s = argv(2);
 106                         n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 107                         s2 = "";
 108                         for(i = 0; i < n; ++i)
 109                                 if(argv(i) != s)
 110                                 {
 111                                         s2 = strcat(s2, " ", argv(i));
 112                                 }
 113                         s2 = substring(s2, 1, strlen(s2) - 1);
 114                         cvar_set("g_maplist", s2);
 115                         return TRUE;
 116                 }
 117                 else if(argv(1) == "shuffle" && argc == 2)
 118                 {
 119                         s = cvar_string("g_maplist");
 120                         for(i = 1; i < (n = tokenizebyseparator(s, " ")); ++i)
 121                         {
 122                                 // swap i-th item at a random position from 0 to i
 123                                 // proof for even distribution:
 124                                 //   n = 1: obvious
 125                                 //   n -> n+1:
 126                                 //     item n+1 gets at any position with chance 1/(n+1)
 127                                 //     all others will get their 1/n chance reduced by factor n/(n+1)
 128                                 //     to be on place n+1, their chance will be 1/(n+1)
 129                                 //     1/n * n/(n+1) = 1/(n+1)
 130                                 //     q.e.d.
 131                                 f = floor(random() * (i + 1)); // 0 to i
 132                                 if(f == i)
 133                                         continue; // no change
 134
 135                                 s2 = "";
 136                                 for(j = 0; j < n; ++j)
 137                                         s2 = strcat(s2, " ", argv((j == i) ? f : (j == f) ? i : j));
 138                                 s = substring(s2, 1, strlen(s2) - 1);
 139                         }
 140                         cvar_set("g_maplist", s);
 141                         return TRUE;
 142                 }
 143         }
 144         else if(argv(0) == "rpn")
 145         {
 146                 if(!rpn_db)
 147                 {
 148                         rpn_db = db_create();
 149                         db_put(rpn_db, "stack.pointer", "0");
 150                         db_put(rpn_db, "stack.pos", "-1");
 151                 }
 152                 if(argc >= 2)
 153                 {
 154                         float rpnpos;
 155                         string rpncmd;
 156                         float f2, f3;
 157                         rpn_sp = 0;
 158                         rpn_error = FALSE;
 159                         for(rpnpos = 1; rpnpos < argc; ++rpnpos)
 160                         {
 161                                 rpncmd = argv(rpnpos);
 162                                 f = strlen(rpncmd);
 163                                 if(rpncmd == "") {
 164                                 } else if(stof(substring(rpncmd, 0, 1)) > 0) {
 165                                         rpn_push(rpncmd);
 166                                 } else if(substring(rpncmd, 0, 1) == "0") {
 167                                         rpn_push(rpncmd);
 168                                 } else if(f >= 2 && substring(rpncmd, 0, 1) == "+") {
 169                                         rpn_push(rpncmd);
 170                                 } else if(f >= 2 && substring(rpncmd, 0, 1) == "-") {
 171                                         rpn_push(rpncmd);
 172                                 } else if(f >= 2 && substring(rpncmd, 0, 1) == "/") {
 173                                         rpn_push(substring(rpncmd, 1, strlen(rpncmd) - 1));
 174                                 } else if(rpncmd == "clear") {
 175                                         rpn_sp = 0;
 176                                 } else if(rpncmd == "def" || rpncmd == "=") {
 177                                         s = rpn_pop();
 178                                         s2 = rpn_pop();
 179 #ifdef MENUQC
 180                                         registercvar(s2, "", 0);
 181 #else
 182                                         registercvar(s2, "");
 183 #endif
 184                                         if(!rpn_error) // don't change cvars if a stack error had happened!
 185                                                 cvar_set(s2, s);
 186                                 } else if(rpncmd == "defs" || rpncmd == "@") {
 187                                         s = "";
 188                                         i = rpn_popf();
 189                                         j = (i == 0);
 190                                         while(rpn_sp > 1 && (j || i > 0))
 191                                         {
 192                                                 s = strcat("/", rpn_pop(), " ", s);
 193                                                 --i;
 194                                         }
 195                                         s2 = rpn_pop();
 196 #ifdef MENUQC
 197                                         registercvar(s2, "", 0);
 198 #else
 199                                         registercvar(s2, "");
 200 #endif
 201                                         if(!rpn_error) // don't change cvars if a stack error had happened!
 202                                                 cvar_set(s2, s);
 203                                 } else if(rpncmd == "load") {
 204                                         rpn_set(cvar_string(rpn_get()));
 205                                 } else if(rpncmd == "exch") {
 206                                         s = rpn_pop();
 207                                         s2 = rpn_get();
 208                                         rpn_set(s);
 209                                         rpn_push(s2);
 210                                 } else if(rpncmd == "dup") {
 211                                         rpn_push(rpn_get());
 212                                 } else if(rpncmd == "pop") {
 213                                         rpn_pop();
 214                                 } else if(rpncmd == "add" || rpncmd == "+") {
 215                                         f = rpn_popf();
 216                                         rpn_setf(rpn_getf() + f);
 217                                 } else if(rpncmd == "sub" || rpncmd == "-") {
 218                                         f = rpn_popf();
 219                                         rpn_setf(rpn_getf() - f);
 220                                 } else if(rpncmd == "mul" || rpncmd == "*") {
 221                                         f = rpn_popf();
 222                                         rpn_setf(rpn_getf() * f);
 223                                 } else if(rpncmd == "div" || rpncmd == "/") {
 224                                         f = rpn_popf();
 225                                         rpn_setf(rpn_getf() / f);
 226                                 } else if(rpncmd == "mod" || rpncmd == "%") {
 227                                         f = rpn_popf();
 228                                         f2 = rpn_getf();
 229                                         rpn_setf(f2 - f * floor(f2 / f));
 230                                 } else if(rpncmd == "abs") {
 231                                         rpn_setf(fabs(rpn_getf()));
 232                                 } else if(rpncmd == "sgn") {
 233                                         f = rpn_getf();
 234                                         if(f < 0)
 235                                                 rpn_set("-1");
 236                                         else if(f > 0)
 237                                                 rpn_set("1");
 238                                         else
 239                                                 rpn_set("0");
 240                                 } else if(rpncmd == "neg" || rpncmd == "~") {
 241                                         rpn_setf(-rpn_getf());
 242                                 } else if(rpncmd == "floor" || rpncmd == "f") {
 243                                         rpn_setf(floor(rpn_getf()));
 244                                 } else if(rpncmd == "ceil" || rpncmd == "c") {
 245                                         rpn_setf(ceil(rpn_getf()));
 246                                 } else if(rpncmd == "max") {
 247                                         f = rpn_popf();
 248                                         f2 = rpn_getf();
 249                                         rpn_setf(max(f2, f));
 250                                 } else if(rpncmd == "min") {
 251                                         f = rpn_popf();
 252                                         f2 = rpn_getf();
 253                                         rpn_setf(min(f2, f));
 254                                 } else if(rpncmd == "bound") {
 255                                         f = rpn_popf();
 256                                         f2 = rpn_popf();
 257                                         f3 = rpn_getf();
 258                                         rpn_setf(bound(f3, f2, f));
 259                                 } else if(rpncmd == "when") {
 260                                         f = rpn_popf();
 261                                         f2 = rpn_popf();
 262                                         f3 = rpn_getf();
 263                                         if(f)
 264                                                 rpn_setf(f3);
 265                                         else
 266                                                 rpn_setf(f2);
 267                                 } else if(rpncmd == ">" || rpncmd == "gt") {
 268                                         f = rpn_popf();
 269                                         rpn_setf(rpn_getf() > f);
 270                                 } else if(rpncmd == "<" || rpncmd == "lt") {
 271                                         f = rpn_popf();
 272                                         rpn_setf(rpn_getf() < f);
 273                                 } else if(rpncmd == "==" || rpncmd == "eq") {
 274                                         f = rpn_popf();
 275                                         rpn_setf(rpn_getf() == f);
 276                                 } else if(rpncmd == ">=" || rpncmd == "ge") {
 277                                         f = rpn_popf();
 278                                         rpn_setf(rpn_getf() >= f);
 279                                 } else if(rpncmd == "<=" || rpncmd == "le") {
 280                                         f = rpn_popf();
 281                                         rpn_setf(rpn_getf() <= f);
 282                                 } else if(rpncmd == "!=" || rpncmd == "ne") {
 283                                         f = rpn_popf();
 284                                         rpn_setf(rpn_getf() != f);
 285                                 } else if(rpncmd == "rand") {
 286                                         rpn_setf(ceil(random() * rpn_getf()) - 1);
 287                                 } else if(rpncmd == "dbpush") {
 288                                         s = rpn_pop();
 289                                         if(!rpn_error)
 290                                         {
 291                                                 i = stof(db_get(rpn_db, "stack.pointer"));
 292                                                 db_put(rpn_db, "stack.pointer", ftos(i+1));
 293                                                 db_put(rpn_db, strcat("stack.", ftos(i)), s);
 294                                         }
 295                                         if(!i)
 296                                                 db_put(rpn_db, "stack.pos", "0");
 297                                 } else if(rpncmd == "dbpop") {
 298                                         i = stof(db_get(rpn_db, "stack.pointer"));
 299                                         if(i)
 300                                         {
 301                                                 s = ftos(i-1);
 302                                                 db_put(rpn_db, "stack.pointer", s);
 303                                                 rpn_push(db_get(rpn_db, strcat("stack.", s)));
 304                                                 j = stof(db_get(rpn_db, "stack.pos"));
 305                                                 if(j >= i)
 306                                                         db_put(rpn_db, "stack.pos", ftos(i-2));
 307                                         } else {
 308                                                 rpn_error = 1;
 309                                                 print("rpn: database underflow\n");
 310                                         }
 311                                 } else if(rpncmd == "dbget") {
 312
 313                                         i = stof(db_get(rpn_db, "stack.pointer"));
 314                                         if(i)
 315                                         {
 316                                                 rpn_push(db_get(rpn_db, strcat("stack.", ftos(i-1))));
 317                                         } else {
 318                                                 rpn_error = 1;
 319                                                 print("rpn: database empty\n");
 320                                         }
 321                                 } else if(rpncmd == "dblen") {
 322                                         rpn_push(db_get(rpn_db, "stack.pointer"));
 323                                 } else if(rpncmd == "dbclr") {
 324                                         db_close(rpn_db);
 325                                         rpn_db = db_create();
 326                                         db_put(rpn_db, "stack.pointer", "0");
 327                                         db_put(rpn_db, "stack.pos", "-1");
 328                                 } else if(rpncmd == "dbsave") {
 329                                         s = rpn_pop();
 330                                         if(!rpn_error)
 331                                                 db_save(rpn_db, s);
 332                                 } else if(rpncmd == "dbload") {
 333                                         s = rpn_pop();
 334                                         if(!rpn_error)
 335                                         {
 336                                                 db_close(rpn_db);
 337                                                 rpn_db = db_load(s);
 338                                         }
 339                                 } else if(rpncmd == "dbins") {
 340                                         s = rpn_pop();
 341                                         if(!rpn_error)
 342                                                 //if(rpn_sp > 0)
 343                                         {
 344                                                 j = stof(db_get(rpn_db, "stack.pointer"));
 345                                                 i = stof(db_get(rpn_db, "stack.pos"));
 346
 347                                                 if(i < 0)
 348                                                 {
 349                                                         i = 0;
 350                                                         db_put(rpn_db, "stack.pos", "0");
 351                                                 }
 352
 353                                                 db_put(rpn_db, "stack.pointer", ftos(j+1));
 354                                                 for(--j; j >= i; --j)
 355                                                 {
 356                                                         db_put(rpn_db, strcat("stack.", ftos(j+1)),
 357                                                                db_get(rpn_db, (strcat("stack.", ftos(j))))
 358                                                                 );
 359                                                 }
 360                                                 db_put(rpn_db, strcat("stack.", ftos(i)), s);
 361                                         }
 362                                 } else if(rpncmd == "dbext") {
 363                                         j = stof(db_get(rpn_db, "stack.pointer"));
 364                                         i = stof(db_get(rpn_db, "stack.pos"));
 365                                         if(!j)
 366                                         {
 367                                                 rpn_error = TRUE;
 368                                                 print("rpn: empty database\n");
 369                                         } else {
 370                                                 --j;
 371                                                 rpn_push(db_get(rpn_db, strcat("stack.", ftos(i))));
 372                                                 db_put(rpn_db, "stack.pointer", ftos(j));
 373                                                 if(i == j)
 374                                                 {
 375                                                         db_put(rpn_db, "stack.pos", ftos(j-1));
 376                                                 } else {
 377                                                         while(i < j)
 378                                                         {
 379                                                                 db_put(rpn_db, strcat("stack.", ftos(i)),
 380                                                                        db_get(rpn_db, (strcat("stack.", ftos(i+1))))
 381                                                                         );
 382                                                                 ++i;
 383                                                         }
 384                                                 }
 385                                         }
 386                                 } else if(rpncmd == "dbread") {
 387                                         s = db_get(rpn_db, "stack.pos");
 388                                         if(stof(s) >= 0)
 389                                         {
 390                                                 rpn_push(db_get(rpn_db, strcat("stack.", s)));
 391                                         } else {
 392                                                 rpn_error = 1;
 393                                                 print("rpn: empty database\n");
 394                                         }
 395                                 } else if(rpncmd == "dbat") {
 396                                         rpn_push(db_get(rpn_db, "stack.pos"));
 397                                 } else if(rpncmd == "dbmov") {
 398                                         j = stof(db_get(rpn_db, "stack.pointer"));
 399                                         i = stof(db_get(rpn_db, "stack.pos"));
 400                                         i += rpn_popf();
 401                                         if(!rpn_error)
 402                                         {
 403                                                 if(i < 0 || i >= j)
 404                                                 {
 405                                                         print("rpn: database cursor out of bounds\n");
 406                                                         rpn_error = TRUE;
 407                                                 }
 408                                                 if(!rpn_error)
 409                                                 {
 410                                                         db_put(rpn_db, "stack.pos", ftos(i));
 411                                                 }
 412                                         }
 413                                 } else if(rpncmd == "dbgoto") {
 414                                         s = rpn_pop();
 415                                         j = stof(db_get(rpn_db, "stack.pointer"));
 416                                         if(!j)
 417                                         {
 418                                                 rpn_error = TRUE;
 419                                                 print("rpn: empty database, cannot move cursor\n");
 420                                         }
 421                                         if(!rpn_error)
 422                                         {
 423                                                 if(s == "end")
 424                                                         i = stof(db_get(rpn_db, "stack.pointer"))-1;
 425                                                 else if(s == "beg")
 426                                                         i = 0;
 427                                                 else
 428                                                         i = stof(s);
 429
 430                                                 j = stof(db_get(rpn_db, "stack.pointer"));
 431                                                 if(i < 0 || i >= j)
 432                                                 {
 433                                                         print("rpn: database cursor destination out of bounds\n");
 434                                                         rpn_error = TRUE;
 435                                                 }
 436                                                 if(!rpn_error)
 437                                                 {
 438                                                         db_put(rpn_db, "stack.pos", ftos(i));
 439                                                 }
 440                                         }
 441                                 } else if(rpncmd == "union") {
 442                                         // s s2 union
 443                                         s2 = rpn_pop();
 444                                         s = rpn_get();
 445                                         f = tokenize_sane(s);
 446                                         f2 = tokenize_sane(strcat(s, " ", s2));
 447                                         // tokens 0..(f-1) represent s
 448                                         // tokens f..f2 represent s2
 449                                         // UNION: add all tokens to s that are in s2 but not in s
 450                                         s = "";
 451                                         for(i = 0; i < f; ++i)
 452                                                 s = strcat(s, " ", argv(i));
 453                                         for(i = f; i < f2; ++i) {
 454                                                 for(j = 0; j < f; ++j)
 455                                                         if(argv(i) == argv(j))
 456                                                                 goto skip_union;
 457                                                 s = strcat(s, " ", argv(i));
 458 :skip_union
 459                                         }
 460                                         if(substring(s, 0, 1) == " ")
 461                                                 s = substring(s, 1, 99999);
 462                                         rpn_set(s);
 463                                         tokenize_sane(command);
 464                                 } else if(rpncmd == "intersection") {
 465                                         // s s2 intersection
 466                                         s2 = rpn_pop();
 467                                         s = rpn_get();
 468                                         f = tokenize_sane(s);
 469                                         f2 = tokenize_sane(strcat(s, " ", s2));
 470                                         // tokens 0..(f-1) represent s
 471                                         // tokens f..f2 represent s2
 472                                         // INTERSECTION: keep only the tokens from s that are also in s2
 473                                         s = "";
 474                                         for(i = 0; i < f; ++i) {
 475                                                 for(j = f; j < f2; ++j)
 476                                                         if(argv(i) == argv(j))
 477                                                         {
 478                                                                 s = strcat(s, " ", argv(i));
 479                                                                 break;
 480                                                         }
 481                                         }
 482                                         if(substring(s, 0, 1) == " ")
 483                                                 s = substring(s, 1, 99999);
 484                                         rpn_set(s);
 485                                         tokenize_sane(command);
 486                                 } else if(rpncmd == "difference") {
 487                                         // s s2 difference
 488                                         s2 = rpn_pop();
 489                                         s = rpn_get();
 490                                         f = tokenize_sane(s);
 491                                         f2 = tokenize_sane(strcat(s, " ", s2));
 492                                         // tokens 0..(f-1) represent s
 493                                         // tokens f..f2 represent s2
 494                                         // DIFFERENCE: keep only the tokens from s that are not in s2
 495                                         s = "";
 496                                         for(i = 0; i < f; ++i) {
 497                                                 for(j = f; j < f2; ++j)
 498                                                         if(argv(i) == argv(j))
 499                                                                 goto skip_difference;
 500                                                 s = strcat(s, " ", argv(i));
 501 :skip_difference
 502                                         }
 503                                         if(substring(s, 0, 1) == " ")
 504                                                 s = substring(s, 1, 99999);
 505                                         rpn_set(s);
 506                                         tokenize_sane(command);
 507                                 } else if(rpncmd == "shuffle") {
 508                                         // s shuffle
 509                                         s = rpn_get();
 510                                         f = tokenize_sane(s);
 511
 512                                         for(i = 0; i < f - 1; ++i) {
 513                                                 // move a random item from i..f-1 to position i
 514                                                 s = "";
 515                                                 f2 = floor(random() * (f - i) + i);
 516                                                 for(j = 0; j < i; ++j)
 517                                                         s = strcat(s, " ", argv(j));
 518                                                 s = strcat(s, " ", argv(f2));
 519                                                 for(j = i; j < f; ++j)
 520                                                         if(j != f2)
 521                                                                 s = strcat(s, " ", argv(j));
 522                                                 f = tokenize_sane(s);
 523                                         }
 524
 525                                         if(substring(s, 0, 1) == " ")
 526                                                 s = substring(s, 1, 99999);
 527                                         rpn_set(s);
 528                                         tokenize_sane(command);
 529                                         } else if(rpncmd == "fexists_assert") {
 530                                         s = rpn_pop();
 531                                         if(!rpn_error)
 532                                         {
 533                                                 f = fopen(s, FILE_READ);
 534                                                 if(f != -1)
 535                                                         fclose(f);
 536                                                 else {
 537                                                         print("rpn: ERROR: ", s, " does not exist!\n");
 538                                                         rpn_error = TRUE;
 539                                                 }
 540                                         }
 541                                 } else {
 542                                         rpn_push(cvar_string(rpncmd));
 543                                 }
 544                                 if(rpn_error)
 545                                         break;
 546                         }
 547                         while(rpn_sp > 0)
 548                         {
 549                                 s = rpn_pop();
 550                                 print("rpn: still on stack: ", s, "\n");
 551                         }
 552                         return TRUE;
 553                 }
 554 #ifdef MENUQC
 555         } else if(argv(0) == "cp") {
 556                 if(argc >= 2)
 557                 {
 558                         s = argv(1);
 559                         for(i = 2; i < argc; ++i)
 560                                 s = strcat(s, " ", argv(i));
 561                         centerprint(unescape(s));
 562                 }
 563                 return TRUE;
 564 #endif
 565         } else if(argv(0) == "suggestmap") {
 566                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 567         }
 568
 569         return FALSE;
 570 }