data/qcsrc/common/gamecommand.qc

   1 #define MAX_RPN_STACK 16
   2 float rpn_db;
   3 float rpn_error;
   4 float rpn_sp;
   5 string rpn_stack[MAX_RPN_STACK];
   6 string rpn_pop() {
   7         if(rpn_sp > 0) {
   8                 --rpn_sp;
   9                 return rpn_stack[rpn_sp];
  10         } else {
  11                 print("rpn: stack underflow\n");
  12                 rpn_error = TRUE;
  13                 return "";
  14         }
  15 }
  16 void rpn_push(string s) {
  17         if(rpn_sp < MAX_RPN_STACK) {
  18                 rpn_stack[rpn_sp] = s;
  19                 ++rpn_sp;
  20         } else {
  21                 print("rpn: stack overflow\n");
  22                 rpn_error = TRUE;
  23         }
  24 }
  25 string rpn_get() {
  26         if(rpn_sp > 0) {
  27                 return rpn_stack[rpn_sp - 1];
  28         } else {
  29                 print("rpn: empty stack\n");
  30                 rpn_error = TRUE;
  31                 return "";
  32         }
  33 }
  34 void rpn_set(string s) {
  35         if(rpn_sp > 0) {
  36                 rpn_stack[rpn_sp - 1] = s;
  37         } else {
  38                 print("rpn: empty stack\n");
  39                 rpn_error = TRUE;
  40         }
  41 }
  42 float rpn_getf() { return stof(rpn_get()); }
  43 float rpn_popf() { return stof(rpn_pop()); }
  44 void rpn_pushf(float f) { return rpn_push(ftos(f)); }
  45 void rpn_setf(float f) { return rpn_set(ftos(f)); }
  46
  47 float GameCommand_Generic(string command)
  48 {
  49         float argc;
  50         float i, j, f, n;
  51         string s, s2;
  52         argc = tokenize(command);
  53         if(argv(0) == "help")
  54         {
  55                 print("  rpn EXPRESSION... - a RPN calculator.\n");
  56                 print("    Operator description (x: string, s: set, f: float):\n");
  57                 print("    x pop ----------------------------->     : removes the top\n");
  58                 print("    x dup -----------------------------> x x : duplicates the top\n");
  59                 print("    x x exch --------------------------> x x : swap the top two\n");
  60                 print("    /cvarname load --------------------> x   : loads a cvar\n");
  61                 print("    /cvarname x def ------------------->     : writes to a cvar\n");
  62                 print("    f f add|sub|mul|div|mod|max|min ---> f   : adds/... two numbers\n");
  63                 print("    f f eq|ne|gt|ge|lt|le -------------> f   : compares two numbers\n");
  64                 print("    f neg|abs|sgn|rand|floor|ceil------> f   : negates/... a number\n");
  65                 print("    f f f bound -----------------------> f   : bounds the middle number\n");
  66                 print("    f1 f2 b when ----------------------> f   : f1 if b, f2 otherwise\n");
  67                 print("    s s union|intersection|difference -> s   : set operations\n");
  68                 print("    s shuffle -------------------------> s   : randomly arrange elements\n");
  69                 print("    x dbpush -------------------------->     : pushes the top onto the database\n");
  70                 print("    dbpop|dbget -----------------------> x   : removes/reads DB's top\n");
  71                 print("    dblen|dbat ------------------------> f   : gets the DB's size/cursor pos\n");
  72                 print("    x dbins --------------------------->     : moves the top into the DB\n");
  73                 print("    dbext|dbread ----------------------> x   : extract/get from the DB's cursor\n");
  74                 print("    f dbmov|dbgoto -------------------->     : move or set the DB's cursor\n");
  75                 print("    Set operations operate on 'such''strings'.\n");
  76                 print("    Unknown tokens insert their cvar value.\n");
  77                 print("  maplist add map\n");
  78                 print("  maplist remove map\n");
  79                 print("  maplist shuffle\n");
  80                 return TRUE;
  81         }
  82
  83         if(argv(0) == "maplist")
  84         {
  85                 if(argv(1) == "add" && argc == 3)
  86                 {
  87 #ifdef MAPINFO
  88                         f = fopen(strcat("maps/", argv(2), ".bsp"), FILE_READ);
  89                         if(f != -1)
  90                                 fclose(f);
  91                         else {
  92                                 print("maplist: ERROR: ", argv(2), " does not exist!\n");
  93                                 return TRUE;
  94                         }
  95                         if(cvar_string("g_maplist") == "")
  96                                 cvar_set("g_maplist", argv(2));
  97                         else
  98                                 cvar_set("g_maplist", strcat(argv(2), " ", cvar_string("g_maplist")));
  99 #else
 100                         f = fopen(strcat("maps/", argv(2), ".mapcfg"), FILE_READ);
 101                         if(f != -1)
 102                                 fclose(f);
 103                         else {
 104                                 print("maplist: ERROR: ", argv(2), " does not exist!\n");
 105                                 return TRUE;
 106                         }
 107                         cvar_set("g_maplist", strcat("'", argv(2), "'", cvar_string("g_maplist")));
 108 #endif
 109                         return TRUE;
 110                 }
 111                 else if(argv(1) == "remove" && argc == 3)
 112                 {
 113                         s = argv(2);
 114 #ifdef MAPINFO
 115                         n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 116 #else
 117                         n = tokenize(cvar_string("g_maplist"));
 118 #endif
 119                         s2 = "";
 120                         for(i = 0; i < n; ++i)
 121                                 if(argv(i) != s)
 122                                 {
 123 #ifdef MAPINFO
 124                                         s2 = strcat(s2, " ", argv(i));
 125 #else
 126                                         s2 = strcat(s2, "'", argv(i), "'");
 127 #endif
 128                                 }
 129 #ifdef MAPINFO
 130                         s2 = substring(s2, 1, strlen(s2) - 1);
 131 #endif
 132                         cvar_set("g_maplist", s2);
 133                         return TRUE;
 134                 }
 135                 else if(argv(1) == "shuffle" && argc == 2)
 136                 {
 137                         s = cvar_string("g_maplist");
 138 #ifdef MAPINFO
 139                         for(i = 1; i < (n = tokenizebyseparator(s, " ")); ++i)
 140 #else
 141                         for(i = 1; i < (n = tokenize(s)); ++i)
 142 #endif
 143                         {
 144                                 // swap i-th item at a random position from 0 to i
 145                                 // proof for even distribution:
 146                                 //   n = 1: obvious
 147                                 //   n -> n+1:
 148                                 //     item n+1 gets at any position with chance 1/(n+1)
 149                                 //     all others will get their 1/n chance reduced by factor n/(n+1)
 150                                 //     to be on place n+1, their chance will be 1/(n+1)
 151                                 //     1/n * n/(n+1) = 1/(n+1)
 152                                 //     q.e.d.
 153                                 f = ceil(random() * (i + 1)) - 1; // 0 to i
 154                                 if(f == i)
 155                                         continue; // no change
 156
 157                                 s2 = "";
 158                                 for(j = 0; j < n; ++j)
 159 #ifdef MAPINFO
 160                                         s2 = strcat(s2, " ", argv((j == i) ? f : (j == f) ? i : j));
 161                                 s = substring(s2, 1, strlen(s2) - 1);
 162 #else
 163                                         s2 = strcat(s2, "'", argv((j == i) ? f : (j == f) ? i : j), "'");
 164                                 s = s2;
 165 #endif
 166                         }
 167                         cvar_set("g_maplist", s);
 168                         return TRUE;
 169                 }
 170         }
 171         else if(argv(0) == "rpn")
 172         {
 173                 if(!rpn_db)
 174                 {
 175                         rpn_db = db_create();
 176                         db_put(rpn_db, "stack.pointer", "0");
 177                         db_put(rpn_db, "stack.pos", "-1");
 178                 }
 179                 if(argc >= 2)
 180                 {
 181                         float rpnpos;
 182                         string rpncmd;
 183                         float f2, f3;
 184                         rpn_sp = 0;
 185                         rpn_error = FALSE;
 186                         for(rpnpos = 1; rpnpos < argc; ++rpnpos)
 187                         {
 188                                 rpncmd = argv(rpnpos);
 189                                 f = strlen(rpncmd);
 190                                 if(rpncmd == "") {
 191                                 } else if(stof(substring(rpncmd, 0, 1)) > 0) {
 192                                         rpn_push(rpncmd);
 193                                 } else if(substring(rpncmd, 0, 1) == "0") {
 194                                         rpn_push(rpncmd);
 195                                 } else if(f >= 2 && substring(rpncmd, 0, 1) == "+") {
 196                                         rpn_push(rpncmd);
 197                                 } else if(f >= 2 && substring(rpncmd, 0, 1) == "-") {
 198                                         rpn_push(rpncmd);
 199                                 } else if(f >= 2 && substring(rpncmd, 0, 1) == "/") {
 200                                         rpn_push(substring(rpncmd, 1, strlen(rpncmd) - 1));
 201                                 } else if(rpncmd == "clear") {
 202                                         rpn_sp = 0;
 203                                 } else if(rpncmd == "def" || rpncmd == "=") {
 204                                         s = rpn_pop();
 205                                         s2 = rpn_pop();
 206 #ifdef MENUQC
 207                                         registercvar(s2, "", 0);
 208 #else
 209                                         registercvar(s2, "");
 210 #endif
 211                                         if(!rpn_error) // don't change cvars if a stack error had happened!
 212                                                 cvar_set(s2, s);
 213                                 } else if(rpncmd == "defs" || rpncmd == "@") {
 214                                         s = "";
 215                                         i = rpn_popf();
 216                                         j = (i == 0);
 217                                         while(rpn_sp > 1 && (j || i > 0))
 218                                         {
 219                                                 s = strcat("/", rpn_pop(), " ", s);
 220                                                 --i;
 221                                         }
 222                                         s2 = rpn_pop();
 223 #ifdef MENUQC
 224                                         registercvar(s2, "", 0);
 225 #else
 226                                         registercvar(s2, "");
 227 #endif
 228                                         if(!rpn_error) // don't change cvars if a stack error had happened!
 229                                                 cvar_set(s2, s);
 230                                 } else if(rpncmd == "load") {
 231                                         rpn_set(cvar_string(rpn_get()));
 232                                 } else if(rpncmd == "exch") {
 233                                         s = rpn_pop();
 234                                         s2 = rpn_get();
 235                                         rpn_set(s);
 236                                         rpn_push(s2);
 237                                 } else if(rpncmd == "dup") {
 238                                         rpn_push(rpn_get());
 239                                 } else if(rpncmd == "pop") {
 240                                         rpn_pop();
 241                                 } else if(rpncmd == "add" || rpncmd == "+") {
 242                                         f = rpn_popf();
 243                                         rpn_setf(rpn_getf() + f);
 244                                 } else if(rpncmd == "sub" || rpncmd == "-") {
 245                                         f = rpn_popf();
 246                                         rpn_setf(rpn_getf() - f);
 247                                 } else if(rpncmd == "mul" || rpncmd == "*") {
 248                                         f = rpn_popf();
 249                                         rpn_setf(rpn_getf() * f);
 250                                 } else if(rpncmd == "div" || rpncmd == "/") {
 251                                         f = rpn_popf();
 252                                         rpn_setf(rpn_getf() / f);
 253                                 } else if(rpncmd == "mod" || rpncmd == "%") {
 254                                         f = rpn_popf();
 255                                         f2 = rpn_getf();
 256                                         rpn_setf(f2 - f * floor(f2 / f));
 257                                 } else if(rpncmd == "abs") {
 258                                         rpn_setf(fabs(rpn_getf()));
 259                                 } else if(rpncmd == "sgn") {
 260                                         f = rpn_getf();
 261                                         if(f < 0)
 262                                                 rpn_set("-1");
 263                                         else if(f > 0)
 264                                                 rpn_set("1");
 265                                         else
 266                                                 rpn_set("0");
 267                                 } else if(rpncmd == "neg" || rpncmd == "~") {
 268                                         rpn_setf(-rpn_getf());
 269                                 } else if(rpncmd == "floor" || rpncmd == "f") {
 270                                         rpn_setf(floor(rpn_getf()));
 271                                 } else if(rpncmd == "ceil" || rpncmd == "c") {
 272                                         rpn_setf(ceil(rpn_getf()));
 273                                 } else if(rpncmd == "max") {
 274                                         f = rpn_popf();
 275                                         f2 = rpn_getf();
 276                                         rpn_setf(max(f2, f));
 277                                 } else if(rpncmd == "min") {
 278                                         f = rpn_popf();
 279                                         f2 = rpn_getf();
 280                                         rpn_setf(min(f2, f));
 281                                 } else if(rpncmd == "bound") {
 282                                         f = rpn_popf();
 283                                         f2 = rpn_popf();
 284                                         f3 = rpn_getf();
 285                                         rpn_setf(bound(f3, f2, f));
 286                                 } else if(rpncmd == "when") {
 287                                         f = rpn_popf();
 288                                         f2 = rpn_popf();
 289                                         f3 = rpn_getf();
 290                                         if(f)
 291                                                 rpn_setf(f3);
 292                                         else
 293                                                 rpn_setf(f2);
 294                                 } else if(rpncmd == ">" || rpncmd == "gt") {
 295                                         f = rpn_popf();
 296                                         rpn_setf(rpn_getf() > f);
 297                                 } else if(rpncmd == "<" || rpncmd == "lt") {
 298                                         f = rpn_popf();
 299                                         rpn_setf(rpn_getf() < f);
 300                                 } else if(rpncmd == "==" || rpncmd == "eq") {
 301                                         f = rpn_popf();
 302                                         rpn_setf(rpn_getf() == f);
 303                                 } else if(rpncmd == ">=" || rpncmd == "ge") {
 304                                         f = rpn_popf();
 305                                         rpn_setf(rpn_getf() >= f);
 306                                 } else if(rpncmd == "<=" || rpncmd == "le") {
 307                                         f = rpn_popf();
 308                                         rpn_setf(rpn_getf() <= f);
 309                                 } else if(rpncmd == "!=" || rpncmd == "ne") {
 310                                         f = rpn_popf();
 311                                         rpn_setf(rpn_getf() != f);
 312                                 } else if(rpncmd == "rand") {
 313                                         rpn_setf(ceil(random() * rpn_getf()) - 1);
 314                                 } else if(rpncmd == "dbpush") {
 315                                         s = rpn_pop();
 316                                         if(!rpn_error)
 317                                         {
 318                                                 i = stof(db_get(rpn_db, "stack.pointer"));
 319                                                 db_put(rpn_db, "stack.pointer", ftos(i+1));
 320                                                 db_put(rpn_db, strcat("stack.", ftos(i)), s);
 321                                         }
 322                                         if(!i)
 323                                                 db_put(rpn_db, "stack.pos", "0");
 324                                 } else if(rpncmd == "dbpop") {
 325                                         i = stof(db_get(rpn_db, "stack.pointer"));
 326                                         if(i)
 327                                         {
 328                                                 s = ftos(i-1);
 329                                                 db_put(rpn_db, "stack.pointer", s);
 330                                                 rpn_push(db_get(rpn_db, strcat("stack.", s)));
 331                                                 j = stof(db_get(rpn_db, "stack.pos"));
 332                                                 if(j >= i)
 333                                                         db_put(rpn_db, "stack.pos", ftos(i-2));
 334                                         } else {
 335                                                 rpn_error = 1;
 336                                                 print("rpn: database underflow\n");
 337                                         }
 338                                 } else if(rpncmd == "dbget") {
 339
 340                                         i = stof(db_get(rpn_db, "stack.pointer"));
 341                                         if(i)
 342                                         {
 343                                                 rpn_push(db_get(rpn_db, strcat("stack.", ftos(i-1))));
 344                                         } else {
 345                                                 rpn_error = 1;
 346                                                 print("rpn: database empty\n");
 347                                         }
 348                                 } else if(rpncmd == "dblen") {
 349                                         rpn_push(db_get(rpn_db, "stack.pointer"));
 350                                 } else if(rpncmd == "dbins") {
 351                                         s = rpn_pop();
 352                                         if(!rpn_error)
 353                                                 //if(rpn_sp > 0)
 354                                         {
 355                                                 j = stof(db_get(rpn_db, "stack.pointer"));
 356                                                 i = stof(db_get(rpn_db, "stack.pos"));
 357
 358                                                 if(i < 0)
 359                                                 {
 360                                                         i = 0;
 361                                                         db_put(rpn_db, "stack.pos", "0");
 362                                                 }
 363
 364                                                 db_put(rpn_db, "stack.pointer", ftos(j+1));
 365                                                 for(--j; j >= i; --j)
 366                                                 {
 367                                                         db_put(rpn_db, strcat("stack.", ftos(j+1)),
 368                                                                db_get(rpn_db, (strcat("stack.", ftos(j))))
 369                                                                 );
 370                                                 }
 371                                                 db_put(rpn_db, strcat("stack.", ftos(i)), s);
 372                                         }
 373                                 } else if(rpncmd == "dbext") {
 374                                         j = stof(db_get(rpn_db, "stack.pointer"));
 375                                         i = stof(db_get(rpn_db, "stack.pos"));
 376                                         if(!j)
 377                                         {
 378                                                 rpn_error = TRUE;
 379                                                 print("rpn: empty database\n");
 380                                         } else {
 381                                                 --j;
 382                                                 rpn_push(db_get(rpn_db, strcat("stack.", ftos(i))));
 383                                                 db_put(rpn_db, "stack.pointer", ftos(j));
 384                                                 if(i == j)
 385                                                 {
 386                                                         db_put(rpn_db, "stack.pos", ftos(j-1));
 387                                                 } else {
 388                                                         while(i < j)
 389                                                         {
 390                                                                 db_put(rpn_db, strcat("stack.", ftos(i)),
 391                                                                        db_get(rpn_db, (strcat("stack.", ftos(i+1))))
 392                                                                         );
 393                                                                 ++i;
 394                                                         }
 395                                                 }
 396                                         }
 397                                 } else if(rpncmd == "dbread") {
 398                                         s = db_get(rpn_db, "stack.pos");
 399                                         if(stof(s) >= 0)
 400                                         {
 401                                                 rpn_push(db_get(rpn_db, strcat("stack.", s)));
 402                                         } else {
 403                                                 rpn_error = 1;
 404                                                 print("rpn: empty database\n");
 405                                         }
 406                                 } else if(rpncmd == "dbat") {
 407                                         rpn_push(db_get(rpn_db, "stack.pos"));
 408                                 } else if(rpncmd == "dbmov") {
 409                                         j = stof(db_get(rpn_db, "stack.pointer"));
 410                                         i = stof(db_get(rpn_db, "stack.pos"));
 411                                         i += rpn_popf();
 412                                         if(!rpn_error)
 413                                         {
 414                                                 if(i < 0 || i >= j)
 415                                                 {
 416                                                         print("rpn: database cursor out of bounds\n");
 417                                                         rpn_error = TRUE;
 418                                                 }
 419                                                 if(!rpn_error)
 420                                                 {
 421                                                         db_put(rpn_db, "stack.pos", ftos(i));
 422                                                 }
 423                                         }
 424                                 } else if(rpncmd == "dbgoto") {
 425                                         s = rpn_pop();
 426                                         j = stof(db_get(rpn_db, "stack.pointer"));
 427                                         if(!j)
 428                                         {
 429                                                 rpn_error = TRUE;
 430                                                 print("rpn: empty database, cannot move cursor\n");
 431                                         }
 432                                         if(!rpn_error)
 433                                         {
 434                                                 if(s == "end")
 435                                                         i = stof(db_get(rpn_db, "stack.pointer"))-1;
 436                                                 else if(s == "beg")
 437                                                         i = 0;
 438                                                 else
 439                                                         i = stof(s);
 440
 441                                                 j = stof(db_get(rpn_db, "stack.pointer"));
 442                                                 if(i < 0 || i >= j)
 443                                                 {
 444                                                         print("rpn: database cursor destination out of bounds\n");
 445                                                         rpn_error = TRUE;
 446                                                 }
 447                                                 if(!rpn_error)
 448                                                 {
 449                                                         db_put(rpn_db, "stack.pos", ftos(i));
 450                                                 }
 451                                         }
 452                                 } else if(rpncmd == "union") {
 453                                         // s s2 union
 454                                         s2 = rpn_pop();
 455                                         s = rpn_get();
 456                                         f = tokenize(s);
 457                                         f2 = tokenize(strcat(s, " ", s2));
 458                                         // tokens 0..(f-1) represent s
 459                                         // tokens f..f2 represent s2
 460                                         // UNION: add all tokens to s that are in s2 but not in s
 461                                         s = "";
 462                                         for(i = 0; i < f; ++i)
 463                                                 s = strcat(s, " ", argv(i));
 464                                         for(i = f; i < f2; ++i) {
 465                                                 for(j = 0; j < f; ++j)
 466                                                         if(argv(i) == argv(j))
 467                                                                 goto skip_union;
 468                                                 s = strcat(s, " ", argv(i));
 469 :skip_union
 470                                         }
 471                                         if(substring(s, 0, 1) == " ")
 472                                                 s = substring(s, 1, 99999);
 473                                         rpn_set(s);
 474                                         tokenize(command);
 475                                 } else if(rpncmd == "intersection") {
 476                                         // s s2 intersection
 477                                         s2 = rpn_pop();
 478                                         s = rpn_get();
 479                                         f = tokenize(s);
 480                                         f2 = tokenize(strcat(s, " ", s2));
 481                                         // tokens 0..(f-1) represent s
 482                                         // tokens f..f2 represent s2
 483                                         // INTERSECTION: keep only the tokens from s that are also in s2
 484                                         s = "";
 485                                         for(i = 0; i < f; ++i) {
 486                                                 for(j = f; j < f2; ++j)
 487                                                         if(argv(i) == argv(j))
 488                                                         {
 489                                                                 s = strcat(s, " ", argv(i));
 490                                                                 break;
 491                                                         }
 492                                         }
 493                                         if(substring(s, 0, 1) == " ")
 494                                                 s = substring(s, 1, 99999);
 495                                         rpn_set(s);
 496                                         tokenize(command);
 497                                 } else if(rpncmd == "difference") {
 498                                         // s s2 difference
 499                                         s2 = rpn_pop();
 500                                         s = rpn_get();
 501                                         f = tokenize(s);
 502                                         f2 = tokenize(strcat(s, " ", s2));
 503                                         // tokens 0..(f-1) represent s
 504                                         // tokens f..f2 represent s2
 505                                         // DIFFERENCE: keep only the tokens from s that are not in s2
 506                                         s = "";
 507                                         for(i = 0; i < f; ++i) {
 508                                                 for(j = f; j < f2; ++j)
 509                                                         if(argv(i) == argv(j))
 510                                                                 goto skip_difference;
 511                                                 s = strcat(s, " ", argv(i));
 512 :skip_difference
 513                                         }
 514                                         if(substring(s, 0, 1) == " ")
 515                                                 s = substring(s, 1, 99999);
 516                                         rpn_set(s);
 517                                         tokenize(command);
 518                                 } else if(rpncmd == "shuffle") {
 519                                         // s shuffle
 520                                         s = rpn_get();
 521                                         f = tokenize(s);
 522
 523                                         for(i = 0; i < f - 1; ++i) {
 524                                                 // move a random item from i..f-1 to position i
 525                                                 s = "";
 526                                                 f2 = ceil(random() * (f - i) + i) - 1;
 527                                                 for(j = 0; j < i; ++j)
 528                                                         s = strcat(s, " ", argv(j));
 529                                                 s = strcat(s, " ", argv(f2));
 530                                                 for(j = i; j < f; ++j)
 531                                                         if(j != f2)
 532                                                                 s = strcat(s, " ", argv(j));
 533                                                 f = tokenize(s);
 534                                         }
 535
 536                                         if(substring(s, 0, 1) == " ")
 537                                                 s = substring(s, 1, 99999);
 538                                         rpn_set(s);
 539                                         tokenize(command);
 540                                         } else if(rpncmd == "fexists_assert") {
 541                                         s = rpn_pop();
 542                                         if(!rpn_error)
 543                                         {
 544                                                 f = fopen(s, FILE_READ);
 545                                                 if(f != -1)
 546                                                         fclose(f);
 547                                                 else {
 548                                                         print("rpn: ERROR: ", s, " does not exist!\n");
 549                                                         rpn_error = TRUE;
 550                                                 }
 551                                         }
 552                                 } else {
 553                                         rpn_push(cvar_string(rpncmd));
 554                                 }
 555                                 if(rpn_error)
 556                                         break;
 557                         }
 558                         while(rpn_sp > 0)
 559                         {
 560                                 s = rpn_pop();
 561                                 print("rpn: still on stack: ", s, "\n");
 562                         }
 563                         return TRUE;
 564                 }
 565         }
 566
 567         return FALSE;
 568 }