data/qcsrc/common/gamecommand.qc

   1 #define MAX_RPN_STACK 16
   2 float rpn_db;
   3 float rpn_error;
   4 float rpn_sp;
   5 string rpn_stack[MAX_RPN_STACK];
   6 string rpn_pop() {
   7         if(rpn_sp > 0) {
   8                 --rpn_sp;
   9                 return rpn_stack[rpn_sp];
  10         } else {
  11                 print("rpn: stack underflow\n");
  12                 rpn_error = TRUE;
  13                 return "";
  14         }
  15 }
  16 void rpn_push(string s) {
  17         if(rpn_sp < MAX_RPN_STACK) {
  18                 rpn_stack[rpn_sp] = s;
  19                 ++rpn_sp;
  20         } else {
  21                 print("rpn: stack overflow\n");
  22                 rpn_error = TRUE;
  23         }
  24 }
  25 string rpn_get() {
  26         if(rpn_sp > 0) {
  27                 return rpn_stack[rpn_sp - 1];
  28         } else {
  29                 print("rpn: empty stack\n");
  30                 rpn_error = TRUE;
  31                 return "";
  32         }
  33 }
  34 void rpn_set(string s) {
  35         if(rpn_sp > 0) {
  36                 rpn_stack[rpn_sp - 1] = s;
  37         } else {
  38                 print("rpn: empty stack\n");
  39                 rpn_error = TRUE;
  40         }
  41 }
  42 float rpn_getf() { return stof(rpn_get()); }
  43 float rpn_popf() { return stof(rpn_pop()); }
  44 void rpn_pushf(float f) { return rpn_push(ftos(f)); }
  45 void rpn_setf(float f) { return rpn_set(ftos(f)); }
  46
  47 #define NUM_MARKUPS     41
  48 float markup_init;
  49 string markup_from[NUM_MARKUPS];
  50 string markup_to[NUM_MARKUPS];
  51 void GameCommand_MarkupInit()
  52 {
  53         float i;
  54         if (markup_init)
  55                 return;
  56         markup_init = 1;
  57         i = 0;
  58         markup_from[i] = "&alien"; markup_to[i] = "\x12"; ++i;
  59         markup_from[i] = "&:-)"; markup_to[i] = "\x13"; ++i;
  60         markup_from[i] = "&:-("; markup_to[i] = "\x14"; ++i;
  61         markup_from[i] = "&x-P"; markup_to[i] = "\x15"; ++i;
  62         markup_from[i] = "&:-/"; markup_to[i] = "\x16"; ++i;
  63         markup_from[i] = "&:-D"; markup_to[i] = "\x17"; ++i;
  64         markup_from[i] = "&<<"; markup_to[i] = "\x18"; ++i;
  65         markup_from[i] = "&>>"; markup_to[i] = "\x19"; ++i;
  66         markup_from[i] = "&dot"; markup_to[i] = "\x1a"; ++i;
  67         markup_from[i] = "&^_"; markup_to[i] = "\x1b"; ++i;
  68         markup_from[i] = "&ysplat"; markup_to[i] = "\x1c"; ++i;
  69         markup_from[i] = "&-]"; markup_to[i] = "\x1d"; ++i;
  70         markup_from[i] = "&--"; markup_to[i] = "\x1e"; ++i;
  71         markup_from[i] = "&[-"; markup_to[i] = "\x1f"; ++i;
  72         markup_from[i] = "&s<"; markup_to[i] = "\x2c"; ++i;
  73         markup_from[i] = "&s>"; markup_to[i] = "\x2e"; ++i;
  74         markup_from[i] = "&<-"; markup_to[i] = "\x7f"; ++i;
  75         markup_from[i] = "&[="; markup_to[i] = "\x80"; ++i;
  76         markup_from[i] = "&=="; markup_to[i] = "\x81"; ++i;
  77         markup_from[i] = "&=]"; markup_to[i] = "\x82"; ++i;
  78         markup_from[i] = "&r!"; markup_to[i] = "\x84"; ++i;
  79         markup_from[i] = "&|o|"; markup_to[i] = "\x85"; ++i;
  80         markup_from[i] = "&|u|"; markup_to[i] = "\x86"; ++i;
  81         markup_from[i] = "&|i|"; markup_to[i] = "\x87"; ++i;
  82         markup_from[i] = "&|c|"; markup_to[i] = "\x88"; ++i;
  83         markup_from[i] = "&[c]"; markup_to[i] = "\x89"; ++i;
  84         markup_from[i] = "&[n]"; markup_to[i] = "\x8a"; ++i;
  85         markup_from[i] = "&[]"; markup_to[i] = "\x8b"; ++i;
  86         markup_from[i] = "&r?"; markup_to[i] = "\x8c"; ++i;
  87         markup_from[i] = "&|>"; markup_to[i] = "\x8d"; ++i;
  88         markup_from[i] = "&splat0"; markup_to[i] = "\x8e"; ++i;
  89         markup_from[i] = "&splat1"; markup_to[i] = "\x8f"; ++i;
  90         markup_from[i] = "&[["; markup_to[i] = "\x90"; ++i;
  91         markup_from[i] = "&]]"; markup_to[i] = "\x91"; ++i;
  92         markup_from[i] = "&splat2"; markup_to[i] = "\x9a"; ++i;
  93         markup_from[i] = "&)("; markup_to[i] = "\x9b"; ++i;
  94         markup_from[i] = "&splat3"; markup_to[i] = "\x9c"; ++i;
  95         markup_from[i] = "&(."; markup_to[i] = "\x9d"; ++i;
  96         markup_from[i] = "&.."; markup_to[i] = "\x9e"; ++i;
  97         markup_from[i] = "&.)"; markup_to[i] = "\x9f"; ++i;
  98         markup_from[i] = "&<|"; markup_to[i] = "\xff"; ++i;
  99 }
 100
 101 string GameCommand_Markup(string s2)
 102 {
 103         float red, ccase, i, j, x;
 104         string s, s3;
 105
 106         x = 0;
 107         for(i = 0; i < 16; ++i)
 108         {
 109                 for(j = 0; j < 16; ++j)
 110                 {
 111                         print(chr2str(x));
 112                         ++x;
 113                 }
 114                 print("\n");
 115         }
 116
 117         GameCommand_MarkupInit();
 118
 119         s = "";
 120
 121         red = 0;
 122         ccase = 0;
 123         for(i = 0; i < strlen(s2); ++i)
 124         {
 125                 for(j = 0; j < NUM_MARKUPS; ++j)
 126                 {
 127                         s3 = substring(s2, i, strlen(markup_from[j]));
 128                         if (s3 == markup_from[j])
 129                         {
 130                                 s = strcat(s, markup_to[j]);
 131                                 i += strlen(markup_from[j]) - 1;
 132                                 break;
 133                         }
 134                 }
 135
 136                 if(j == NUM_MARKUPS)
 137                 {
 138                         if(substring(s2, i, 2) == "&&")
 139                         {
 140                                 s = strcat(s, strconv(ccase, red, red, "&"));
 141                                 ++i;
 142                         }
 143                         else if(substring(s2, i, 2) == "&d")
 144                         {
 145                                 red = 2;
 146                                 ccase = 0;
 147                                 ++i;
 148                         }
 149                         else if(substring(s2, i, 2) == "&a")
 150                         {
 151                                 red = 2;
 152                                 ccase = 2;
 153                                 ++i;
 154                         }
 155                         else if(substring(s2, i, 2) == "&n")
 156                         {
 157                                 red = 0;
 158                                 ccase = 0;
 159                                 ++i;
 160                         }
 161                         else
 162                                 s = strcat(s, strconv(ccase, red, red, substring(s2, i, 1)));
 163                 }
 164         }
 165
 166         return s;
 167 }
 168
 169 float GameCommand_Generic(string command)
 170 {
 171         float argc;
 172         float i, j, f, n;
 173         vector rgb;
 174         string s, s2, c;
 175         argc = tokenize_console(command);
 176         if(argv(0) == "help")
 177         {
 178                 print("  rpn EXPRESSION... - a RPN calculator.\n");
 179                 print("    Operator description (x: string, s: set, f: float):\n");
 180                 print("    x pop ----------------------------->     : removes the top\n");
 181                 print("    x dup -----------------------------> x x : duplicates the top\n");
 182                 print("    x x exch --------------------------> x x : swap the top two\n");
 183                 print("    /cvarname load --------------------> x   : loads a cvar\n");
 184                 print("    /cvarname x def ------------------->     : writes to a cvar\n");
 185                 print("    f f add|sub|mul|div|mod|max|min ---> f   : adds/... two numbers\n");
 186                 print("    f f eq|ne|gt|ge|lt|le -------------> f   : compares two numbers\n");
 187                 print("    f neg|abs|sgn|rand|floor|ceil------> f   : negates/... a number\n");
 188                 print("    f f f bound -----------------------> f   : bounds the middle number\n");
 189                 print("    f1 f2 b when ----------------------> f   : f1 if b, f2 otherwise\n");
 190                 print("    s s union|intersection|difference -> s   : set operations\n");
 191                 print("    s shuffle -------------------------> s   : randomly arrange elements\n");
 192                 print("    x dbpush -------------------------->     : pushes the top onto the database\n");
 193                 print("    dbpop|dbget -----------------------> x   : removes/reads DB's top\n");
 194                 print("    dblen|dbat ------------------------> f   : gets the DB's size/cursor pos\n");
 195                 print("    dbclr ----------------------------->     : clear the DB\n");
 196                 print("    s dbsave|dbload-------------------->     : save/load the DB to/from a file\n");
 197                 print("    x dbins --------------------------->     : moves the top into the DB\n");
 198                 print("    dbext|dbread ----------------------> x   : extract/get from the DB's cursor\n");
 199                 print("    f dbmov|dbgoto -------------------->     : move or set the DB's cursor\n");
 200                 print("    s localtime -----------------------> s   : formats the current local time\n");
 201                 print("    s gmtime --------------------------> s   : formats the current UTC time\n");
 202                 print("    time ------------------------------> f   : seconds since VM start\n");
 203                 print("    Set operations operate on 'such''strings'.\n");
 204                 print("    Unknown tokens insert their cvar value.\n");
 205                 print("  maplist add map\n");
 206                 print("  maplist remove map\n");
 207                 print("  maplist shuffle\n");
 208                 print("  maplist cleanup\n");
 209                 print("  maplist maplist\n");
 210                 print("  maplist lsmaps\n");
 211                 print("  addtolist variable addedvalue\n");
 212                 print("  records\n");
 213                 return TRUE;
 214         }
 215
 216         if(argv(0) == "maplist")
 217         {
 218                 if(argv(1) == "add" && argc == 3)
 219                 {
 220                         f = fopen(strcat("maps/", argv(2), ".bsp"), FILE_READ);
 221                         if(f != -1)
 222                                 fclose(f);
 223                         else {
 224                                 print("maplist: ERROR: ", argv(2), " does not exist!\n");
 225                                 return TRUE;
 226                         }
 227                         if(cvar_string("g_maplist") == "")
 228                                 cvar_set("g_maplist", argv(2));
 229                         else
 230                                 cvar_set("g_maplist", strcat(argv(2), " ", cvar_string("g_maplist")));
 231                         return TRUE;
 232                 }
 233                 else if(argv(1) == "remove" && argc == 3)
 234                 {
 235                         s = argv(2);
 236                         n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 237                         s2 = "";
 238                         for(i = 0; i < n; ++i)
 239                                 if(argv(i) != s)
 240                                         s2 = strcat(s2, " ", argv(i));
 241                         s2 = substring(s2, 1, strlen(s2) - 1);
 242                         cvar_set("g_maplist", s2);
 243                         return TRUE;
 244                 }
 245                 else if(argv(1) == "shuffle" && argc == 2)
 246                 {
 247                         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
 248                         return TRUE;
 249                 }
 250                 else if(argv(1) == "cleanup")
 251                 {
 252                         MapInfo_Enumerate();
 253                         if(cvar("g_maplist_allow_hidden"))
 254                                 i = MAPINFO_FLAG_FORBIDDEN;
 255                         else
 256                                 i = MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN;
 257                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, i, 0);
 258                         n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 259                         s2 = "";
 260                         for(i = 0; i < n; ++i)
 261                                 if(MapInfo_CheckMap(argv(i)))
 262                                         s2 = strcat(s2, " ", argv(i));
 263                         s2 = substring(s2, 1, strlen(s2) - 1);
 264                         cvar_set("g_maplist", s2);
 265                         return TRUE;
 266                 }
 267                 else if(argv(1) == "maplist") {
 268                         print(maplist_reply);
 269                         return TRUE;
 270                 }
 271                 else if(argv(1) == "lsmaps") {
 272                         print(lsmaps_reply);
 273                         return TRUE;
 274                 }
 275         }
 276         else if(argc >= 3 && argv(0) == "red")
 277         {
 278                 s = substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2));
 279                 localcmd(strcat(argv(1), " ", GameCommand_Markup(s)));
 280                 return TRUE;
 281         }
 282         else if(argc >= 3 && crc16(0, argv(0)) == 38566 && crc16(0, strcat(argv(0), argv(0), argv(0))) == 59830)
 283         {
 284                 // other test case
 285                 s = strconv(2, 0, 0, substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 286
 287                 n = floor(random() * 6 + 2);
 288
 289                 s2 = "";
 290                 for(i = 0; i < n; ++i)
 291                 {
 292                         s2 = strcat(s2, "AH");
 293                 }
 294
 295                 if(random() < 0.1)
 296                         s2 = strcat(substring(s2, 1, strlen(s2) - 1), "A");
 297
 298                 if(s == "")
 299                         s = s2;
 300                 else
 301                         if(random() < 0.8)
 302                                 s = strcat(s, " ", s2);
 303                         else
 304                                 s = strcat(s2, " ", s);
 305
 306                 s2 = substring(s, strlen(s) - 2, 2);
 307                 if(s2 == "AH" || s2 == "AY")
 308                         s = strcat(s, "))");
 309                 else
 310                         s = strcat(s, " ))");
 311
 312                 if(random() < 0.1)
 313                         s = substring(s, 0, strlen(s) - 1);
 314
 315                 if(random() < 0.1)
 316                         s = strconv(1, 0, 0, s);
 317
 318                 localcmd(strcat(argv(1), " ", s));
 319
 320                 return TRUE;
 321         }
 322         else if(argc >= 3 && crc16(0, argv(0)) == 3826 && crc16(0, strcat(argv(0), argv(0), argv(0))) == 55970)
 323         {
 324                 // test case for terrencehill's color codes
 325                 s = strdecolorize(substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 326                 s2 = "";
 327
 328                 n = strlen(s);
 329                 j = ((6 * max(1, floor(strlen(s)/32 + random() * 2 - 1))) / n) * (1 - 2 * (random() > 0.5));
 330                 f = random() * 6;
 331
 332                 for(i = 0; i < n; ++i)
 333                 {
 334                         c = substring(s, i, 1);
 335
 336                         if(c == ";")
 337                                 c = ":";
 338                         else if(c == "^")
 339                         {
 340                                 c = "^^";
 341                                 if(substring(s, i+1, 1) == "^")
 342                                         ++i;
 343                         }
 344
 345                         if(c != " ")
 346                         {
 347                                 rgb = hsl_to_rgb('1 0 0' * (j * i + f) + '0 1 .5');
 348                                 c = strcat(rgb_to_hexcolor(rgb), c);
 349                         }
 350                         s2 = strcat(s2, c);
 351                 }
 352
 353                 localcmd(strcat(argv(1), " ", s2));
 354
 355                 return TRUE;
 356         }
 357         else if(argv(0) == "rpn")
 358         {
 359                 if(!rpn_db)
 360                 {
 361                         rpn_db = db_create();
 362                         db_put(rpn_db, "stack.pointer", "0");
 363                         db_put(rpn_db, "stack.pos", "-1");
 364                 }
 365                 if(argc >= 2)
 366                 {
 367                         float rpnpos;
 368                         string rpncmd;
 369                         float f2, f3;
 370                         rpn_sp = 0;
 371                         rpn_error = FALSE;
 372                         for(rpnpos = 1; rpnpos < argc; ++rpnpos)
 373                         {
 374                                 rpncmd = argv(rpnpos);
 375                                 f = strlen(rpncmd);
 376                                 if(rpncmd == "") {
 377                                 } else if(stof(substring(rpncmd, 0, 1)) > 0) {
 378                                         rpn_push(rpncmd);
 379                                 } else if(substring(rpncmd, 0, 1) == "0") {
 380                                         rpn_push(rpncmd);
 381                                 } else if(f >= 2 && substring(rpncmd, 0, 1) == "+") {
 382                                         rpn_push(rpncmd);
 383                                 } else if(f >= 2 && substring(rpncmd, 0, 1) == "-") {
 384                                         rpn_push(rpncmd);
 385                                 } else if(f >= 2 && substring(rpncmd, 0, 1) == "/") {
 386                                         rpn_push(substring(rpncmd, 1, strlen(rpncmd) - 1));
 387                                 } else if(rpncmd == "clear") {
 388                                         rpn_sp = 0;
 389                                 } else if(rpncmd == "def" || rpncmd == "=") {
 390                                         s = rpn_pop();
 391                                         s2 = rpn_pop();
 392 #ifdef MENUQC
 393                                         registercvar(s2, "", 0);
 394 #else
 395                                         registercvar(s2, "");
 396 #endif
 397                                         if(!rpn_error) // don't change cvars if a stack error had happened!
 398                                                 cvar_set(s2, s);
 399                                 } else if(rpncmd == "defs" || rpncmd == "@") {
 400                                         s = "";
 401                                         i = rpn_popf();
 402                                         j = (i == 0);
 403                                         while(rpn_sp > 1 && (j || i > 0))
 404                                         {
 405                                                 s = strcat("/", rpn_pop(), " ", s);
 406                                                 --i;
 407                                         }
 408                                         s2 = rpn_pop();
 409 #ifdef MENUQC
 410                                         registercvar(s2, "", 0);
 411 #else
 412                                         registercvar(s2, "");
 413 #endif
 414                                         if(!rpn_error) // don't change cvars if a stack error had happened!
 415                                                 cvar_set(s2, s);
 416                                 } else if(rpncmd == "load") {
 417                                         rpn_set(cvar_string(rpn_get()));
 418                                 } else if(rpncmd == "exch") {
 419                                         s = rpn_pop();
 420                                         s2 = rpn_get();
 421                                         rpn_set(s);
 422                                         rpn_push(s2);
 423                                 } else if(rpncmd == "dup") {
 424                                         rpn_push(rpn_get());
 425                                 } else if(rpncmd == "pop") {
 426                                         rpn_pop();
 427                                 } else if(rpncmd == "add" || rpncmd == "+") {
 428                                         f = rpn_popf();
 429                                         rpn_setf(rpn_getf() + f);
 430                                 } else if(rpncmd == "sub" || rpncmd == "-") {
 431                                         f = rpn_popf();
 432                                         rpn_setf(rpn_getf() - f);
 433                                 } else if(rpncmd == "mul" || rpncmd == "*") {
 434                                         f = rpn_popf();
 435                                         rpn_setf(rpn_getf() * f);
 436                                 } else if(rpncmd == "div" || rpncmd == "/") {
 437                                         f = rpn_popf();
 438                                         rpn_setf(rpn_getf() / f);
 439                                 } else if(rpncmd == "mod" || rpncmd == "%") {
 440                                         f = rpn_popf();
 441                                         f2 = rpn_getf();
 442                                         rpn_setf(f2 - f * floor(f2 / f));
 443                                 } else if(rpncmd == "abs") {
 444                                         rpn_setf(fabs(rpn_getf()));
 445                                 } else if(rpncmd == "sgn") {
 446                                         f = rpn_getf();
 447                                         if(f < 0)
 448                                                 rpn_set("-1");
 449                                         else if(f > 0)
 450                                                 rpn_set("1");
 451                                         else
 452                                                 rpn_set("0");
 453                                 } else if(rpncmd == "neg" || rpncmd == "~") {
 454                                         rpn_setf(-rpn_getf());
 455                                 } else if(rpncmd == "floor" || rpncmd == "f") {
 456                                         rpn_setf(floor(rpn_getf()));
 457                                 } else if(rpncmd == "ceil" || rpncmd == "c") {
 458                                         rpn_setf(ceil(rpn_getf()));
 459                                 } else if(rpncmd == "max") {
 460                                         f = rpn_popf();
 461                                         f2 = rpn_getf();
 462                                         rpn_setf(max(f2, f));
 463                                 } else if(rpncmd == "min") {
 464                                         f = rpn_popf();
 465                                         f2 = rpn_getf();
 466                                         rpn_setf(min(f2, f));
 467                                 } else if(rpncmd == "bound") {
 468                                         f = rpn_popf();
 469                                         f2 = rpn_popf();
 470                                         f3 = rpn_getf();
 471                                         rpn_setf(bound(f3, f2, f));
 472                                 } else if(rpncmd == "when") {
 473                                         f = rpn_popf();
 474                                         f2 = rpn_popf();
 475                                         f3 = rpn_getf();
 476                                         if(f)
 477                                                 rpn_setf(f3);
 478                                         else
 479                                                 rpn_setf(f2);
 480                                 } else if(rpncmd == ">" || rpncmd == "gt") {
 481                                         f = rpn_popf();
 482                                         rpn_setf(rpn_getf() > f);
 483                                 } else if(rpncmd == "<" || rpncmd == "lt") {
 484                                         f = rpn_popf();
 485                                         rpn_setf(rpn_getf() < f);
 486                                 } else if(rpncmd == "==" || rpncmd == "eq") {
 487                                         f = rpn_popf();
 488                                         rpn_setf(rpn_getf() == f);
 489                                 } else if(rpncmd == ">=" || rpncmd == "ge") {
 490                                         f = rpn_popf();
 491                                         rpn_setf(rpn_getf() >= f);
 492                                 } else if(rpncmd == "<=" || rpncmd == "le") {
 493                                         f = rpn_popf();
 494                                         rpn_setf(rpn_getf() <= f);
 495                                 } else if(rpncmd == "!=" || rpncmd == "ne") {
 496                                         f = rpn_popf();
 497                                         rpn_setf(rpn_getf() != f);
 498                                 } else if(rpncmd == "rand") {
 499                                         rpn_setf(ceil(random() * rpn_getf()) - 1);
 500                                 } else if(rpncmd == "crc16") {
 501                                         rpn_setf(crc16(FALSE, rpn_get()));
 502                                 } else if(rpncmd == "dbpush") {
 503                                         s = rpn_pop();
 504                                         if(!rpn_error)
 505                                         {
 506                                                 i = stof(db_get(rpn_db, "stack.pointer"));
 507                                                 db_put(rpn_db, "stack.pointer", ftos(i+1));
 508                                                 db_put(rpn_db, strcat("stack.", ftos(i)), s);
 509                                         }
 510                                         if(!i)
 511                                                 db_put(rpn_db, "stack.pos", "0");
 512                                 } else if(rpncmd == "dbpop") {
 513                                         i = stof(db_get(rpn_db, "stack.pointer"));
 514                                         if(i)
 515                                         {
 516                                                 s = ftos(i-1);
 517                                                 db_put(rpn_db, "stack.pointer", s);
 518                                                 rpn_push(db_get(rpn_db, strcat("stack.", s)));
 519                                                 j = stof(db_get(rpn_db, "stack.pos"));
 520                                                 if(j >= i)
 521                                                         db_put(rpn_db, "stack.pos", ftos(i-2));
 522                                         } else {
 523                                                 rpn_error = 1;
 524                                                 print("rpn: database underflow\n");
 525                                         }
 526                                 } else if(rpncmd == "dbget") {
 527
 528                                         i = stof(db_get(rpn_db, "stack.pointer"));
 529                                         if(i)
 530                                         {
 531                                                 rpn_push(db_get(rpn_db, strcat("stack.", ftos(i-1))));
 532                                         } else {
 533                                                 rpn_error = 1;
 534                                                 print("rpn: database empty\n");
 535                                         }
 536                                 } else if(rpncmd == "dblen") {
 537                                         rpn_push(db_get(rpn_db, "stack.pointer"));
 538                                 } else if(rpncmd == "dbclr") {
 539                                         db_close(rpn_db);
 540                                         rpn_db = db_create();
 541                                         db_put(rpn_db, "stack.pointer", "0");
 542                                         db_put(rpn_db, "stack.pos", "-1");
 543                                 } else if(rpncmd == "dbsave") {
 544                                         s = rpn_pop();
 545                                         if(!rpn_error)
 546                                                 db_save(rpn_db, s);
 547                                 } else if(rpncmd == "dbload") {
 548                                         s = rpn_pop();
 549                                         if(!rpn_error)
 550                                         {
 551                                                 db_close(rpn_db);
 552                                                 rpn_db = db_load(s);
 553                                         }
 554                                 } else if(rpncmd == "dbins") {
 555                                         s = rpn_pop();
 556                                         if(!rpn_error)
 557                                                 //if(rpn_sp > 0)
 558                                         {
 559                                                 j = stof(db_get(rpn_db, "stack.pointer"));
 560                                                 i = stof(db_get(rpn_db, "stack.pos"));
 561
 562                                                 if(i < 0)
 563                                                 {
 564                                                         i = 0;
 565                                                         db_put(rpn_db, "stack.pos", "0");
 566                                                 }
 567
 568                                                 db_put(rpn_db, "stack.pointer", ftos(j+1));
 569                                                 for(--j; j >= i; --j)
 570                                                 {
 571                                                         db_put(rpn_db, strcat("stack.", ftos(j+1)),
 572                                                                db_get(rpn_db, (strcat("stack.", ftos(j))))
 573                                                                 );
 574                                                 }
 575                                                 db_put(rpn_db, strcat("stack.", ftos(i)), s);
 576                                         }
 577                                 } else if(rpncmd == "dbext") {
 578                                         j = stof(db_get(rpn_db, "stack.pointer"));
 579                                         i = stof(db_get(rpn_db, "stack.pos"));
 580                                         if(!j)
 581                                         {
 582                                                 rpn_error = TRUE;
 583                                                 print("rpn: empty database\n");
 584                                         } else {
 585                                                 --j;
 586                                                 rpn_push(db_get(rpn_db, strcat("stack.", ftos(i))));
 587                                                 db_put(rpn_db, "stack.pointer", ftos(j));
 588                                                 if(i == j)
 589                                                 {
 590                                                         db_put(rpn_db, "stack.pos", ftos(j-1));
 591                                                 } else {
 592                                                         while(i < j)
 593                                                         {
 594                                                                 db_put(rpn_db, strcat("stack.", ftos(i)),
 595                                                                        db_get(rpn_db, (strcat("stack.", ftos(i+1))))
 596                                                                         );
 597                                                                 ++i;
 598                                                         }
 599                                                 }
 600                                         }
 601                                 } else if(rpncmd == "dbread") {
 602                                         s = db_get(rpn_db, "stack.pos");
 603                                         if(stof(s) >= 0)
 604                                         {
 605                                                 rpn_push(db_get(rpn_db, strcat("stack.", s)));
 606                                         } else {
 607                                                 rpn_error = 1;
 608                                                 print("rpn: empty database\n");
 609                                         }
 610                                 } else if(rpncmd == "dbat") {
 611                                         rpn_push(db_get(rpn_db, "stack.pos"));
 612                                 } else if(rpncmd == "dbmov") {
 613                                         j = stof(db_get(rpn_db, "stack.pointer"));
 614                                         i = stof(db_get(rpn_db, "stack.pos"));
 615                                         i += rpn_popf();
 616                                         if(!rpn_error)
 617                                         {
 618                                                 if(i < 0 || i >= j)
 619                                                 {
 620                                                         print("rpn: database cursor out of bounds\n");
 621                                                         rpn_error = TRUE;
 622                                                 }
 623                                                 if(!rpn_error)
 624                                                 {
 625                                                         db_put(rpn_db, "stack.pos", ftos(i));
 626                                                 }
 627                                         }
 628                                 } else if(rpncmd == "dbgoto") {
 629                                         s = rpn_pop();
 630                                         j = stof(db_get(rpn_db, "stack.pointer"));
 631                                         if(!j)
 632                                         {
 633                                                 rpn_error = TRUE;
 634                                                 print("rpn: empty database, cannot move cursor\n");
 635                                         }
 636                                         if(!rpn_error)
 637                                         {
 638                                                 if(s == "end")
 639                                                         i = stof(db_get(rpn_db, "stack.pointer"))-1;
 640                                                 else if(s == "beg")
 641                                                         i = 0;
 642                                                 else
 643                                                         i = stof(s);
 644
 645                                                 j = stof(db_get(rpn_db, "stack.pointer"));
 646                                                 if(i < 0 || i >= j)
 647                                                 {
 648                                                         print("rpn: database cursor destination out of bounds\n");
 649                                                         rpn_error = TRUE;
 650                                                 }
 651                                                 if(!rpn_error)
 652                                                 {
 653                                                         db_put(rpn_db, "stack.pos", ftos(i));
 654                                                 }
 655                                         }
 656                                 } else if(rpncmd == "union") {
 657                                         // s s2 union
 658                                         s2 = rpn_pop();
 659                                         s = rpn_get();
 660                                         f = tokenize_console(s);
 661                                         f2 = tokenize_console(strcat(s, " ", s2));
 662                                         // tokens 0..(f-1) represent s
 663                                         // tokens f..f2 represent s2
 664                                         // UNION: add all tokens to s that are in s2 but not in s
 665                                         s = "";
 666                                         for(i = 0; i < f; ++i)
 667                                                 s = strcat(s, " ", argv(i));
 668                                         for(i = f; i < f2; ++i) {
 669                                                 for(j = 0; j < f; ++j)
 670                                                         if(argv(i) == argv(j))
 671                                                                 goto skip_union;
 672                                                 s = strcat(s, " ", argv(i));
 673 :skip_union
 674                                         }
 675                                         if(substring(s, 0, 1) == " ")
 676                                                 s = substring(s, 1, 99999);
 677                                         rpn_set(s);
 678                                         tokenize_console(command);
 679                                 } else if(rpncmd == "intersection") {
 680                                         // s s2 intersection
 681                                         s2 = rpn_pop();
 682                                         s = rpn_get();
 683                                         f = tokenize_console(s);
 684                                         f2 = tokenize_console(strcat(s, " ", s2));
 685                                         // tokens 0..(f-1) represent s
 686                                         // tokens f..f2 represent s2
 687                                         // INTERSECTION: keep only the tokens from s that are also in s2
 688                                         s = "";
 689                                         for(i = 0; i < f; ++i) {
 690                                                 for(j = f; j < f2; ++j)
 691                                                         if(argv(i) == argv(j))
 692                                                         {
 693                                                                 s = strcat(s, " ", argv(i));
 694                                                                 break;
 695                                                         }
 696                                         }
 697                                         if(substring(s, 0, 1) == " ")
 698                                                 s = substring(s, 1, 99999);
 699                                         rpn_set(s);
 700                                         tokenize_console(command);
 701                                 } else if(rpncmd == "difference") {
 702                                         // s s2 difference
 703                                         s2 = rpn_pop();
 704                                         s = rpn_get();
 705                                         f = tokenize_console(s);
 706                                         f2 = tokenize_console(strcat(s, " ", s2));
 707                                         // tokens 0..(f-1) represent s
 708                                         // tokens f..f2 represent s2
 709                                         // DIFFERENCE: keep only the tokens from s that are not in s2
 710                                         s = "";
 711                                         for(i = 0; i < f; ++i) {
 712                                                 for(j = f; j < f2; ++j)
 713                                                         if(argv(i) == argv(j))
 714                                                                 goto skip_difference;
 715                                                 s = strcat(s, " ", argv(i));
 716 :skip_difference
 717                                         }
 718                                         if(substring(s, 0, 1) == " ")
 719                                                 s = substring(s, 1, 99999);
 720                                         rpn_set(s);
 721                                         tokenize_console(command);
 722                                 } else if(rpncmd == "shuffle") {
 723                                         // s shuffle
 724                                         s = rpn_get();
 725                                         f = tokenize_console(s);
 726
 727                                         for(i = 0; i < f - 1; ++i) {
 728                                                 // move a random item from i..f-1 to position i
 729                                                 s = "";
 730                                                 f2 = floor(random() * (f - i) + i);
 731                                                 for(j = 0; j < i; ++j)
 732                                                         s = strcat(s, " ", argv(j));
 733                                                 s = strcat(s, " ", argv(f2));
 734                                                 for(j = i; j < f; ++j)
 735                                                         if(j != f2)
 736                                                                 s = strcat(s, " ", argv(j));
 737                                                 f = tokenize_console(s);
 738                                         }
 739
 740                                         if(substring(s, 0, 1) == " ")
 741                                                 s = substring(s, 1, 99999);
 742                                         rpn_set(s);
 743                                         tokenize_console(command);
 744                                 } else if(rpncmd == "fexists_assert") {
 745                                         s = rpn_pop();
 746                                         if(!rpn_error)
 747                                         {
 748                                                 f = fopen(s, FILE_READ);
 749                                                 if(f != -1)
 750                                                         fclose(f);
 751                                                 else {
 752                                                         print("rpn: ERROR: ", s, " does not exist!\n");
 753                                                         rpn_error = TRUE;
 754                                                 }
 755                                         }
 756                                 } else if(rpncmd == "fexists") {
 757                                         s = rpn_get();
 758                                         if(!rpn_error)
 759                                         {
 760                                                 f = fopen(s, FILE_READ);
 761                                                 if(f != -1) {
 762                                                         fclose(f);
 763                                                         rpn_setf(1);
 764                                                 } else {
 765                                                         rpn_setf(0);
 766                                                 }
 767                                         }
 768                                 } else if(rpncmd == "localtime") {
 769                                         rpn_set(strftime(TRUE, rpn_get()));
 770                                 } else if(rpncmd == "gmtime") {
 771                                         rpn_set(strftime(FALSE, rpn_get()));
 772                                 } else if(rpncmd == "time") {
 773                                         rpn_pushf(time);
 774                                 } else {
 775                                         rpn_push(cvar_string(rpncmd));
 776                                 }
 777                                 if(rpn_error)
 778                                         break;
 779                         }
 780                         while(rpn_sp > 0)
 781                         {
 782                                 s = rpn_pop();
 783                                 print("rpn: still on stack: ", s, "\n");
 784                         }
 785                         return TRUE;
 786                 }
 787         } else if(argv(0) == "addtolist") {
 788                 if(argc >= 2)
 789                 {
 790                         s = argv(1);
 791                         s2 = argv(2);
 792                         if(cvar_string(s) == "")
 793                                 cvar_set(s, s2);
 794                         else {
 795                                 n = tokenizebyseparator(cvar_string(s), " ");
 796                                 for(i = 0; i < n; ++i)
 797                                         if(argv(i) == s2)
 798                                                 return TRUE; // already in list
 799                                 cvar_set(s, strcat(s2, " ", cvar_string(s)));
 800                         }
 801                 }
 802                 return TRUE;
 803         }
 804         else if(argv(0) == "records") {
 805                 print(records_reply);
 806                 return TRUE;
 807 #ifdef MENUQC
 808         } else if(argv(0) == "cp") {
 809                 if(argc >= 2)
 810                 {
 811                         s = argv(1);
 812                         for(i = 2; i < argc; ++i)
 813                                 s = strcat(s, " ", argv(i));
 814                         centerprint(unescape(s));
 815                 }
 816                 return TRUE;
 817 #endif
 818         }
 819
 820         return FALSE;
 821 }