data/qcsrc/common/gamecommand.qc

   1 #define MAX_RPN_STACK 16
   2 float rpn_db;
   3 float rpn_error;
   4 float rpn_sp;
   5 string rpn_stack[MAX_RPN_STACK];
   6 string rpn_pop() {
   7         if(rpn_sp > 0) {
   8                 --rpn_sp;
   9                 return rpn_stack[rpn_sp];
  10         } else {
  11                 print("rpn: stack underflow\n");
  12                 rpn_error = TRUE;
  13                 return "";
  14         }
  15 }
  16 void rpn_push(string s) {
  17         if(rpn_sp < MAX_RPN_STACK) {
  18                 rpn_stack[rpn_sp] = s;
  19                 ++rpn_sp;
  20         } else {
  21                 print("rpn: stack overflow\n");
  22                 rpn_error = TRUE;
  23         }
  24 }
  25 string rpn_get() {
  26         if(rpn_sp > 0) {
  27                 return rpn_stack[rpn_sp - 1];
  28         } else {
  29                 print("rpn: empty stack\n");
  30                 rpn_error = TRUE;
  31                 return "";
  32         }
  33 }
  34 void rpn_set(string s) {
  35         if(rpn_sp > 0) {
  36                 rpn_stack[rpn_sp - 1] = s;
  37         } else {
  38                 print("rpn: empty stack\n");
  39                 rpn_error = TRUE;
  40         }
  41 }
  42 float rpn_getf() { return stof(rpn_get()); }
  43 float rpn_popf() { return stof(rpn_pop()); }
  44 void rpn_pushf(float f) { return rpn_push(ftos(f)); }
  45 void rpn_setf(float f) { return rpn_set(ftos(f)); }
  46
  47 #define NUM_MARKUPS     41
  48 float markup_init;
  49 string markup_from[NUM_MARKUPS];
  50 string markup_to[NUM_MARKUPS];
  51 void GameCommand_MarkupInit()
  52 {
  53         float i;
  54         if (markup_init)
  55                 return;
  56         markup_init = 1;
  57         i = 0;
  58         markup_from[i] = "&alien"; markup_to[i] = "\x12"; ++i;
  59         markup_from[i] = "&:-)"; markup_to[i] = "\x13"; ++i;
  60         markup_from[i] = "&:-("; markup_to[i] = "\x14"; ++i;
  61         markup_from[i] = "&x-P"; markup_to[i] = "\x15"; ++i;
  62         markup_from[i] = "&:-/"; markup_to[i] = "\x16"; ++i;
  63         markup_from[i] = "&:-D"; markup_to[i] = "\x17"; ++i;
  64         markup_from[i] = "&<<"; markup_to[i] = "\x18"; ++i;
  65         markup_from[i] = "&>>"; markup_to[i] = "\x19"; ++i;
  66         markup_from[i] = "&dot"; markup_to[i] = "\x1a"; ++i;
  67         markup_from[i] = "&^_"; markup_to[i] = "\x1b"; ++i;
  68         markup_from[i] = "&ysplat"; markup_to[i] = "\x1c"; ++i;
  69         markup_from[i] = "&-]"; markup_to[i] = "\x1d"; ++i;
  70         markup_from[i] = "&--"; markup_to[i] = "\x1e"; ++i;
  71         markup_from[i] = "&[-"; markup_to[i] = "\x1f"; ++i;
  72         markup_from[i] = "&s<"; markup_to[i] = "\x2c"; ++i;
  73         markup_from[i] = "&s>"; markup_to[i] = "\x2e"; ++i;
  74         markup_from[i] = "&<-"; markup_to[i] = "\x7f"; ++i;
  75         markup_from[i] = "&[="; markup_to[i] = "\x80"; ++i;
  76         markup_from[i] = "&=="; markup_to[i] = "\x81"; ++i;
  77         markup_from[i] = "&=]"; markup_to[i] = "\x82"; ++i;
  78         markup_from[i] = "&r!"; markup_to[i] = "\x84"; ++i;
  79         markup_from[i] = "&|o|"; markup_to[i] = "\x85"; ++i;
  80         markup_from[i] = "&|u|"; markup_to[i] = "\x86"; ++i;
  81         markup_from[i] = "&|i|"; markup_to[i] = "\x87"; ++i;
  82         markup_from[i] = "&|c|"; markup_to[i] = "\x88"; ++i;
  83         markup_from[i] = "&[c]"; markup_to[i] = "\x89"; ++i;
  84         markup_from[i] = "&[n]"; markup_to[i] = "\x8a"; ++i;
  85         markup_from[i] = "&[]"; markup_to[i] = "\x8b"; ++i;
  86         markup_from[i] = "&r?"; markup_to[i] = "\x8c"; ++i;
  87         markup_from[i] = "&|>"; markup_to[i] = "\x8d"; ++i;
  88         markup_from[i] = "&splat0"; markup_to[i] = "\x8e"; ++i;
  89         markup_from[i] = "&splat1"; markup_to[i] = "\x8f"; ++i;
  90         markup_from[i] = "&[["; markup_to[i] = "\x90"; ++i;
  91         markup_from[i] = "&]]"; markup_to[i] = "\x91"; ++i;
  92         markup_from[i] = "&splat2"; markup_to[i] = "\x9a"; ++i;
  93         markup_from[i] = "&)("; markup_to[i] = "\x9b"; ++i;
  94         markup_from[i] = "&splat3"; markup_to[i] = "\x9c"; ++i;
  95         markup_from[i] = "&(."; markup_to[i] = "\x9d"; ++i;
  96         markup_from[i] = "&.."; markup_to[i] = "\x9e"; ++i;
  97         markup_from[i] = "&.)"; markup_to[i] = "\x9f"; ++i;
  98         markup_from[i] = "&<|"; markup_to[i] = "\xff"; ++i;
  99 }
 100
 101 string GameCommand_Markup(string s2)
 102 {
 103         float red, ccase, i, j;
 104         string s, s3;
 105
 106         GameCommand_MarkupInit();
 107
 108         s = "";
 109
 110         red = 0;
 111         ccase = 0;
 112         for(i = 0; i < strlen(s2); ++i)
 113         {
 114                 for(j = 0; j < NUM_MARKUPS; ++j)
 115                 {
 116                         s3 = substring(s2, i, strlen(markup_from[j]));
 117                         if (s3 == markup_from[j])
 118                         {
 119                                 s = strcat(s, markup_to[j]);
 120                                 i += strlen(markup_from[j]) - 1;
 121                                 break;
 122                         }
 123                 }
 124
 125                 if(j == NUM_MARKUPS)
 126                 {
 127                         if(substring(s2, i, 2) == "&&")
 128                         {
 129                                 s = strcat(s, strconv(ccase, red, red, "&"));
 130                                 ++i;
 131                         }
 132                         else if(substring(s2, i, 2) == "&d")
 133                         {
 134                                 red = 2;
 135                                 ccase = 0;
 136                                 ++i;
 137                         }
 138                         else if(substring(s2, i, 2) == "&a")
 139                         {
 140                                 red = 2;
 141                                 ccase = 2;
 142                                 ++i;
 143                         }
 144                         else if(substring(s2, i, 2) == "&n")
 145                         {
 146                                 red = 0;
 147                                 ccase = 0;
 148                                 ++i;
 149                         }
 150                         else
 151                                 s = strcat(s, strconv(ccase, red, red, substring(s2, i, 1)));
 152                 }
 153         }
 154
 155         return s;
 156 }
 157
 158 float GameCommand_Generic(string command)
 159 {
 160         float argc;
 161         float i, j, f, n;
 162         vector rgb;
 163         string s, s2, c;
 164         argc = tokenize_console(command);
 165         if(argv(0) == "help")
 166         {
 167                 print("  rpn EXPRESSION... - a RPN calculator.\n");
 168                 print("    Operator description (x: string, s: set, f: float):\n");
 169                 print("    x pop ----------------------------->     : removes the top\n");
 170                 print("    x dup -----------------------------> x x : duplicates the top\n");
 171                 print("    x x exch --------------------------> x x : swap the top two\n");
 172                 print("    /cvarname load --------------------> x   : loads a cvar\n");
 173                 print("    /cvarname x def ------------------->     : writes to a cvar\n");
 174                 print("    f f add|sub|mul|div|mod|max|min ---> f   : adds/... two numbers\n");
 175                 print("    f f eq|ne|gt|ge|lt|le -------------> f   : compares two numbers\n");
 176                 print("    f neg|abs|sgn|rand|floor|ceil------> f   : negates/... a number\n");
 177                 print("    f f f bound -----------------------> f   : bounds the middle number\n");
 178                 print("    f1 f2 b when ----------------------> f   : f1 if b, f2 otherwise\n");
 179                 print("    s s union|intersection|difference -> s   : set operations\n");
 180                 print("    s shuffle -------------------------> s   : randomly arrange elements\n");
 181                 print("    /key /value put ------------------->     : set a database key\n");
 182                 print("    /key get --------------------------> s   : get a database value\n");
 183                 print("    x dbpush -------------------------->     : pushes the top onto the database\n");
 184                 print("    dbpop|dbget -----------------------> x   : removes/reads DB's top\n");
 185                 print("    dblen|dbat ------------------------> f   : gets the DB's size/cursor pos\n");
 186                 print("    dbclr ----------------------------->     : clear the DB\n");
 187                 print("    s dbsave|dbload-------------------->     : save/load the DB to/from a file\n");
 188                 print("    x dbins --------------------------->     : moves the top into the DB\n");
 189                 print("    dbext|dbread ----------------------> x   : extract/get from the DB's cursor\n");
 190                 print("    f dbmov|dbgoto -------------------->     : move or set the DB's cursor\n");
 191                 print("    s localtime -----------------------> s   : formats the current local time\n");
 192                 print("    s gmtime --------------------------> s   : formats the current UTC time\n");
 193                 print("    time ------------------------------> f   : seconds since VM start\n");
 194                 print("    Set operations operate on 'such''strings'.\n");
 195                 print("    Unknown tokens insert their cvar value.\n");
 196                 print("  maplist add map\n");
 197                 print("  maplist remove map\n");
 198                 print("  maplist shuffle\n");
 199                 print("  maplist cleanup\n");
 200                 print("  maplist maplist\n");
 201                 print("  maplist lsmaps\n");
 202                 print("  addtolist variable addedvalue\n");
 203                 print("  records\n");
 204                 print("  rankings (map argument optional)\n");
 205                 return TRUE;
 206         }
 207
 208         if(argv(0) == "maplist")
 209         {
 210                 if(argv(1) == "add" && argc == 3)
 211                 {
 212                         f = fopen(strcat("maps/", argv(2), ".bsp"), FILE_READ);
 213                         if(f != -1)
 214                                 fclose(f);
 215                         else {
 216                                 print("maplist: ERROR: ", argv(2), " does not exist!\n");
 217                                 return TRUE;
 218                         }
 219                         if(cvar_string("g_maplist") == "")
 220                                 cvar_set("g_maplist", argv(2));
 221                         else
 222                                 cvar_set("g_maplist", strcat(argv(2), " ", cvar_string("g_maplist")));
 223                         return TRUE;
 224                 }
 225                 else if(argv(1) == "remove" && argc == 3)
 226                 {
 227                         s = argv(2);
 228                         n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 229                         s2 = "";
 230                         for(i = 0; i < n; ++i)
 231                                 if(argv(i) != s)
 232                                         s2 = strcat(s2, " ", argv(i));
 233                         s2 = substring(s2, 1, strlen(s2) - 1);
 234                         cvar_set("g_maplist", s2);
 235                         return TRUE;
 236                 }
 237                 else if(argv(1) == "shuffle" && argc == 2)
 238                 {
 239                         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
 240                         return TRUE;
 241                 }
 242                 else if(argv(1) == "cleanup")
 243                 {
 244                         MapInfo_Enumerate();
 245                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 246                         n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 247                         s2 = "";
 248                         for(i = 0; i < n; ++i)
 249                                 if(MapInfo_CheckMap(argv(i)))
 250                                         s2 = strcat(s2, " ", argv(i));
 251                         s2 = substring(s2, 1, strlen(s2) - 1);
 252                         cvar_set("g_maplist", s2);
 253                         return TRUE;
 254                 }
 255                 else if(argv(1) == "maplist") {
 256                         print(maplist_reply);
 257                         return TRUE;
 258                 }
 259                 else if(argv(1) == "lsmaps") {
 260                         print(lsmaps_reply);
 261                         return TRUE;
 262                 }
 263         }
 264         else if(argc >= 3 && argv(0) == "red")
 265         {
 266                 s = substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2));
 267                 localcmd(strcat(argv(1), " ", GameCommand_Markup(s)));
 268                 return TRUE;
 269         }
 270         else if(argc >= 3 && crc16(0, argv(0)) == 38566 && crc16(0, strcat(argv(0), argv(0), argv(0))) == 59830)
 271         {
 272                 // other test case
 273                 s = strconv(2, 0, 0, substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 274
 275                 n = floor(random() * 6 + 2);
 276
 277                 s2 = "";
 278                 for(i = 0; i < n; ++i)
 279                 {
 280                         s2 = strcat(s2, "AH");
 281                 }
 282
 283                 if(random() < 0.1)
 284                         s2 = strcat(substring(s2, 1, strlen(s2) - 1), "A");
 285
 286                 if(s == "")
 287                         s = s2;
 288                 else
 289                         if(random() < 0.8)
 290                                 s = strcat(s, " ", s2);
 291                         else
 292                                 s = strcat(s2, " ", s);
 293
 294                 s2 = substring(s, strlen(s) - 2, 2);
 295                 if(s2 == "AH" || s2 == "AY")
 296                         s = strcat(s, "))");
 297                 else
 298                         s = strcat(s, " ))");
 299
 300                 if(random() < 0.1)
 301                         s = substring(s, 0, strlen(s) - 1);
 302
 303                 if(random() < 0.1)
 304                         s = strconv(1, 0, 0, s);
 305
 306                 localcmd(strcat(argv(1), " ", s));
 307
 308                 return TRUE;
 309         }
 310         else if(argc >= 3 && crc16(0, argv(0)) == 3826 && crc16(0, strcat(argv(0), argv(0), argv(0))) == 55970)
 311         {
 312                 // test case for terrencehill's color codes
 313                 s = strdecolorize(substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 314                 s2 = "";
 315
 316                 n = strlen(s);
 317                 j = ((6 * max(1, floor(strlen(s)/32 + random() * 2 - 1))) / n) * (1 - 2 * (random() > 0.5));
 318                 f = random() * 6;
 319
 320                 for(i = 0; i < n; ++i)
 321                 {
 322                         c = substring(s, i, 1);
 323
 324                         if(c == ";")
 325                                 c = ":";
 326                         else if(c == "^")
 327                         {
 328                                 c = "^^";
 329                                 if(substring(s, i+1, 1) == "^")
 330                                         ++i;
 331                         }
 332
 333                         if(c != " ")
 334                         {
 335                                 rgb = hsl_to_rgb('1 0 0' * (j * i + f) + '0 1 .5');
 336                                 c = strcat(rgb_to_hexcolor(rgb), c);
 337                         }
 338                         s2 = strcat(s2, c);
 339                 }
 340
 341                 localcmd(strcat(argv(1), " ", s2));
 342
 343                 return TRUE;
 344         }
 345         else if(argv(0) == "rpn")
 346         {
 347                 if(!rpn_db)
 348                 {
 349                         rpn_db = db_create();
 350                         db_put(rpn_db, "stack.pointer", "0");
 351                         db_put(rpn_db, "stack.pos", "-1");
 352                 }
 353                 if(argc >= 2)
 354                 {
 355                         float rpnpos;
 356                         string rpncmd;
 357                         float f2, f3;
 358                         rpn_sp = 0;
 359                         rpn_error = FALSE;
 360                         for(rpnpos = 1; rpnpos < argc; ++rpnpos)
 361                         {
 362                                 rpncmd = argv(rpnpos);
 363                                 f = strlen(rpncmd);
 364                                 if(rpncmd == "") {
 365                                 } else if(stof(substring(rpncmd, 0, 1)) > 0) {
 366                                         rpn_push(rpncmd);
 367                                 } else if(substring(rpncmd, 0, 1) == "0") {
 368                                         rpn_push(rpncmd);
 369                                 } else if(f >= 2 && substring(rpncmd, 0, 1) == "+") {
 370                                         rpn_push(rpncmd);
 371                                 } else if(f >= 2 && substring(rpncmd, 0, 1) == "-") {
 372                                         rpn_push(rpncmd);
 373                                 } else if(f >= 2 && substring(rpncmd, 0, 1) == "/") {
 374                                         rpn_push(substring(rpncmd, 1, strlen(rpncmd) - 1));
 375                                 } else if(rpncmd == "clear") {
 376                                         rpn_sp = 0;
 377                                 } else if(rpncmd == "def" || rpncmd == "=") {
 378                                         s = rpn_pop();
 379                                         s2 = rpn_pop();
 380
 381                                         if(s2 != "")
 382                                         {
 383 #ifdef MENUQC
 384                                                 registercvar(s2, "", 0);
 385 #else
 386                                                 registercvar(s2, "");
 387 #endif
 388                                                 if(!rpn_error) // don't change cvars if a stack error had happened!
 389                                                         cvar_set(s2, s);
 390                                         }
 391                                         else
 392                                         {
 393                                                 print("rpn: empty cvar name for 'def'\n");
 394                                                 rpn_error = TRUE;
 395                                         }
 396                                 } else if(rpncmd == "defs" || rpncmd == "@") {
 397                                         s = "";
 398                                         i = rpn_popf();
 399                                         j = (i == 0);
 400                                         while(rpn_sp > 1 && (j || i > 0))
 401                                         {
 402                                                 s = strcat("/", rpn_pop(), " ", s);
 403                                                 --i;
 404                                         }
 405                                         s2 = rpn_pop();
 406                                         if(s2 != "")
 407                                         {
 408 #ifdef MENUQC
 409                                                 registercvar(s2, "", 0);
 410 #else
 411                                                 registercvar(s2, "");
 412 #endif
 413                                                 if(!rpn_error) // don't change cvars if a stack error had happened!
 414                                                         cvar_set(s2, s);
 415                                         }
 416                                         else
 417                                         {
 418                                                 print("rpn: empty cvar name for 'defs'\n");
 419                                                 rpn_error = TRUE;
 420                                         }
 421                                 } else if(rpncmd == "load") {
 422 #ifdef SVQC
 423                                         rpn_set(cvar_string_builtin(rpn_get())); // cvar name comes from user
 424 #else
 425                                         rpn_set(cvar_string(rpn_get()));
 426 #endif
 427                                 } else if(rpncmd == "exch") {
 428                                         s = rpn_pop();
 429                                         s2 = rpn_get();
 430                                         rpn_set(s);
 431                                         rpn_push(s2);
 432                                 } else if(rpncmd == "dup") {
 433                                         rpn_push(rpn_get());
 434                                 } else if(rpncmd == "pop") {
 435                                         rpn_pop();
 436                                 } else if(rpncmd == "add" || rpncmd == "+") {
 437                                         f = rpn_popf();
 438                                         rpn_setf(rpn_getf() + f);
 439                                 } else if(rpncmd == "sub" || rpncmd == "-") {
 440                                         f = rpn_popf();
 441                                         rpn_setf(rpn_getf() - f);
 442                                 } else if(rpncmd == "mul" || rpncmd == "*") {
 443                                         f = rpn_popf();
 444                                         rpn_setf(rpn_getf() * f);
 445                                 } else if(rpncmd == "div" || rpncmd == "/") {
 446                                         f = rpn_popf();
 447                                         rpn_setf(rpn_getf() / f);
 448                                 } else if(rpncmd == "mod" || rpncmd == "%") {
 449                                         f = rpn_popf();
 450                                         f2 = rpn_getf();
 451                                         rpn_setf(f2 - f * floor(f2 / f));
 452                                 } else if(rpncmd == "abs") {
 453                                         rpn_setf(fabs(rpn_getf()));
 454                                 } else if(rpncmd == "sgn") {
 455                                         f = rpn_getf();
 456                                         if(f < 0)
 457                                                 rpn_set("-1");
 458                                         else if(f > 0)
 459                                                 rpn_set("1");
 460                                         else
 461                                                 rpn_set("0");
 462                                 } else if(rpncmd == "neg" || rpncmd == "~") {
 463                                         rpn_setf(-rpn_getf());
 464                                 } else if(rpncmd == "floor" || rpncmd == "f") {
 465                                         rpn_setf(floor(rpn_getf()));
 466                                 } else if(rpncmd == "ceil" || rpncmd == "c") {
 467                                         rpn_setf(ceil(rpn_getf()));
 468                                 } else if(rpncmd == "max") {
 469                                         f = rpn_popf();
 470                                         f2 = rpn_getf();
 471                                         rpn_setf(max(f2, f));
 472                                 } else if(rpncmd == "min") {
 473                                         f = rpn_popf();
 474                                         f2 = rpn_getf();
 475                                         rpn_setf(min(f2, f));
 476                                 } else if(rpncmd == "bound") {
 477                                         f = rpn_popf();
 478                                         f2 = rpn_popf();
 479                                         f3 = rpn_getf();
 480                                         rpn_setf(bound(f3, f2, f));
 481                                 } else if(rpncmd == "when") {
 482                                         f = rpn_popf();
 483                                         f2 = rpn_popf();
 484                                         f3 = rpn_getf();
 485                                         if(f)
 486                                                 rpn_setf(f3);
 487                                         else
 488                                                 rpn_setf(f2);
 489                                 } else if(rpncmd == ">" || rpncmd == "gt") {
 490                                         f = rpn_popf();
 491                                         rpn_setf(rpn_getf() > f);
 492                                 } else if(rpncmd == "<" || rpncmd == "lt") {
 493                                         f = rpn_popf();
 494                                         rpn_setf(rpn_getf() < f);
 495                                 } else if(rpncmd == "==" || rpncmd == "eq") {
 496                                         f = rpn_popf();
 497                                         rpn_setf(rpn_getf() == f);
 498                                 } else if(rpncmd == ">=" || rpncmd == "ge") {
 499                                         f = rpn_popf();
 500                                         rpn_setf(rpn_getf() >= f);
 501                                 } else if(rpncmd == "<=" || rpncmd == "le") {
 502                                         f = rpn_popf();
 503                                         rpn_setf(rpn_getf() <= f);
 504                                 } else if(rpncmd == "!=" || rpncmd == "ne") {
 505                                         f = rpn_popf();
 506                                         rpn_setf(rpn_getf() != f);
 507                                 } else if(rpncmd == "rand") {
 508                                         rpn_setf(ceil(random() * rpn_getf()) - 1);
 509                                 } else if(rpncmd == "crc16") {
 510                                         rpn_setf(crc16(FALSE, rpn_get()));
 511                                 } else if(rpncmd == "put") {
 512                                         s2 = rpn_pop();
 513                                         if (!rpn_error)
 514                                         {
 515                                                 s = rpn_pop();
 516                                                 if (!rpn_error)
 517                                                         db_put(rpn_db, s, s2);
 518                                         }
 519                                 } else if(rpncmd == "get") {
 520                                         s = rpn_pop();
 521                                         if (!rpn_error)
 522                                                 rpn_push(db_get(rpn_db, s));
 523                                 } else if(rpncmd == "dbpush") {
 524                                         s = rpn_pop();
 525                                         if(!rpn_error)
 526                                         {
 527                                                 i = stof(db_get(rpn_db, "stack.pointer"));
 528                                                 db_put(rpn_db, "stack.pointer", ftos(i+1));
 529                                                 db_put(rpn_db, strcat("stack.", ftos(i)), s);
 530                                         }
 531                                         if(!i)
 532                                                 db_put(rpn_db, "stack.pos", "0");
 533                                 } else if(rpncmd == "dbpop") {
 534                                         i = stof(db_get(rpn_db, "stack.pointer"));
 535                                         if(i)
 536                                         {
 537                                                 s = ftos(i-1);
 538                                                 db_put(rpn_db, "stack.pointer", s);
 539                                                 rpn_push(db_get(rpn_db, strcat("stack.", s)));
 540                                                 j = stof(db_get(rpn_db, "stack.pos"));
 541                                                 if(j >= i)
 542                                                         db_put(rpn_db, "stack.pos", ftos(i-2));
 543                                         } else {
 544                                                 rpn_error = 1;
 545                                                 print("rpn: database underflow\n");
 546                                         }
 547                                 } else if(rpncmd == "dbget") {
 548
 549                                         i = stof(db_get(rpn_db, "stack.pointer"));
 550                                         if(i)
 551                                         {
 552                                                 rpn_push(db_get(rpn_db, strcat("stack.", ftos(i-1))));
 553                                         } else {
 554                                                 rpn_error = 1;
 555                                                 print("rpn: database empty\n");
 556                                         }
 557                                 } else if(rpncmd == "dblen") {
 558                                         rpn_push(db_get(rpn_db, "stack.pointer"));
 559                                 } else if(rpncmd == "dbclr") {
 560                                         db_close(rpn_db);
 561                                         rpn_db = db_create();
 562                                         db_put(rpn_db, "stack.pointer", "0");
 563                                         db_put(rpn_db, "stack.pos", "-1");
 564                                 } else if(rpncmd == "dbsave") {
 565                                         s = rpn_pop();
 566                                         if(!rpn_error)
 567                                                 db_save(rpn_db, s);
 568                                 } else if(rpncmd == "dbload") {
 569                                         s = rpn_pop();
 570                                         if(!rpn_error)
 571                                         {
 572                                                 db_close(rpn_db);
 573                                                 rpn_db = db_load(s);
 574                                         }
 575                                 } else if(rpncmd == "dbins") {
 576                                         s = rpn_pop();
 577                                         if(!rpn_error)
 578                                                 //if(rpn_sp > 0)
 579                                         {
 580                                                 j = stof(db_get(rpn_db, "stack.pointer"));
 581                                                 i = stof(db_get(rpn_db, "stack.pos"));
 582
 583                                                 if(i < 0)
 584                                                 {
 585                                                         i = 0;
 586                                                         db_put(rpn_db, "stack.pos", "0");
 587                                                 }
 588
 589                                                 db_put(rpn_db, "stack.pointer", ftos(j+1));
 590                                                 for(--j; j >= i; --j)
 591                                                 {
 592                                                         db_put(rpn_db, strcat("stack.", ftos(j+1)),
 593                                                                db_get(rpn_db, (strcat("stack.", ftos(j))))
 594                                                                 );
 595                                                 }
 596                                                 db_put(rpn_db, strcat("stack.", ftos(i)), s);
 597                                         }
 598                                 } else if(rpncmd == "dbext") {
 599                                         j = stof(db_get(rpn_db, "stack.pointer"));
 600                                         i = stof(db_get(rpn_db, "stack.pos"));
 601                                         if(!j)
 602                                         {
 603                                                 rpn_error = TRUE;
 604                                                 print("rpn: empty database\n");
 605                                         } else {
 606                                                 --j;
 607                                                 rpn_push(db_get(rpn_db, strcat("stack.", ftos(i))));
 608                                                 db_put(rpn_db, "stack.pointer", ftos(j));
 609                                                 if(i == j)
 610                                                 {
 611                                                         db_put(rpn_db, "stack.pos", ftos(j-1));
 612                                                 } else {
 613                                                         while(i < j)
 614                                                         {
 615                                                                 db_put(rpn_db, strcat("stack.", ftos(i)),
 616                                                                        db_get(rpn_db, (strcat("stack.", ftos(i+1))))
 617                                                                         );
 618                                                                 ++i;
 619                                                         }
 620                                                 }
 621                                         }
 622                                 } else if(rpncmd == "dbread") {
 623                                         s = db_get(rpn_db, "stack.pos");
 624                                         if(stof(s) >= 0)
 625                                         {
 626                                                 rpn_push(db_get(rpn_db, strcat("stack.", s)));
 627                                         } else {
 628                                                 rpn_error = 1;
 629                                                 print("rpn: empty database\n");
 630                                         }
 631                                 } else if(rpncmd == "dbat") {
 632                                         rpn_push(db_get(rpn_db, "stack.pos"));
 633                                 } else if(rpncmd == "dbmov") {
 634                                         j = stof(db_get(rpn_db, "stack.pointer"));
 635                                         i = stof(db_get(rpn_db, "stack.pos"));
 636                                         i += rpn_popf();
 637                                         if(!rpn_error)
 638                                         {
 639                                                 if(i < 0 || i >= j)
 640                                                 {
 641                                                         print("rpn: database cursor out of bounds\n");
 642                                                         rpn_error = TRUE;
 643                                                 }
 644                                                 if(!rpn_error)
 645                                                 {
 646                                                         db_put(rpn_db, "stack.pos", ftos(i));
 647                                                 }
 648                                         }
 649                                 } else if(rpncmd == "dbgoto") {
 650                                         s = rpn_pop();
 651                                         j = stof(db_get(rpn_db, "stack.pointer"));
 652                                         if(!j)
 653                                         {
 654                                                 rpn_error = TRUE;
 655                                                 print("rpn: empty database, cannot move cursor\n");
 656                                         }
 657                                         if(!rpn_error)
 658                                         {
 659                                                 if(s == "end")
 660                                                         i = stof(db_get(rpn_db, "stack.pointer"))-1;
 661                                                 else if(s == "beg")
 662                                                         i = 0;
 663                                                 else
 664                                                         i = stof(s);
 665
 666                                                 j = stof(db_get(rpn_db, "stack.pointer"));
 667                                                 if(i < 0 || i >= j)
 668                                                 {
 669                                                         print("rpn: database cursor destination out of bounds\n");
 670                                                         rpn_error = TRUE;
 671                                                 }
 672                                                 if(!rpn_error)
 673                                                 {
 674                                                         db_put(rpn_db, "stack.pos", ftos(i));
 675                                                 }
 676                                         }
 677                                 } else if(rpncmd == "union") {
 678                                         // s s2 union
 679                                         s2 = rpn_pop();
 680                                         s = rpn_get();
 681                                         f = tokenize_console(s);
 682                                         f2 = tokenize_console(strcat(s, " ", s2));
 683                                         // tokens 0..(f-1) represent s
 684                                         // tokens f..f2 represent s2
 685                                         // UNION: add all tokens to s that are in s2 but not in s
 686                                         s = "";
 687                                         for(i = 0; i < f; ++i)
 688                                                 s = strcat(s, " ", argv(i));
 689                                         for(i = f; i < f2; ++i) {
 690                                                 for(j = 0; j < f; ++j)
 691                                                         if(argv(i) == argv(j))
 692                                                                 goto skip_union;
 693                                                 s = strcat(s, " ", argv(i));
 694 :skip_union
 695                                         }
 696                                         if(substring(s, 0, 1) == " ")
 697                                                 s = substring(s, 1, 99999);
 698                                         rpn_set(s);
 699                                         tokenize_console(command);
 700                                 } else if(rpncmd == "intersection") {
 701                                         // s s2 intersection
 702                                         s2 = rpn_pop();
 703                                         s = rpn_get();
 704                                         f = tokenize_console(s);
 705                                         f2 = tokenize_console(strcat(s, " ", s2));
 706                                         // tokens 0..(f-1) represent s
 707                                         // tokens f..f2 represent s2
 708                                         // INTERSECTION: keep only the tokens from s that are also in s2
 709                                         s = "";
 710                                         for(i = 0; i < f; ++i) {
 711                                                 for(j = f; j < f2; ++j)
 712                                                         if(argv(i) == argv(j))
 713                                                         {
 714                                                                 s = strcat(s, " ", argv(i));
 715                                                                 break;
 716                                                         }
 717                                         }
 718                                         if(substring(s, 0, 1) == " ")
 719                                                 s = substring(s, 1, 99999);
 720                                         rpn_set(s);
 721                                         tokenize_console(command);
 722                                 } else if(rpncmd == "difference") {
 723                                         // s s2 difference
 724                                         s2 = rpn_pop();
 725                                         s = rpn_get();
 726                                         f = tokenize_console(s);
 727                                         f2 = tokenize_console(strcat(s, " ", s2));
 728                                         // tokens 0..(f-1) represent s
 729                                         // tokens f..f2 represent s2
 730                                         // DIFFERENCE: keep only the tokens from s that are not in s2
 731                                         s = "";
 732                                         for(i = 0; i < f; ++i) {
 733                                                 for(j = f; j < f2; ++j)
 734                                                         if(argv(i) == argv(j))
 735                                                                 goto skip_difference;
 736                                                 s = strcat(s, " ", argv(i));
 737 :skip_difference
 738                                         }
 739                                         if(substring(s, 0, 1) == " ")
 740                                                 s = substring(s, 1, 99999);
 741                                         rpn_set(s);
 742                                         tokenize_console(command);
 743                                 } else if(rpncmd == "shuffle") {
 744                                         // s shuffle
 745                                         s = rpn_get();
 746                                         f = tokenize_console(s);
 747
 748                                         for(i = 0; i < f - 1; ++i) {
 749                                                 // move a random item from i..f-1 to position i
 750                                                 s = "";
 751                                                 f2 = floor(random() * (f - i) + i);
 752                                                 for(j = 0; j < i; ++j)
 753                                                         s = strcat(s, " ", argv(j));
 754                                                 s = strcat(s, " ", argv(f2));
 755                                                 for(j = i; j < f; ++j)
 756                                                         if(j != f2)
 757                                                                 s = strcat(s, " ", argv(j));
 758                                                 f = tokenize_console(s);
 759                                         }
 760
 761                                         if(substring(s, 0, 1) == " ")
 762                                                 s = substring(s, 1, 99999);
 763                                         rpn_set(s);
 764                                         tokenize_console(command);
 765                                 } else if(rpncmd == "fexists_assert") {
 766                                         s = rpn_pop();
 767                                         if(!rpn_error)
 768                                         {
 769                                                 f = fopen(s, FILE_READ);
 770                                                 if(f != -1)
 771                                                         fclose(f);
 772                                                 else {
 773                                                         print("rpn: ERROR: ", s, " does not exist!\n");
 774                                                         rpn_error = TRUE;
 775                                                 }
 776                                         }
 777                                 } else if(rpncmd == "fexists") {
 778                                         s = rpn_get();
 779                                         if(!rpn_error)
 780                                         {
 781                                                 f = fopen(s, FILE_READ);
 782                                                 if(f != -1) {
 783                                                         fclose(f);
 784                                                         rpn_setf(1);
 785                                                 } else {
 786                                                         rpn_setf(0);
 787                                                 }
 788                                         }
 789                                 } else if(rpncmd == "localtime") {
 790                                         rpn_set(strftime(TRUE, rpn_get()));
 791                                 } else if(rpncmd == "gmtime") {
 792                                         rpn_set(strftime(FALSE, rpn_get()));
 793                                 } else if(rpncmd == "time") {
 794                                         rpn_pushf(time);
 795                                 } else {
 796                                         rpn_push(cvar_string(rpncmd));
 797                                 }
 798                                 if(rpn_error)
 799                                         break;
 800                         }
 801                         while(rpn_sp > 0)
 802                         {
 803                                 s = rpn_pop();
 804                                 print("rpn: still on stack: ", s, "\n");
 805                         }
 806                         return TRUE;
 807                 }
 808         } else if(argv(0) == "addtolist") {
 809                 if(argc >= 2)
 810                 {
 811                         s = argv(1);
 812                         s2 = argv(2);
 813                         if(cvar_string(s) == "")
 814                                 cvar_set(s, s2);
 815                         else {
 816                                 n = tokenizebyseparator(cvar_string(s), " ");
 817                                 for(i = 0; i < n; ++i)
 818                                         if(argv(i) == s2)
 819                                                 return TRUE; // already in list
 820                                 cvar_set(s, strcat(s2, " ", cvar_string(s)));
 821                         }
 822                 }
 823                 return TRUE;
 824         }
 825         else if(argv(0) == "records") {
 826                 print(records_reply);
 827                 return TRUE;
 828         }
 829         else if(argv(0) == "rankings") {
 830                 print(rankings_reply);
 831                 return TRUE;
 832 #ifdef MENUQC
 833         } else if(argv(0) == "cp") {
 834                 if(argc >= 2)
 835                 {
 836                         s = argv(1);
 837                         for(i = 2; i < argc; ++i)
 838                                 s = strcat(s, " ", argv(i));
 839                         centerprint(unescape(s));
 840                 }
 841                 return TRUE;
 842 #endif
 843         }
 844
 845         return FALSE;
 846 }