data/qcsrc/client/sbar.qc

   1 void drawstringright(vector, string, vector, vector, float, float);
   2 void drawstringcenter(vector, string, vector, vector, float, float);
   3 void Sbar_DrawAccuracyStats();
   4 void Sbar_DrawAccuracyStats_Description_Splash(vector);
   5 void Sbar_DrawAccuracyStats_Description_Hitscan(vector);
   6 float weapon_hits[WEP_COUNT];
   7 float weapon_fired[WEP_COUNT];
   8 float weapon_number;
   9
  10 float last_weapon;
  11 float weapontime;
  12
  13 float sbar_alpha_fg;
  14 float sbar_alpha_bg;
  15 float sbar_color_bg_team;
  16 float sbar_border_thickness;
  17 float sbar_scoreboard_alpha_bg;
  18 float sbar_scoreboard_highlight;
  19 float sbar_hudselector;
  20 float sbar_hud_accuracy;
  21
  22 float ps_primary, ps_secondary;
  23 float ts_primary, ts_secondary;
  24
  25 vector sbar, color;
  26 vector element_offset = '0 6 0'; // global item offset from the bottom edge
  27
  28 void CSQC_kh_hud();
  29 void CSQC_ctf_hud();
  30 void CSQC_nb_hud();
  31 void MapVote_Draw();
  32 void Sbar_FinaleOverlay()
  33 {
  34         /*vector pos;
  35         pos_x = (vid_conwidth - 1)/2;
  36         pos_y = 16;
  37         pos_z = 0;*/
  38
  39         //drawpic(pos, "gfx/finale", '0 0 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
  40
  41         //drawstring(pos, "END", sbar_fontsize, '1 1 1', 1, DRAWFLAG_NORMAL);
  42         MapVote_Draw();
  43 }
  44
  45 float weaponspace[10];
  46 float weapon_first, weapon_last;
  47 void Sbar_DrawWeapon_Clear()
  48 {
  49         float idx;
  50         weapon_first = -2;
  51         weapon_last = -1;
  52         for(idx = 0; idx < 10; ++idx)
  53                 weaponspace[idx] = 0;
  54         for(idx = 0; idx <= 23; ++idx)
  55         {
  56                 if(weaponimpulse[idx] >= 0)
  57                 {
  58                         if(weapon_first < 0)
  59                                 weapon_first = idx;
  60                         weapon_last = idx;
  61                 }
  62         }
  63 }
  64 void Sbar_DrawWeapon(float nr, float fade, float active, float wc)
  65 {
  66         vector pos, vsize, fill_colour;
  67         float value, idx, imp, sp, weapon_hit, weapon_damage, weapon_stats;
  68
  69         imp = weaponimpulse[nr];
  70         weapon_hit = weapon_hits[wc];
  71         weapon_damage = weapon_fired[wc];
  72         if(imp == 0)
  73                 idx = 9;
  74         else
  75                 idx = imp - 1;
  76
  77         value = (active) ? 1 : 0.6;
  78         color_x = color_y = color_z = value;
  79
  80         // width = 300, height = 100
  81         const float w_width = 25, w_height = 12, w_space = 2, font_size = 8;
  82
  83         sp = weaponspace[idx] + 1;
  84         weaponspace[idx] = sp;
  85
  86         pos_x = (vid_conwidth + 10 - w_width * 9) * 0.5 + w_width * idx;
  87         pos_y = (vid_conheight - w_height * sp) - 38; // move 38 pixels up
  88         pos_z = 0;
  89         vsize_x = w_width;
  90         vsize_y = w_height;
  91         vsize_z = 0;
  92         if (active)
  93                 drawpic(pos, "gfx/hud/sb_ammobg", vsize, color, value * fade * sbar_alpha_fg, DRAWFLAG_NORMAL);
  94         drawpic(pos, strcat("gfx/hud/inv_weapon", ftos(nr)), vsize, color, value * fade * sbar_alpha_fg, DRAWFLAG_NORMAL);
  95         pos_x += w_space;
  96         pos_y += w_space;
  97         vsize_x = font_size;
  98         vsize_y = font_size;
  99         vsize_z = 0;
 100         drawstring(pos, ftos(imp), vsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
 101
 102         // draw the weapon accuracy on the HUD
 103         if(sbar_hud_accuracy)
 104         {
 105                 weapon_stats = rint(100*weapon_hit/weapon_damage);
 106                 fill_colour_x = 1 - 0.015 * weapon_stats;
 107                 fill_colour_y = 1 - 0.015 * (100 - weapon_stats);
 108                 drawstringright(pos + '22 0 0', strcat(ftos(weapon_stats),"%"), '6 6 0', fill_colour, sbar_alpha_fg, 0);
 109         }
 110 }
 111
 112 void Sbar_DrawXNum (vector pos, float num, float digits, float lettersize, vector rgb, float highlighted, float stroke, float a, float dflags)
 113 {
 114         float l, i;
 115         string str, tmp, l_length;
 116         float minus;
 117         vector vsize, num_color;
 118         num_color = rgb;
 119
 120         vsize_x = vsize_y = lettersize;
 121         vsize_z = 0;
 122
 123         if(num < 0)
 124         {
 125                 minus = true;
 126                 num = -num;
 127                 pos_x -= lettersize;
 128         } else
 129                 minus = false;
 130
 131         if(digits < 0)
 132         {
 133                 tmp = ftos(num);
 134                 digits = -digits;
 135                 str = strcat(substring("0000000000", 0, digits - strlen(tmp)), tmp);
 136         } else
 137                 str = ftos(num);
 138
 139         l = strlen(str);
 140         l_length = ftos(l);
 141
 142         if(l > digits)
 143         {
 144                 str = substring(str, l-digits, 999);
 145                 l = strlen(str);
 146         } else if(l < digits)
 147                 pos_x += (digits-l) * lettersize;
 148
 149         if (highlighted == 1) {
 150                 vector hl_size;
 151                 hl_size_x = vsize_x * l + vsize_x * 0.2;
 152                 hl_size_y = vsize_y * 1.1;
 153                 hl_size_z = 0;
 154                 if(minus)
 155                         hl_size_x = hl_size_x + vsize_x;
 156
 157                 vector hl_pos;
 158                 hl_pos_x = pos_x - lettersize/10;
 159                 hl_pos_y = pos_y - lettersize/20;
 160                 hl_pos_z = 0;
 161
 162                 drawpic(hl_pos, strcat("gfx/hud/sb_highlight_", l_length), hl_size, '1 1 1', sbar_alpha_fg, dflags);
 163         }
 164
 165         if (stroke == 1)
 166                 num_color = '1 1 1';
 167
 168         if(minus)
 169         {
 170                 drawpic(pos, "gfx/hud/num_minus", vsize, num_color, a * sbar_alpha_fg, dflags);
 171                 if (stroke == 1)
 172                         drawpic(pos, "gfx/hud/num_minus_stroke", vsize, rgb, a * sbar_alpha_fg, dflags);
 173                 pos_x += lettersize;
 174         }
 175
 176         for(i = 0; i < l; ++i)
 177         {
 178                 drawpic(pos, strcat("gfx/hud/num_", substring(str, i, 1)), vsize, num_color, a * sbar_alpha_fg, dflags);
 179                 if (stroke == 1)
 180                         drawpic(pos, strcat("gfx/hud/num_", substring(str, i, 1), "_stroke"), vsize, rgb, a * sbar_alpha_fg, dflags);
 181                 pos_x += lettersize;
 182         }
 183 }
 184
 185 void Sbar_DrawXNum_Colored (vector pos, float x, float lettersize, float alpha)
 186 {
 187         if(x > 200) {
 188                 color_x = 0;
 189                 color_y = 1;
 190                 color_z = 0;
 191         }
 192         else if(x > 150) {
 193                 color_x = 0.4 - (x-150)*0.02 * 0.4; //red value between 0.4 -> 0
 194                 color_y = 0.9 + (x-150)*0.02 * 0.1; // green value between 0.9 -> 1
 195                 color_z = 0;
 196         }
 197         else if(x > 100) {
 198                 color_x = 1 - (x-100)*0.02 * 0.6; //red value between 1 -> 0.4
 199                 color_y = 1 - (x-100)*0.02 * 0.1; // green value between 1 -> 0.9
 200                 color_z = 1 - (x-100)*0.02; // blue value between 1 -> 0
 201         }
 202         else if(x > 50) {
 203                 color_x = 1;
 204                 color_y = 1;
 205                 color_z = 0.2 + (x-50)*0.02 * 0.8; // blue value between 0.2 -> 1
 206         }
 207         else if(x > 20) {
 208                 color_x = 1;
 209                 color_y = (x-20)*90/27/100; // green value between 0 -> 1
 210                 color_z = (x-20)*90/27/100 * 0.2; // blue value between 0 -> 0.2
 211         }
 212         else {
 213                 color_x = 1;
 214                 color_y = 0;
 215                 color_z = 0;
 216         }
 217         Sbar_DrawXNum(pos, x, 3, lettersize, color, 0, 0, alpha, DRAWFLAG_NORMAL);
 218 }
 219
 220 void Cmd_Sbar_SetFields(float argc);
 221 void Sbar_InitScores()
 222 {
 223         float i, f;
 224
 225         ps_primary = ps_secondary = ts_primary = ts_secondary = -1;
 226         for(i = 0; i < MAX_SCORE; ++i)
 227         {
 228                 f = (scores_flags[i] & SFL_SORT_PRIO_MASK);
 229                 if(f == SFL_SORT_PRIO_PRIMARY)
 230                         ps_primary = i;
 231                 if(f == SFL_SORT_PRIO_SECONDARY)
 232                         ps_secondary = i;
 233         }
 234         if(ps_secondary == -1)
 235                 ps_secondary = ps_primary;
 236
 237         for(i = 0; i < MAX_TEAMSCORE; ++i)
 238         {
 239                 f = (teamscores_flags[i] & SFL_SORT_PRIO_MASK);
 240                 if(f == SFL_SORT_PRIO_PRIMARY)
 241                         ts_primary = i;
 242                 if(f == SFL_SORT_PRIO_SECONDARY)
 243                         ts_secondary = i;
 244         }
 245         if(ts_secondary == -1)
 246                 ts_secondary = ts_primary;
 247
 248         Cmd_Sbar_SetFields(0);
 249 }
 250
 251 void Sbar_UpdatePlayerPos(entity pl);
 252 float SetTeam(entity pl, float Team);
 253 //float lastpnum;
 254 void Sbar_UpdatePlayerTeams()
 255 {
 256         float Team;
 257         entity pl, tmp;
 258         float num;
 259
 260         num = 0;
 261         for(pl = players.sort_next; pl; pl = pl.sort_next)
 262         {
 263                 num += 1;
 264                 Team = GetPlayerColor(pl.sv_entnum);
 265                 if(SetTeam(pl, Team))
 266                 {
 267                         tmp = pl.sort_prev;
 268                         Sbar_UpdatePlayerPos(pl);
 269                         if(tmp)
 270                                 pl = tmp;
 271                         else
 272                                 pl = players.sort_next;
 273                 }
 274         }
 275         /*
 276         if(num != lastpnum)
 277                 print(strcat("PNUM: ", ftos(num), "\n"));
 278         lastpnum = num;
 279         */
 280 }
 281
 282 float Sbar_ComparePlayerScores(entity left, entity right)
 283 {
 284         float vl, vr;
 285         vl = GetPlayerColor(left.sv_entnum);
 286         vr = GetPlayerColor(right.sv_entnum);
 287
 288         if(!left.gotscores)
 289                 vl = COLOR_SPECTATOR;
 290         if(!right.gotscores)
 291                 vr = COLOR_SPECTATOR;
 292
 293         if(vl > vr)
 294                 return true;
 295         if(vl < vr)
 296                 return false;
 297
 298         if(vl == COLOR_SPECTATOR)
 299         {
 300                 // FIRST the one with scores (spectators), THEN the ones without (downloaders)
 301                 // no other sorting
 302                 if(!left.gotscores && right.gotscores)
 303                         return true;
 304                 return false;
 305         }
 306
 307         vl = left.scores[ps_primary];
 308         vr = right.scores[ps_primary];
 309         if(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)
 310         {
 311                 if(vl == 0 && vr != 0)
 312                         return 1;
 313                 if(vl != 0 && vr == 0)
 314                         return 0;
 315         }
 316         if(vl > vr)
 317                 return IS_INCREASING(scores_flags[ps_primary]);
 318         if(vl < vr)
 319                 return IS_DECREASING(scores_flags[ps_primary]);
 320
 321         vl = left.scores[ps_secondary];
 322         vr = right.scores[ps_secondary];
 323         if(scores_flags[ps_secondary] & SFL_ZERO_IS_WORST)
 324         {
 325                 if(vl == 0 && vr != 0)
 326                         return 1;
 327                 if(vl != 0 && vr == 0)
 328                         return 0;
 329         }
 330         if(vl > vr)
 331                 return IS_INCREASING(scores_flags[ps_secondary]);
 332         if(vl < vr)
 333                 return IS_DECREASING(scores_flags[ps_secondary]);
 334
 335         return false;
 336 }
 337
 338 void Sbar_UpdatePlayerPos(entity player)
 339 {
 340         for(other = player.sort_next; other && Sbar_ComparePlayerScores(player, other); other = player.sort_next)
 341         {
 342                 SORT_SWAP(player, other);
 343         }
 344         for(other = player.sort_prev; other != players && Sbar_ComparePlayerScores(other, player); other = player.sort_prev)
 345         {
 346                 SORT_SWAP(other, player);
 347         }
 348 }
 349
 350 float Sbar_CompareTeamScores(entity left, entity right)
 351 {
 352         float vl, vr;
 353
 354         if(left.team == COLOR_SPECTATOR)
 355                 return 1;
 356         if(right.team == COLOR_SPECTATOR)
 357                 return 0;
 358
 359         vl = left.teamscores[ts_primary];
 360         vr = right.teamscores[ts_primary];
 361         if(vl > vr)
 362                 return IS_INCREASING(teamscores_flags[ts_primary]);
 363         if(vl < vr)
 364                 return IS_DECREASING(teamscores_flags[ts_primary]);
 365
 366         vl = left.teamscores[ts_secondary];
 367         vr = right.teamscores[ts_secondary];
 368         if(vl > vr)
 369                 return IS_INCREASING(teamscores_flags[ts_secondary]);
 370         if(vl < vr)
 371                 return IS_DECREASING(teamscores_flags[ts_secondary]);
 372
 373         return false;
 374 }
 375
 376 void Sbar_UpdateTeamPos(entity Team)
 377 {
 378         for(other = Team.sort_next; other && Sbar_CompareTeamScores(Team, other); other = Team.sort_next)
 379         {
 380                 SORT_SWAP(Team, other);
 381         }
 382         for(other = Team.sort_prev; other != teams && Sbar_CompareTeamScores(other, Team); other = Team.sort_prev)
 383         {
 384                 SORT_SWAP(other, Team);
 385         }
 386 }
 387
 388 void Cmd_Sbar_Help(float argc)
 389 {
 390         print("You can modify the scoreboard using the\n");
 391         print("^3|---------------------------------------------------------------|\n");
 392         print("^1 TO BE DONE\n");
 393         print("Usage:\n");
 394         print("^2sbar_columns_set default\n");
 395         print("^2sbar_columns_set ^7filed1 field2 ...\n");
 396         print("The following field names are recognized (case INsensitive):\n");
 397         print("You can use a ^3|^7 to start the right-aligned fields.\n");
 398
 399         print("^3name^7 or ^3nick^7             Name of a player\n");
 400         print("^3ping^7                     Ping time\n\n");
 401         print("^3kd^7 or ^3kdr^7 or ^3kdratio^7 or ^3k/d\n");
 402         print("                         The kill-death ratio\n");
 403
 404         print("Before a field you can put a + or - sign, then a comma separated list\n");
 405         print("of game types, then a slash, to make the field show up only in these\n");
 406         print("or in all but these game types.\n");
 407
 408         print("The special game type names 'teams' and 'noteams' can be used to\n");
 409         print("include/exclude ALL teams/noteams game modes.\n");
 410
 411         local float i;
 412         print("Additional columns:\n");
 413         for(i = 0; i < MAX_SCORE; ++i)
 414         {
 415                 if(scores_label[i] != "")
 416                         print(strcat(scores_label[i], "\n"));
 417         }
 418 }
 419
 420 #define MIN_NAMELEN 24
 421 #define MAX_NAMELEN 24
 422
 423 string Sbar_DefaultColumnLayout()
 424 {
 425         return strcat( // fteqcc sucks
 426                 "ping pl name | ",
 427                 "-teams,race,lms/kills -teams,lms/deaths -teams,lms,race/suicides -race,dm,tdm/frags ", // tdm already has this in "score"
 428                 "+ctf/caps +ctf/pickups +ctf/fckills +ctf/returns ",
 429                 "+lms/lives +lms/rank ",
 430                 "+/caps +kh/pushes +kh/destroyed ",
 431                 "?+race/laps ?+race/time ?+race/fastest ",
 432                 "+as/objectives +nexball/faults +nexball/goals ",
 433                 "-lms,race,nexball/score");
 434 }
 435
 436 void Cmd_Sbar_SetFields(float argc)
 437 {
 438         float i, j, slash;
 439         string str, pattern;
 440         float digit;
 441         float have_name, have_primary, have_secondary, have_separator;
 442         float missing;
 443
 444         // TODO: re enable with gametype dependant cvars?
 445         if(argc < 2) // no arguments provided
 446                 argc = tokenizebyseparator(strcat("x ", cvar_string("sbar_columns")), " ");
 447
 448         if(argc < 2)
 449                 argc = tokenizebyseparator(strcat("x ", Sbar_DefaultColumnLayout()), " ");
 450
 451         if(argc == 2)
 452         {
 453                 if(argv(1) == "default")
 454                         argc = tokenizebyseparator(strcat("x ", Sbar_DefaultColumnLayout()), " ");
 455                 else if(argv(1) == "all")
 456                 {
 457                         string s;
 458                         s = "ping pl color name |";
 459                         for(i = 0; i < MAX_SCORE; ++i)
 460                         {
 461                                 if(i != ps_primary)
 462                                 if(i != ps_secondary)
 463                                 if(scores_label[i] != "")
 464                                         s = strcat(s, " ", scores_label[i]);
 465                         }
 466                         if(ps_secondary != ps_primary)
 467                                 s = strcat(s, " ", scores_label[ps_secondary]);
 468                         s = strcat(s, " ", scores_label[ps_primary]);
 469                         argc = tokenizebyseparator(strcat("x ", s), " ");
 470                 }
 471         }
 472
 473
 474         sbar_num_fields = 0;
 475
 476         drawfont = sbar_font;
 477         digit = stringwidth("0123456789", FALSE) / 10;
 478
 479         for(i = 0; i < argc - 1; ++i)
 480         {
 481                 float nocomplain;
 482                 str = argv(i+1);
 483
 484                 nocomplain = FALSE;
 485                 if(substring(str, 0, 1) == "?")
 486                 {
 487                         nocomplain = TRUE;
 488                         str = substring(str, 1, strlen(str) - 1);
 489                 }
 490
 491                 slash = strstrofs(str, "/", 0);
 492                 if(slash >= 0)
 493                 {
 494                         pattern = substring(str, 0, slash);
 495                         str = substring(str, slash + 1, strlen(str) - (slash + 1));
 496
 497                         if not(isGametypeInFilter(gametype, teamplay, pattern))
 498                                 continue;
 499                 }
 500
 501                 strunzone(sbar_title[sbar_num_fields]);
 502                 sbar_title[sbar_num_fields] = strzone(str);
 503                 sbar_size[sbar_num_fields] = stringwidth(str, FALSE);
 504                 str = strtolower(str);
 505
 506                 if(str == "ping") {
 507                         sbar_field[sbar_num_fields] = SP_PING;
 508                 } else if(str == "pl") {
 509                         sbar_field[sbar_num_fields] = SP_PL;
 510                 } else if(str == "kd" || str == "kdr" || str == "kdratio" || str == "k/d") {
 511                         sbar_field[sbar_num_fields] = SP_KDRATIO;
 512                 } else if(str == "name" || str == "nick") {
 513                         sbar_field[sbar_num_fields] = SP_NAME;
 514                         sbar_size[sbar_num_fields] = MIN_NAMELEN; // minimum size? any use?
 515                         have_name = 1;
 516                 } else if(str == "|") {
 517                         sbar_field[sbar_num_fields] = SP_SEPARATOR;
 518                         have_separator = 1;
 519                 } else {
 520                         for(j = 0; j < MAX_SCORE; ++j)
 521                                 if(str == strtolower(scores_label[j]))
 522                                         goto found; // sorry, but otherwise fteqcc -O3 miscompiles this and warns about "unreachable code"
 523 :notfound
 524                         if(str == "frags")
 525                         {
 526                                 j = SP_FRAGS;
 527                         }
 528                         else
 529                         {
 530                                 if not(nocomplain)
 531                                         print(strcat("^1Error:^7 Unknown score field: '", str, "'\n"));
 532                                 continue;
 533                         }
 534 :found
 535                         sbar_field[sbar_num_fields] = j;
 536                         if(j == ps_primary)
 537                                 have_primary = 1;
 538                         if(j == ps_secondary)
 539                                 have_secondary = 1;
 540                 }
 541                 ++sbar_num_fields;
 542                 if(sbar_num_fields >= MAX_SBAR_FIELDS)
 543                         break;
 544         }
 545
 546         if(scores_flags[ps_primary] & SFL_ALLOW_HIDE)
 547                 have_primary = 1;
 548         if(scores_flags[ps_secondary] & SFL_ALLOW_HIDE)
 549                 have_secondary = 1;
 550         if(ps_primary == ps_secondary)
 551                 have_secondary = 1;
 552         missing = (!have_primary) + (!have_secondary) + (!have_separator) + (!have_name);
 553
 554         if(sbar_num_fields+missing < MAX_SBAR_FIELDS)
 555         {
 556                 if(!have_name)
 557                 {
 558                         strunzone(sbar_title[sbar_num_fields]);
 559                         for(i = sbar_num_fields; i > 0; --i)
 560                         {
 561                                 sbar_title[i] = sbar_title[i-1];
 562                                 sbar_size[i] = sbar_size[i-1];
 563                                 sbar_field[i] = sbar_field[i-1];
 564                         }
 565                         sbar_title[0] = strzone("name");
 566                         sbar_field[0] = SP_NAME;
 567                         sbar_size[0] = MIN_NAMELEN; // minimum size? any use?
 568                         ++sbar_num_fields;
 569                         print("fixed missing field 'name'\n");
 570
 571                         if(!have_separator)
 572                         {
 573                                 strunzone(sbar_title[sbar_num_fields]);
 574                                 for(i = sbar_num_fields; i > 1; --i)
 575                                 {
 576                                         sbar_title[i] = sbar_title[i-1];
 577                                         sbar_size[i] = sbar_size[i-1];
 578                                         sbar_field[i] = sbar_field[i-1];
 579                                 }
 580                                 sbar_title[1] = strzone("|");
 581                                 sbar_field[1] = SP_SEPARATOR;
 582                                 sbar_size[1] = stringwidth("|", FALSE);
 583                                 ++sbar_num_fields;
 584                                 print("fixed missing field '|'\n");
 585                         }
 586                 }
 587                 else if(!have_separator)
 588                 {
 589                         strunzone(sbar_title[sbar_num_fields]);
 590                         sbar_title[sbar_num_fields] = strzone("|");
 591                         sbar_size[sbar_num_fields] = stringwidth("|", FALSE);
 592                         sbar_field[sbar_num_fields] = SP_SEPARATOR;
 593                         ++sbar_num_fields;
 594                         print("fixed missing field '|'\n");
 595                 }
 596
 597                 if(!have_secondary)
 598                 {
 599                         strunzone(sbar_title[sbar_num_fields]);
 600                         sbar_title[sbar_num_fields] = strzone(scores_label[ps_secondary]);
 601                         sbar_size[sbar_num_fields] = stringwidth(sbar_title[sbar_num_fields], FALSE);
 602                         sbar_field[sbar_num_fields] = ps_secondary;
 603                         ++sbar_num_fields;
 604                         print("fixed missing field '", scores_label[ps_secondary], "'\n");
 605                 }
 606
 607                 if(!have_primary)
 608                 {
 609                         strunzone(sbar_title[sbar_num_fields]);
 610                         sbar_title[sbar_num_fields] = strzone(scores_label[ps_primary]);
 611                         sbar_size[sbar_num_fields] = stringwidth(sbar_title[sbar_num_fields], FALSE);
 612                         sbar_field[sbar_num_fields] = ps_primary;
 613                         ++sbar_num_fields;
 614                         print("fixed missing field '", scores_label[ps_primary], "'\n");
 615                 }
 616         }
 617
 618         sbar_field[sbar_num_fields] = SP_END;
 619 }
 620
 621 // MOVEUP::
 622 vector sbar_field_rgb;
 623 string sbar_field_icon0;
 624 string sbar_field_icon1;
 625 string sbar_field_icon2;
 626 vector sbar_field_icon0_rgb;
 627 vector sbar_field_icon1_rgb;
 628 vector sbar_field_icon2_rgb;
 629 float sbar_field_icon0_alpha;
 630 float sbar_field_icon1_alpha;
 631 float sbar_field_icon2_alpha;
 632 string Sbar_GetField(entity pl, float field)
 633 {
 634         float tmp, num, denom, f;
 635         string str;
 636         sbar_field_rgb = '1 1 1';
 637         sbar_field_icon0 = "";
 638         sbar_field_icon1 = "";
 639         sbar_field_icon2 = "";
 640         sbar_field_icon0_rgb = '1 1 1';
 641         sbar_field_icon1_rgb = '1 1 1';
 642         sbar_field_icon2_rgb = '1 1 1';
 643         sbar_field_icon0_alpha = 1;
 644         sbar_field_icon1_alpha = 1;
 645         sbar_field_icon2_alpha = 1;
 646         switch(field)
 647         {
 648                 case SP_PING:
 649                         if not(pl.gotscores)
 650                                 return "\x8D\x8D\x8D"; // >>> sign
 651                         str = getplayerkey(pl.sv_entnum, "ping");
 652                         if(str == "0")
 653                                 return "N/A";
 654                         tmp = max(0, min(220, stof(str)-80)) / 220;
 655                         sbar_field_rgb = '1 1 1' - '0 1 1'*tmp;
 656                         return str;
 657
 658                 case SP_PL:
 659                         if not(pl.gotscores)
 660                                 return "N/A";
 661                         str = getplayerkey(pl.sv_entnum, "pl");
 662                         if(str == "0")
 663                                 return "";
 664                         tmp = bound(0, stof(str), 20) / 20; // 20% is REALLY BAD pl
 665                         sbar_field_rgb = '1 0.5 0.5' - '0 0.5 0.5'*tmp;
 666                         return str;
 667
 668                 case SP_NAME:
 669                         if(ready_waiting && pl.ready)
 670                         {
 671                                 sbar_field_icon0 = "gfx/sb_player_ready";
 672                         }
 673                         else if(!teamplay)
 674                         {
 675                                 f = stof(getplayerkey(pl.sv_entnum, "colors"));
 676                                 {
 677                                         sbar_field_icon0 = "gfx/sb_playercolor_base";
 678                                         sbar_field_icon1 = "gfx/sb_playercolor_shirt";
 679                                         sbar_field_icon1_rgb = colormapPaletteColor(floor(f / 16), 0);
 680                                         sbar_field_icon2 = "gfx/sb_playercolor_pants";
 681                                         sbar_field_icon2_rgb = colormapPaletteColor(mod(f, 16), 1);
 682                                 }
 683                         }
 684                         return GetPlayerName(pl.sv_entnum);
 685
 686                 case SP_FRAGS:
 687                         f = pl.(scores[SP_KILLS]);
 688                         f -= pl.(scores[SP_SUICIDES]);
 689                         return ftos(f);
 690
 691                 case SP_KDRATIO:
 692                         num = pl.(scores[SP_KILLS]);
 693                         denom = pl.(scores[SP_DEATHS]);
 694
 695                         if(denom == 0) {
 696                                 sbar_field_rgb = '0 1 0';
 697                                 str = ftos(num);
 698                         } else if(num <= 0) {
 699                                 sbar_field_rgb = '1 0 0';
 700                                 str = ftos(num/denom);
 701                         } else
 702                                 str = ftos(num/denom);
 703
 704                         tmp = strstrofs(str, ".", 0);
 705                         if(tmp > 0)
 706                                 str = substring(str, 0, tmp+2);
 707                         return str;
 708
 709                 default:
 710                         tmp = pl.(scores[field]);
 711                         f = scores_flags[field];
 712                         if(field == ps_primary)
 713                                 sbar_field_rgb = '1 1 0';
 714                         else if(field == ps_secondary)
 715                                 sbar_field_rgb = '0 1 1';
 716                         else
 717                                 sbar_field_rgb = '1 1 1';
 718                         return ScoreString(f, tmp);
 719         }
 720         //return "error";
 721 }
 722
 723 float xmin, xmax, ymin, ymax, sbwidth;
 724 float sbar_fixscoreboardcolumnwidth_len;
 725 float sbar_fixscoreboardcolumnwidth_iconlen;
 726 float sbar_fixscoreboardcolumnwidth_marginlen;
 727
 728 float stringwidth_colors(string s)
 729 {
 730         return stringwidth(s, TRUE);
 731 }
 732
 733 float stringwidth_nocolors(string s)
 734 {
 735         return stringwidth(s, FALSE);
 736 }
 737
 738 string Sbar_FixScoreboardColumnWidth(float i, string str)
 739 {
 740         float field, maxsize, j, f;
 741         vector sz;
 742         field = sbar_field[i];
 743
 744         if(field == SP_NAME) // name gets all remaining space
 745         {
 746                 maxsize = (xmax - xmin) / sbar_fontsize_x;
 747                 for(j = 0; j < sbar_num_fields; ++j) if(j != i) if(sbar_field[j] != SP_SEPARATOR)
 748                         maxsize -= sbar_size[j] + 1;
 749                 maxsize += 1;
 750                 str = textShortenToWidth(str, maxsize, stringwidth_colors);
 751                 sbar_fixscoreboardcolumnwidth_len = stringwidth(str, TRUE);
 752         }
 753         else
 754                 sbar_fixscoreboardcolumnwidth_len = stringwidth(str, FALSE);
 755
 756         sbar_fixscoreboardcolumnwidth_iconlen = 0;
 757
 758         if(sbar_field_icon0 != "")
 759         {
 760                 sz = drawgetimagesize(sbar_field_icon0);
 761                 f = sz_x / sz_y;
 762                 if(sbar_fixscoreboardcolumnwidth_iconlen < f)
 763                         sbar_fixscoreboardcolumnwidth_iconlen = f;
 764         }
 765
 766         if(sbar_field_icon1 != "")
 767         {
 768                 sz = drawgetimagesize(sbar_field_icon1);
 769                 f = sz_x / sz_y;
 770                 if(sbar_fixscoreboardcolumnwidth_iconlen < f)
 771                         sbar_fixscoreboardcolumnwidth_iconlen = f;
 772         }
 773
 774         if(sbar_field_icon2 != "")
 775         {
 776                 sz = drawgetimagesize(sbar_field_icon2);
 777                 f = sz_x / sz_y;
 778                 if(sbar_fixscoreboardcolumnwidth_iconlen < f)
 779                         sbar_fixscoreboardcolumnwidth_iconlen = f;
 780         }
 781
 782         sbar_fixscoreboardcolumnwidth_iconlen *= sbar_fontsize_y / sbar_fontsize_x; // fix icon aspect
 783
 784         if(sbar_fixscoreboardcolumnwidth_iconlen != 0 && sbar_fixscoreboardcolumnwidth_len != 0)
 785                 sbar_fixscoreboardcolumnwidth_marginlen = stringwidth(" ", FALSE);
 786         else
 787                 sbar_fixscoreboardcolumnwidth_marginlen = 0;
 788
 789         f = sbar_fixscoreboardcolumnwidth_len + sbar_fixscoreboardcolumnwidth_marginlen + sbar_fixscoreboardcolumnwidth_iconlen;
 790         if(sbar_size[i] < f)
 791                 sbar_size[i] = f;
 792
 793         return str;
 794 }
 795
 796 void Sbar_PrintScoreboardItem(vector pos, entity pl, float is_self, float pl_number)
 797 {
 798         vector tmp;
 799         string str;
 800         float i, field;
 801         float is_spec;
 802         is_spec = (GetPlayerColor(pl.sv_entnum) == COLOR_SPECTATOR);
 803
 804         // Layout:
 805         tmp_x = sbwidth;
 806         tmp_y = sbar_fontsize_y * 1.25;
 807         tmp_z = 0;
 808
 809         // alternated rows highlighting
 810         if (is_self)
 811                 drawfill(pos - '1 1 0', tmp + '2 0 0', '1 1 1', 0.25, DRAWFLAG_NORMAL);
 812         else
 813         {
 814                 if (sbar_scoreboard_highlight)
 815                         if(!mod(pl_number,2))
 816                                 drawfill(pos - '1 1 0', tmp + '2 0 0', '1 1 1', 0.09, DRAWFLAG_NORMAL);
 817         }
 818
 819         tmp_y = 0;
 820
 821         for(i = 0; i < sbar_num_fields; ++i)
 822         {
 823                 field = sbar_field[i];
 824                 if(field == SP_SEPARATOR)
 825                         break;
 826
 827                 if(is_spec && field != SP_NAME && field != SP_PING) {
 828                         pos_x += sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 829                         continue;
 830                 }
 831                 str = Sbar_GetField(pl, field);
 832                 str = Sbar_FixScoreboardColumnWidth(i, str);
 833
 834                 pos_x += sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 835
 836                 if(field == SP_NAME) {
 837                         tmp_x = sbar_fontsize_x*(sbar_size[i] - sbar_fixscoreboardcolumnwidth_iconlen - sbar_fixscoreboardcolumnwidth_marginlen) + sbar_fontsize_x;
 838                         drawcolorcodedstring(pos - tmp, str, sbar_fontsize, 1, DRAWFLAG_NORMAL);
 839                 } else {
 840                         tmp_x = sbar_fixscoreboardcolumnwidth_len*sbar_fontsize_x + sbar_fontsize_x;
 841                         drawstring(pos - tmp, str, sbar_fontsize, sbar_field_rgb, 1, DRAWFLAG_NORMAL);
 842                 }
 843
 844                 tmp_x = sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 845                 if(sbar_field_icon0 != "")
 846                         drawpic(pos - tmp, sbar_field_icon0, '0 1 0' * sbar_fontsize_y + '1 0 0' * sbar_fontsize_x * sbar_fixscoreboardcolumnwidth_iconlen, sbar_field_icon1_rgb, sbar_field_icon0_alpha, DRAWFLAG_NORMAL);
 847                 if(sbar_field_icon1 != "")
 848                         drawpic(pos - tmp, sbar_field_icon1, '0 1 0' * sbar_fontsize_y + '1 0 0' * sbar_fontsize_x * sbar_fixscoreboardcolumnwidth_iconlen, sbar_field_icon1_rgb, sbar_field_icon1_alpha, DRAWFLAG_NORMAL);
 849                 if(sbar_field_icon2 != "")
 850                         drawpic(pos - tmp, sbar_field_icon2, '0 1 0' * sbar_fontsize_y + '1 0 0' * sbar_fontsize_x * sbar_fixscoreboardcolumnwidth_iconlen, sbar_field_icon2_rgb, sbar_field_icon2_alpha, DRAWFLAG_NORMAL);
 851         }
 852
 853         if(sbar_field[i] == SP_SEPARATOR)
 854         {
 855                 pos_x = xmax;
 856                 for(i = sbar_num_fields-1; i > 0; --i)
 857                 {
 858                         field = sbar_field[i];
 859                         if(field == SP_SEPARATOR)
 860                                 break;
 861
 862                         if(is_spec && field != SP_NAME && field != SP_PING) {
 863                                 pos_x -= sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 864                                 continue;
 865                         }
 866
 867                         str = Sbar_GetField(pl, field);
 868                         str = Sbar_FixScoreboardColumnWidth(i, str);
 869
 870                         if(field == SP_NAME) {
 871                                 tmp_x = sbar_fontsize_x*sbar_fixscoreboardcolumnwidth_len; // left or right aligned? let's put it right...
 872                                 drawcolorcodedstring(pos - tmp, str, sbar_fontsize, 1, DRAWFLAG_NORMAL);
 873                         } else {
 874                                 tmp_x = sbar_fontsize_x*sbar_fixscoreboardcolumnwidth_len; //strlen(str);
 875                                 drawstring(pos - tmp, str, sbar_fontsize, sbar_field_rgb, 1, DRAWFLAG_NORMAL);
 876                         }
 877
 878                         tmp_x = sbar_fontsize_x*sbar_size[i];
 879                         if(sbar_field_icon0 != "")
 880                                 drawpic(pos - tmp, sbar_field_icon0, '0 1 0' * sbar_fontsize_y + '1 0 0' * sbar_fontsize_x * sbar_fixscoreboardcolumnwidth_iconlen, sbar_field_icon1_rgb, sbar_field_icon0_alpha, DRAWFLAG_NORMAL);
 881                         if(sbar_field_icon1 != "")
 882                                 drawpic(pos - tmp, sbar_field_icon1, '0 1 0' * sbar_fontsize_y + '1 0 0' * sbar_fontsize_x * sbar_fixscoreboardcolumnwidth_iconlen, sbar_field_icon1_rgb, sbar_field_icon1_alpha, DRAWFLAG_NORMAL);
 883                         if(sbar_field_icon2 != "")
 884                                 drawpic(pos - tmp, sbar_field_icon2, '0 1 0' * sbar_fontsize_y + '1 0 0' * sbar_fontsize_x * sbar_fixscoreboardcolumnwidth_iconlen, sbar_field_icon2_rgb, sbar_field_icon2_alpha, DRAWFLAG_NORMAL);
 885
 886                         pos_x -= sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 887                 }
 888         }
 889 }
 890
 891 /*
 892  * Sbar_Scoreboard_MakeTable
 893  *
 894  * Makes a table for a team (for all playing players in DM) and fills it
 895  */
 896
 897 vector Sbar_Scoreboard_MakeTable(vector pos, entity tm, vector rgb, vector bg_size)
 898 {
 899         float body_table_height, i, pos_x_save;
 900         vector tmp, column_dim;
 901         entity pl;
 902
 903         body_table_height = 1.25 * sbar_fontsize_y * max(1, tm.team_size); // no player? show 1 empty line
 904
 905         pos -= '1 1 0';
 906
 907         tmp_x = sbwidth + 2;
 908
 909         tmp_y = 1.25 * sbar_fontsize_y;
 910
 911         // rounded header
 912         drawpic(pos, "gfx/hud/sb_scoreboard_tableheader", tmp, '0.5 0.5 0.5', sbar_scoreboard_alpha_bg, DRAWFLAG_NORMAL);
 913
 914         // table border
 915         tmp_y += sbar_border_thickness;
 916         tmp_y += body_table_height;
 917         drawborderlines(sbar_border_thickness, pos, tmp, '0 0 0', sbar_scoreboard_alpha_bg, DRAWFLAG_NORMAL); // more transparency for the scoreboard
 918
 919         // separator header/table
 920         pos_y += 1.25 * sbar_fontsize_y;
 921         tmp_y = sbar_border_thickness;
 922         drawfill(pos, tmp, '0 0 0', sbar_scoreboard_alpha_bg, DRAWFLAG_NORMAL);
 923
 924         pos_y += sbar_border_thickness;
 925
 926         // table background
 927         tmp_y = body_table_height;
 928         drawpic_tiled(pos, "gfx/hud/sb_scoreboard_bg", bg_size, tmp, rgb * sbar_color_bg_team, sbar_scoreboard_alpha_bg, DRAWFLAG_NORMAL);
 929
 930         // anyway, apply some color
 931         //drawfill(pos, tmp + '2 0 0', rgb, 0.1, DRAWFLAG_NORMAL);
 932
 933         // go back to the top to make alternated columns highlighting and to print the strings
 934         pos_y -= 1.25 * sbar_fontsize_y;
 935         pos_y -= sbar_border_thickness;
 936
 937         pos += '1 1 0';
 938
 939         pos_x_save = pos_x; // will be restored after the columns headers are printed
 940
 941         if (sbar_scoreboard_highlight)
 942         {
 943                 column_dim_y = 1.25 * sbar_fontsize_y; // header
 944                 column_dim_y += sbar_border_thickness;
 945                 column_dim_y += body_table_height;
 946         }
 947
 948         // print the strings of the columns headers
 949         for(i = 0; i < sbar_num_fields; ++i)
 950         {
 951                 if(sbar_field[i] == SP_SEPARATOR)
 952                         break;
 953                 column_dim_x = sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 954                 if (sbar_scoreboard_highlight)
 955                 {
 956                         if (mod(i,2))
 957                                 drawfill(pos - '0 1 0' - sbar_fontsize_x / 2 * '1 0 0', column_dim, '0 0 0', sbar_scoreboard_alpha_bg * 0.4, DRAWFLAG_NORMAL);
 958                 }
 959                 drawstring(pos, sbar_title[i], sbar_fontsize, rgb, 1, DRAWFLAG_NORMAL);
 960                 pos_x += column_dim_x;
 961         }
 962         if(sbar_field[i] == SP_SEPARATOR)
 963         {
 964                 pos_x = xmax;
 965                 for(i = sbar_num_fields-1; i > 0; --i)
 966                 {
 967                         if(sbar_field[i] == SP_SEPARATOR)
 968                                 break;
 969                         /**
 970                          * FTEQCC BUG!
 971                          * Using strlen(sbar_title[i])*8 instead of
 972                          * stringwidth(sbar_title[i], FALSE) will mess it all up
 973                          */
 974                         pos_x -= stringwidth(sbar_title[i], FALSE)*sbar_fontsize_x;
 975
 976                         if (sbar_scoreboard_highlight)
 977                         {
 978                                 if (i == sbar_num_fields-1)
 979                                         column_dim_x = sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x / 2;
 980                                 else
 981                                         column_dim_x = sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 982                                 if (!mod(i,2))
 983                                         drawfill(pos - '0 1 0' - sbar_fontsize_x / 2 * '1 0 0', column_dim, '0 0 0', sbar_scoreboard_alpha_bg * 0.2, DRAWFLAG_NORMAL);
 984                         }
 985                         drawstring(pos, sbar_title[i], sbar_fontsize, rgb, 1, DRAWFLAG_NORMAL);
 986                         pos_x -= sbar_fontsize_x;
 987                 }
 988         }
 989
 990         pos_x = pos_x_save;
 991         pos_y += 1.25 * sbar_fontsize_y; // skip the header
 992         pos_y += sbar_border_thickness;
 993
 994         i = 0;
 995         if (teamplay)
 996                 for(pl = players.sort_next; pl; pl = pl.sort_next)
 997                 {
 998                         if(pl.team != tm.team)
 999                                 continue;
1000                         Sbar_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1), i);
1001                         pos_y += 1.25 * sbar_fontsize_y;
1002                         ++i;
1003                 }
1004         else
1005                 for(pl = players.sort_next; pl; pl = pl.sort_next)
1006                 {
1007                         if(pl.team == COLOR_SPECTATOR)
1008                                 continue;
1009                         Sbar_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1), i);
1010                         pos_y += 1.25 * sbar_fontsize_y;
1011                         ++i;
1012                 }
1013
1014         pos_y += 1.25 * sbar_fontsize_y;
1015         pos_y += 1.25 * sbar_fontsize_y; // add an empty row
1016
1017         return pos;
1018 }
1019
1020 float lastpingstime;
1021 float scoreboard_bottom;
1022 void Sbar_DrawScoreboard()
1023 {
1024         vector rgb, pos, tmp, sbar_save;
1025         entity pl, tm;
1026         float specs;
1027         float center_x;
1028
1029         if(time > lastpingstime + 10)
1030         {
1031                 localcmd("pings\n");
1032                 lastpingstime = time;
1033         }
1034
1035         sbwidth = Sbar_GetWidth(6.5 * sbar_fontsize_y);
1036
1037         xmin = 0.5 * (vid_conwidth - sbwidth);
1038         ymin = 60;
1039
1040         xmax = vid_conwidth - xmin;
1041     ymax = vid_conheight - 0.2*vid_conheight;
1042
1043         center_x = xmin + 0.5*sbwidth;
1044
1045         // Initializes position
1046         pos_x = xmin;
1047         pos_y = ymin;
1048         pos_z = 0;
1049
1050         // Heading
1051         drawfont = sbar_bigfont;
1052         drawstringcenter('0 1 0' * ymin, "Scoreboard", '24 24 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1053
1054         pos_y += 24 + 4;
1055         pos_y += sbar_fontsize_y;
1056
1057         drawfont = sbar_font;
1058
1059         sbar_save = sbar;
1060         sbar = '0 0 0';
1061
1062         vector bg_size;
1063         bg_size = drawgetimagesize("gfx/hud/sb_scoreboard_bg");
1064
1065         if(teamplay)
1066         {
1067                 //for(tm = sortedTeams.sort_next; tm; tm = tm.sort_next)
1068                 for(tm = teams.sort_next; tm; tm = tm.sort_next)
1069                 {
1070                         if(!tm.team_size || tm.team == COLOR_SPECTATOR)
1071                                 continue;
1072
1073                         rgb = GetTeamRGB(tm.team);
1074
1075                         Sbar_DrawXNum(sbar + pos - '6.5 0 0' * sbar_fontsize_y + '0 1 0' * sbar_fontsize_y, tm.(teamscores[ts_primary]), 4, sbar_fontsize_y * 1.5, rgb, 0, 1, 1, DRAWFLAG_NORMAL);
1076
1077                         if(ts_primary != ts_secondary)
1078                                 Sbar_DrawXNum(sbar + pos - '4.5 0 0' * sbar_fontsize_y + '0 2.5 0' * sbar_fontsize_y, tm.(teamscores[ts_secondary]), 4, sbar_fontsize_y * 1, rgb, 0, 1, 1, DRAWFLAG_NORMAL);
1079
1080                         pos = Sbar_Scoreboard_MakeTable(pos, tm, rgb, bg_size);
1081                 }
1082         }
1083         else
1084         {
1085                 rgb_x = cvar("sbar_color_bg_r");
1086                 rgb_y = cvar("sbar_color_bg_g");
1087                 rgb_z = cvar("sbar_color_bg_b");
1088
1089                 tm = teams.sort_next;
1090
1091                 pos = Sbar_Scoreboard_MakeTable(pos, tm, rgb, bg_size);
1092         }
1093
1094         tmp = pos + '0 1.5 0' * sbar_fontsize_y;
1095         pos_y += 3 * sbar_fontsize_y;
1096         specs = 0;
1097         for(pl = players.sort_next; pl; pl = pl.sort_next)
1098         {
1099                 if(pl.team != COLOR_SPECTATOR)
1100                         continue;
1101                 Sbar_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1), specs);
1102                 pos_y += 1.25 * sbar_fontsize_y;
1103                 ++specs;
1104         }
1105
1106         if(specs)
1107                 drawstring(tmp, "Spectators", sbar_fontsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1108
1109         string str;
1110         float tl, fl, ll;
1111         str = strcat("playing on ^2", shortmapname, "^7");
1112         tl = getstatf(STAT_TIMELIMIT);
1113         fl = getstatf(STAT_FRAGLIMIT);
1114         ll = getstatf(STAT_LEADLIMIT);
1115         if(gametype == GAME_LMS)
1116         {
1117                 if(tl > 0)
1118                         str = strcat(str, " for up to ^1", ftos(tl), " minutes^7");
1119         }
1120         else
1121         {
1122                 if(tl > 0)
1123                         str = strcat(str, " for ^1", ftos(tl), " minutes^7");
1124                 if(fl > 0)
1125                 {
1126                         if(tl > 0)
1127                                 str = strcat(str, " or");
1128                         if(teamplay)
1129                         {
1130                                 str = strcat(str, " until ^3", ScoreString(teamscores_flags[ts_primary], fl));
1131                                 if(teamscores_label[ts_primary] == "score")
1132                                         str = strcat(str, " points^7");
1133                                 else if(teamscores_label[ts_primary] == "fastest")
1134                                         str = strcat(str, " is beaten^7");
1135                                 else
1136                                         str = strcat(str, " ", teamscores_label[ts_primary]);
1137                         }
1138                         else
1139                         {
1140                                 str = strcat(str, " until ^3", ScoreString(scores_flags[ps_primary], fl));
1141                                 if(scores_label[ps_primary] == "score")
1142                                         str = strcat(str, " points^7");
1143                                 else if(scores_label[ps_primary] == "fastest")
1144                                         str = strcat(str, " is beaten^7");
1145                                 else
1146                                         str = strcat(str, " ", scores_label[ps_primary]);
1147                         }
1148                 }
1149                 if(ll > 0)
1150                 {
1151                         if(tl > 0 || fl > 0)
1152                                 str = strcat(str, " or");
1153                         if(teamplay)
1154                         {
1155                                 str = strcat(str, " until a lead of ^3", ScoreString(teamscores_flags[ts_primary], ll));
1156                                 if(teamscores_label[ts_primary] == "score")
1157                                         str = strcat(str, " points^7");
1158                                 else if(teamscores_label[ts_primary] == "fastest")
1159                                         str = strcat(str, " is beaten^7");
1160                                 else
1161                                         str = strcat(str, " ", teamscores_label[ts_primary]);
1162                         }
1163                         else
1164                         {
1165                                 str = strcat(str, " until a lead of ^3", ScoreString(scores_flags[ps_primary], ll));
1166                                 if(scores_label[ps_primary] == "score")
1167                                         str = strcat(str, " points^7");
1168                                 else if(scores_label[ps_primary] == "fastest")
1169                                         str = strcat(str, " is beaten^7");
1170                                 else
1171                                         str = strcat(str, " ", scores_label[ps_primary]);
1172                         }
1173                 }
1174         }
1175
1176
1177         pos_y += 1.2 * sbar_fontsize_y;
1178         drawcolorcodedstring(pos + '0.5 0 0' * (sbwidth - sbar_fontsize_x * stringwidth(str, TRUE)), str, sbar_fontsize, 0.8, DRAWFLAG_NORMAL);
1179
1180         sbar = sbar_save;
1181         scoreboard_bottom = pos_y + 2 * sbar_fontsize_y;
1182 }
1183
1184 string MakeRaceString(float cp, float mytime, float histime, float lapdelta, string hisname)
1185 {
1186         string col;
1187         string timestr;
1188         string cpname;
1189         string lapstr;
1190         lapstr = "";
1191
1192         if(histime == 0) // goal hit
1193         {
1194                 if(mytime > 0)
1195                 {
1196                         timestr = strcat("+", ftos_decimals(+mytime, 1));
1197                         col = "^1";
1198                 }
1199                 else if(mytime == 0)
1200                 {
1201                         timestr = "+0.0";
1202                         col = "^3";
1203                 }
1204                 else
1205                 {
1206                         timestr = strcat("-", ftos_decimals(-mytime, 1));
1207                         col = "^2";
1208                 }
1209
1210                 if(lapdelta > 0)
1211                 {
1212                         lapstr = strcat(" (-", ftos(lapdelta), "L)");
1213                         col = "^2";
1214                 }
1215                 else if(lapdelta < 0)
1216                 {
1217                         lapstr = strcat(" (+", ftos(-lapdelta), "L)");
1218                         col = "^1";
1219                 }
1220         }
1221         else if(histime > 0) // anticipation
1222         {
1223                 if(mytime >= histime)
1224                         timestr = strcat("+", ftos_decimals(mytime - histime, 1));
1225                 else
1226                         timestr = mmsss(histime * 10);
1227                 col = "^3";
1228         }
1229         else
1230                 col = "^7";
1231
1232         if(cp == 254)
1233                 cpname = "Start line";
1234         else if(cp == 255)
1235                 cpname = "Finish line";
1236         else if(cp)
1237                 cpname = strcat("Intermediate ", ftos(cp));
1238         else
1239                 cpname = "Finish line";
1240
1241         if(histime < 0)
1242                 return strcat(col, cpname);
1243         else if(hisname == "")
1244                 return strcat(col, cpname, " (", timestr, ")");
1245         else
1246                 return strcat(col, cpname, " (", timestr, " ", strcat(hisname, col, lapstr), ")");
1247 }
1248
1249 void Sbar_Score(float margin)
1250 {
1251         float timelimit, minutes, seconds, timeleft, minutesLeft, secondsLeft, distribution, score, desiredPlayerId;
1252         vector sbar_save, score_offset, timer_color, offset;
1253         entity tm, pl, me;
1254         sbar_save = sbar;
1255
1256         vector bottomright;
1257         bottomright_x = vid_conwidth;
1258         bottomright_y = vid_conheight;
1259         bottomright_z = 0;
1260
1261         vector topright;
1262         topright_x = vid_conwidth;
1263         topright_y = 0;
1264         topright_z = 0;
1265
1266         //get the ID (could be "me", or the player I'm spectating)
1267         if (spectatee_status > 0)
1268                 desiredPlayerId = spectatee_status - 1;
1269         else
1270                 desiredPlayerId = player_localentnum - 1;
1271         me = playerslots[desiredPlayerId];
1272
1273         sbar_y = vid_conheight - (32+12);
1274         sbar_x -= margin;
1275
1276         offset = '0 0 0';
1277
1278         if (vid_conwidth >= 800) {
1279                 score_offset_x = 196;
1280                 score_offset_y = 36;
1281         }
1282         else { // move the scores if vid_conwidth < 800
1283                 score_offset_x = 196;
1284                 score_offset_y = 84;
1285         }
1286         score_offset_z = 0;
1287
1288         if(teamplay)
1289         {
1290                 // Layout:
1291                 //
1292                 //   team1 team3 team4
1293                 //
1294                 //         TEAM2
1295                 //for(i = 0; i < 4; ++i)
1296
1297                 float max_fragcount;
1298                 max_fragcount = -999;
1299
1300                 for(tm = teams.sort_next; tm; tm = tm.sort_next)
1301                 {
1302                         if(tm.team == COLOR_SPECTATOR || !tm.team_size) // no players? don't display
1303                                 continue;
1304                         // -32*4 = -128
1305                         score = tm.(teamscores[ts_primary]);
1306
1307                         if (score > max_fragcount)
1308                                 max_fragcount = score;
1309
1310                         if(tm.team == myteam) {
1311                                 if (max_fragcount == score)
1312                                         Sbar_DrawXNum(bottomright - element_offset - score_offset, score, 4, 34, GetTeamRGB(tm.team) * 0.8, 1, 1, sbar_alpha_fg, DRAWFLAG_NORMAL);
1313                                 else
1314                                         Sbar_DrawXNum(bottomright - element_offset - score_offset, score, 4, 34, GetTeamRGB(tm.team) * 0.8, 0, 1, sbar_alpha_fg, DRAWFLAG_NORMAL);
1315                         }
1316                         else
1317                         {
1318                                 if (max_fragcount == score)
1319                                         Sbar_DrawXNum(bottomright - element_offset - score_offset + '132 -6 0' - offset, score, 4, 16, GetTeamRGB(tm.team) * 0.8, 1, 1, sbar_alpha_fg, DRAWFLAG_NORMAL);
1320                                 else
1321                                         Sbar_DrawXNum(bottomright - element_offset - score_offset + '132 -6 0' - offset, score, 4, 16, GetTeamRGB(tm.team) * 0.8, 0, 1, sbar_alpha_fg, DRAWFLAG_NORMAL);
1322                                 offset_y -= 16;
1323                         }
1324                 }
1325         } else {
1326                 // me vector := [team/connected frags id]
1327
1328                 pl = players.sort_next;
1329                 if(pl == me)
1330                         pl = pl.sort_next;
1331
1332                 if(pl) {
1333                         distribution = me.(scores[ps_primary]);
1334                         distribution -= pl.(scores[ps_primary]);
1335                 } else
1336                         distribution = 0;
1337
1338                 score = me.(scores[ps_primary]);
1339
1340                 if(distribution >= 0)
1341                 {
1342                         if (distribution != 0) {
1343                                 // draw a + sign in front of the score
1344                                 if (distribution < 10) { drawpic(bottomright - element_offset - score_offset + '132 -6 0' + '32 0 0', "gfx/hud/num_plus", '16 16 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_ADDITIVE); }
1345                                 else if (distribution < 100) { drawpic(bottomright - element_offset - score_offset + '132 -6 0' + '16 0 0', "gfx/hud/num_plus", '16 16 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_ADDITIVE); }
1346                                 else if (distribution < 1000) { drawpic(bottomright - element_offset - score_offset + '132 -6 0', "gfx/hud/num_plus", '16 16 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_ADDITIVE); }
1347                         }
1348
1349                         Sbar_DrawXNum(bottomright - element_offset - score_offset + '132 -6 0', distribution, 4, 16, ' 1 1 1', 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
1350                         Sbar_DrawXNum(bottomright - element_offset - score_offset, score, 4, 34, '1 1 1', 1, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
1351                 }
1352                 else if(distribution >= -5)
1353                 {
1354                         Sbar_DrawXNum(bottomright - element_offset - score_offset + '132 -6 0', distribution, 4, 16, ' 1 1 0', 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
1355                         Sbar_DrawXNum(bottomright - element_offset - score_offset, score, 4, 34, '1 1 0', 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
1356                 }
1357                 else {
1358                         Sbar_DrawXNum(bottomright - element_offset - score_offset + '132 -6 0', distribution, 4, 16, ' 1 0 0', 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
1359                         Sbar_DrawXNum(bottomright - element_offset - score_offset, score, 4, 34, '1 0 0', 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
1360                 }
1361         }
1362
1363         //draw the remaining or elapsed time
1364         timelimit = getstatf(STAT_TIMELIMIT);
1365
1366         vector bgpos;
1367         if(timelimit > 0)
1368         {
1369                 timeleft = max(0, timelimit * 60 + getstatf(STAT_GAMESTARTTIME) - time);
1370                 timeleft = ceil(timeleft);
1371                 minutesLeft = floor(timeleft / 60);
1372                 secondsLeft = timeleft - minutesLeft*60;
1373
1374                 if(minutesLeft >= 5 || warmup_stage) //don't use red or yellow for timer during warmup
1375                         timer_color = '1 1 1'; //white
1376                 else if(minutesLeft >= 1)
1377                         timer_color = '1 1 0'; //yellow
1378                 else
1379                         timer_color = '1 0 0'; //red
1380
1381                 if (cvar("sbar_increment_maptime")) {
1382                         if (time < getstatf(STAT_GAMESTARTTIME)) {
1383                                 //while restart is still active, show negative counter
1384                                 minutes = 0;
1385                                 seconds = ceil(getstatf(STAT_GAMESTARTTIME) - time);
1386                         } else {
1387                                 float elapsedTime;
1388                                 elapsedTime = floor(time - getstatf(STAT_GAMESTARTTIME)); //127
1389                                 minutes = floor(elapsedTime / 60);
1390                                 seconds = elapsedTime - minutes*60;
1391                         }
1392                 } else {
1393                         minutes = minutesLeft;
1394                         seconds = secondsLeft;
1395                 }
1396
1397                 if (minutes == 0) {
1398                         if (cvar("sbar_increment_maptime") == 1)
1399                                 bgpos_x = topright_x - 54 - 17 - 12;
1400                         else
1401                                 bgpos_x = topright_x - 36 - 7 - 12;
1402                 }
1403                 else if (minutes < 10) // nudge the timer background left if more digits are drawn
1404                         bgpos_x = topright_x - 54 - 17 - 12;
1405                 else if (minutes < 100)
1406                         bgpos_x = topright_x - 72 - 17 - 12;
1407                 else
1408                         bgpos_x = topright_x - 90 - 17 - 12;
1409                 bgpos_y = 0;
1410                 bgpos_z = 0;
1411
1412                 if (cvar("viewsize") <= 100) { // draw timer background when viewsize <= 100
1413                         if (teamplay)
1414                                 drawpic(bgpos, "gfx/hud/sb_timerbg", '120 30 0', GetTeamRGB(myteam) * sbar_color_bg_team, sbar_alpha_bg, DRAWFLAG_NORMAL); // timer bg color = myteam color
1415                         else {
1416                                 color_x = cvar("sbar_color_bg_r");
1417                                 color_y = cvar("sbar_color_bg_g");
1418                                 color_z = cvar("sbar_color_bg_b");
1419
1420                                 drawpic(bgpos, "gfx/hud/sb_timerbg", '120 30 0', color, sbar_alpha_bg, DRAWFLAG_NORMAL);
1421                         }
1422                 }
1423
1424                 if(minutesLeft >= 1) {
1425                         Sbar_DrawXNum(topright - '103 0 0' + '0 2 0', minutes, 3, 18, timer_color, 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
1426                         drawpic(topright - '53 0 0' + '0 1 0', "gfx/hud/num_colon", '18 18 0', timer_color, sbar_alpha_fg, DRAWFLAG_NORMAL);
1427                 }
1428                 Sbar_DrawXNum(topright - '36 0 0' - '3 0 0' + '0 2 0', seconds, -2, 18, timer_color, 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
1429
1430         } else {
1431                 timer_color = '1 1 1'; //white
1432                 minutes = floor(time / 60);
1433                 seconds = floor(time - minutes*60);
1434
1435                 if (minutes < 10)
1436                         bgpos_x = topright_x - 54 - 17 - 12;
1437                 else if (minutes < 100) // nudge the timer background left if more digits are drawn
1438                         bgpos_x = topright_x - 72 - 17 - 12;
1439                 else
1440                         bgpos_x = topright_x - 90 - 17 - 12;
1441                 bgpos_y = 0;
1442                 bgpos_z = 0;
1443
1444                 if (cvar("viewsize") <= 100) { // draw timer background when viewsize <= 100
1445                         if (teamplay)
1446                                 drawpic(bgpos, "gfx/hud/sb_timerbg", '120 30 0', GetTeamRGB(myteam) * sbar_color_bg_team, sbar_alpha_bg, DRAWFLAG_NORMAL); // timer bg color = myteam color
1447                         else {
1448                                 color_x = cvar("sbar_color_bg_r");
1449                                 color_y = cvar("sbar_color_bg_g");
1450                                 color_z = cvar("sbar_color_bg_b");
1451
1452                                 drawpic(bgpos, "gfx/hud/sb_timerbg", '120 30 0', color, sbar_alpha_bg, DRAWFLAG_NORMAL);
1453                         }
1454                 }
1455
1456                 Sbar_DrawXNum(topright - '103 0 0' + '0 2 0', minutes, 3, 18, timer_color, 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
1457                 drawpic(topright - '53 0 0' + '0 1 0', "gfx/hud/num_colon", '18 18 0', timer_color, sbar_alpha_fg, DRAWFLAG_NORMAL);
1458                 Sbar_DrawXNum(topright - '36 0 0' - '3 0 0' + '0 2 0', seconds, -2, 18, timer_color, 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
1459         }
1460
1461         if(gametype == GAME_RACE)
1462         {
1463                 drawfont = sbar_bigfont;
1464                 float a, t;
1465                 vector m;
1466                 string s, forcetime;
1467
1468                 m = '0.5 0 0' * vid_conwidth + '0 0.25 0' * vid_conheight;
1469
1470                 if(race_checkpointtime)
1471                 {
1472                         a = bound(0, 2 - (time - race_checkpointtime), 1);
1473                         s = "";
1474                         forcetime = "";
1475                         if(a > 0) // just hit a checkpoint?
1476                         {
1477                                 if(race_checkpoint != 254)
1478                                 {
1479                                         if(race_time && race_previousbesttime)
1480                                                 s = MakeRaceString(race_checkpoint, race_time / 10 - race_previousbesttime / 10, 0, 0, race_previousbestname);
1481                                         else
1482                                                 s = MakeRaceString(race_checkpoint, 0, -1, 0, race_previousbestname);
1483                                         if(race_time)
1484                                                 forcetime = mmsss(race_time);
1485                                 }
1486                         }
1487                         else
1488                         {
1489                                 if(race_laptime && race_nextbesttime && race_nextcheckpoint != 254)
1490                                 {
1491                                         a = bound(0, 2 - ((race_laptime + race_nextbesttime/10) - (time + race_penaltyaccumulator/10)), 1);
1492                                         if(a > 0) // next one?
1493                                         {
1494                                                 s = MakeRaceString(race_nextcheckpoint, (time + race_penaltyaccumulator/10) - race_laptime, race_nextbesttime / 10, 0, race_nextbestname);
1495                                         }
1496                                 }
1497                         }
1498
1499                         if(s != "" && a > 0)
1500                         {
1501                                 dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1502                                 drawcolorcodedstring(m - '0 16 0' - '8 0 0' * stringwidth(s, TRUE), s, '16 16 0', sbar_alpha_fg * a, DRAWFLAG_NORMAL);
1503                         }
1504
1505                         if(race_penaltytime)
1506                         {
1507                                 a = bound(0, 2 - (time - race_penaltyeventtime), 1);
1508                                 if(a > 0)
1509                                 {
1510                                         s = strcat("^1PENALTY: ", ftos_decimals(race_penaltytime * 0.1, 1), " (", race_penaltyreason, ")");
1511                                         dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1512                                         drawcolorcodedstring(m - '0 32 0' - '8 0 0' * stringwidth(s, TRUE), s, '16 16 0', sbar_alpha_fg * a, DRAWFLAG_NORMAL);
1513                                 }
1514                         }
1515
1516                         if(forcetime != "")
1517                         {
1518                                 a = bound(0, (time - race_checkpointtime) / 0.5, 1);
1519                                 drawstring_expanding(m - '16 0 0' * stringwidth(forcetime, FALSE), forcetime, '32 32 0', '1 1 1', sbar_alpha_fg, 0, a);
1520                         }
1521                         else
1522                                 a = 1;
1523
1524                         if(race_laptime && race_checkpoint != 255)
1525                         {
1526                                 s = mmsss(10*(time + race_penaltyaccumulator/10 - race_laptime));
1527                                 drawstring(m - '16 0 0' * stringwidth(s, FALSE), s, '32 32 0', '1 1 1', sbar_alpha_fg * a, DRAWFLAG_NORMAL);
1528                         }
1529                 }
1530                 else
1531                 {
1532                         if(race_mycheckpointtime)
1533                         {
1534                                 a = bound(0, 2 - (time - race_mycheckpointtime), 1);
1535                                 s = MakeRaceString(race_mycheckpoint, race_mycheckpointdelta / 10, -!race_mycheckpointenemy, race_mycheckpointlapsdelta, race_mycheckpointenemy);
1536                                 dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1537                                 drawcolorcodedstring(m - '0 16 0' - '8 0 0' * stringwidth(s, TRUE), s, '16 16 0', sbar_alpha_fg * a, DRAWFLAG_NORMAL);
1538                         }
1539                         if(race_othercheckpointtime && race_othercheckpointenemy != "")
1540                         {
1541                                 a = bound(0, 2 - (time - race_othercheckpointtime), 1);
1542                                 s = MakeRaceString(race_othercheckpoint, -race_othercheckpointdelta / 10, -!race_othercheckpointenemy, race_othercheckpointlapsdelta, race_othercheckpointenemy);
1543                                 dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1544                                 drawcolorcodedstring(m - '0 0 0' - '8 0 0' * stringwidth(s, TRUE), s, '16 16 0', sbar_alpha_fg * a, DRAWFLAG_NORMAL);
1545                         }
1546
1547                         if(race_penaltytime && !race_penaltyaccumulator)
1548                         {
1549                                 t = race_penaltytime * 0.1 + race_penaltyeventtime;
1550                                 a = bound(0, (1 + t - time), 1);
1551                                 if(a > 0)
1552                                 {
1553                                         if(time < t)
1554                                                 s = strcat("^1PENALTY: ", ftos_decimals(t - time, 1), " (", race_penaltyreason, ")");
1555                                         else
1556                                                 s = strcat("^2PENALTY: 0.0 (", race_penaltyreason, ")");
1557                                         dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1558                                         drawcolorcodedstring(m - '0 32 0' - '8 0 0' * stringwidth(s, TRUE), s, '16 16 0', sbar_alpha_fg * a, DRAWFLAG_NORMAL);
1559                                 }
1560                         }
1561                 }
1562
1563                 drawfont = sbar_font;
1564         }
1565
1566         sbar = sbar_save;
1567 }
1568
1569 float Sbar_WouldDrawScoreboard ()
1570 {
1571         if (sb_showscores)
1572                 return 1;
1573         else if (intermission == 1)
1574                 return 1;
1575         else if (intermission == 2)
1576                 return 1;
1577         else if (getstati(STAT_HEALTH) <= 0 && cvar("cl_deathscoreboard"))
1578                 return 1;
1579         else if(sb_showscores_force)
1580                 return 1;
1581         return 0;
1582 }
1583
1584 void CSQC_Strength_Timer() {
1585         vector bottom;
1586
1587         bottom_x = vid_conwidth/2;
1588         bottom_y = vid_conheight;
1589         bottom_z = 0;
1590
1591         float stat_items, dt;
1592         stat_items = getstati(STAT_ITEMS);
1593         /*
1594         if not(stat_items & IT_STRENGTH)
1595                 if not(stat_items & IT_INVINCIBLE)
1596                         return;
1597         */
1598
1599         if (getstati(STAT_HEALTH) <= 0)
1600                 return;
1601
1602         vector picsize;
1603         float strength_time, invincibility_time, countdown_fontsize;
1604
1605         picsize = '22 22 0';
1606         countdown_fontsize = 18;
1607
1608         //strength
1609         strength_time = getstatf(STAT_STRENGTH_FINISHED);
1610         invincibility_time = getstatf(STAT_INVINCIBLE_FINISHED);
1611
1612         if (strength_time) {
1613                 dt = strength_time - time;
1614                 if(dt > 0)
1615                 {
1616                         if(dt < 5)
1617                         {
1618                                 drawpic_expanding_two(bottom + '192 -46 0', "gfx/hud/sb_str", picsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_ADDITIVE,
1619                                         bound(0, (ceil(dt) - dt) / 0.5, 1));
1620                         }
1621                         else
1622                         {
1623                                 drawpic(bottom + '192 -46 0', "gfx/hud/sb_str", picsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_ADDITIVE);
1624                         }
1625                         Sbar_DrawXNum(bottom + '152 -44 0', ceil(dt), 2, countdown_fontsize, '1 1 1', 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
1626                 }
1627                 else if(dt > -1)
1628                 {
1629                         drawpic_expanding(bottom + '192 -46 0', "gfx/hud/sb_str", picsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_ADDITIVE,
1630                                 bound(0, -dt / 0.5, 1));
1631                 }
1632         }
1633
1634         //invincibility
1635         if (invincibility_time) {
1636                 dt = invincibility_time - time;
1637                 if(dt > 0)
1638                 {
1639                         if(dt < 5)
1640                         {
1641                                 drawpic_expanding_two(bottom + '192 -24 0', "gfx/hud/sb_invinc", picsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_ADDITIVE,
1642                                         bound(0, (ceil(dt) - dt) / 0.5, 1));
1643                         }
1644                         else
1645                         {
1646                                 drawpic(bottom + '192 -24 0', "gfx/hud/sb_invinc", picsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_ADDITIVE);
1647                         }
1648                         Sbar_DrawXNum(bottom + '152 -22 0', ceil(dt), 2, countdown_fontsize, '1 1 1', 0, 0, 1, DRAWFLAG_NORMAL);
1649                 }
1650                 else if(dt > -1)
1651                 {
1652                         drawpic_expanding(bottom + '192 -24 0', "gfx/hud/sb_invinc", picsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_ADDITIVE,
1653                                 bound(0, -dt / 0.5, 1));
1654                 }
1655         }
1656 }
1657
1658 #define CENTERPRINT_MAX_LINES 30
1659 string centerprint_messages[CENTERPRINT_MAX_LINES];
1660 float centerprint_width[CENTERPRINT_MAX_LINES];
1661 vector centerprint_start;
1662 float centerprint_expire;
1663 float centerprint_num;
1664 float centerprint_offset_hint;
1665 vector centerprint_fontsize;
1666
1667 void centerprint(string strMessage)
1668 {
1669         float i, j, n, hcount;
1670         string s;
1671
1672         centerprint_fontsize = Sbar_GetFontsize("scr_centersize");
1673
1674         centerprint_expire = min(centerprint_expire, time); // if any of the returns happens, this message will fade out
1675
1676         if(cvar("scr_centertime") <= 0)
1677                 return;
1678
1679         if(strMessage == "")
1680                 return;
1681
1682         // strip trailing newlines
1683         j = strlen(strMessage) - 1;
1684         while(substring(strMessage, j, 1) == "\n" && j >= 0)
1685                 j = j - 1;
1686         strMessage = substring(strMessage, 0, j + 1);
1687
1688         if(strMessage == "")
1689                 return;
1690
1691         // strip leading newlines and remember them, they are a hint that the message should be lower on the screen
1692         j = 0;
1693         while(substring(strMessage, j, 1) == "\n" && j < strlen(strMessage))
1694                 j = j + 1;
1695         strMessage = substring(strMessage, j, strlen(strMessage) - j);
1696         centerprint_offset_hint = j;
1697
1698         if(strMessage == "")
1699                 return;
1700
1701         // if we get here, we have a message. Initialize its height.
1702         centerprint_num = 0;
1703
1704         n = tokenizebyseparator(strMessage, "\n");
1705         i = hcount = 0;
1706         for(j = 0; j < n; ++j)
1707         {
1708                 getWrappedLine_remaining = argv(j);
1709                 while(getWrappedLine_remaining)
1710                 {
1711                         s = getWrappedLine(vid_conwidth * 0.75 / centerprint_fontsize_x, stringwidth_colors);
1712                         if(centerprint_messages[i])
1713                                 strunzone(centerprint_messages[i]);
1714                         centerprint_messages[i] = strzone(s);
1715                         centerprint_width[i] = stringwidth(s, TRUE);
1716                         ++i;
1717
1718                         // half height for empty lines looks better
1719                         if(s == "")
1720                                 hcount += 0.5;
1721                         else
1722                                 hcount += 1;
1723
1724                         if(i >= CENTERPRINT_MAX_LINES)
1725                                 break;
1726                 }
1727         }
1728
1729         float h, havail;
1730         h = centerprint_fontsize_y*hcount;
1731
1732         havail = vid_conheight;
1733         if(cvar("con_chatpos") < 0)
1734                 havail -= (-cvar("con_chatpos") + cvar("con_chat")) * cvar("con_chatsize"); // avoid overlapping chat
1735
1736         centerprint_start_x = 0;
1737
1738 #if 0
1739         float forbiddenmin, forbiddenmax, allowedmin, allowedmax, preferred;
1740
1741         // here, the centerprint would cover the crosshair. REALLY BAD.
1742         forbiddenmin = vid_conheight * 0.5 - h - 16;
1743         forbiddenmax = vid_conheight * 0.5 + 16;
1744
1745         allowedmin = scoreboard_bottom;
1746         allowedmax = havail - h;
1747         preferred = (havail - h)/2;
1748
1749
1750         // possible orderings (total: 4! / 4 = 6)
1751         //  allowedmin allowedmax forbiddenmin forbiddenmax
1752         //  forbiddenmin forbiddenmax allowedmin allowedmax
1753         if(allowedmax < forbiddenmin || allowedmin > forbiddenmax)
1754         {
1755                 // forbidden doesn't matter in this case
1756                 centerprint_start_y = bound(allowedmin, preferred, allowedmax);
1757         }
1758         //  allowedmin forbiddenmin allowedmax forbiddenmax
1759         else if(allowedmin < forbiddenmin && allowedmax < forbiddenmax)
1760         {
1761                 centerprint_start_y = bound(allowedmin, preferred, forbiddenmin);
1762         }
1763         //  allowedmin forbiddenmin forbiddenmax allowedmax
1764         else if(allowedmin < forbiddenmin)
1765         {
1766                 // make sure the forbidden zone is not covered
1767                 if(preferred > (forbiddenmin + forbiddenmax) * 0.5)
1768                         centerprint_start_y = bound(allowedmin, preferred, forbiddenmin);
1769                 else
1770                         centerprint_start_y = bound(forbiddenmax, preferred, allowedmin);
1771         }
1772         //  forbiddenmin allowedmin allowedmax forbiddenmax
1773         else if(allowedmax < forbiddenmax)
1774         {
1775                 // it's better to leave the allowed zone (overlap with scoreboard) than
1776                 // to cover the forbidden zone (crosshair)
1777                 if(preferred > (forbiddenmin + forbiddenmax) * 0.5)
1778                         centerprint_start_y = forbiddenmax;
1779                 else
1780                         centerprint_start_y = forbiddenmin;
1781         }
1782         //  forbiddenmin allowedmin forbiddenmax allowedmax
1783         else
1784         {
1785                 centerprint_start_y = bound(forbiddenmax, preferred, allowedmax);
1786         }
1787 #else
1788         centerprint_start_y =
1789                 min(
1790                         max(
1791                                 max(scoreboard_bottom, vid_conheight * 0.5 + 16),
1792                                 (havail - h)/2
1793                         ),
1794                         havail - h
1795                 );
1796 #endif
1797
1798         centerprint_num = i;
1799         centerprint_expire = time + cvar("scr_centertime");
1800 }
1801
1802 void Sbar_DrawCenterPrint (void)
1803 {
1804         float i;
1805         vector pos;
1806         string ts;
1807         float a;
1808
1809         //if(time > centerprint_expire)
1810         //      return;
1811
1812         //a = bound(0, 1 - 2 * (time - centerprint_expire), 1);
1813         a = bound(0, 1 - 4 * (time - centerprint_expire), 1);
1814         //sz = 1.2 / (a + 0.2);
1815
1816         if(a <= 0)
1817                 return;
1818
1819         pos = centerprint_start;
1820         for (i=0; i<centerprint_num; i = i + 1)
1821         {
1822                 pos_x = (vid_conwidth - centerprint_fontsize_x * centerprint_width[i]) * 0.5;
1823                 ts = centerprint_messages[i];
1824                 if (ts != "")
1825                 {
1826                         dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1827                         drawcolorcodedstring(pos, ts, centerprint_fontsize, a, DRAWFLAG_NORMAL);
1828                         //  - '0 0.5 0' * (sz - 1) * centerprint_fontsize_x - '0.5 0 0' * (sz - 1) * centerprint_width[i] * centerprint_fontsize_y, centerprint_fontsize * sz
1829                         pos_y = pos_y + centerprint_fontsize_y;
1830                 }
1831                 else
1832                         // half height for empty lines looks better
1833                         pos_y = pos_y + centerprint_fontsize_y * 0.5;
1834         }
1835 }
1836
1837 vector Sbar_DrawNoteLine(vector offset, string s)
1838 {
1839         dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1840         drawcolorcodedstring(
1841                 offset - sbar_fontsize_x * '1 0 0' * stringwidth(s, TRUE),
1842                 s,
1843                 sbar_fontsize,
1844                 sbar_alpha_fg,
1845                 0
1846         );
1847         return offset + sbar_fontsize_y * '0 1 0';
1848 }
1849
1850 void Sbar_DrawPressedKeys(void)
1851 {
1852         vector pos, bgsize;
1853         float pressedkeys;
1854
1855         pos = stov(cvar_string("cl_showpressedkeys_position"));
1856
1857         bgsize = '126 75 0';
1858
1859         pos = '1 0 0' * (vid_conwidth - bgsize_x) * pos_x
1860             + '0 1 0' * (vid_conheight - bgsize_y) * pos_y;
1861         pos -= '-15 -6 0'; // adjust to the origin of these numbers
1862
1863         pressedkeys = getstatf(STAT_PRESSED_KEYS);
1864         drawpic(pos + '-15   -6   0', "gfx/hud/keys/key_bg.tga",           bgsize, '1 1 1', .1, DRAWFLAG_NORMAL);
1865         drawpic(pos + ' 83.5  9   0', ((pressedkeys & KEY_CROUCH) ? "gfx/hud/keys/key_crouch_inv.tga" : "gfx/hud/keys/key_crouch.tga"), ' 24 24 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1866         drawpic(pos + ' 32   -1.5 0', ((pressedkeys & KEY_FORWARD) ? "gfx/hud/keys/key_forward_inv.tga" : "gfx/hud/keys/key_forward.tga"),  ' 32 32 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1867         drawpic(pos + '-11.5  9   0', ((pressedkeys & KEY_JUMP) ? "gfx/hud/keys/key_jump_inv.tga" : "gfx/hud/keys/key_jump.tga"),     ' 24 24 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1868         drawpic(pos + ' -1   32   0', ((pressedkeys & KEY_LEFT) ? "gfx/hud/keys/key_left_inv.tga" : "gfx/hud/keys/key_left.tga"),     ' 32 32 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1869         drawpic(pos + ' 32   32   0', ((pressedkeys & KEY_BACKWARD) ? "gfx/hud/keys/key_backward_inv.tga" : "gfx/hud/keys/key_backward.tga"), ' 32 32 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1870         drawpic(pos + ' 65   32   0', ((pressedkeys & KEY_RIGHT) ? "gfx/hud/keys/key_right_inv.tga" : "gfx/hud/keys/key_right.tga"),    ' 32 32 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1871 }
1872
1873 void Sbar_ShowSpeed(void)
1874 {
1875         vector numsize;
1876         float pos;
1877         string speed;
1878
1879         if (cvar("cl_showspeed_z") == 1)
1880                 speed = ftos(floor(vlen(pmove_vel) + 0.5));
1881         else
1882                 speed = ftos(floor(vlen(pmove_vel - pmove_vel_z * '0 0 1') + 0.5));
1883
1884         pos = cvar("cl_showspeed_position");
1885         numsize_x = numsize_y = cvar("cl_showspeed_size");
1886         pos = (vid_conheight - numsize_y) * pos;
1887
1888         drawstringcenter('1 0 0' + pos * '0 1 0', speed, numsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
1889 }
1890
1891 void Sbar_DrawAccuracyStats()
1892 {
1893         float i, count_hitscan, count_splash, row;  // count is the number of 'colums'
1894         float weapon_hit, weapon_damage, weapon_stats;
1895         float left_border;  // position where the weapons start, the description is in the border
1896         vector fill_colour, fill_size;
1897         vector pos;
1898
1899         float col_margin = 20;  // pixels between the columns
1900         float row_margin = 20;  // pixels between the rows
1901         float top_border;  // position where the first row starts: pixels down the screen
1902
1903         fill_size_x = 5 * sbar_fontsize_x;  // width of the background
1904         fill_size_y = 10 * sbar_fontsize_y;  // height of the background
1905
1906         // 45 pixels is the same as the 'Scoreboard' heading
1907         drawfont = sbar_bigfont;
1908         drawstringcenter('0 45 0', "Weapon Accuracy", 2 * sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
1909         left_border = col_margin + 11 * sbar_fontsize_x;
1910
1911         top_border = 80;
1912         Sbar_DrawAccuracyStats_Description_Hitscan('1 0 0' * col_margin + '0 1 0' * top_border);
1913
1914         top_border = 220;
1915         Sbar_DrawAccuracyStats_Description_Splash('1 0 0' * col_margin + '0 1 0' * top_border);
1916
1917
1918         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
1919         {
1920                 weapon_hit = weapon_hits[i];
1921                 weapon_damage = weapon_fired[i];
1922                 self = get_weaponinfo(i);
1923
1924                 //if ((weapon_number != 42))  // print them all :)
1925                 if ((self.weapon_type == WEP_TYPE_SPLASH) && (weapon_damage))
1926                 {
1927                         top_border = 220;
1928                         weapon_stats = rint(100 * weapon_hit / weapon_damage);
1929
1930                         fill_colour_x = 1 - 0.015 * weapon_stats;
1931                         fill_colour_y = 1 - 0.015 * (100 - weapon_stats);
1932
1933 //                      how the background colour is calculated
1934 //                      %       red     green   red_2           green_2
1935 //                      0       1       0       1 - % * 0.015   1 - (100 - %) * 0.015
1936 //                      10      0.85    0       1 - % * 0.015   1 - (100 - %) * 0.015
1937 //                      20      0.70    0       1 - % * 0.015   1 - (100 - %) * 0.015
1938 //                      30      0.55    0       1 - % * 0.015   1 - (100 - %) * 0.015
1939 //                      40      0.40    0.10    1 - % * 0.015   1 - (100 - %) * 0.015
1940 //                      50      0.25    0.25    1 - % * 0.015   1 - (100 - %) * 0.015
1941 //                      60      0.10    0.40    1 - % * 0.015   1 - (100 - %) * 0.015
1942 //                      70      0       0.55    1 - % * 0.015   1 - (100 - %) * 0.015
1943 //                      80      0       0.70    1 - % * 0.015   1 - (100 - %) * 0.015
1944 //                      90      0       0.85    1 - % * 0.015   1 - (100 - %) * 0.015
1945 //                      100     0       1       1 - % * 0.015   1 - (100 - %) * 0.015
1946
1947                         if ((left_border + count_splash * (fill_size_x + col_margin) + fill_size_x) >= vid_conwidth)
1948                         {
1949                                 count_splash = 0;
1950                                 ++row;
1951                                 Sbar_DrawAccuracyStats_Description_Splash('1 0 0' * col_margin + '0 1 0' * (top_border + row * (fill_size_y + row_margin)));
1952                         }
1953
1954                         pos_x = left_border + count_splash * (fill_size_x + col_margin);
1955                         pos_y = top_border + row * (fill_size_y + row_margin);
1956
1957                         // background
1958                         drawpic(pos, "gfx/hud/sb_accuracy", fill_size , fill_colour, sbar_alpha_bg, DRAWFLAG_NORMAL);
1959                         drawborderlines(sbar_border_thickness, pos, fill_size, '0 0 0', sbar_alpha_bg, DRAWFLAG_NORMAL);
1960
1961                         // the weapon
1962                         drawpic(pos, strcat("gfx/hud/inv_weapon", ftos(i-1)), '1 0.5 0' * fill_size_x , '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
1963
1964                         // the amount of shots fired or max damage
1965                         drawstringright(pos + '4.5 0 0' * sbar_fontsize_x + '0 3 0' * sbar_fontsize_y, ftos(weapon_damage), sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
1966
1967                         // the amount of hits or actual damage
1968                         drawstringright(pos + '4.5 0 0' * sbar_fontsize_x + '0 5 0' * sbar_fontsize_y, ftos(weapon_hit), sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
1969
1970                         // the accuracy
1971                         drawstringright(pos + '4.5 0 0' * sbar_fontsize_x + '0 7 0' * sbar_fontsize_y, strcat(ftos(weapon_stats),"%"), sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
1972
1973                         // the amount of shots missed or damage wasted
1974                         drawstringright(pos + '4.5 0 0' * sbar_fontsize_x + '0 9 0' * sbar_fontsize_y, ftos(weapon_damage - weapon_hit), sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
1975
1976                         ++count_splash;
1977                 }
1978                 else if ((self.weapon_type == WEP_TYPE_HITSCAN) && (weapon_damage))
1979                 {
1980                         top_border = 80;
1981                         weapon_stats = rint(100 * weapon_hit / weapon_damage);
1982
1983                         fill_colour_x = 1 - 0.015 * weapon_stats;
1984                         fill_colour_y = 1 - 0.015 * (100 - weapon_stats);
1985
1986 //                      how the background colour is calculated
1987 //                      %       red     green   red_2           green_2
1988 //                      0       1       0       1 - % * 0.015   1 - (100 - %) * 0.015
1989 //                      10      0.85    0       1 - % * 0.015   1 - (100 - %) * 0.015
1990 //                      20      0.70    0       1 - % * 0.015   1 - (100 - %) * 0.015
1991 //                      30      0.55    0       1 - % * 0.015   1 - (100 - %) * 0.015
1992 //                      40      0.40    0.10    1 - % * 0.015   1 - (100 - %) * 0.015
1993 //                      50      0.25    0.25    1 - % * 0.015   1 - (100 - %) * 0.015
1994 //                      60      0.10    0.40    1 - % * 0.015   1 - (100 - %) * 0.015
1995 //                      70      0       0.55    1 - % * 0.015   1 - (100 - %) * 0.015
1996 //                      80      0       0.70    1 - % * 0.015   1 - (100 - %) * 0.015
1997 //                      90      0       0.85    1 - % * 0.015   1 - (100 - %) * 0.015
1998 //                      100     0       1       1 - % * 0.015   1 - (100 - %) * 0.015
1999
2000                         if ((left_border + count_hitscan * (fill_size_x + col_margin) + fill_size_x + cvar("stats_right_margin")) >= vid_conwidth)
2001                         {
2002                                 count_hitscan = 0;
2003                                 ++row;
2004                                 Sbar_DrawAccuracyStats_Description_Hitscan('1 0 0' * col_margin + '0 1 0' * (top_border + row * (fill_size_y + row_margin)));
2005                         }
2006
2007                         pos_x = left_border + count_hitscan * (fill_size_x + col_margin);
2008                         pos_y = top_border + row * (fill_size_y + row_margin);
2009
2010                         // background
2011                         drawpic(pos, "gfx/hud/sb_accuracy", fill_size , fill_colour, sbar_alpha_bg, DRAWFLAG_NORMAL);
2012                         drawborderlines(sbar_border_thickness, pos, fill_size, '0 0 0', sbar_alpha_bg, DRAWFLAG_NORMAL);
2013
2014                         // the weapon
2015                         drawpic(pos, strcat("gfx/hud/inv_weapon", ftos(i-1)), '1 0.5 0' * fill_size_x , '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2016
2017                         // the amount of shots fired or max damage
2018                         drawstringright(pos + '4.5 0 0' * sbar_fontsize_x + '0 3 0' * sbar_fontsize_y, ftos(weapon_damage), sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2019
2020                         // the amount of hits or actual damage
2021                         drawstringright(pos + '4.5 0 0' * sbar_fontsize_x + '0 5 0' * sbar_fontsize_y, ftos(weapon_hit), sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2022
2023                         // the accuracy
2024                         drawstringright(pos + '4.5 0 0' * sbar_fontsize_x + '0 7 0' * sbar_fontsize_y, strcat(ftos(weapon_stats),"%"), sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2025
2026                         // the amount of shots missed or damage wasted
2027                         drawstringright(pos + '4.5 0 0' * sbar_fontsize_x + '0 9 0' * sbar_fontsize_y, ftos(weapon_damage - weapon_hit), sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2028
2029                         ++count_hitscan;
2030                 }
2031         }
2032 }
2033
2034 void Sbar_DrawAccuracyStats_Description_Hitscan(vector position)
2035 {
2036         drawfont = sbar_font;
2037          // hitscan stats
2038         drawstring(position + '0 3 0' * sbar_fontsize_y, "Shots fired:", sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2039         drawstring(position + '0 5 0' * sbar_fontsize_y, "Shots hit:", sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2040         drawstring(position + '0 7 0' * sbar_fontsize_y, "Accuracy:", sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2041         drawstring(position + '0 9 0' * sbar_fontsize_y, "Shots missed:", sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2042 }
2043
2044 void Sbar_DrawAccuracyStats_Description_Splash(vector position)
2045 {
2046         //splash stats
2047         drawfont = sbar_font;
2048         drawstring(position + '0 3 0' * sbar_fontsize_y, "Maximum damage:", sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2049         drawstring(position + '0 5 0' * sbar_fontsize_y, "Actual damage:", sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2050         drawstring(position + '0 7 0' * sbar_fontsize_y, "Accuracy:", sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2051         drawstring(position + '0 9 0' * sbar_fontsize_y, "Damage wasted:", sbar_fontsize, '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2052 }
2053
2054 void drawstringright(vector position, string text, vector scale, vector rgb, float alpha, float flag)
2055 {
2056         position_x -= 2 / 3 * strlen(text) * scale_x;
2057         drawstring(position, text, scale, rgb, alpha, flag);
2058 }
2059
2060 void drawstringcenter(vector position, string text, vector scale, vector rgb, float alpha, float flag)
2061 {
2062         position_x = 0.5 * (vid_conwidth - 0.6025 * strlen(text) * scale_x);
2063         drawstring(position, text, scale, rgb, alpha, flag);
2064 }
2065
2066 float GetAmmoStat(float i)
2067 {
2068         switch(i)
2069         {
2070                 case 0: return STAT_SHELLS;
2071                 case 1: return STAT_NAILS;
2072                 case 2: return STAT_ROCKETS;
2073                 case 3: return STAT_CELLS;
2074                 case 4: return STAT_FUEL;
2075                 default: return -1;
2076         }
2077 }
2078
2079 float GetAmmoItemCode(float i)
2080 {
2081         switch(i)
2082         {
2083                 case 0: return IT_SHELLS;
2084                 case 1: return IT_NAILS;
2085                 case 2: return IT_ROCKETS;
2086                 case 3: return IT_CELLS;
2087                 case 4: return IT_FUEL;
2088                 default: return -1;
2089         }
2090 }
2091
2092 string GetAmmoPicture(float i)
2093 {
2094         switch(i)
2095         {
2096                 case 0: return "gfx/hud/sb_shells";
2097                 case 1: return "gfx/hud/sb_bullets";
2098                 case 2: return "gfx/hud/sb_rocket";
2099                 case 3: return "gfx/hud/sb_cells";
2100                 case 4: return "gfx/hud/sb_fuel";
2101                 default: return "";
2102         }
2103 }
2104
2105 void Sbar_Draw (void)
2106 {
2107         // vectors for top right, bottom right, bottom and bottom left corners
2108
2109         vector topright;
2110         vector bottom;
2111         vector bottomright;
2112         vector bottomleft;
2113
2114         topright_x = vid_conwidth;
2115         topright_y = 0;
2116         topright_z = 0;
2117
2118         bottom_x = vid_conwidth/2;
2119         bottom_y = vid_conheight;
2120         bottom_z = 0;
2121
2122         bottomright_x = vid_conwidth;
2123         bottomright_y = vid_conheight;
2124         bottomright_z = 0;
2125
2126         bottomleft_x = 0;
2127         bottomleft_y = vid_conheight;
2128         bottomleft_z = 0;
2129
2130         sbar_alpha_bg = cvar("sbar_alpha_bg");
2131         sbar_border_thickness = bound(0, cvar("sbar_border_thickness"), 5);
2132         sbar_color_bg_team = cvar("sbar_color_bg_team");
2133         sbar_scoreboard_alpha_bg = cvar("sbar_scoreboard_alpha_bg");
2134         sbar_scoreboard_highlight = cvar("sbar_scoreboard_highlight");
2135
2136         float i;
2137         float weapon_stats;
2138         float x, fade;
2139         float stat_items, stat_weapons;
2140
2141         weapon_stats = getstati(STAT_DAMAGE_HITS);
2142         weapon_number = weapon_stats & 63;
2143         weapon_hits[weapon_number] = rint(weapon_stats / 64);
2144
2145         weapon_stats = getstati(STAT_DAMAGE_FIRED);
2146         weapon_number = weapon_stats & 63;
2147         weapon_fired[weapon_number] = rint(weapon_stats / 64);
2148
2149         vector o; o = '1 0 0' * vid_conwidth;
2150         o_y = 28; // move spectator text slightly down to prevent overlapping the timer
2151
2152         string s;
2153
2154         sbar_fontsize = Sbar_GetFontsize("sbar_fontsize");
2155
2156         if(spectatee_status && !intermission)
2157         {
2158                 if(spectatee_status == -1)
2159                         s = "^1Observing";
2160                 else
2161                         s = strcat("^1Spectating ^7", GetPlayerName(spectatee_status - 1));
2162                 o = Sbar_DrawNoteLine(o, s);
2163
2164                 if(spectatee_status == -1)
2165                         s = strcat("^1Press ^3", getcommandkey("primary fire", "+attack"), "^1 to spectate");
2166                 else
2167                         s = strcat("^1Press ^3", getcommandkey("primary fire", "+attack"), "^1 for another player");
2168                 o = Sbar_DrawNoteLine(o, s);
2169
2170                 if(spectatee_status == -1)
2171                         s = strcat("^1Use ^3", getcommandkey("next weapon", "weapnext"), "^1 or ^3", getcommandkey("previous weapon", "weapprev"), "^1 to change the speed");
2172                 else
2173                         s = strcat("^1Press ^3", getcommandkey("secondary fire", "+attack2"), "^1 to observe");
2174                 o = Sbar_DrawNoteLine(o, s);
2175
2176                 s = strcat("^1Press ^3", getcommandkey("server info", "+show_info"), "^1 for gamemode info");
2177                 o = Sbar_DrawNoteLine(o, s);
2178
2179                 if(gametype == GAME_ARENA)
2180                         s = "^1Wait for your turn to join";
2181                 else if(gametype == GAME_LMS)
2182                 {
2183                         entity sk;
2184                         sk = playerslots[player_localentnum - 1];
2185                         if(sk.(scores[ps_primary]) >= 666)
2186                                 s = "^1Match has already begun";
2187                         else if(sk.(scores[ps_primary]) > 0)
2188                                 s = "^1You have no more lives left";
2189                         else
2190                                 s = strcat("^1Press ^3", getcommandkey("jump", "+jump"), "^1 to join");
2191                 }
2192                 else
2193                         s = strcat("^1Press ^3", getcommandkey("jump", "+jump"), "^1 to join");
2194                 o = Sbar_DrawNoteLine(o, s);
2195
2196                 //show restart countdown:
2197                 if (time < getstatf(STAT_GAMESTARTTIME)) {
2198                         float countdown;
2199                         //we need to ceil, otherwise the countdown would be off by .5 when using round()
2200                         countdown = ceil(getstatf(STAT_GAMESTARTTIME) - time);
2201                         s = strcat("^1Game starts in ^3", ftos(countdown), "^1 seconds");
2202                         o = Sbar_DrawNoteLine(o, s);
2203                 }
2204         }
2205         if(warmup_stage && !intermission)
2206         {
2207                 s = "^2Currently in ^1warmup^2 stage!";
2208                 o = Sbar_DrawNoteLine(o, s);
2209         }
2210
2211         // move more important stuff more to the middle so its more visible
2212         o_y = vid_conheight * 0.66;
2213
2214         string blinkcolor;
2215         if(mod(time, 1) >= 0.5)
2216                 blinkcolor = "^1";
2217         else
2218                 blinkcolor = "^3";
2219
2220         if(ready_waiting && !intermission)
2221         {
2222                 if(ready_waiting_for_me)
2223                 {
2224                         if(warmup_stage)
2225                                 s = strcat(blinkcolor, "Press ^3", getcommandkey("ready", "ready"), blinkcolor, " to end warmup");
2226                         else
2227                                 s = strcat(blinkcolor, "Press ^3", getcommandkey("ready", "ready"), blinkcolor, " once you are ready");
2228                 }
2229                 else
2230                 {
2231                         if(warmup_stage)
2232                                 s = strcat("^2Waiting for others to ready up to end warmup...");
2233                         else
2234                                 s = strcat("^2Waiting for others to ready up...");
2235                 }
2236                 o = Sbar_DrawNoteLine(o, s);
2237         }
2238         else if(warmup_stage && !intermission)
2239         {
2240                 s = strcat("^2Press ^3", getcommandkey("ready", "ready"), "^2 to end warmup");
2241                 o = Sbar_DrawNoteLine(o, s);
2242         }
2243         if(vote_waiting)
2244         {
2245                 s = strcat("^2A vote has been called for ^1", vote_called_vote);
2246                 o = Sbar_DrawNoteLine(o, s);
2247
2248                 if(vote_waiting_for_me)
2249                 {
2250                         s = strcat(blinkcolor, "Press ^3", getcommandkey("vote yes", "vyes"), blinkcolor, " to accept");
2251                         o = Sbar_DrawNoteLine(o, s);
2252
2253                         s = strcat(blinkcolor, "Press ^3", getcommandkey("vote no", "vno"), blinkcolor, " to reject");
2254                         o = Sbar_DrawNoteLine(o, s);
2255
2256                         s = strcat(blinkcolor, "Press ^3", getcommandkey("vote abstain", "vabstain"), blinkcolor, " to abstain");
2257                         o = Sbar_DrawNoteLine(o, s);
2258                 }
2259                 else
2260                 {
2261                         s = strcat("^2Waiting for others to vote...");
2262                         o = Sbar_DrawNoteLine(o, s);
2263                 }
2264         }
2265         if(teamplay && !intermission && !spectatee_status)
2266         {
2267                 entity tm;
2268                 float ts_min, ts_max;
2269                 tm = teams.sort_next;
2270                 if (tm)
2271                 {
2272                         for(; tm.sort_next; tm = tm.sort_next)
2273                         {
2274                                 if(!tm.team_size || tm.team == COLOR_SPECTATOR)
2275                                         continue;
2276                                 if(!ts_min) ts_min = tm.team_size;
2277                                 else ts_min = min(ts_min, tm.team_size);
2278                                 if(!ts_max) ts_max = tm.team_size;
2279                                 else ts_max = max(ts_max, tm.team_size);
2280                         }
2281                         if ((ts_max - ts_min) > 1)
2282                         {
2283                                 s = strcat(blinkcolor, "Teamnumbers are unbalanced!");
2284                                 tm = GetTeam(myteam, false);
2285                                 if (tm)
2286                                 if (tm.team != COLOR_SPECTATOR)
2287                                 if (tm.team_size == ts_max)
2288                                         s = strcat(s, " Press ^3", getcommandkey("team menu", "menu_showteamselect"), blinkcolor, " to adjust");
2289
2290                                 o = Sbar_DrawNoteLine(o, s);
2291                         }
2292                 }
2293         }
2294
2295         Sbar_UpdatePlayerTeams();
2296
2297         if (intermission == 2) // map voting screen
2298         {
2299                 if(sb_showscores) {
2300                         Sbar_DrawScoreboard();
2301                         Sbar_Score(16);
2302                 }
2303                 else if(sb_showaccuracy) {
2304                         Sbar_DrawAccuracyStats();
2305                         Sbar_Score(16);
2306                 }
2307                 else
2308                         Sbar_FinaleOverlay();
2309         }
2310         else if (sb_showscores_force || getstati(STAT_HEALTH) <= 0 || intermission == 1)
2311         {
2312                 if(sb_showaccuracy)
2313                         Sbar_DrawAccuracyStats();
2314                 else
2315                         Sbar_DrawScoreboard();
2316                 Sbar_Score(16);
2317         }
2318         else
2319         {
2320                 if (sb_showscores)
2321                         Sbar_DrawScoreboard();
2322                 else if(sb_showaccuracy)
2323                         Sbar_DrawAccuracyStats();
2324
2325                 float armor, health;
2326                 armor = getstati(STAT_ARMOR);
2327                 health = getstati(STAT_HEALTH);
2328
2329                 stat_items = getstati(STAT_ITEMS);
2330                 stat_weapons = getstati(STAT_WEAPONS);
2331
2332                 fade = 3.2 - 2 * (time - weapontime);
2333                 fade = bound(0.7, fade, 1);
2334
2335                 vector bg_size; // hud background size
2336                 bg_size_x = 800;
2337                 if (vid_conwidth > 800) // if conwidth > 800, resize the background image
2338                         bg_size_x = vid_conwidth;
2339                 bg_size_y = 58;
2340                 bg_size_z = 0;
2341
2342                 vector bgoffset; // hud background offset
2343                 bgoffset_x = 0;
2344                 bgoffset_y = 0;
2345                 bgoffset_z = 0;
2346                 if (vid_conwidth < 800) // if conwidth < 800 we need to offset the background image to keep it centered, as it will be scaled up
2347                         bgoffset_x = (vid_conwidth - 800) / 2;
2348
2349                 if (cvar("viewsize") <= 100) {
2350                         if (teamplay)
2351                                 drawpic(bottomleft - '0 58 0' + bgoffset, "gfx/hud/sbar", bg_size, GetTeamRGB(myteam) * sbar_color_bg_team, sbar_alpha_bg, DRAWFLAG_NORMAL); // hud color = myteam color
2352                         else {
2353                                 // allow for custom HUD colors in non-teamgames
2354                                 color_x = cvar("sbar_color_bg_r");
2355                                 color_y = cvar("sbar_color_bg_g");
2356                                 color_z = cvar("sbar_color_bg_b");
2357
2358                                 drawpic(bottomleft - '0 58 0' + bgoffset, "gfx/hud/sbar", bg_size, color, sbar_alpha_bg, DRAWFLAG_NORMAL);
2359                         }
2360                 }
2361
2362                 if(sbar_hudselector == 2) // combined health and armor display
2363                 {
2364                         vector v;
2365                         v = healtharmor_maxdamage(health, armor, armorblockpercent);
2366
2367                         vector num_pos;
2368                         num_pos = bottom - element_offset - '0 22 0' + '-96 0 0';
2369
2370                         x = floor(v_x + 1);
2371
2372                         if(v_z) // fully armored
2373                         {
2374                                 // here, armorideal > armor
2375                                 drawpic(num_pos + '78 -4.5 0', "gfx/hud/sb_health", '32 32 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2376                                 drawpic(num_pos + '108 -4.5 0', "gfx/hud/sb_armor", '20 20 0', '1 1 1', sbar_alpha_fg * armor / v_y, DRAWFLAG_NORMAL);
2377                         }
2378                         else
2379                         {
2380                                 drawpic(num_pos + '108 -4.5 0', "gfx/hud/sb_health", '20 20 0', '1 1 1', sbar_alpha_fg * v_y / armor, DRAWFLAG_NORMAL);
2381                                 drawpic(num_pos + '78 -4.5 0', "gfx/hud/sb_armor", '32 32 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2382                         }
2383                         Sbar_DrawXNum_Colored(num_pos, x, 24, sbar_alpha_fg); // draw the combined health and armor
2384                 }
2385
2386                 else
2387                 {
2388                         vector health_pos, armor_pos;
2389
2390                         if (sbar_hudselector == 0) { // old style layout with armor left of health
2391                                 health_pos = bottom - element_offset - '0 22 0' + '14 0 0';
2392                                 armor_pos = bottom - element_offset - '0 22 0' + '-96 0 0';
2393                         }
2394                         else {
2395                                 health_pos = bottom - element_offset - '0 22 0' + '-96 0 0';
2396                                 armor_pos = bottom - element_offset - '0 22 0' + '14 0 0';
2397                         }
2398
2399                         // armor
2400                         x = armor;
2401                         if (x > 0)
2402                         {
2403                                 drawpic(armor_pos + '78 -4.5 0', "gfx/hud/sb_armor", '32 32 0', '1 1 1', (x+10)/55 * sbar_alpha_fg, DRAWFLAG_NORMAL);
2404                                 if (x > 45)
2405                                         Sbar_DrawXNum_Colored(armor_pos, x, 24, sbar_alpha_fg);
2406                                 else
2407                                         Sbar_DrawXNum_Colored(armor_pos, x, 24, (x+10)/55 * sbar_alpha_fg);
2408                         }
2409
2410                         // health
2411                         x = health;
2412                         drawpic(health_pos + '78 -4.5 0', "gfx/hud/sb_health", '32 32 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2413                         Sbar_DrawXNum_Colored(health_pos, x, 24, sbar_alpha_fg);
2414                 }
2415
2416                 // weapon icons
2417                 x = 1.0;
2418                 Sbar_DrawWeapon_Clear();
2419                 for(i = 1; i <= 24; ++i)
2420                 {
2421                         if(weaponimpulse[i-1] >= 0)
2422                         if(stat_weapons & x)
2423                         {
2424                                 Sbar_DrawWeapon(i-1, fade, (i == activeweapon), i);
2425                         }
2426                         x *= 2;
2427                 }
2428
2429                 // ammo
2430                 float a; // i will be the ammo type (already declared), a will contain how much ammo there is of type i
2431                 vector pos;
2432                 pos_z = 0;
2433
2434                 for (i = 0; i < 4; ++i) {
2435                         a = getstati(GetAmmoStat(i)); // how much ammo do we have of type i?
2436
2437                         if(sbar_currentammo)
2438                         {
2439                                 pos = '0 0 0';
2440                                 if (stat_items & GetAmmoItemCode(i))
2441                                 {
2442                                         if(vid_conwidth >= 800) {
2443                                                 pos_x = 170;
2444                                                 pos_y = -40;
2445                                         }
2446                                         else {
2447                                                 pos_x = vid_conwidth - 110;
2448                                                 pos_y = -128;
2449                                         }
2450
2451                                         drawpic(bottomleft + pos + '0 1.5 0', "gfx/hud/sb_ammobg", '107 29 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2452                                         drawpic(bottomleft + pos + '76 3 0', GetAmmoPicture(i), '24 24 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2453                                         if(a < 10)
2454                                                 Sbar_DrawXNum(bottomleft + pos + '5 5 0', a, 3, 24, '0.7 0 0', 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
2455                                         else
2456                                                 Sbar_DrawXNum(bottomleft + pos + '5 5 0', a, 3, 24, '1 1 1', 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
2457                                 }
2458                         }
2459                         else
2460                         {
2461                                 if (a > 0) {
2462                                         pos = '0 0 0';
2463                                         if (vid_conwidth >= 800)
2464                                                 switch (i) {
2465                                                         case 0: pos_x = 114; pos_y = -48; break; // shells
2466                                                         case 1: pos_x = 114; pos_y = -26; break; // bullets
2467                                                         case 2: pos_x = 200; pos_y = -48; break; // rockets
2468                                                         case 3: pos_x = 200; pos_y = -26; break; // cells
2469                                                 }
2470                                         else // if vid_conwidth is lower than 800, ammo will overlap with weapon icons and health so we'll move it to the right
2471                                                 switch (i) {
2472                                                         case 0: pos_x = vid_conwidth - 158; pos_y = -150; break; // shells
2473                                                         case 1: pos_x = vid_conwidth - 158; pos_y = -128; break; // bullets
2474                                                         case 2: pos_x = vid_conwidth - 84; pos_y = -150; break; // rockets
2475                                                         case 3: pos_x = vid_conwidth - 84; pos_y = -128; break; // cells
2476                                                 }
2477
2478                                         if (stat_items & GetAmmoItemCode(i))
2479                                                 drawpic(bottomleft + pos + '0 1.5 0', "gfx/hud/sb_ammobg", '80 22 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2480                                         drawpic(bottomleft + pos + '56 3 0', GetAmmoPicture(i), '18 18 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2481                                         if (a < 10) {
2482                                                 if(stat_items & GetAmmoItemCode(i))
2483                                                         Sbar_DrawXNum(bottomleft + pos + '6 4.5 0', a, 3, 16, '0.7 0 0', 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
2484                                                 else
2485                                                         Sbar_DrawXNum(bottomleft + pos + '6 4.5 0', a, 3, 16, '0.7 0 0', 0, 0, sbar_alpha_fg * 0.7, DRAWFLAG_NORMAL);
2486                                         } else {
2487                                                 if(stat_items & GetAmmoItemCode(i))
2488                                                         Sbar_DrawXNum(bottomleft + pos + '6 4.5 0', a, 3, 16, '1 1 1', 0, 0, sbar_alpha_fg, DRAWFLAG_NORMAL);
2489                                                 else
2490                                                         Sbar_DrawXNum(bottomleft + pos + '6 4.5 0', a, 3, 16, '0.7 0.7 0.7', 0, 0, sbar_alpha_fg * 0.7, DRAWFLAG_NORMAL);
2491                                         }
2492                                 }
2493                         }
2494                 }
2495
2496                 // fuel ammo
2497                 a = getstati(GetAmmoStat(4)); // how much fuel do we have?
2498
2499                 if (a > 0) { // if we have fuel, draw the amount
2500                         float invincibility_time, dt;
2501                         invincibility_time = getstatf(STAT_INVINCIBLE_FINISHED);
2502                         dt = invincibility_time - time;
2503                         if (dt > 0) { // if the invincibility timer is active, draw fuel ammo elsewhere
2504                                 pos_x = bottom_x + 140;
2505                                 pos_y = bottom_y - 72;
2506                         }
2507                         else { // if the invincibility timer is inactive, draw the fuel ammo there (it's rare to have invincibility + fuel anyway)
2508                                 pos_x = bottom_x + 140;
2509                                 pos_y = bottom_y - 22;
2510                         }
2511                         drawpic(pos - '0 2 0' + '52 0 0', GetAmmoPicture(4), '20 20 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
2512                         if (a > 10)
2513                                 Sbar_DrawXNum(pos, a, 3, 16, '1 1 1', 0, 0, 1, DRAWFLAG_NORMAL);
2514                         else
2515                                 Sbar_DrawXNum(pos, a, 3, 16, '0.7 0 0', 0, 0, 1, DRAWFLAG_NORMAL);
2516                 }
2517
2518                 // draw scores and timer
2519                 Sbar_Score(16);
2520
2521                 //show strength/invincibility ICON and timer:
2522                 CSQC_Strength_Timer();
2523
2524                 if(gametype == GAME_KEYHUNT)
2525                 {
2526                         CSQC_kh_hud();
2527                 } else if(gametype == GAME_CTF)
2528                 {
2529                         CSQC_ctf_hud();
2530                 } else if(gametype == GAME_NEXBALL)
2531                 {
2532                         CSQC_nb_hud();
2533                 }
2534         }
2535 }
2536
2537 // CTF HUD
2538 void CSQC_ctf_hud(void)
2539 {
2540         vector bottomleft, redflag_pos, blueflag_pos;
2541         bottomleft_x = 0;
2542         bottomleft_y = vid_conheight;
2543         bottomleft_z = 0;
2544
2545         float redflag, blueflag;
2546         float stat_items;
2547
2548         stat_items = getstati(STAT_ITEMS);
2549         redflag = (stat_items/IT_RED_FLAG_TAKEN) & 3;
2550         blueflag = (stat_items/IT_BLUE_FLAG_TAKEN) & 3;
2551
2552         if (myteam == COLOR_TEAM1) { // always draw own flag on left
2553                 redflag_pos = bottomleft - element_offset - '-4 36 0';
2554                 blueflag_pos = bottomleft - element_offset - '-68 36 0';
2555         }
2556
2557         else {
2558                 blueflag_pos = bottomleft - element_offset - '-4 36 0';
2559                 redflag_pos = bottomleft - element_offset - '-68 36 0';
2560         }
2561
2562         switch(redflag)
2563         {
2564         case 1: drawpic(redflag_pos, "gfx/hud/sb_flag_red_taken", '48 48 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL); break;
2565         case 2: drawpic(redflag_pos, "gfx/hud/sb_flag_red_lost", '48 48 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL); break;
2566         case 3: drawpic(redflag_pos, "gfx/hud/sb_flag_red_carrying", '48 48 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL); break;
2567         default:
2568                 if(stat_items & IT_CTF_SHIELDED)
2569                         if(myteam == COLOR_TEAM2)
2570                                 drawpic(redflag_pos, "gfx/hud/sb_flag_red_shielded", '48 48 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL); break;
2571         }
2572
2573         switch(blueflag)
2574         {
2575         case 1: drawpic(blueflag_pos, "gfx/hud/sb_flag_blue_taken", '48 48 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL); break;
2576         case 2: drawpic(blueflag_pos, "gfx/hud/sb_flag_blue_lost", '48 48 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL); break;
2577         case 3: drawpic(blueflag_pos, "gfx/hud/sb_flag_blue_carrying", '48 48 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL); break;
2578         default:
2579                 if(stat_items & IT_CTF_SHIELDED)
2580                         if(myteam == COLOR_TEAM1)
2581                                 drawpic(blueflag_pos, "gfx/hud/sb_flag_blue_shielded", '48 48 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL); break;
2582         }
2583 }
2584
2585 // Keyhunt HUD
2586 void CSQC_kh_hud(void)
2587 {
2588         float kh_keys, kh_keys_status, kh_teams_set;
2589         vector red_pos, blue_pos, yellow_pos, pink_pos, kh_size;
2590
2591         vector bottomleft;
2592         bottomleft_x = 0;
2593         bottomleft_y = vid_conheight;
2594         bottomleft_z = 0;
2595
2596         red_pos_x = 6;
2597         red_pos_y = vid_conheight - 35 - 6;
2598         red_pos_z = 0;
2599
2600         blue_pos_x = 6 + (24 * 1);
2601         blue_pos_y = vid_conheight - 35 - 6;
2602         blue_pos_z = 0;
2603
2604         yellow_pos_x = 6 + (24 * 2);
2605         yellow_pos_y = vid_conheight - 35 - 6;
2606         yellow_pos_z = 0;
2607
2608         pink_pos_x = 6 + (24 * 3);
2609         pink_pos_y = vid_conheight - 35 - 6;
2610         pink_pos_z = 0;
2611
2612         kh_keys = getstati(STAT_KH_KEYS);
2613         kh_keys_status = kh_keys / 256;
2614         kh_teams_set = cvar("_teams_available");  // set in keyhunt.qc
2615
2616         kh_size = '22 35 0';
2617
2618         if (kh_keys_status & 1)  // red
2619                 drawpic (red_pos, "gfx/hud/sb_kh_red", kh_size, '1 1 1', 0.3, DRAWFLAG_NORMAL);  // show 30% alpha key
2620         if (kh_keys & 1)
2621                 drawpic (red_pos, "gfx/hud/sb_kh_red", kh_size, '1 1 1', 1.0, DRAWFLAG_NORMAL);  // show solid key 100% alpha
2622
2623         if (kh_keys_status & 2)  // blue
2624                 drawpic (blue_pos, "gfx/hud/sb_kh_blue", kh_size, '1 1 1', 0.3, DRAWFLAG_NORMAL);
2625         if (kh_keys & 2)
2626                 drawpic (blue_pos, "gfx/hud/sb_kh_blue", kh_size, '1 1 1', 1.0, DRAWFLAG_NORMAL);
2627
2628         if (kh_teams_set & 4)  // yellow
2629         {
2630                 if (kh_keys_status & 4)
2631                         drawpic (yellow_pos, "gfx/hud/sb_kh_yellow", kh_size, '1 1 1', 0.3, DRAWFLAG_NORMAL);
2632                 if (kh_keys & 4)
2633                         drawpic (yellow_pos, "gfx/hud/sb_kh_yellow", kh_size, '1 1 1', 1.0, DRAWFLAG_NORMAL);
2634         }
2635
2636         if (kh_teams_set & 8)  // pink
2637         {
2638                 if (kh_keys_status & 8)
2639                         drawpic (pink_pos, "gfx/hud/sb_kh_pink", kh_size, '1 1 1', 0.3, DRAWFLAG_NORMAL);
2640                 if (kh_keys & 8)
2641                         drawpic (pink_pos, "gfx/hud/sb_kh_pink", kh_size, '1 1 1', 1.0, DRAWFLAG_NORMAL);
2642         }
2643 }
2644
2645 //Nexball HUD
2646 #define NBPB_SIZE '96 38 0'
2647 #define NBPB_BT 2                   //thickness
2648 #define NBPB_BRGB '1 1 1'
2649 #define NBPB_BALPH 1                //alpha
2650 #define NBPB_BFLAG DRAWFLAG_NORMAL
2651 #define NBPB_IALPH 0.4
2652 #define NBPB_IFLAG DRAWFLAG_NORMAL
2653 #define NBPB_IRGB '0.7 0.1 0'
2654
2655 void CSQC_nb_hud(void)
2656 {
2657         float stat_items, nb_pb_starttime, dt, p;
2658         vector pos;
2659
2660         stat_items = getstati(STAT_ITEMS);
2661         nb_pb_starttime = getstatf(STAT_NB_METERSTART);
2662
2663         pos_x = 4;
2664         pos_y = vid_conheight - 42;
2665         pos_z = 0;
2666
2667         //Manage the progress bar if any
2668         if (nb_pb_starttime > 0)
2669         {
2670                 vector s;
2671                 dt = mod(time - nb_pb_starttime, nb_pb_period);
2672                 // one period of positive triangle
2673                 p = 2 * dt / nb_pb_period;
2674                 if (p > 1)
2675                         p = 2 - p;
2676
2677                 s = NBPB_SIZE;
2678                 //Draw the filling
2679                 drawfill(pos, p * s_x * '1 0 0' + s_y * '0 1 0', NBPB_IRGB, NBPB_IALPH, NBPB_IFLAG);
2680
2681                 //Draw the box
2682                 s = NBPB_SIZE;
2683                 drawline(NBPB_BT, pos    , pos + '1 0 0' * s_x, NBPB_BRGB, NBPB_BALPH, NBPB_BFLAG);
2684                 drawline(NBPB_BT, pos    , pos + '0 1 0' * s_y, NBPB_BRGB, NBPB_BALPH, NBPB_BFLAG);
2685                 drawline(NBPB_BT, pos + s, pos + '1 0 0' * s_x, NBPB_BRGB, NBPB_BALPH, NBPB_BFLAG);
2686                 drawline(NBPB_BT, pos + s, pos + '0 1 0' * s_y, NBPB_BRGB, NBPB_BALPH, NBPB_BFLAG);
2687         }
2688
2689         pos_x += 12; //horizontal margin to the picture
2690         pos_y += 2; //vertical margin to the picture
2691
2692         if (stat_items & IT_KEY1)
2693                 drawpic(pos, "gfx/hud/sb_nexball_carrying", '80 34 0', '1 1 1', 1, DRAWFLAG_NORMAL);
2694 }