data/qcsrc/client/sbar.qc

   1
   2 float last_weapon;
   3 float activeweapon;
   4 float weapontime;
   5
   6 float sb_lines; // still don't know what to do with that NOTE: check dp's sbar.c to see what that should be
   7
   8 vector sbar;
   9 float sbar_alpha_fg;
  10 float sbar_hudselector;
  11
  12 float ps_primary, ps_secondary;
  13 float ts_primary, ts_secondary;
  14
  15 void CSQC_kh_hud();
  16 void CSQC_ctf_hud();
  17 void MapVote_Draw();
  18 void Sbar_FinaleOverlay()
  19 {
  20         /*vector pos;
  21         pos_x = (vid_conwidth - 1)/2;
  22         pos_y = 16;
  23         pos_z = 0;*/
  24
  25         //drawpic(pos, "gfx/finale", '0 0 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
  26
  27         //drawstring(pos, "END", sbar_fontsize, '1 1 1', 1, DRAWFLAG_NORMAL);
  28         MapVote_Draw();
  29 }
  30
  31 void Sbar_DrawWeapon(float nr, float fade, float active)
  32 {
  33         vector pos, vsize, color;
  34         float value;
  35
  36         value = (active) ? 1 : 0.6;
  37         color_x = color_y = color_z = value;
  38
  39         if(sbar_hudselector == 1)
  40         {
  41                 // width = 300, height = 100
  42                 const float w_width = 32, w_height = 12, w_space = 2, font_size = 8;
  43
  44                 pos_x = (vid_conwidth - w_width * 9) * 0.5 + w_width * nr;
  45                 pos_y = (vid_conheight - w_height);
  46                 pos_z = 0;
  47                 vsize_x = w_width;
  48                 vsize_y = w_height;
  49                 vsize_z = 0;
  50                 drawpic(pos, strcat("gfx/inv_weapon", ftos(nr)), vsize, color, value * fade * sbar_alpha_fg, 0);
  51                 pos_x += w_space;
  52                 pos_y += w_space;
  53                 vsize_x = font_size;
  54                 vsize_y = font_size;
  55                 vsize_z = 0;
  56                 drawstring(pos, ftos(nr+1), vsize, '1 1 0', sbar_alpha_fg, 0);
  57
  58         }
  59         else
  60         {
  61                 // width = 300, height = 100
  62                 const float w2_width = 300, w2_height = 100, w2_space = 10;
  63                 const float w2_scale = 0.4;
  64
  65                 pos_x = vid_conwidth - (w2_width + w2_space) * w2_scale;
  66                 pos_y = (w2_height + w2_space) * w2_scale * nr + w2_space;
  67                 pos_z = 0;
  68                 vsize_x = w2_width * w2_scale;
  69                 vsize_y = w2_height * w2_scale;
  70                 vsize_z = 0;
  71
  72                 drawpic(pos, strcat("gfx/inv_weapon", ftos(nr)), vsize, color, value * fade * sbar_alpha_fg, 0);
  73         }
  74 }
  75 void Sbar_DrawXNum (vector pos, float num, float digits, float lettersize, vector rgb, float a, float dflags)
  76 {
  77         float l, i;
  78         string str, tmp;
  79         float minus;
  80         vector vsize;
  81
  82         vsize_x = vsize_y = lettersize;
  83         vsize_z = 0;
  84
  85         if(num < 0)
  86         {
  87                 minus = true;
  88                 num = -num;
  89                 pos_x -= lettersize;
  90         } else
  91                 minus = false;
  92
  93         if(digits < 0)
  94         {
  95                 tmp = ftos(num);
  96                 digits = -digits;
  97                 str = strcat(substring("0000000000", 0, digits - strlen(tmp)), tmp);
  98         } else
  99                 str = ftos(num);
 100
 101         l = strlen(str);
 102
 103         if(l > digits)
 104         {
 105                 str = substring(str, l-digits, 999);
 106                 l = strlen(str);
 107         } else if(l < digits)
 108                 pos_x += (digits-l) * lettersize;
 109
 110         if(minus)
 111         {
 112                 drawpic(sbar + pos, "gfx/num_minus", vsize, rgb, a * sbar_alpha_fg, dflags);
 113                 pos_x += lettersize;
 114         }
 115
 116         for(i = 0; i < l; ++i)
 117         {
 118                 drawpic(sbar + pos, strcat("gfx/num_", substring(str, i, 1)), vsize, rgb, a * sbar_alpha_fg, dflags);
 119                 pos_x += lettersize;
 120         }
 121 }
 122
 123 void Cmd_Sbar_SetFields(float argc);
 124 void Sbar_InitScores()
 125 {
 126         float i, f;
 127
 128         ps_primary = ps_secondary = ts_primary = ts_secondary = -1;
 129         for(i = 0; i < MAX_SCORE; ++i)
 130         {
 131                 f = (scores_flags[i] & SFL_SORT_PRIO_MASK);
 132                 if(f == SFL_SORT_PRIO_PRIMARY)
 133                         ps_primary = i;
 134                 if(f == SFL_SORT_PRIO_SECONDARY)
 135                         ps_secondary = i;
 136         }
 137         if(ps_secondary == -1)
 138                 ps_secondary = ps_primary;
 139
 140         for(i = 0; i < MAX_TEAMSCORE; ++i)
 141         {
 142                 f = (teamscores_flags[i] & SFL_SORT_PRIO_MASK);
 143                 if(f == SFL_SORT_PRIO_PRIMARY)
 144                         ts_primary = i;
 145                 if(f == SFL_SORT_PRIO_SECONDARY)
 146                         ts_secondary = i;
 147         }
 148         if(ts_secondary == -1)
 149                 ts_secondary = ts_primary;
 150
 151         Cmd_Sbar_SetFields(0);
 152 }
 153
 154 void Sbar_UpdatePlayerPos(entity pl);
 155 float SetTeam(entity pl, float Team);
 156 //float lastpnum;
 157 void Sbar_UpdatePlayerTeams()
 158 {
 159         float Team;
 160         entity pl, tmp;
 161         float num;
 162
 163         num = 0;
 164         for(pl = players.sort_next; pl; pl = pl.sort_next)
 165         {
 166                 num += 1;
 167                 Team = GetPlayerColor(pl.sv_entnum);
 168                 if(SetTeam(pl, Team))
 169                 {
 170                         tmp = pl.sort_prev;
 171                         Sbar_UpdatePlayerPos(pl);
 172                         if(tmp)
 173                                 pl = tmp;
 174                         else
 175                                 pl = players.sort_next;
 176                 }
 177         }
 178         /*
 179         if(num != lastpnum)
 180                 print(strcat("PNUM: ", ftos(num), "\n"));
 181         lastpnum = num;
 182         */
 183 }
 184
 185 float Sbar_ComparePlayerScores(entity left, entity right)
 186 {
 187         float vl, vr;
 188         vl = GetPlayerColor(left.sv_entnum);
 189         vr = GetPlayerColor(right.sv_entnum);
 190
 191         if(vl > vr)
 192                 return true;
 193         if(vl < vr)
 194                 return false;
 195
 196         if(vl == COLOR_SPECTATOR)
 197         {
 198                 // FIRST the one with scores (spectators), THEN the ones without (downloaders)
 199                 // no other sorting
 200                 if(!left.gotscores && right.gotscores)
 201                         return true;
 202                 return false;
 203         }
 204
 205         vl = left.scores[ps_primary];
 206         vr = right.scores[ps_primary];
 207         if(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)
 208         {
 209                 if(vl == 0 && vr != 0)
 210                         return 1;
 211                 if(vl != 0 && vr == 0)
 212                         return 0;
 213         }
 214         if(vl > vr)
 215                 return IS_INCREASING(scores_flags[ps_primary]);
 216         if(vl < vr)
 217                 return IS_DECREASING(scores_flags[ps_primary]);
 218
 219         vl = left.scores[ps_secondary];
 220         vr = right.scores[ps_secondary];
 221         if(scores_flags[ps_secondary] & SFL_ZERO_IS_WORST)
 222         {
 223                 if(vl == 0 && vr != 0)
 224                         return 1;
 225                 if(vl != 0 && vr == 0)
 226                         return 0;
 227         }
 228         if(vl > vr)
 229                 return IS_INCREASING(scores_flags[ps_secondary]);
 230         if(vl < vr)
 231                 return IS_DECREASING(scores_flags[ps_secondary]);
 232
 233         return false;
 234 }
 235
 236 void Sbar_UpdatePlayerPos(entity player)
 237 {
 238         for(other = player.sort_next; other && Sbar_ComparePlayerScores(player, other); other = player.sort_next)
 239         {
 240                 SORT_SWAP(player, other);
 241         }
 242         for(other = player.sort_prev; other != players && Sbar_ComparePlayerScores(other, player); other = player.sort_prev)
 243         {
 244                 SORT_SWAP(other, player);
 245         }
 246 }
 247
 248 float Sbar_CompareTeamScores(entity left, entity right)
 249 {
 250         float vl, vr;
 251
 252         if(left.team == COLOR_SPECTATOR)
 253                 return 1;
 254         if(right.team == COLOR_SPECTATOR)
 255                 return 0;
 256
 257         vl = left.teamscores[ts_primary];
 258         vr = right.teamscores[ts_primary];
 259         if(vl > vr)
 260                 return IS_INCREASING(teamscores_flags[ts_primary]);
 261         if(vl < vr)
 262                 return IS_DECREASING(teamscores_flags[ts_primary]);
 263
 264         vl = left.teamscores[ts_secondary];
 265         vr = right.teamscores[ts_secondary];
 266         if(vl > vr)
 267                 return IS_INCREASING(teamscores_flags[ts_secondary]);
 268         if(vl < vr)
 269                 return IS_DECREASING(teamscores_flags[ts_secondary]);
 270
 271         return false;
 272 }
 273
 274 void Sbar_UpdateTeamPos(entity Team)
 275 {
 276         for(other = Team.sort_next; other && Sbar_CompareTeamScores(Team, other); other = Team.sort_next)
 277         {
 278                 SORT_SWAP(Team, other);
 279         }
 280         for(other = Team.sort_prev; other != teams && Sbar_CompareTeamScores(other, Team); other = Team.sort_prev)
 281         {
 282                 SORT_SWAP(other, Team);
 283         }
 284 }
 285
 286 void Cmd_Sbar_Help(float argc)
 287 {
 288         print("You can modify the scoreboard using the\n");
 289         print("^3|---------------------------------------------------------------|\n");
 290         print("^1 TO BE DONE\n");
 291         print("Usage:\n");
 292         print("^2sbar_columns_set default\n");
 293         print("^2sbar_columns_set ^7filed1 field2 ...\n");
 294         print("The following field names are recognized (case INsensitive):\n");
 295         print("You can use a ^3|^7 to start the right-aligned fields.\n");
 296
 297         print("^3name^7 or ^3nick^7             Name of a player\n");
 298         print("^3ping^7                     Ping time\n\n");
 299         print("^3kd^7 or ^3kdr^7 or ^3kdratio^7 or ^3k/d\n");
 300         print("                         The kill-death ratio\n");
 301
 302         print("Before a field you can put a + or - sign, then a comma separated list\n");
 303         print("of game types, then a slash, to make the field show up only in these\n");
 304         print("or in all but these game types.\n");
 305
 306         local float i;
 307         print("Additional columns:\n");
 308         for(i = 0; i < MAX_SCORE; ++i)
 309         {
 310                 if(scores_label[i] != "")
 311                         print(strcat(scores_label[i], "\n"));
 312         }
 313 }
 314
 315 #define MIN_NAMELEN 24
 316 #define MAX_NAMELEN 24
 317
 318 string Sbar_DefaultColumnLayout()
 319 {
 320         return "ping pl name | -ctf,kh/kills -ctf,kh/deaths +lms/lives +lms/rank +kh,ctf/caps +kh/pushes +kh/destroyed -lms/score";
 321 }
 322
 323 void Cmd_Sbar_SetFields(float argc)
 324 {
 325         float i, j, slash;
 326         string str, pattern, subpattern;
 327         float digit;
 328         float have_name, have_primary, have_secondary, have_separator;
 329         float missing;
 330
 331         // TODO: re enable with gametype dependant cvars?
 332         if(argc < 2) // no arguments provided
 333                 argc = tokenizebyseparator(strcat("x ", cvar_string("sbar_columns")), " ");
 334
 335         if(argc < 2)
 336                 argc = tokenizebyseparator(strcat("x ", Sbar_DefaultColumnLayout()), " ");
 337
 338         if(argc == 2)
 339         {
 340                 if(argv(1) == "default")
 341                         argc = tokenizebyseparator(strcat("x ", Sbar_DefaultColumnLayout()), " ");
 342                 else if(argv(1) == "all")
 343                 {
 344                         string s;
 345                         s = "ping name |";
 346                         for(i = 0; i < MAX_SCORE; ++i)
 347                         {
 348                                 if(i != ps_primary)
 349                                 if(i != ps_secondary)
 350                                 if(scores_label[i] != "")
 351                                         s = strcat(s, " ", scores_label[i]);
 352                         }
 353                         if(ps_secondary != ps_primary)
 354                                 s = strcat(s, " ", scores_label[ps_secondary]);
 355                         s = strcat(s, " ", scores_label[ps_primary]);
 356                         argc = tokenizebyseparator(strcat("x ", s), " ");
 357                 }
 358         }
 359
 360
 361         argc = min(MAX_SBAR_FIELDS, argc);
 362         sbar_num_fields = 0;
 363
 364         drawfont = sbar_font;
 365         digit = stringwidth("0123456789", FALSE) / 10;
 366
 367         subpattern = strcat(",", GametypeNameFromType(gametype), ",");
 368
 369         argc = min(argc-1, MAX_SBAR_FIELDS-1);
 370         for(i = 0; i < argc; ++i)
 371         {
 372                 str = argv(i+1);
 373
 374                 slash = strstrofs(str, "/", 0);
 375                 if(slash >= 0)
 376                 {
 377                         pattern = substring(str, 0, slash);
 378                         str = substring(str, slash + 1, strlen(str) - (slash + 1));
 379
 380                         if(substring(pattern, 0, 1) == "-")
 381                         {
 382                                 pattern = substring(pattern, 1, strlen(pattern) - 1);
 383                                 if(strstrofs(strcat(",", pattern, ","), subpattern, 0) >= 0)
 384                                         continue;
 385                         }
 386                         else
 387                         {
 388                                 if(substring(pattern, 0, 1) == "+")
 389                                         pattern = substring(pattern, 1, strlen(pattern) - 1);
 390                                 if(strstrofs(strcat(",", pattern, ","), subpattern, 0) < 0)
 391                                         continue;
 392                         }
 393                 }
 394
 395                 strunzone(sbar_title[sbar_num_fields]);
 396                 sbar_title[sbar_num_fields] = strzone(str);
 397                 sbar_size[sbar_num_fields] = stringwidth(str, FALSE);
 398                 str = strtolower(str);
 399
 400                 if(str == "ping") {
 401                         sbar_field[sbar_num_fields] = SP_PING;
 402                 } else if(str == "pl") {
 403                         sbar_field[sbar_num_fields] = SP_PL;
 404                 } else if(str == "kd" || str == "kdr" || str == "kdratio" || str == "k/d") {
 405                         sbar_field[sbar_num_fields] = SP_KDRATIO;
 406                 } else if(str == "name" || str == "nick") {
 407                         sbar_field[sbar_num_fields] = SP_NAME;
 408                         sbar_size[sbar_num_fields] = MIN_NAMELEN; // minimum size? any use?
 409                         have_name = 1;
 410                 } else if(str == "|") {
 411                         sbar_field[sbar_num_fields] = SP_SEPARATOR;
 412                         have_separator = 1;
 413                 } else {
 414                         for(j = 0; j < MAX_SCORE; ++j)
 415                                 if(str == strtolower(scores_label[j]))
 416                                         goto found; // sorry, but otherwise fteqcc -O3 miscompiles this and warns about "unreachable code"
 417 :notfound
 418                         print(strcat("^1Error:^7 Unknown score field: '", str, "'\n"));
 419                         continue;
 420 :found
 421                         sbar_field[sbar_num_fields] = j;
 422                         if(j == ps_primary)
 423                                 have_primary = 1;
 424                         if(j == ps_secondary)
 425                                 have_secondary = 1;
 426                 }
 427                 ++sbar_num_fields;
 428         }
 429
 430         if(scores_flags[ps_primary] & SFL_ALLOW_HIDE)
 431                 have_primary = 1;
 432         if(scores_flags[ps_secondary] & SFL_ALLOW_HIDE)
 433                 have_secondary = 1;
 434         if(ps_primary == ps_secondary)
 435                 have_secondary = 1;
 436         missing = !have_primary + !have_secondary + !have_separator + !have_name;
 437
 438         if(sbar_num_fields+missing < MAX_SBAR_FIELDS)
 439         {
 440                 if(!have_name)
 441                 {
 442                         strunzone(sbar_title[sbar_num_fields]);
 443                         for(i = sbar_num_fields; i > 0; --i)
 444                         {
 445                                 sbar_title[i] = sbar_title[i-1];
 446                                 sbar_size[i] = sbar_size[i-1];
 447                                 sbar_field[i] = sbar_field[i-1];
 448                         }
 449                         sbar_title[0] = strzone("name");
 450                         sbar_field[0] = SP_NAME;
 451                         sbar_size[0] = MIN_NAMELEN; // minimum size? any use?
 452                         ++sbar_num_fields;
 453                         print("fixed missing field 'name'\n");
 454
 455                         if(!have_separator)
 456                         {
 457                                 strunzone(sbar_title[sbar_num_fields]);
 458                                 for(i = sbar_num_fields; i > 1; --i)
 459                                 {
 460                                         sbar_title[i] = sbar_title[i-1];
 461                                         sbar_size[i] = sbar_size[i-1];
 462                                         sbar_field[i] = sbar_field[i-1];
 463                                 }
 464                                 sbar_title[1] = strzone("|");
 465                                 sbar_field[1] = SP_SEPARATOR;
 466                                 sbar_size[1] = stringwidth("|", FALSE);
 467                                 ++sbar_num_fields;
 468                                 print("fixed missing field '|'\n");
 469                         }
 470                 }
 471                 else if(!have_separator)
 472                 {
 473                         strunzone(sbar_title[sbar_num_fields]);
 474                         sbar_title[sbar_num_fields] = strzone("|");
 475                         sbar_size[sbar_num_fields] = stringwidth("|", FALSE);
 476                         sbar_field[sbar_num_fields] = SP_SEPARATOR;
 477                         ++sbar_num_fields;
 478                         print("fixed missing field '|'\n");
 479                 }
 480
 481                 if(!have_secondary)
 482                 {
 483                         strunzone(sbar_title[sbar_num_fields]);
 484                         sbar_title[sbar_num_fields] = strzone(scores_label[ps_secondary]);
 485                         sbar_size[sbar_num_fields] = stringwidth(sbar_title[sbar_num_fields], FALSE);
 486                         sbar_field[sbar_num_fields] = ps_secondary;
 487                         ++sbar_num_fields;
 488                         print("fixed missing field '", scores_label[ps_secondary], "'\n");
 489                 }
 490
 491                 if(!have_primary)
 492                 {
 493                         strunzone(sbar_title[sbar_num_fields]);
 494                         sbar_title[sbar_num_fields] = strzone(scores_label[ps_primary]);
 495                         sbar_size[sbar_num_fields] = stringwidth(sbar_title[sbar_num_fields], FALSE);
 496                         sbar_field[sbar_num_fields] = ps_primary;
 497                         ++sbar_num_fields;
 498                         print("fixed missing field '", scores_label[ps_primary], "'\n");
 499                 }
 500         }
 501
 502         sbar_field[sbar_num_fields] = SP_END;
 503 }
 504
 505 // MOVEUP::
 506 vector sbar_field_rgb;
 507 string Sbar_GetField(entity pl, float field)
 508 {
 509         float tmp, num, denom, f;
 510         string str;
 511         sbar_field_rgb = '1 1 1';
 512         switch(field)
 513         {
 514                 case SP_PING:
 515                         if not(pl.gotscores)
 516                                 return "\x8D\x8D\x8D"; // >>> sign
 517                         str = getplayerkey(pl.sv_entnum, "ping");
 518                         if(str == "0")
 519                                 return "N/A";
 520                         tmp = max(0, min(220, stof(str)-80)) / 220;
 521                         sbar_field_rgb = '1 1 1' - '0 1 1'*tmp;
 522                         return str;
 523
 524                 case SP_PL:
 525                         if not(pl.gotscores)
 526                                 return "N/A";
 527                         str = getplayerkey(pl.sv_entnum, "pl");
 528                         if(str == "0")
 529                                 return "";
 530                         tmp = bound(0, stof(str), 20) / 20; // 20% is REALLY BAD pl
 531                         sbar_field_rgb = '1 0.5 0.5' - '0 0.5 0.5'*tmp;
 532                         return str;
 533
 534                 case SP_NAME:
 535                         return getplayerkey(pl.sv_entnum, "name");
 536
 537                 case SP_KDRATIO:
 538                         num = pl.(scores[SP_KILLS]);
 539                         denom = pl.(scores[SP_DEATHS]);
 540
 541                         if(denom == 0) {
 542                                 sbar_field_rgb = '0 1 0';
 543                                 str = ftos(num);
 544                         } else if(num <= 0) {
 545                                 sbar_field_rgb = '1 0 0';
 546                                 str = ftos(num/denom);
 547                         } else
 548                                 str = ftos(num/denom);
 549
 550                         tmp = strstrofs(str, ".", 0);
 551                         if(tmp > 0)
 552                                 str = substring(str, 0, tmp+2);
 553                         return str;
 554
 555                 default:
 556                         tmp = pl.(scores[field]);
 557                         f = scores_flags[field];
 558                         if(field == ps_primary)
 559                                 sbar_field_rgb = '1 1 0';
 560                         else if(field == ps_secondary)
 561                                 sbar_field_rgb = '0 1 1';
 562                         else
 563                                 sbar_field_rgb = '1 1 1';
 564                         return ScoreString(f, tmp);
 565         }
 566         //return "error";
 567 }
 568
 569 // shamelessly stolen from menu QC :P <- as if I would steal YOUR code pfft ;)
 570 float textLengthUpToWidth(string theText, float maxWidth, float handleColors)
 571 {
 572         // STOP.
 573         // The following function is SLOW.
 574         // For your safety and for the protection of those around you...
 575         // DO NOT CALL THIS AT HOME.
 576         // No really, don't.
 577         if(stringwidth(theText, handleColors) <= maxWidth)
 578                 return strlen(theText); // yeah!
 579
 580         // binary search for right place to cut string
 581         float left, right, middle; // this always works
 582         left = 0;
 583         right = strlen(theText); // this always fails
 584         do
 585         {
 586                 middle = floor((left + right) / 2);
 587                 if(stringwidth(substring(theText, 0, middle), handleColors) <= maxWidth)
 588                         left = middle;
 589                 else
 590                         right = middle;
 591         }
 592         while(left < right - 1);
 593
 594         // NOTE: when color codes are involved, this binary search is,
 595         // mathematically, BROKEN. However, it is obviously guaranteed to
 596         // terminate, as the range still halves each time - but nevertheless, it is
 597         // guaranteed that it finds ONE valid cutoff place (where "left" is in
 598         // range, and "right" is outside).
 599
 600         return left;
 601 }
 602 string textShortenToWidth(string theText, float maxWidth, float handleColors)
 603 {
 604         if(stringwidth(theText, handleColors) <= maxWidth)
 605                 return theText;
 606         else
 607                 return strcat(substring(theText, 0, textLengthUpToWidth(theText, maxWidth - stringwidth("...", handleColors), handleColors)), "...");
 608 }
 609
 610 float xmin, xmax, ymin, ymax, sbwidth, sbheight;
 611
 612 void Sbar_PrintScoreboardItem(vector pos, entity pl, float is_self)
 613 {
 614         vector tmp;
 615         string str;
 616         float i, field, len;
 617         float is_spec;
 618         is_spec = (GetPlayerColor(pl.sv_entnum) == COLOR_SPECTATOR);
 619
 620         // Layout:
 621         tmp_z = 0;
 622         if(is_self)
 623         {
 624                 tmp_x = sbwidth;
 625                 tmp_y = sbar_fontsize_y;
 626                 drawfill(pos - '1 1 0', tmp + '2 2 0', '1 1 1', 0.3, DRAWFLAG_NORMAL);
 627         }
 628         tmp_y = 0;
 629
 630         for(i = 0; i < sbar_num_fields; ++i)
 631         {
 632                 field = sbar_field[i];
 633                 if(field == SP_SEPARATOR)
 634                         break;
 635
 636                 if(is_spec && field != SP_NAME && field != SP_PING) {
 637                         pos_x += sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 638                         continue;
 639                 }
 640                 str = Sbar_GetField(pl, field);
 641
 642                 if(field == SP_NAME)
 643                 {
 644                         float realsize;
 645                         float j;
 646                         realsize = sbar_size[i];
 647                         if(i+1 < sbar_num_fields)
 648                                 if(sbar_field[i+1] == SP_SEPARATOR)
 649                                 {
 650                                         realsize = (xmax - xmin) / sbar_fontsize_x;
 651                                         for(j = 0; j < sbar_num_fields; ++j) if(j != i) if(sbar_field[j] != SP_SEPARATOR)
 652                                                 realsize -= sbar_size[j] + 1;
 653                                         realsize += 1;
 654                                 }
 655                         str = textShortenToWidth(str, realsize, TRUE);
 656                 }
 657                 len = stringwidth(str, TRUE);
 658
 659                 if(sbar_size[i] < len)
 660                         sbar_size[i] = len;
 661
 662                 pos_x += sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 663
 664                 if(field == SP_NAME) {
 665                         tmp_x = sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 666                         drawcolorcodedstring(pos - tmp, str, sbar_fontsize, 1, DRAWFLAG_NORMAL);
 667                 } else {
 668                         tmp_x = len*sbar_fontsize_x + sbar_fontsize_x;
 669                         drawstring(pos - tmp, str, sbar_fontsize, sbar_field_rgb, 1, DRAWFLAG_NORMAL);
 670                 }
 671         }
 672
 673         if(sbar_field[i] == SP_SEPARATOR)
 674         {
 675                 pos_x = xmax;
 676                 for(i = sbar_num_fields-1; i > 0; --i)
 677                 {
 678                         field = sbar_field[i];
 679                         if(field == SP_SEPARATOR)
 680                                 break;
 681
 682                         if(is_spec && field != SP_NAME && field != SP_PING) {
 683                                 pos_x -= sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 684                                 continue;
 685                         }
 686
 687                         str = Sbar_GetField(pl, field);
 688
 689                         if(field == SP_NAME)
 690                                 str = textShortenToWidth(str, sbar_size[i], TRUE);
 691                         len = stringwidth(str, TRUE);
 692
 693                         if(sbar_size[i] < len)
 694                                 sbar_size[i] = len;
 695
 696                         if(field == SP_NAME) {
 697                                 tmp_x = sbar_fontsize_x*len; // left or right aligned? let's put it right...
 698                                 drawcolorcodedstring(pos - tmp, str, sbar_fontsize, 1, DRAWFLAG_NORMAL);
 699                         } else {
 700                                 tmp_x = sbar_fontsize_x*len; //strlen(str);
 701                                 drawstring(pos - tmp, str, sbar_fontsize, sbar_field_rgb, 1, DRAWFLAG_NORMAL);
 702                         }
 703                         pos_x -= sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 704                 }
 705         }
 706 }
 707
 708 float lastpingstime;
 709 void Sbar_DrawScoreboard()
 710 {
 711         //float xmin, ymin, xmax, ymax;
 712         vector rgb, pos, tmp, sbar_save;
 713         entity pl, tm;
 714         float specs, i;
 715         float center_x;
 716
 717         if(time > lastpingstime + 10)
 718         {
 719                 localcmd("pings\n");
 720                 lastpingstime = time;
 721         }
 722
 723         xmin = vid_conwidth / 5;
 724         ymin = 20;
 725
 726         xmax = vid_conwidth - xmin;
 727         ymax = vid_conheight - 0.2*vid_conheight;
 728
 729         sbwidth = xmax - xmin;
 730         sbheight = ymax - ymin;
 731
 732         center_x = xmin + 0.5*sbwidth;
 733
 734         //Sbar_UpdateFields();
 735
 736         // Initializes position
 737         //pos_x = xmin;
 738         pos_y = ymin;
 739         pos_z = 0;
 740
 741         // Heading
 742         drawfont = sbar_bigfont;
 743         pos_x = center_x - stringwidth("Scoreboard", TRUE)*0.5*24;
 744         drawstring(pos, "Scoreboard", '24 24 0', '1 1 1', 1, DRAWFLAG_NORMAL);
 745         pos_x = xmin;
 746         pos_y += 24 + 4;
 747
 748         // Titlebar background:
 749         tmp_x = sbwidth;
 750         tmp_y = sbar_fontsize_y;
 751         drawfill(pos - '1 1 0', tmp + '2 2 0', '0.5 0.5 0.5', 0.5, DRAWFLAG_NORMAL);
 752
 753         drawfont = sbar_font;
 754
 755         for(i = 0; i < sbar_num_fields; ++i)
 756         {
 757                 if(sbar_field[i] == SP_SEPARATOR)
 758                         break;
 759                 drawstring(pos, sbar_title[i], sbar_fontsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 760                 pos_x += sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 761         }
 762
 763         if(sbar_field[i] == SP_SEPARATOR)
 764         {
 765                 pos_x = xmax + sbar_fontsize_x;
 766                 tmp_y = tmp_z = 0;
 767                 for(i = sbar_num_fields-1; i > 0; --i)
 768                 {
 769                         if(sbar_field[i] == SP_SEPARATOR)
 770                                 break;
 771
 772                         pos_x -= sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 773                         /**
 774                          * FTEQCC BUG!
 775                          * Using the following line will fuck it all up:
 776                          **
 777                          * tmp_x = sbar_size[i] - strlen(sbar_title[i])*8;
 778                          */
 779                         tmp_x = sbar_fontsize_x*sbar_size[i];
 780                         tmp_x -= stringwidth(sbar_title[i], FALSE)*sbar_fontsize_x;
 781                         drawstring(pos + tmp, sbar_title[i], sbar_fontsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 782                 }
 783         }
 784
 785         pos_x = xmin;
 786         pos_y += 1.5 * sbar_fontsize_y;
 787
 788         sbar_save = sbar;
 789         sbar = '0 0 0';
 790
 791         if(teamplay)
 792         {
 793                 //for(tm = sortedTeams.sort_next; tm; tm = tm.sort_next)
 794                 for(tm = teams.sort_next; tm; tm = tm.sort_next)
 795                 {
 796                         if(!tm.team_size || tm.team == COLOR_SPECTATOR)
 797                                 continue;
 798
 799                         rgb = GetTeamRGB(tm.team);
 800
 801                         pos_x = xmin;
 802
 803                         Sbar_DrawXNum(
 804                                 pos - '6.5 0 0' * sbar_fontsize_y,
 805                                 tm.(teamscores[ts_primary]),
 806                                 4, sbar_fontsize_y * 1.5, rgb, 1, DRAWFLAG_NORMAL);
 807
 808                         if(ts_primary != ts_secondary)
 809                         Sbar_DrawXNum(
 810                                 pos - '4.5 0 0' * sbar_fontsize_y + '0 1.5 0' * sbar_fontsize_y,
 811                                 tm.(teamscores[ts_secondary]),
 812                                 4, sbar_fontsize_y * 1, rgb, 1, DRAWFLAG_NORMAL);
 813
 814                         specs = tm.team_size;
 815
 816                         if(specs < 2)
 817                                 specs = 2;
 818
 819                         tmp_x = sbwidth;
 820                         tmp_y = 1.25 * sbar_fontsize_y * specs;
 821                         drawfill(pos - '1 1 0', tmp + '2 0 0', rgb, 0.2, DRAWFLAG_NORMAL);
 822
 823                         for(pl = players.sort_next; pl; pl = pl.sort_next)
 824                         {
 825                                 if(pl.team != tm.team)
 826                                         continue;
 827                                 Sbar_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1));
 828                                 pos_y += 1.25 * sbar_fontsize_y;
 829                                 tmp_y -= 1.25 * sbar_fontsize_y;
 830                         }
 831                         pos_y += tmp_y + 1.5 * sbar_fontsize_y;
 832                 }
 833                 // rgb := tempvector :)
 834                 rgb = pos + '0 1.5 0' * sbar_fontsize_y;
 835                 pos_y += 3 * sbar_fontsize_y;
 836                 specs = 0;
 837                 for(pl = players.sort_next; pl; pl = pl.sort_next)
 838                 {
 839                         if(pl.team != COLOR_SPECTATOR)
 840                                 continue;
 841                         //drawcolorcodedstring(pos, getplayerkey(pl.sb_player, "name"), '8 8 0', 1, 0);
 842                         Sbar_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1));
 843                         pos += '0 1.25 0' * sbar_fontsize_y;
 844                         ++specs;
 845                 }
 846
 847                 if(specs)
 848                         drawstring(rgb, "Spectators", sbar_fontsize, '1 1 1', 1, 0);
 849         } else {
 850                 pos_x = xmin;
 851                 for(pl = players.sort_next; pl; pl = pl.sort_next)
 852                 {
 853                         if(pl.team == COLOR_SPECTATOR)
 854                                 continue;
 855                         Sbar_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1));
 856                         pos_y += 1.25 * sbar_fontsize_y;
 857                         tmp_y -= 1.25 * sbar_fontsize_y;
 858                 }
 859
 860                 // rgb := tempvector :)
 861                 rgb = pos + '0 1.5 0' * sbar_fontsize_y;
 862                 pos_y += 3 * sbar_fontsize_y;
 863                 specs = 0;
 864                 for(pl = players.sort_next; pl; pl = pl.sort_next)
 865                 {
 866                         if(pl.team != COLOR_SPECTATOR)
 867                                 continue;
 868                         Sbar_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1));
 869                         pos += '0 1.25 0' * sbar_fontsize_y;
 870                         ++specs;
 871                 }
 872
 873                 if(specs)
 874                         drawstring(rgb, "Spectators", sbar_fontsize, '1 1 1', 1, 0);
 875         }
 876
 877         string str;
 878         float tl, fl;
 879         str = strcat("playing on ^2", shortmapname, "^7");
 880         tl = getstatf(STAT_TIMELIMIT);
 881         fl = getstatf(STAT_FRAGLIMIT);
 882         if(gametype == GAME_LMS)
 883         {
 884                 if(tl > 0)
 885                         str = strcat(str, " for up to ^1", ftos(tl), " minutes^7");
 886         }
 887         else
 888         {
 889                 if(tl > 0)
 890                         str = strcat(str, " for ^1", ftos(tl), " minutes^7");
 891                 if(fl > 0)
 892                 {
 893                         if(tl > 0)
 894                                 str = strcat(str, " or");
 895                         str = strcat(str, " until ^3", ScoreString(scores_flags[ps_primary], fl));
 896                         if(scores_label[ps_primary] == "score")
 897                                 str = strcat(str, " points^7");
 898                         else if(scores_label[ps_primary] == "fastest")
 899                                 str = strcat(str, " is beaten^7");
 900                         else
 901                                 str = strcat(str, " ", scores_label[ps_primary]);
 902                 }
 903         }
 904
 905         pos_y += 1.5 * sbar_fontsize_y;
 906         drawcolorcodedstring(pos + '0.5 0 0' * (sbwidth - sbar_fontsize_x * stringwidth(str, TRUE)), str, sbar_fontsize, 0.8, 0);
 907
 908         sbar = sbar_save;
 909 }
 910
 911 string MakeRaceString(float cp, float mytime, float histime, float lapdelta, string hisname)
 912 {
 913         string col;
 914         string timestr;
 915         string cpname;
 916         string lapstr;
 917         lapstr = "";
 918
 919         if(histime == 0) // goal hit
 920         {
 921                 if(mytime > 0)
 922                 {
 923                         timestr = strcat("+", ftos_decimals(+mytime, 1));
 924                         col = "^1";
 925                 }
 926                 else if(mytime == 0)
 927                 {
 928                         timestr = "+0.0";
 929                         col = "^3";
 930                 }
 931                 else
 932                 {
 933                         timestr = strcat("-", ftos_decimals(-mytime, 1));
 934                         col = "^2";
 935                 }
 936
 937                 if(lapdelta > 0)
 938                 {
 939                         lapstr = strcat(" (-", ftos(lapdelta), "L)");
 940                         col = "^2";
 941                 }
 942                 else if(lapdelta < 0)
 943                 {
 944                         lapstr = strcat(" (+", ftos(-lapdelta), "L)");
 945                         col = "^1";
 946                 }
 947         }
 948         else if(histime > 0) // anticipation
 949         {
 950                 if(mytime >= histime)
 951                         timestr = strcat("+", ftos_decimals(mytime - histime, 1));
 952                 else
 953                         timestr = mmsss(histime * 10);
 954                 col = "^3";
 955         }
 956         else
 957                 col = "^7";
 958
 959         if(cp)
 960                 cpname = strcat("Intermediate ", ftos(cp));
 961         else
 962                 cpname = "Finish line";
 963
 964         if(histime < 0)
 965                 return strcat(col, cpname);
 966         else if(hisname == "")
 967                 return strcat(col, cpname, " (", timestr, ")");
 968         else
 969                 return strcat(col, cpname, " (", timestr, " ", strcat(hisname, col, lapstr), ")");
 970 }
 971
 972 void dummyfunction(float a1, float a2, float a3, float a4, float a5, float a6, float a7, float a8)
 973 {
 974 }
 975
 976 void Sbar_Score(float margin)
 977 {
 978         float timelimit, timeleft, minutes, seconds, distribution, myplace, score;
 979         vector sbar_save, place;
 980         entity tm, pl, me;
 981         sbar_save = sbar;
 982
 983         myteam = GetPlayerColor(player_localentnum - 1);
 984
 985         sbar_y = vid_conheight - (32+12);
 986         sbar_x -= margin;
 987
 988         place = '-48 -12 0';
 989         if(teamplay)
 990         {
 991                 // Layout:
 992                 //
 993                 //   team1 team3 team4
 994                 //
 995                 //         TEAM2
 996                 //for(i = 0; i < 4; ++i)
 997                 for(tm = teams.sort_next; tm; tm = tm.sort_next)
 998                 {
 999                         if(tm.team == COLOR_SPECTATOR || !tm.team_size) // no players? don't display
1000                                 continue;
1001                         // -32*4 = -128
1002                         score = tm.(teamscores[ts_primary]);
1003                         if(tm.team == myteam)
1004                                 Sbar_DrawXNum('-128 0 0', score, 4, 32, GetTeamRGB(tm.team), 1, DRAWFLAG_NORMAL);
1005                         else
1006                         {
1007                                 Sbar_DrawXNum(place, score, 4, 12, GetTeamRGB(tm.team), 1, DRAWFLAG_NORMAL);
1008                                 place_x -= 4*12;
1009                         }
1010                 }
1011         } else {
1012                 // me vector := [team/connected frags id]
1013                 myplace = 0;
1014                 for(me = players.sort_next; me; me = me.sort_next)
1015                 {
1016                         if(me.team != COLOR_SPECTATOR)
1017                                 ++myplace;
1018                         if(me.sv_entnum == player_localentnum - 1)
1019                                 break;
1020                 }
1021                 pl = players;
1022                 if(pl == me)
1023                         pl = pl.sort_next;
1024
1025                 if(pl) {
1026                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
1027                 } else
1028                         distribution = 0;
1029
1030                 if(myplace == 1)
1031                         Sbar_DrawXNum('-36 -12 0', myplace, 3, 12, '1 1 1', 1, DRAWFLAG_NORMAL);
1032                 else if(myplace == 2)
1033                         Sbar_DrawXNum('-36 -12 0', myplace, 3, 12, '1 1 0', 1, DRAWFLAG_NORMAL);
1034                 else
1035                         Sbar_DrawXNum('-36 -12 0', myplace, 3, 12, '1 0 0', 1, DRAWFLAG_NORMAL);
1036
1037                 score = me.(scores[ps_primary]);
1038                 if(distribution >= 0)
1039                 {
1040                         Sbar_DrawXNum('-84 -12 0', distribution, 4, 12, ' 1 1 1', 1, DRAWFLAG_NORMAL);
1041                         Sbar_DrawXNum('-128 0 0', score, 4, 32, '1 1 1', 1, DRAWFLAG_NORMAL);
1042                 } else if(distribution >= -5)
1043                 {
1044                         Sbar_DrawXNum('-84 -12 0', distribution, 4, 12, ' 1 1 0', 1, DRAWFLAG_NORMAL);
1045                         Sbar_DrawXNum('-128 0 0', score, 4, 32, '1 1 0', 1, DRAWFLAG_NORMAL);
1046                 } else {
1047                         Sbar_DrawXNum('-84 -12 0', distribution, 4, 12, ' 1 0 0', 1, DRAWFLAG_NORMAL);
1048                         Sbar_DrawXNum('-128 0 0', score, 4, 32, '1 0 0', 1, DRAWFLAG_NORMAL);
1049                 }
1050         }
1051         timelimit = getstatf(STAT_TIMELIMIT);
1052         if(timelimit)
1053         {
1054                 timeleft = max(0, timelimit * 60 - time);
1055                 minutes = floor(timeleft / 60);
1056                 seconds = floor(timeleft - minutes*60);
1057                 if(minutes >= 5)
1058                 {
1059                         Sbar_DrawXNum('-72 32 0', minutes, 3, 12, '1 1 1', 1, DRAWFLAG_NORMAL);
1060                         drawpic(sbar + '-36 32 0', "gfx/num_colon", '12 12 0', '1 1 1', sbar_alpha_fg, 0);
1061                         Sbar_DrawXNum('-24 32 0', seconds, -2, 12, '1 1 1', 1, DRAWFLAG_NORMAL);
1062                 } else if(minutes >= 1)
1063                 {
1064                         Sbar_DrawXNum('-72 32 0', minutes, 3, 12, '1 1 0', 1, DRAWFLAG_NORMAL);
1065                         drawpic(sbar + '-36 32 0', "gfx/num_colon", '12 12 0', '1 1 0', sbar_alpha_fg, 0);
1066                         Sbar_DrawXNum('-24 32 0', seconds, -2, 12, '1 1 0', 1, DRAWFLAG_NORMAL);
1067                 } else {
1068                         Sbar_DrawXNum('-24 32 0', seconds, -2, 12, '1 0 0', 1, DRAWFLAG_NORMAL);
1069                 }
1070         } else {
1071                 minutes = floor(time / 60);
1072                 seconds = floor(time - minutes*60);
1073                 Sbar_DrawXNum('-72 32 0', minutes, 3, 12, '1 1 1', 1, DRAWFLAG_NORMAL);
1074                 drawpic(sbar + '-36 32 0', "gfx/num_colon", '12 12 0', '1 1 1', sbar_alpha_fg, 0);
1075                 Sbar_DrawXNum('-24 32 0', seconds, -2, 12, '1 1 1', 1, DRAWFLAG_NORMAL);
1076         }
1077
1078         if(gametype == GAME_RACE)
1079         {
1080                 drawfont = sbar_bigfont;
1081                 float a;
1082                 vector m;
1083                 string s, forcetime;
1084
1085                 m = '0.5 0 0' * vid_conwidth + '0 0.25 0' * vid_conheight;
1086
1087                 if(race_checkpointtime)
1088                 {
1089
1090                         a = bound(0, 2 - (time - race_checkpointtime), 1);
1091                         s = "";
1092                         forcetime = "";
1093                         if(a > 0) // just hit a checkpoint?
1094                         {
1095                                 if(race_time && race_previousbesttime)
1096                                         s = MakeRaceString(race_checkpoint, race_time / 10 - race_previousbesttime / 10, 0, 0, race_previousbestname);
1097                                 else
1098                                         s = MakeRaceString(race_checkpoint, 0, -1, 0, race_previousbestname);
1099                                 if(race_time)
1100                                         forcetime = mmsss(race_time);
1101                         }
1102                         else
1103                         {
1104                                 if(race_laptime && race_nextbesttime)
1105                                 {
1106                                         a = bound(0, 2 - ((race_laptime + race_nextbesttime/10) - time), 1);
1107                                         if(a > 0) // next one?
1108                                         {
1109                                                 s = MakeRaceString(race_nextcheckpoint, time - race_laptime, race_nextbesttime / 10, 0, race_nextbestname);
1110                                         }
1111                                 }
1112                         }
1113
1114                         if(s != "" && a > 0)
1115                         {
1116                                 dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1117                                 drawcolorcodedstring(m - '0 16 0' - '8 0 0' * stringwidth(s, TRUE), s, '16 16 0', sbar_alpha_fg * a, 0);
1118                         }
1119
1120                         if(forcetime != "")
1121                         {
1122                                 float sz;
1123                                 a = bound(0, 1 - 2 * (time - race_checkpointtime), 1);
1124                                 sz = 1.2 / (a + 0.2);
1125                                 drawstring(m - '0 0 0' - '0 16 0' * (sz - 1) - '16 0 0' * sz * stringwidth(forcetime, FALSE), forcetime, '32 32 0' * sz, '1 1 1', sbar_alpha_fg * a, 0);
1126                                 a = 1 - a;
1127                         }
1128                         else
1129                                 a = 1;
1130
1131                         if(race_laptime)
1132                         {
1133                                 s = mmsss(10*(time - race_laptime));
1134                                 drawstring(m - '0 0 0' - '16 0 0' * stringwidth(s, FALSE), s, '32 32 0', '1 1 1', sbar_alpha_fg * a, 0);
1135                         }
1136                 }
1137                 else
1138                 {
1139                         if(race_mycheckpointtime)
1140                         {
1141                                 a = bound(0, 2 - (time - race_mycheckpointtime), 1);
1142                                 s = MakeRaceString(race_mycheckpoint, race_mycheckpointdelta / 10, -!race_mycheckpointenemy, race_mycheckpointlapsdelta, race_mycheckpointenemy);
1143                                 dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1144                                 drawcolorcodedstring(m - '0 16 0' - '8 0 0' * stringwidth(s, TRUE), s, '16 16 0', sbar_alpha_fg * a, 0);
1145                         }
1146                         if(race_othercheckpointtime && race_othercheckpointenemy != "")
1147                         {
1148                                 a = bound(0, 2 - (time - race_othercheckpointtime), 1);
1149                                 s = MakeRaceString(race_othercheckpoint, -race_othercheckpointdelta / 10, -!race_othercheckpointenemy, race_othercheckpointlapsdelta, race_othercheckpointenemy);
1150                                 dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1151                                 drawcolorcodedstring(m - '0 0 0' - '8 0 0' * stringwidth(s, TRUE), s, '16 16 0', sbar_alpha_fg * a, 0);
1152                         }
1153                 }
1154
1155                 drawfont = sbar_font;
1156         }
1157
1158         sbar = sbar_save;
1159 }
1160
1161 void Sbar_MiniscoreItem(vector pos, entity pl, float is_self)
1162 {
1163         float x, score;
1164         pos_x += 72;
1165
1166         if(teamplay)
1167                 drawfill(pos + '0 1 0', '40 6 0', GetTeamRGB(pl.team)*0.5, 1, DRAWFLAG_NORMAL);
1168         else
1169                 drawfill(pos + '0 1 0', '40 6 0', '0.5 0.5 0.5', 0.5, DRAWFLAG_NORMAL);
1170         x = pos_x;
1171         pos_x += 5*8;
1172         score = pl.(scores[ps_primary]);
1173         pos_x -= stringwidth(ftos(score), FALSE)*8;
1174         drawstring(pos, ftos(score), '8 8 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1175         pos_x = x;
1176         if(is_self)
1177         {
1178                 pos_x += 48;
1179                 drawstring(pos, "\x0D", '8 8 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1180                 pos_x += 8;
1181         } else
1182                 pos_x += 56;
1183         drawcolorcodedstring(pos, getplayerkey(pl.sv_entnum, "name"), '8 8 0', 1, 0);
1184 }
1185
1186 void Sbar_MiniscoreTeamItem(vector pos, float color, float frags, float is_self)
1187 {
1188         float x;
1189         pos_x += 72;
1190
1191         if(teamplay)
1192                 drawfill(pos + '0 1 0', '40 6 0', GetTeamRGB(color)*0.5, 1, DRAWFLAG_NORMAL);
1193         else
1194                 drawfill(pos + '0 1 0', '40 6 0', '0.5 0.5 0.5', 0.5, DRAWFLAG_NORMAL);
1195         x = pos_x;
1196         pos_x += 5*8;
1197         pos_x -= stringwidth(ftos(frags), FALSE)*8;
1198         drawstring(pos, ftos(frags), '8 8 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1199         pos_x = x;
1200         if(is_self)
1201         {
1202                 pos_x += 48;
1203                 drawstring(pos, "\x0D", '8 8 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1204                 pos_x += 8;
1205         } else
1206                 pos_x += 56;
1207         drawstring(pos, GetTeamName(color), '8 8 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1208 }
1209
1210 void Sbar_MiniDeathmatchOverlay(vector pos)
1211 {
1212         float numlines, up, down, score;
1213         entity me, tm, pl;
1214         float miniscoreboard_size;
1215         miniscoreboard_size = cvar("sbar_miniscoreboard_size");
1216
1217         if(miniscoreboard_size == 0)
1218                 return;
1219         pos_y = vid_conheight - 8;
1220
1221         if(miniscoreboard_size < 0)
1222                 numlines = (vid_conheight - sbar_y + 7) / 8;
1223         else
1224                 numlines = miniscoreboard_size;
1225
1226         // give up if there isn't enough room
1227         if(pos_x >= vid_conwidth || pos_y >= vid_conheight || numlines < 1)
1228                 return;
1229
1230         // me vector := [team/connected frags id]
1231         for(me = players.sort_next; me; me = me.sort_next)
1232         {
1233                 if(me.sv_entnum == player_localentnum - 1)
1234                         break;
1235         }
1236
1237         if(teamplay)
1238                 numlines -= numteams;
1239
1240         // figure out how many players above and below we can show
1241         up = floor(numlines/2);
1242         down = up;
1243         if((up + down) > numlines)
1244                 down = numlines - up;
1245
1246         // render bottom-up
1247         for(pl = me.sort_next; pl && down > 0; pl = pl.sort_next)
1248         {
1249                 if(pl.team == COLOR_SPECTATOR)
1250                         continue;
1251                 Sbar_MiniscoreItem(pos, pl, false);
1252                 pos_y -= 9;
1253                 --down;
1254         }
1255         Sbar_MiniscoreItem(pos, me, true);
1256         pos_y -= 9;
1257         up += down; // if there weren't enough lines below... add them
1258         for(pl = me.sort_prev; pl && up > 0; pl = pl.sort_prev)
1259         {
1260                 if(pl.team == COLOR_SPECTATOR)
1261                         continue;
1262                 Sbar_MiniscoreItem(pos, pl, false);
1263                 pos_y -= 9;
1264                 --up;
1265         }
1266
1267         if(teamplay)
1268         {
1269                 for(tm = teams.sort_next; tm.sort_next; tm = tm.sort_next);
1270                 for(; tm; tm = tm.sort_prev)
1271                 {
1272                         if(!tm.team_size || tm.team == COLOR_SPECTATOR)
1273                                 continue;
1274                         score = tm.(teamscores[ts_primary]);
1275                         Sbar_MiniscoreTeamItem(pos, tm.team, score, (tm.team == me.team));
1276                         pos_y -= 9;
1277                 }
1278         }
1279 }
1280
1281 float Sbar_WouldDrawScoreboard ()
1282 {
1283         if (sb_showscores)
1284                 return 1;
1285         else if (intermission == 1)
1286                 return 1;
1287         else if (intermission == 2)
1288                 return 1;
1289         else if (getstati(STAT_HEALTH) <= 0 && cvar("cl_deathscoreboard"))
1290                 return 1;
1291         else if(sb_showscores_force)
1292                 return 1;
1293         return 0;
1294 }
1295
1296 void Sbar_Draw (void)
1297 {
1298         float i;
1299         float x, fade;
1300         float stat_items;
1301
1302         sbar_fontsize = Sbar_GetFontsize();
1303
1304         if(spectatee_status)
1305         {
1306                 string s;
1307                 vector o;
1308                 o = '1 0 0' * vid_conwidth;
1309                 if(spectatee_status == -1)
1310                         s = "^1Observing";
1311                 else
1312                         s = strcat("^1Spectating ^7", getplayerkey(spectatee_status - 1, "name"));
1313                 dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1314                 drawcolorcodedstring(
1315                         o - sbar_fontsize_x * '1 0 0' * stringwidth(s, TRUE),
1316                         s,
1317                         sbar_fontsize,
1318                         sbar_alpha_fg,
1319                         0
1320                 );
1321                 o += sbar_fontsize_y * '0 1 0';
1322
1323                 if(spectatee_status == -1)
1324                         s = "^1Press ^3primary fire^1 to spectate";
1325                 else
1326                         s = "^1Press ^3primary fire^1 for another player";
1327                 dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1328                 drawcolorcodedstring(
1329                         o - sbar_fontsize_x * '1 0 0' * stringwidth(s, TRUE),
1330                         s,
1331                         sbar_fontsize,
1332                         sbar_alpha_fg,
1333                         0
1334                 );
1335                 o += sbar_fontsize_y * '0 1 0';
1336
1337                 if(spectatee_status == -1)
1338                         s = "^1Use ^3weapon switching^1 to change the speed";
1339                 else
1340                         s = "^1Press ^3secondary fire^1 to observe";
1341                 dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1342                 drawcolorcodedstring(
1343                         o - sbar_fontsize_x * '1 0 0' * stringwidth(s, TRUE),
1344                         s,
1345                         sbar_fontsize,
1346                         sbar_alpha_fg,
1347                         0
1348                 );
1349                 o += sbar_fontsize_y * '0 1 0';
1350
1351                 if(gametype == GAME_ARENA)
1352                         s = "^1Wait for your turn to join";
1353                 else if(gametype == GAME_LMS)
1354                 {
1355                         entity sk;
1356                         sk = playerslots[player_localentnum - 1];
1357                         if(sk.(scores[ps_primary]) >= 666)
1358                                 s = "^1Match has already begun";
1359                         else if(sk.(scores[ps_primary]) > 0)
1360                                 s = "^1You have no more lives left";
1361                         else
1362                                 s = "^1Press ^7jump^1 to join";
1363                 }
1364                 else
1365                         s = "^1Press ^7jump^1 to join";
1366                 dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1367                 drawcolorcodedstring(
1368                         o - sbar_fontsize_x * '1 0 0' * stringwidth(s, TRUE),
1369                         s,
1370                         sbar_fontsize,
1371                         sbar_alpha_fg,
1372                         0
1373                 );
1374                 o += sbar_fontsize_y * '0 1 0';
1375         }
1376
1377         //Sbar_SortFrags();
1378         Sbar_UpdatePlayerTeams();
1379
1380         sb_lines = 24;
1381
1382         if (sb_showscores)
1383                 Sbar_DrawScoreboard();
1384         else if (intermission == 1)
1385         {
1386                 Sbar_DrawScoreboard();
1387                 return;
1388         }
1389         else if (intermission == 2)
1390                 Sbar_FinaleOverlay();
1391         else
1392         {
1393                 if (sb_showscores || sb_showscores_force || (getstati(STAT_HEALTH) <= 0 && cvar("cl_deathscoreboard")))
1394                 {
1395                         sbar_x = (vid_conwidth - 640.0)*0.5;
1396                         sbar_y = vid_conheight - 47;
1397                         //Sbar_DrawAlphaPic (sbar_x, sbar_y, sb_scorebar, sbar_alpha_bg.value);
1398                         //drawpic('0 0 0', "gfx/scorebar", '0 0 0', '1 1 1', cvar("sbar_alpha_bg"), 0);
1399                         Sbar_DrawScoreboard ();
1400                 }
1401                 else
1402                 {
1403                         if (sb_lines && sbar_hudselector == 1)
1404                         {
1405                                 stat_items = getstati(STAT_ITEMS);
1406
1407                                 sbar_x = (vid_conwidth - 320.0)*0.5;
1408                                 sbar_y = vid_conheight - 24.0 - 16.0;
1409                                 sbar_z = 0;
1410
1411                                 fade = 3.2 - 2 * (time - weapontime);
1412                                 fade = bound(0.7, fade, 1);
1413
1414                                 x = 1.0;
1415                                 for(i = 0; i < 8; ++i)
1416                                 {
1417                                         if(stat_items & x)
1418                                         {
1419                                                 Sbar_DrawWeapon(i+1, fade, (i + 2 == activeweapon));
1420                                         }
1421                                         x *= 2;
1422                                 }
1423                                 x *= 2*2*2*2;
1424                                 if(stat_items & x)
1425                                 {
1426                                         Sbar_DrawWeapon(0, fade, (activeweapon == 1));
1427                                 }
1428
1429                                 // armor
1430                                 x = getstati(STAT_ARMOR);
1431                                 if (x > 0)
1432                                 {
1433                                         // "gfx/sb_armor"
1434                                         //Sbar_DrawStretchPic (72, 0, sb_armor[0], sbar_alpha_fg.value, 24, 24);
1435                                         drawpic(sbar + '72 0 0', "gfx/sb_armor", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1436                                         if(x > 200)
1437                                                 Sbar_DrawXNum('0 0 0', x, 3, 24, '0 1 0', 1, 0);
1438                                         else if(x > 100)
1439                                                 Sbar_DrawXNum('0 0 0', x, 3, 24, '0.2 1 0', 1, 0);
1440                                         else if(x > 50)
1441                                                 Sbar_DrawXNum('0 0 0', x, 3, 24, '0.6 0.7 0.8', 1, 0);
1442                                         else if(x > 25)
1443                                                 Sbar_DrawXNum('0 0 0', x, 3, 24, '1 1 0.2', 1, 0);
1444                                         else
1445                                                 Sbar_DrawXNum('0 0 0', x, 3, 24, '0.7 0 0', 1, 0);
1446                                 }
1447
1448                                 // health
1449                                 x = getstati(STAT_HEALTH);
1450                                 if (x != 0)
1451                                 {
1452                                         // "gfx/sb_health"
1453                                         //Sbar_DrawStretchPic (184, 0, sb_health, sbar_alpha_fg.value, 24, 24);
1454                                         drawpic(sbar + '184 0 0', "gfx/sb_health", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1455                                         if(x > 200)
1456                                                 Sbar_DrawXNum('112 0 0', x, 3, 24, '0 1 0', 1, 0);
1457                                         else if(x > 100)
1458                                                 Sbar_DrawXNum('112 0 0', x, 3, 24, '0.2 1 0', 1, 0);
1459                                         else if(x > 50)
1460                                                 Sbar_DrawXNum('112 0 0', x, 3, 24, '0.6 0.7 0.8', 1, 0);
1461                                         else if(x > 25)
1462                                                 Sbar_DrawXNum('112 0 0', x, 3, 24, '1 1 0.2', 1, 0);
1463                                         else
1464                                                 Sbar_DrawXNum('112 0 0', x, 3, 24, '0.7 0 0', 1, 0);
1465                                 }
1466
1467                                 // ammo
1468                                 x = getstati(STAT_AMMO);
1469                                 if ((stat_items & (NEX_IT_SHELLS | NEX_IT_BULLETS | NEX_IT_ROCKETS | NEX_IT_CELLS)) || x != 0)
1470                                 {
1471                                         if (stat_items & NEX_IT_SHELLS)
1472                                                 drawpic(sbar + '296 0 0', "gfx/sb_shells", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1473                                         else if (stat_items & NEX_IT_BULLETS)
1474                                                 drawpic(sbar + '296 0 0', "gfx/sb_bullets", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1475                                         else if (stat_items & NEX_IT_ROCKETS)
1476                                                 drawpic(sbar + '296 0 0', "gfx/sb_rocket", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1477                                         else if (stat_items & NEX_IT_CELLS)
1478                                                 drawpic(sbar + '296 0 0', "gfx/sb_cells", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1479                                         if(x > 10)
1480                                                 Sbar_DrawXNum('224 0 0', x, 3, 24, '0.6 0.7 0.8', 1, 0);
1481                                         else
1482                                                 Sbar_DrawXNum('224 0 0', x, 3, 24, '0.7 0 0', 1, 0);
1483                                 }
1484
1485                                 if (sbar_x + 320 + 160 <= vid_conwidth)
1486                                         Sbar_MiniDeathmatchOverlay(sbar + '320 0 0');
1487                                 if (sbar_x > 0)
1488                                         Sbar_Score(16);
1489                                 // The margin can be at most 8 to support 640x480 console size:
1490                                 //   320 + 2 * (144 + 16) = 640
1491                         }
1492                         else if (sb_lines)
1493                         {
1494
1495                                 stat_items = getstati(STAT_ITEMS);
1496
1497                                 sbar_x = (vid_conwidth - 640.0)*0.5;
1498                                 sbar_y = vid_conheight - 47;
1499                                 sbar_z = 0;
1500
1501                                 fade = 3 - 2 * (time - weapontime);
1502
1503                                 x = 1.0;
1504                                 for(i = 0; i < 8; ++i)
1505                                 {
1506                                         if(stat_items & x)
1507                                         {
1508                                                 Sbar_DrawWeapon(i+1, fade, (i + 2 == activeweapon));
1509                                         }
1510                                         x *= 2;
1511                                 }
1512                                 x *= 2*2*2*2;
1513                                 if(stat_items & x)
1514                                 {
1515                                         Sbar_DrawWeapon(0, fade, (activeweapon == 1));
1516                                 }
1517
1518                                 if (sb_lines > 24)
1519                                         drawpic(sbar, "gfx/sbar", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1520                                 else
1521                                         drawpic(sbar, "gfx/sbar_minimal", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1522
1523                                 // armor
1524                                 // (340-3*24) = 268
1525                                 Sbar_DrawXNum('268 12 0', getstati(STAT_ARMOR), 3, 24, '0.6 0.7 0.8', 1, 0);
1526
1527                                 // health
1528                                 // (154-3*24) = 82
1529                                 x = getstati(STAT_HEALTH);
1530                                 if(x > 100)
1531                                         Sbar_DrawXNum('82 12 0', x, 3, 24, '1 1 1', 1, 0);
1532                                 else if(x <= 25 && time - floor(time) > 0.5)
1533                                         Sbar_DrawXNum('82 12 0', x, 3, 24, '0.7 0 0', 1, 0);
1534                                 else
1535                                         Sbar_DrawXNum('81 12 0', x, 3, 24, '0.6 0.7 0.8', 1, 0);
1536
1537                                 // AK dont draw ammo for the laser
1538                                 x = getstati(STAT_AMMO);
1539                                 if(activeweapon != 12)
1540                                 {
1541                                         // (519-3*24) = 447
1542                                         if (stat_items & NEX_IT_SHELLS)
1543                                                 drawpic(sbar + '519 0 0', "gfx/sb_shells", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1544                                         else if (stat_items & NEX_IT_BULLETS)
1545                                                 drawpic(sbar + '519 0 0', "gfx/sb_bullets", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1546                                         else if (stat_items & NEX_IT_ROCKETS)
1547                                                 drawpic(sbar + '519 0 0', "gfx/sb_rocket", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1548                                         else if (stat_items & NEX_IT_CELLS)
1549                                                 drawpic(sbar + '519 0 0', "gfx/sb_cells", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1550                                         if(x > 10)
1551                                                 Sbar_DrawXNum('447 12 0', x, 3, 24, '0.6 0.7 0.8', 1, 0);
1552                                         else
1553                                                 Sbar_DrawXNum('447 12 0', x, 3, 24, '0.7 0 0', 1, 0);
1554                                 }
1555
1556                                 if (sb_lines > 24)
1557                                         drawpic(sbar, "gfx/sbar_overlay", '0 0 0', '1 1 1', 1, DRAWFLAG_MODULATE);
1558
1559                                 if (sbar_x + 600 + 160 <= vid_conwidth)
1560                                         Sbar_MiniDeathmatchOverlay (sbar + '600 0 0');
1561
1562                                 if (sbar_x > 0)
1563                                         Sbar_Score(-16);
1564                                 // Because:
1565                                 //   Mini scoreboard uses 12*4 per other team, that is, 144
1566                                 //   pixels when there are four teams...
1567                                 //   Nexuiz by default sets vid_conwidth to 800... makes
1568                                 //   sbar_x == 80...
1569                                 //   so we need to shift it by 64 pixels to the right to fit
1570                                 //   BUT: then it overlaps with the image that gets drawn
1571                                 //   for viewsize 100! Therefore, just account for 3 teams,
1572                                 //   that is, 96 pixels mini scoreboard size, needing 16 pixels
1573                                 //   to the right!
1574                         }
1575
1576
1577                         if(gametype == GAME_KEYHUNT)
1578                         {
1579                                 CSQC_kh_hud();
1580                         } else if(gametype == GAME_CTF)
1581                         {
1582                                 CSQC_ctf_hud();
1583                         }
1584                 }
1585         }
1586 }
1587
1588 void CSQC_ctf_hud(void)
1589 {
1590         // cvar("sbar_flagstatus_right") move the flag icons right
1591         // cvar("sbar_flagstatus_pos") pixel position of the nexuiz flagstatus icons
1592         float redflag, blueflag;
1593         float stat_items;
1594         vector pos;
1595
1596         stat_items = getstati(STAT_ITEMS);
1597         redflag = (stat_items/32768) & 3;
1598         blueflag = (stat_items/131072) & 3;
1599
1600         /**
1601          * FTEQCC BUG!
1602          * For some reason now not even THAT works there...
1603          * Maybe the minus' precedence screws it up? The last one there, maybe I should use brackets
1604          **
1605          * pos_x = (cvar("sbar_flagstatus_right")) ? vid_conwidth - 10 - sbar_x - 64 : 10 - sbar_x;
1606          ** Should try those later:
1607          * pos_x = (cvar("sbar_flagstatus_right")) ? (vid_conwidth - 10 - sbar_x - 64) : (10 - sbar_x);
1608          * pos_x = ( (cvar("sbar_flagstatus_right")) ? vid_conwidth - 10 - 64 : 10 ) - sbar_x;
1609          */
1610
1611         if(cvar("sbar_flagstatus_right"))
1612                 pos_x = vid_conwidth - 10 - sbar_x - 64;
1613         else
1614                 pos_x = 10 - sbar_x;
1615
1616         pos_z = 0;
1617
1618         if(sbar_hudselector == 1)
1619                 pos_y = (vid_conheight - sbar_y) - cvar("sbar_flagstatus_pos") - 64;
1620         else
1621                 pos_y = -117;
1622
1623         pos += sbar;
1624
1625         switch(redflag)
1626         {
1627         case 1: drawpic(pos, "gfx/sb_flag_red_taken", '0 0 0', '1 1 1', 1, DRAWFLAG_NORMAL); break;
1628         case 2: drawpic(pos, "gfx/sb_flag_red_lost", '0 0 0', '1 1 1', 1, DRAWFLAG_NORMAL); break;
1629         case 3: drawpic(pos, "gfx/sb_flag_red_carrying", '0 0 0', '1 1 1', 1, DRAWFLAG_NORMAL); break;
1630         }
1631
1632         pos_y -= 64;
1633
1634         switch(blueflag)
1635         {
1636         case 1: drawpic(pos, "gfx/sb_flag_blue_taken", '0 0 0', '1 1 1', 1, 0); break;
1637         case 2: drawpic(pos, "gfx/sb_flag_blue_lost", '0 0 0', '1 1 1', 1, 0); break;
1638         case 3: drawpic(pos, "gfx/sb_flag_blue_carrying", '0 0 0', '1 1 1', 1, 0); break;
1639         }
1640 }