data/qcsrc/common/gamecommand.qc

   1 #define MAX_RPN_STACK 16
   2 float rpn_db;
   3 float rpn_error;
   4 float rpn_sp;
   5 string rpn_stack[MAX_RPN_STACK];
   6 string rpn_pop() {
   7         if(rpn_sp > 0) {
   8                 --rpn_sp;
   9                 return rpn_stack[rpn_sp];
  10         } else {
  11                 print("rpn: stack underflow\n");
  12                 rpn_error = TRUE;
  13                 return "";
  14         }
  15 }
  16 void rpn_push(string s) {
  17         if(rpn_sp < MAX_RPN_STACK) {
  18                 rpn_stack[rpn_sp] = s;
  19                 ++rpn_sp;
  20         } else {
  21                 print("rpn: stack overflow\n");
  22                 rpn_error = TRUE;
  23         }
  24 }
  25 string rpn_get() {
  26         if(rpn_sp > 0) {
  27                 return rpn_stack[rpn_sp - 1];
  28         } else {
  29                 print("rpn: empty stack\n");
  30                 rpn_error = TRUE;
  31                 return "";
  32         }
  33 }
  34 void rpn_set(string s) {
  35         if(rpn_sp > 0) {
  36                 rpn_stack[rpn_sp - 1] = s;
  37         } else {
  38                 print("rpn: empty stack\n");
  39                 rpn_error = TRUE;
  40         }
  41 }
  42 float rpn_getf() { return stof(rpn_get()); }
  43 float rpn_popf() { return stof(rpn_pop()); }
  44 void rpn_pushf(float f) { return rpn_push(ftos(f)); }
  45 void rpn_setf(float f) { return rpn_set(ftos(f)); }
  46
  47 #define NUM_MARKUPS     41
  48 float markup_init;
  49 string markup_from[NUM_MARKUPS];
  50 string markup_to[NUM_MARKUPS];
  51 void GameCommand_MarkupInit()
  52 {
  53         float i;
  54         if (markup_init)
  55                 return;
  56         markup_init = 1;
  57         i = 0;
  58         markup_from[i] = "&alien"; markup_to[i] = "\x12"; ++i;
  59         markup_from[i] = "&:-)"; markup_to[i] = "\x13"; ++i;
  60         markup_from[i] = "&:-("; markup_to[i] = "\x14"; ++i;
  61         markup_from[i] = "&x-P"; markup_to[i] = "\x15"; ++i;
  62         markup_from[i] = "&:-/"; markup_to[i] = "\x16"; ++i;
  63         markup_from[i] = "&:-D"; markup_to[i] = "\x17"; ++i;
  64         markup_from[i] = "&<<"; markup_to[i] = "\x18"; ++i;
  65         markup_from[i] = "&>>"; markup_to[i] = "\x19"; ++i;
  66         markup_from[i] = "&dot"; markup_to[i] = "\x1a"; ++i;
  67         markup_from[i] = "&^_"; markup_to[i] = "\x1b"; ++i;
  68         markup_from[i] = "&ysplat"; markup_to[i] = "\x1c"; ++i;
  69         markup_from[i] = "&-]"; markup_to[i] = "\x1d"; ++i;
  70         markup_from[i] = "&--"; markup_to[i] = "\x1e"; ++i;
  71         markup_from[i] = "&[-"; markup_to[i] = "\x1f"; ++i;
  72         markup_from[i] = "&s<"; markup_to[i] = "\x2c"; ++i;
  73         markup_from[i] = "&s>"; markup_to[i] = "\x2e"; ++i;
  74         markup_from[i] = "&<-"; markup_to[i] = "\x7f"; ++i;
  75         markup_from[i] = "&[="; markup_to[i] = "\x80"; ++i;
  76         markup_from[i] = "&=="; markup_to[i] = "\x81"; ++i;
  77         markup_from[i] = "&=]"; markup_to[i] = "\x82"; ++i;
  78         markup_from[i] = "&r!"; markup_to[i] = "\x84"; ++i;
  79         markup_from[i] = "&|o|"; markup_to[i] = "\x85"; ++i;
  80         markup_from[i] = "&|u|"; markup_to[i] = "\x86"; ++i;
  81         markup_from[i] = "&|i|"; markup_to[i] = "\x87"; ++i;
  82         markup_from[i] = "&|c|"; markup_to[i] = "\x88"; ++i;
  83         markup_from[i] = "&[c]"; markup_to[i] = "\x89"; ++i;
  84         markup_from[i] = "&[n]"; markup_to[i] = "\x8a"; ++i;
  85         markup_from[i] = "&[]"; markup_to[i] = "\x8b"; ++i;
  86         markup_from[i] = "&r?"; markup_to[i] = "\x8c"; ++i;
  87         markup_from[i] = "&|>"; markup_to[i] = "\x8d"; ++i;
  88         markup_from[i] = "&splat0"; markup_to[i] = "\x8e"; ++i;
  89         markup_from[i] = "&splat1"; markup_to[i] = "\x8f"; ++i;
  90         markup_from[i] = "&[["; markup_to[i] = "\x90"; ++i;
  91         markup_from[i] = "&]]"; markup_to[i] = "\x91"; ++i;
  92         markup_from[i] = "&splat2"; markup_to[i] = "\x9a"; ++i;
  93         markup_from[i] = "&)("; markup_to[i] = "\x9b"; ++i;
  94         markup_from[i] = "&splat3"; markup_to[i] = "\x9c"; ++i;
  95         markup_from[i] = "&(."; markup_to[i] = "\x9d"; ++i;
  96         markup_from[i] = "&.."; markup_to[i] = "\x9e"; ++i;
  97         markup_from[i] = "&.)"; markup_to[i] = "\x9f"; ++i;
  98         markup_from[i] = "&<|"; markup_to[i] = "\xff"; ++i;
  99 }
 100
 101 string GameCommand_Markup(string s2)
 102 {
 103         float red, ccase, i, j;
 104         string s, s3;
 105
 106         GameCommand_MarkupInit();
 107
 108         s = "";
 109
 110         red = 0;
 111         ccase = 0;
 112         for(i = 0; i < strlen(s2); ++i)
 113         {
 114                 for(j = 0; j < NUM_MARKUPS; ++j)
 115                 {
 116                         s3 = substring(s2, i, strlen(markup_from[j]));
 117                         if (s3 == markup_from[j])
 118                         {
 119                                 s = strcat(s, markup_to[j]);
 120                                 i += strlen(markup_from[j]) - 1;
 121                                 break;
 122                         }
 123                 }
 124
 125                 if(j == NUM_MARKUPS)
 126                 {
 127                         if(substring(s2, i, 2) == "&&")
 128                         {
 129                                 s = strcat(s, strconv(ccase, red, red, "&"));
 130                                 ++i;
 131                         }
 132                         else if(substring(s2, i, 2) == "&d")
 133                         {
 134                                 red = 2;
 135                                 ccase = 0;
 136                                 ++i;
 137                         }
 138                         else if(substring(s2, i, 2) == "&a")
 139                         {
 140                                 red = 2;
 141                                 ccase = 2;
 142                                 ++i;
 143                         }
 144                         else if(substring(s2, i, 2) == "&n")
 145                         {
 146                                 red = 0;
 147                                 ccase = 0;
 148                                 ++i;
 149                         }
 150                         else
 151                                 s = strcat(s, strconv(ccase, red, red, substring(s2, i, 1)));
 152                 }
 153         }
 154
 155         return s;
 156 }
 157
 158 float GameCommand_Generic(string command)
 159 {
 160         float argc;
 161         float i, j, f, n;
 162         vector rgb;
 163         string s, s2, c;
 164         argc = tokenize_console(command);
 165         if(argv(0) == "help")
 166         {
 167                 print("  rpn EXPRESSION... - a RPN calculator.\n");
 168                 print("    Operator description (x: string, s: set, f: float):\n");
 169                 print("    x pop ----------------------------->     : removes the top\n");
 170                 print("    x dup -----------------------------> x x : duplicates the top\n");
 171                 print("    x x exch --------------------------> x x : swap the top two\n");
 172                 print("    /cvarname load --------------------> x   : loads a cvar\n");
 173                 print("    /cvarname x def ------------------->     : writes to a cvar\n");
 174                 print("    f f add|sub|mul|div|mod|max|min ---> f   : adds/... two numbers\n");
 175                 print("    f f eq|ne|gt|ge|lt|le -------------> f   : compares two numbers\n");
 176                 print("    f neg|abs|sgn|rand|floor|ceil------> f   : negates/... a number\n");
 177                 print("    f f f bound -----------------------> f   : bounds the middle number\n");
 178                 print("    f1 f2 b when ----------------------> f   : f1 if b, f2 otherwise\n");
 179                 print("    s s union|intersection|difference -> s   : set operations\n");
 180                 print("    s shuffle -------------------------> s   : randomly arrange elements\n");
 181                 print("    x dbpush -------------------------->     : pushes the top onto the database\n");
 182                 print("    dbpop|dbget -----------------------> x   : removes/reads DB's top\n");
 183                 print("    dblen|dbat ------------------------> f   : gets the DB's size/cursor pos\n");
 184                 print("    dbclr ----------------------------->     : clear the DB\n");
 185                 print("    s dbsave|dbload-------------------->     : save/load the DB to/from a file\n");
 186                 print("    x dbins --------------------------->     : moves the top into the DB\n");
 187                 print("    dbext|dbread ----------------------> x   : extract/get from the DB's cursor\n");
 188                 print("    f dbmov|dbgoto -------------------->     : move or set the DB's cursor\n");
 189                 print("    s localtime -----------------------> s   : formats the current local time\n");
 190                 print("    s gmtime --------------------------> s   : formats the current UTC time\n");
 191                 print("    time ------------------------------> f   : seconds since VM start\n");
 192                 print("    Set operations operate on 'such''strings'.\n");
 193                 print("    Unknown tokens insert their cvar value.\n");
 194                 print("  maplist add map\n");
 195                 print("  maplist remove map\n");
 196                 print("  maplist shuffle\n");
 197                 print("  maplist cleanup\n");
 198                 print("  maplist maplist\n");
 199                 print("  maplist lsmaps\n");
 200                 print("  addtolist variable addedvalue\n");
 201                 print("  records\n");
 202                 return TRUE;
 203         }
 204
 205         if(argv(0) == "maplist")
 206         {
 207                 if(argv(1) == "add" && argc == 3)
 208                 {
 209                         f = fopen(strcat("maps/", argv(2), ".bsp"), FILE_READ);
 210                         if(f != -1)
 211                                 fclose(f);
 212                         else {
 213                                 print("maplist: ERROR: ", argv(2), " does not exist!\n");
 214                                 return TRUE;
 215                         }
 216                         if(cvar_string("g_maplist") == "")
 217                                 cvar_set("g_maplist", argv(2));
 218                         else
 219                                 cvar_set("g_maplist", strcat(argv(2), " ", cvar_string("g_maplist")));
 220                         return TRUE;
 221                 }
 222                 else if(argv(1) == "remove" && argc == 3)
 223                 {
 224                         s = argv(2);
 225                         n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 226                         s2 = "";
 227                         for(i = 0; i < n; ++i)
 228                                 if(argv(i) != s)
 229                                         s2 = strcat(s2, " ", argv(i));
 230                         s2 = substring(s2, 1, strlen(s2) - 1);
 231                         cvar_set("g_maplist", s2);
 232                         return TRUE;
 233                 }
 234                 else if(argv(1) == "shuffle" && argc == 2)
 235                 {
 236                         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
 237                         return TRUE;
 238                 }
 239                 else if(argv(1) == "cleanup")
 240                 {
 241                         MapInfo_Enumerate();
 242                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 243                         n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 244                         s2 = "";
 245                         for(i = 0; i < n; ++i)
 246                                 if(MapInfo_CheckMap(argv(i)))
 247                                         s2 = strcat(s2, " ", argv(i));
 248                         s2 = substring(s2, 1, strlen(s2) - 1);
 249                         cvar_set("g_maplist", s2);
 250                         return TRUE;
 251                 }
 252                 else if(argv(1) == "maplist") {
 253                         print(maplist_reply);
 254                         return TRUE;
 255                 }
 256                 else if(argv(1) == "lsmaps") {
 257                         print(lsmaps_reply);
 258                         return TRUE;
 259                 }
 260         }
 261         else if(argc >= 3 && argv(0) == "red")
 262         {
 263                 s = substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2));
 264                 localcmd(strcat(argv(1), " ", GameCommand_Markup(s)));
 265                 return TRUE;
 266         }
 267         else if(argc >= 3 && crc16(0, argv(0)) == 38566 && crc16(0, strcat(argv(0), argv(0), argv(0))) == 59830)
 268         {
 269                 // other test case
 270                 s = strconv(2, 0, 0, substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 271
 272                 n = floor(random() * 6 + 2);
 273
 274                 s2 = "";
 275                 for(i = 0; i < n; ++i)
 276                 {
 277                         s2 = strcat(s2, "AH");
 278                 }
 279
 280                 if(random() < 0.1)
 281                         s2 = strcat(substring(s2, 1, strlen(s2) - 1), "A");
 282
 283                 if(s == "")
 284                         s = s2;
 285                 else
 286                         if(random() < 0.8)
 287                                 s = strcat(s, " ", s2);
 288                         else
 289                                 s = strcat(s2, " ", s);
 290
 291                 s2 = substring(s, strlen(s) - 2, 2);
 292                 if(s2 == "AH" || s2 == "AY")
 293                         s = strcat(s, "))");
 294                 else
 295                         s = strcat(s, " ))");
 296
 297                 if(random() < 0.1)
 298                         s = substring(s, 0, strlen(s) - 1);
 299
 300                 if(random() < 0.1)
 301                         s = strconv(1, 0, 0, s);
 302
 303                 localcmd(strcat(argv(1), " ", s));
 304
 305                 return TRUE;
 306         }
 307         else if(argc >= 3 && crc16(0, argv(0)) == 3826 && crc16(0, strcat(argv(0), argv(0), argv(0))) == 55970)
 308         {
 309                 // test case for terrencehill's color codes
 310                 s = strdecolorize(substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 311                 s2 = "";
 312
 313                 n = strlen(s);
 314                 j = ((6 * max(1, floor(strlen(s)/32 + random() * 2 - 1))) / n) * (1 - 2 * (random() > 0.5));
 315                 f = random() * 6;
 316
 317                 for(i = 0; i < n; ++i)
 318                 {
 319                         c = substring(s, i, 1);
 320
 321                         if(c == ";")
 322                                 c = ":";
 323                         else if(c == "^")
 324                         {
 325                                 c = "^^";
 326                                 if(substring(s, i+1, 1) == "^")
 327                                         ++i;
 328                         }
 329
 330                         if(c != " ")
 331                         {
 332                                 rgb = hsl_to_rgb('1 0 0' * (j * i + f) + '0 1 .5');
 333                                 c = strcat(rgb_to_hexcolor(rgb), c);
 334                         }
 335                         s2 = strcat(s2, c);
 336                 }
 337
 338                 localcmd(strcat(argv(1), " ", s2));
 339
 340                 return TRUE;
 341         }
 342         else if(argv(0) == "rpn")
 343         {
 344                 if(!rpn_db)
 345                 {
 346                         rpn_db = db_create();
 347                         db_put(rpn_db, "stack.pointer", "0");
 348                         db_put(rpn_db, "stack.pos", "-1");
 349                 }
 350                 if(argc >= 2)
 351                 {
 352                         float rpnpos;
 353                         string rpncmd;
 354                         float f2, f3;
 355                         rpn_sp = 0;
 356                         rpn_error = FALSE;
 357                         for(rpnpos = 1; rpnpos < argc; ++rpnpos)
 358                         {
 359                                 rpncmd = argv(rpnpos);
 360                                 f = strlen(rpncmd);
 361                                 if(rpncmd == "") {
 362                                 } else if(stof(substring(rpncmd, 0, 1)) > 0) {
 363                                         rpn_push(rpncmd);
 364                                 } else if(substring(rpncmd, 0, 1) == "0") {
 365                                         rpn_push(rpncmd);
 366                                 } else if(f >= 2 && substring(rpncmd, 0, 1) == "+") {
 367                                         rpn_push(rpncmd);
 368                                 } else if(f >= 2 && substring(rpncmd, 0, 1) == "-") {
 369                                         rpn_push(rpncmd);
 370                                 } else if(f >= 2 && substring(rpncmd, 0, 1) == "/") {
 371                                         rpn_push(substring(rpncmd, 1, strlen(rpncmd) - 1));
 372                                 } else if(rpncmd == "clear") {
 373                                         rpn_sp = 0;
 374                                 } else if(rpncmd == "def" || rpncmd == "=") {
 375                                         s = rpn_pop();
 376                                         s2 = rpn_pop();
 377 #ifdef MENUQC
 378                                         registercvar(s2, "", 0);
 379 #else
 380                                         registercvar(s2, "");
 381 #endif
 382                                         if(!rpn_error) // don't change cvars if a stack error had happened!
 383                                                 cvar_set(s2, s);
 384                                 } else if(rpncmd == "defs" || rpncmd == "@") {
 385                                         s = "";
 386                                         i = rpn_popf();
 387                                         j = (i == 0);
 388                                         while(rpn_sp > 1 && (j || i > 0))
 389                                         {
 390                                                 s = strcat("/", rpn_pop(), " ", s);
 391                                                 --i;
 392                                         }
 393                                         s2 = rpn_pop();
 394 #ifdef MENUQC
 395                                         registercvar(s2, "", 0);
 396 #else
 397                                         registercvar(s2, "");
 398 #endif
 399                                         if(!rpn_error) // don't change cvars if a stack error had happened!
 400                                                 cvar_set(s2, s);
 401                                 } else if(rpncmd == "load") {
 402                                         rpn_set(cvar_string(rpn_get()));
 403                                 } else if(rpncmd == "exch") {
 404                                         s = rpn_pop();
 405                                         s2 = rpn_get();
 406                                         rpn_set(s);
 407                                         rpn_push(s2);
 408                                 } else if(rpncmd == "dup") {
 409                                         rpn_push(rpn_get());
 410                                 } else if(rpncmd == "pop") {
 411                                         rpn_pop();
 412                                 } else if(rpncmd == "add" || rpncmd == "+") {
 413                                         f = rpn_popf();
 414                                         rpn_setf(rpn_getf() + f);
 415                                 } else if(rpncmd == "sub" || rpncmd == "-") {
 416                                         f = rpn_popf();
 417                                         rpn_setf(rpn_getf() - f);
 418                                 } else if(rpncmd == "mul" || rpncmd == "*") {
 419                                         f = rpn_popf();
 420                                         rpn_setf(rpn_getf() * f);
 421                                 } else if(rpncmd == "div" || rpncmd == "/") {
 422                                         f = rpn_popf();
 423                                         rpn_setf(rpn_getf() / f);
 424                                 } else if(rpncmd == "mod" || rpncmd == "%") {
 425                                         f = rpn_popf();
 426                                         f2 = rpn_getf();
 427                                         rpn_setf(f2 - f * floor(f2 / f));
 428                                 } else if(rpncmd == "abs") {
 429                                         rpn_setf(fabs(rpn_getf()));
 430                                 } else if(rpncmd == "sgn") {
 431                                         f = rpn_getf();
 432                                         if(f < 0)
 433                                                 rpn_set("-1");
 434                                         else if(f > 0)
 435                                                 rpn_set("1");
 436                                         else
 437                                                 rpn_set("0");
 438                                 } else if(rpncmd == "neg" || rpncmd == "~") {
 439                                         rpn_setf(-rpn_getf());
 440                                 } else if(rpncmd == "floor" || rpncmd == "f") {
 441                                         rpn_setf(floor(rpn_getf()));
 442                                 } else if(rpncmd == "ceil" || rpncmd == "c") {
 443                                         rpn_setf(ceil(rpn_getf()));
 444                                 } else if(rpncmd == "max") {
 445                                         f = rpn_popf();
 446                                         f2 = rpn_getf();
 447                                         rpn_setf(max(f2, f));
 448                                 } else if(rpncmd == "min") {
 449                                         f = rpn_popf();
 450                                         f2 = rpn_getf();
 451                                         rpn_setf(min(f2, f));
 452                                 } else if(rpncmd == "bound") {
 453                                         f = rpn_popf();
 454                                         f2 = rpn_popf();
 455                                         f3 = rpn_getf();
 456                                         rpn_setf(bound(f3, f2, f));
 457                                 } else if(rpncmd == "when") {
 458                                         f = rpn_popf();
 459                                         f2 = rpn_popf();
 460                                         f3 = rpn_getf();
 461                                         if(f)
 462                                                 rpn_setf(f3);
 463                                         else
 464                                                 rpn_setf(f2);
 465                                 } else if(rpncmd == ">" || rpncmd == "gt") {
 466                                         f = rpn_popf();
 467                                         rpn_setf(rpn_getf() > f);
 468                                 } else if(rpncmd == "<" || rpncmd == "lt") {
 469                                         f = rpn_popf();
 470                                         rpn_setf(rpn_getf() < f);
 471                                 } else if(rpncmd == "==" || rpncmd == "eq") {
 472                                         f = rpn_popf();
 473                                         rpn_setf(rpn_getf() == f);
 474                                 } else if(rpncmd == ">=" || rpncmd == "ge") {
 475                                         f = rpn_popf();
 476                                         rpn_setf(rpn_getf() >= f);
 477                                 } else if(rpncmd == "<=" || rpncmd == "le") {
 478                                         f = rpn_popf();
 479                                         rpn_setf(rpn_getf() <= f);
 480                                 } else if(rpncmd == "!=" || rpncmd == "ne") {
 481                                         f = rpn_popf();
 482                                         rpn_setf(rpn_getf() != f);
 483                                 } else if(rpncmd == "rand") {
 484                                         rpn_setf(ceil(random() * rpn_getf()) - 1);
 485                                 } else if(rpncmd == "crc16") {
 486                                         rpn_setf(crc16(FALSE, rpn_get()));
 487                                 } else if(rpncmd == "dbpush") {
 488                                         s = rpn_pop();
 489                                         if(!rpn_error)
 490                                         {
 491                                                 i = stof(db_get(rpn_db, "stack.pointer"));
 492                                                 db_put(rpn_db, "stack.pointer", ftos(i+1));
 493                                                 db_put(rpn_db, strcat("stack.", ftos(i)), s);
 494                                         }
 495                                         if(!i)
 496                                                 db_put(rpn_db, "stack.pos", "0");
 497                                 } else if(rpncmd == "dbpop") {
 498                                         i = stof(db_get(rpn_db, "stack.pointer"));
 499                                         if(i)
 500                                         {
 501                                                 s = ftos(i-1);
 502                                                 db_put(rpn_db, "stack.pointer", s);
 503                                                 rpn_push(db_get(rpn_db, strcat("stack.", s)));
 504                                                 j = stof(db_get(rpn_db, "stack.pos"));
 505                                                 if(j >= i)
 506                                                         db_put(rpn_db, "stack.pos", ftos(i-2));
 507                                         } else {
 508                                                 rpn_error = 1;
 509                                                 print("rpn: database underflow\n");
 510                                         }
 511                                 } else if(rpncmd == "dbget") {
 512
 513                                         i = stof(db_get(rpn_db, "stack.pointer"));
 514                                         if(i)
 515                                         {
 516                                                 rpn_push(db_get(rpn_db, strcat("stack.", ftos(i-1))));
 517                                         } else {
 518                                                 rpn_error = 1;
 519                                                 print("rpn: database empty\n");
 520                                         }
 521                                 } else if(rpncmd == "dblen") {
 522                                         rpn_push(db_get(rpn_db, "stack.pointer"));
 523                                 } else if(rpncmd == "dbclr") {
 524                                         db_close(rpn_db);
 525                                         rpn_db = db_create();
 526                                         db_put(rpn_db, "stack.pointer", "0");
 527                                         db_put(rpn_db, "stack.pos", "-1");
 528                                 } else if(rpncmd == "dbsave") {
 529                                         s = rpn_pop();
 530                                         if(!rpn_error)
 531                                                 db_save(rpn_db, s);
 532                                 } else if(rpncmd == "dbload") {
 533                                         s = rpn_pop();
 534                                         if(!rpn_error)
 535                                         {
 536                                                 db_close(rpn_db);
 537                                                 rpn_db = db_load(s);
 538                                         }
 539                                 } else if(rpncmd == "dbins") {
 540                                         s = rpn_pop();
 541                                         if(!rpn_error)
 542                                                 //if(rpn_sp > 0)
 543                                         {
 544                                                 j = stof(db_get(rpn_db, "stack.pointer"));
 545                                                 i = stof(db_get(rpn_db, "stack.pos"));
 546
 547                                                 if(i < 0)
 548                                                 {
 549                                                         i = 0;
 550                                                         db_put(rpn_db, "stack.pos", "0");
 551                                                 }
 552
 553                                                 db_put(rpn_db, "stack.pointer", ftos(j+1));
 554                                                 for(--j; j >= i; --j)
 555                                                 {
 556                                                         db_put(rpn_db, strcat("stack.", ftos(j+1)),
 557                                                                db_get(rpn_db, (strcat("stack.", ftos(j))))
 558                                                                 );
 559                                                 }
 560                                                 db_put(rpn_db, strcat("stack.", ftos(i)), s);
 561                                         }
 562                                 } else if(rpncmd == "dbext") {
 563                                         j = stof(db_get(rpn_db, "stack.pointer"));
 564                                         i = stof(db_get(rpn_db, "stack.pos"));
 565                                         if(!j)
 566                                         {
 567                                                 rpn_error = TRUE;
 568                                                 print("rpn: empty database\n");
 569                                         } else {
 570                                                 --j;
 571                                                 rpn_push(db_get(rpn_db, strcat("stack.", ftos(i))));
 572                                                 db_put(rpn_db, "stack.pointer", ftos(j));
 573                                                 if(i == j)
 574                                                 {
 575                                                         db_put(rpn_db, "stack.pos", ftos(j-1));
 576                                                 } else {
 577                                                         while(i < j)
 578                                                         {
 579                                                                 db_put(rpn_db, strcat("stack.", ftos(i)),
 580                                                                        db_get(rpn_db, (strcat("stack.", ftos(i+1))))
 581                                                                         );
 582                                                                 ++i;
 583                                                         }
 584                                                 }
 585                                         }
 586                                 } else if(rpncmd == "dbread") {
 587                                         s = db_get(rpn_db, "stack.pos");
 588                                         if(stof(s) >= 0)
 589                                         {
 590                                                 rpn_push(db_get(rpn_db, strcat("stack.", s)));
 591                                         } else {
 592                                                 rpn_error = 1;
 593                                                 print("rpn: empty database\n");
 594                                         }
 595                                 } else if(rpncmd == "dbat") {
 596                                         rpn_push(db_get(rpn_db, "stack.pos"));
 597                                 } else if(rpncmd == "dbmov") {
 598                                         j = stof(db_get(rpn_db, "stack.pointer"));
 599                                         i = stof(db_get(rpn_db, "stack.pos"));
 600                                         i += rpn_popf();
 601                                         if(!rpn_error)
 602                                         {
 603                                                 if(i < 0 || i >= j)
 604                                                 {
 605                                                         print("rpn: database cursor out of bounds\n");
 606                                                         rpn_error = TRUE;
 607                                                 }
 608                                                 if(!rpn_error)
 609                                                 {
 610                                                         db_put(rpn_db, "stack.pos", ftos(i));
 611                                                 }
 612                                         }
 613                                 } else if(rpncmd == "dbgoto") {
 614                                         s = rpn_pop();
 615                                         j = stof(db_get(rpn_db, "stack.pointer"));
 616                                         if(!j)
 617                                         {
 618                                                 rpn_error = TRUE;
 619                                                 print("rpn: empty database, cannot move cursor\n");
 620                                         }
 621                                         if(!rpn_error)
 622                                         {
 623                                                 if(s == "end")
 624                                                         i = stof(db_get(rpn_db, "stack.pointer"))-1;
 625                                                 else if(s == "beg")
 626                                                         i = 0;
 627                                                 else
 628                                                         i = stof(s);
 629
 630                                                 j = stof(db_get(rpn_db, "stack.pointer"));
 631                                                 if(i < 0 || i >= j)
 632                                                 {
 633                                                         print("rpn: database cursor destination out of bounds\n");
 634                                                         rpn_error = TRUE;
 635                                                 }
 636                                                 if(!rpn_error)
 637                                                 {
 638                                                         db_put(rpn_db, "stack.pos", ftos(i));
 639                                                 }
 640                                         }
 641                                 } else if(rpncmd == "union") {
 642                                         // s s2 union
 643                                         s2 = rpn_pop();
 644                                         s = rpn_get();
 645                                         f = tokenize_console(s);
 646                                         f2 = tokenize_console(strcat(s, " ", s2));
 647                                         // tokens 0..(f-1) represent s
 648                                         // tokens f..f2 represent s2
 649                                         // UNION: add all tokens to s that are in s2 but not in s
 650                                         s = "";
 651                                         for(i = 0; i < f; ++i)
 652                                                 s = strcat(s, " ", argv(i));
 653                                         for(i = f; i < f2; ++i) {
 654                                                 for(j = 0; j < f; ++j)
 655                                                         if(argv(i) == argv(j))
 656                                                                 goto skip_union;
 657                                                 s = strcat(s, " ", argv(i));
 658 :skip_union
 659                                         }
 660                                         if(substring(s, 0, 1) == " ")
 661                                                 s = substring(s, 1, 99999);
 662                                         rpn_set(s);
 663                                         tokenize_console(command);
 664                                 } else if(rpncmd == "intersection") {
 665                                         // s s2 intersection
 666                                         s2 = rpn_pop();
 667                                         s = rpn_get();
 668                                         f = tokenize_console(s);
 669                                         f2 = tokenize_console(strcat(s, " ", s2));
 670                                         // tokens 0..(f-1) represent s
 671                                         // tokens f..f2 represent s2
 672                                         // INTERSECTION: keep only the tokens from s that are also in s2
 673                                         s = "";
 674                                         for(i = 0; i < f; ++i) {
 675                                                 for(j = f; j < f2; ++j)
 676                                                         if(argv(i) == argv(j))
 677                                                         {
 678                                                                 s = strcat(s, " ", argv(i));
 679                                                                 break;
 680                                                         }
 681                                         }
 682                                         if(substring(s, 0, 1) == " ")
 683                                                 s = substring(s, 1, 99999);
 684                                         rpn_set(s);
 685                                         tokenize_console(command);
 686                                 } else if(rpncmd == "difference") {
 687                                         // s s2 difference
 688                                         s2 = rpn_pop();
 689                                         s = rpn_get();
 690                                         f = tokenize_console(s);
 691                                         f2 = tokenize_console(strcat(s, " ", s2));
 692                                         // tokens 0..(f-1) represent s
 693                                         // tokens f..f2 represent s2
 694                                         // DIFFERENCE: keep only the tokens from s that are not in s2
 695                                         s = "";
 696                                         for(i = 0; i < f; ++i) {
 697                                                 for(j = f; j < f2; ++j)
 698                                                         if(argv(i) == argv(j))
 699                                                                 goto skip_difference;
 700                                                 s = strcat(s, " ", argv(i));
 701 :skip_difference
 702                                         }
 703                                         if(substring(s, 0, 1) == " ")
 704                                                 s = substring(s, 1, 99999);
 705                                         rpn_set(s);
 706                                         tokenize_console(command);
 707                                 } else if(rpncmd == "shuffle") {
 708                                         // s shuffle
 709                                         s = rpn_get();
 710                                         f = tokenize_console(s);
 711
 712                                         for(i = 0; i < f - 1; ++i) {
 713                                                 // move a random item from i..f-1 to position i
 714                                                 s = "";
 715                                                 f2 = floor(random() * (f - i) + i);
 716                                                 for(j = 0; j < i; ++j)
 717                                                         s = strcat(s, " ", argv(j));
 718                                                 s = strcat(s, " ", argv(f2));
 719                                                 for(j = i; j < f; ++j)
 720                                                         if(j != f2)
 721                                                                 s = strcat(s, " ", argv(j));
 722                                                 f = tokenize_console(s);
 723                                         }
 724
 725                                         if(substring(s, 0, 1) == " ")
 726                                                 s = substring(s, 1, 99999);
 727                                         rpn_set(s);
 728                                         tokenize_console(command);
 729                                 } else if(rpncmd == "fexists_assert") {
 730                                         s = rpn_pop();
 731                                         if(!rpn_error)
 732                                         {
 733                                                 f = fopen(s, FILE_READ);
 734                                                 if(f != -1)
 735                                                         fclose(f);
 736                                                 else {
 737                                                         print("rpn: ERROR: ", s, " does not exist!\n");
 738                                                         rpn_error = TRUE;
 739                                                 }
 740                                         }
 741                                 } else if(rpncmd == "fexists") {
 742                                         s = rpn_get();
 743                                         if(!rpn_error)
 744                                         {
 745                                                 f = fopen(s, FILE_READ);
 746                                                 if(f != -1) {
 747                                                         fclose(f);
 748                                                         rpn_setf(1);
 749                                                 } else {
 750                                                         rpn_setf(0);
 751                                                 }
 752                                         }
 753                                 } else if(rpncmd == "localtime") {
 754                                         rpn_set(strftime(TRUE, rpn_get()));
 755                                 } else if(rpncmd == "gmtime") {
 756                                         rpn_set(strftime(FALSE, rpn_get()));
 757                                 } else if(rpncmd == "time") {
 758                                         rpn_pushf(time);
 759                                 } else {
 760                                         rpn_push(cvar_string(rpncmd));
 761                                 }
 762                                 if(rpn_error)
 763                                         break;
 764                         }
 765                         while(rpn_sp > 0)
 766                         {
 767                                 s = rpn_pop();
 768                                 print("rpn: still on stack: ", s, "\n");
 769                         }
 770                         return TRUE;
 771                 }
 772         } else if(argv(0) == "addtolist") {
 773                 if(argc >= 2)
 774                 {
 775                         s = argv(1);
 776                         s2 = argv(2);
 777                         if(cvar_string(s) == "")
 778                                 cvar_set(s, s2);
 779                         else {
 780                                 n = tokenizebyseparator(cvar_string(s), " ");
 781                                 for(i = 0; i < n; ++i)
 782                                         if(argv(i) == s2)
 783                                                 return TRUE; // already in list
 784                                 cvar_set(s, strcat(s2, " ", cvar_string(s)));
 785                         }
 786                 }
 787                 return TRUE;
 788         }
 789         else if(argv(0) == "records") {
 790                 print(records_reply);
 791                 return TRUE;
 792 #ifdef MENUQC
 793         } else if(argv(0) == "cp") {
 794                 if(argc >= 2)
 795                 {
 796                         s = argv(1);
 797                         for(i = 2; i < argc; ++i)
 798                                 s = strcat(s, " ", argv(i));
 799                         centerprint(unescape(s));
 800                 }
 801                 return TRUE;
 802 #endif
 803         }
 804
 805         return FALSE;
 806 }