data/qcsrc/client/projectile.qc

   1 .float spawntime;
   2 .vector trail_oldorigin;
   3
   4 void SUB_Null()
   5 {
   6 }
   7
   8 void SUB_Stop()
   9 {
  10         self.move_velocity = self.move_avelocity = '0 0 0';
  11         self.move_movetype = MOVETYPE_NONE;
  12 }
  13
  14 .float count; // set if clientside projectile
  15 .float cnt; // sound index
  16 .float gravity;
  17 .float snd_looping;
  18
  19 void Projectile_DrawTrail(vector to)
  20 {
  21         vector from;
  22         from = self.trail_oldorigin;
  23         self.trail_oldorigin = to;
  24         switch(self.cnt)
  25         {
  26                 case PROJECTILE_ROCKET:
  27                         trailparticles(self, particleeffectnum("TR_ROCKET"), from, to);
  28                         break;
  29                 case PROJECTILE_TAG:
  30                         trailparticles(self, particleeffectnum("TR_VORESPIKE"), from, to);
  31                         break;
  32                 case PROJECTILE_ELECTRO_BEAM:
  33                         trailparticles(self, particleeffectnum("TR_NEXUIZPLASMA"), from, to);
  34                         break;
  35                 case PROJECTILE_GRENADE:
  36                         trailparticles(self, particleeffectnum("TR_KNIGHTSPIKE"), from, to);
  37                         break;
  38                 case PROJECTILE_GRENADE_BOUNCING:
  39                         trailparticles(self, particleeffectnum("TR_KNIGHTSPIKE"), from, to);
  40                         break;
  41                 case PROJECTILE_PORTO_RED:
  42                         trailparticles(self, particleeffectnum("TR_WIZSPIKE"), from, to);
  43                         break;
  44                 case PROJECTILE_PORTO_BLUE:
  45                         trailparticles(self, particleeffectnum("TR_WIZSPIKE"), from, to);
  46                         break;
  47                 case PROJECTILE_FLAC:
  48                         trailparticles(self, particleeffectnum("TR_VORESPIKE"), from, to);
  49                         break;
  50                 case PROJECTILE_SEEKER:
  51                         trailparticles(self, particleeffectnum("TR_ROCKET"), from, to);
  52                         break;
  53                 case PROJECTILE_HOOKBOMB:
  54                         trailparticles(self, particleeffectnum("TR_KNIGHTSPIKE"), from, to);
  55                         break;
  56                 case PROJECTILE_HAGAR:
  57                         trailparticles(self, particleeffectnum("TR_GRENADE"), from, to);
  58                         break;
  59                 case PROJECTILE_HAGAR_BOUNCING:
  60                         trailparticles(self, particleeffectnum("TR_GRENADE"), from, to);
  61                         break;
  62                 case PROJECTILE_BULLET:
  63                 case PROJECTILE_BULLET_GLOWING:
  64                         trailparticles(self, particleeffectnum("tr_bullet"), from, to);
  65                         break;
  66                 default:
  67                         break;
  68         }
  69
  70 }
  71
  72 void Projectile_Draw()
  73 {
  74         vector rot;
  75         vector trailorigin;
  76         float f;
  77         float drawn;
  78         float t;
  79
  80         f = self.move_flags;
  81
  82         if(self.count & 0x80)
  83         {
  84                 //self.move_flags &~= FL_ONGROUND;
  85                 Movetype_Physics(TRUE);
  86                 if(!(self.move_flags & FL_ONGROUND))
  87                         self.angles = vectoangles(self.velocity);
  88         }
  89         else
  90         {
  91                 InterpolateOrigin_Do();
  92         }
  93
  94         if(self.count & 0x80)
  95         {
  96                 drawn = (time >= self.spawntime - 0.02);
  97                 t = max(time, self.spawntime);
  98         }
  99         else
 100         {
 101                 drawn = (self.iflags & IFLAG_VALID);
 102                 t = time;
 103         }
 104
 105         if(!(f & FL_ONGROUND))
 106         {
 107                 rot = '0 0 0';
 108                 switch(self.cnt)
 109                 {
 110                         /*
 111                         case PROJECTILE_GRENADE:
 112                                 rot = '-2000 0 0'; // forward
 113                                 break;
 114                         */
 115                         case PROJECTILE_GRENADE_BOUNCING:
 116                                 rot = '0 -1000 0'; // sideways
 117                                 break;
 118                         case PROJECTILE_HOOKBOMB:
 119                                 rot = '1000 0 0'; // forward
 120                                 break;
 121                         default:
 122                                 break;
 123                 }
 124                 self.angles = AnglesTransform_Multiply(self.angles, rot * (t - self.spawntime));
 125
 126                 fixedmakevectors(self.angles);
 127
 128                 trailorigin = self.origin;
 129                 switch(self.cnt)
 130                 {
 131                         case PROJECTILE_GRENADE:
 132                         case PROJECTILE_GRENADE_BOUNCING:
 133                                 trailorigin += v_right * 1 + v_forward * -10;
 134                                 break;
 135                         default:
 136                                 break;
 137                 }
 138                 if(drawn)
 139                         Projectile_DrawTrail(trailorigin);
 140                 else
 141                         self.trail_oldorigin = trailorigin;
 142         }
 143
 144         if(!drawn)
 145                 return;
 146
 147         switch(self.cnt)
 148         {
 149                 case PROJECTILE_BULLET_GLOWING:
 150                         R_AddDynamicLight(self.origin, 50, '1 1 0');
 151                         break;
 152                 default:
 153                         break;
 154         }
 155
 156         self.renderflags = 0;
 157
 158         R_AddEntity(self);
 159 }
 160
 161 void loopsound(entity e, float ch, string samp, float vol, float attn)
 162 {
 163         if(csqc_flags & CSQC_FLAG_COLORCODES)
 164         {
 165                 sound(e, ch, samp, vol, attn);
 166                 e.snd_looping = 1;
 167         }
 168 }
 169
 170 void Ent_RemoveProjectile()
 171 {
 172         if(self.snd_looping)
 173                 sound(self, CHAN_PROJECTILE, "misc/null.wav", VOL_BASE, ATTN_NORM);
 174
 175         if(self.count & 0x80)
 176         {
 177                 tracebox(self.origin, self.mins, self.maxs, self.origin + self.velocity * 0.05, MOVE_NORMAL, self);
 178                 Projectile_DrawTrail(trace_endpos);
 179         }
 180 }
 181
 182 void Ent_Projectile()
 183 {
 184         float f;
 185
 186         // projectile properties:
 187         //   kind (interpolated, or clientside)
 188         //
 189         //   modelindex
 190         //   origin
 191         //   scale
 192         //   if clientside:
 193         //     velocity
 194         //     gravity
 195         //   soundindex (hardcoded list)
 196         //   effects
 197         //
 198         // projectiles don't send angles, because they always follow the velocity
 199
 200         f = ReadByte();
 201         self.count = (f & 0x80);
 202         self.iflags = (self.iflags & IFLAG_INTERNALMASK) | IFLAG_AUTOANGLES | IFLAG_ANGLES;
 203         self.move_flags &~= FL_ONGROUND;
 204         self.solid = SOLID_TRIGGER;
 205         //self.effects = EF_NOMODELFLAGS;
 206
 207         // sv_gameplayfix_delayprojectiles
 208         if(!self.move_time)
 209         {
 210                 self.move_time = time + ticrate;
 211                 self.spawntime = time + ticrate;
 212         }
 213         else
 214                 self.move_time = max(self.move_time, time);
 215
 216         if(!(self.count & 0x80))
 217                 InterpolateOrigin_Undo();
 218
 219         if(f & 1)
 220         {
 221                 self.origin_x = ReadCoord();
 222                 self.origin_y = ReadCoord();
 223                 self.origin_z = ReadCoord();
 224                 if(self.count & 0x80)
 225                 {
 226                         self.velocity_x = ReadCoord();
 227                         self.velocity_y = ReadCoord();
 228                         self.velocity_z = ReadCoord();
 229                         self.gravity = ReadCoord();
 230
 231                         self.move_origin = self.origin;
 232                         self.move_velocity = self.velocity;
 233                 }
 234
 235                 self.trail_oldorigin = self.origin;
 236         }
 237
 238         if(f & 2)
 239         {
 240                 self.cnt = ReadByte();
 241
 242                 self.scale = 1;
 243                 switch(self.cnt)
 244                 {
 245                         case PROJECTILE_ELECTRO: setmodel(self, "models/ebomb.mdl"); break;
 246                         case PROJECTILE_ROCKET: setmodel(self, "models/rocket.md3"); self.scale = 3; break;
 247                         case PROJECTILE_TAG: setmodel(self, "models/laser.mdl"); break;
 248                         case PROJECTILE_BULLET: setmodel(self, "models/tracer.mdl"); break;
 249                         case PROJECTILE_BULLET_GLOWING: setmodel(self, "models/tracer.mdl"); break;
 250                         case PROJECTILE_CRYLINK: setmodel(self, "models/plasmatrail.mdl"); break;
 251                         case PROJECTILE_ELECTRO_BEAM: setmodel(self, "models/elaser.mdl"); break;
 252                         case PROJECTILE_GRENADE: setmodel(self, "models/grenademodel.md3"); break;
 253                         case PROJECTILE_GRENADE_BOUNCING: setmodel(self, "models/grenademodel.md3"); break;
 254                         case PROJECTILE_LASER: setmodel(self, "models/laser.mdl"); break;
 255                         case PROJECTILE_HLAC: setmodel(self, "models/hlac_bullet.md3"); break;
 256                         case PROJECTILE_SEEKER: setmodel(self, "models/tagrocket.md3"); self.scale = 2; break;
 257                         case PROJECTILE_FLAC: setmodel(self, "models/hagarmissile.mdl"); self.scale = 0.4; break;
 258                         case PROJECTILE_PORTO_RED: setmodel(self, "models/grenademodel.md3"); self.scale = 4; break;
 259                         case PROJECTILE_PORTO_BLUE: setmodel(self, "models/grenademodel.md3"); self.scale = 4; break;
 260                         case PROJECTILE_HOOKBOMB: setmodel(self, "models/grenademodel.md3"); break;
 261                         case PROJECTILE_HAGAR: setmodel(self, "models/hagarmissile.mdl"); self.scale = 0.4; break;
 262                         case PROJECTILE_HAGAR_BOUNCING: setmodel(self, "models/hagarmissile.mdl"); self.scale = 0.4; break;
 263                         default:
 264                                 error("Received invalid CSQC projectile, can't work with this!");
 265                                 break;
 266                 }
 267
 268                 self.mins = '0 0 0';
 269                 self.maxs = '0 0 0';
 270                 self.colormod = '0 0 0';
 271                 self.move_touch = SUB_Stop;
 272                 self.move_movetype = MOVETYPE_TOSS;
 273
 274                 switch(self.cnt)
 275                 {
 276                         case PROJECTILE_ELECTRO:
 277                                 // only new engines support sound moving with object
 278                                 loopsound(self, CHAN_PROJECTILE, "weapons/electro_fly.wav", VOL_BASE, ATTN_NORM);
 279                                 self.mins = '0 0 -3';
 280                                 self.maxs = '0 0 -3';
 281                                 self.move_movetype = MOVETYPE_BOUNCE;
 282                                 self.move_touch = SUB_Null;
 283                                 break;
 284                         case PROJECTILE_ROCKET:
 285                                 loopsound(self, CHAN_PROJECTILE, "weapons/rocket_fly.wav", VOL_BASE, ATTN_NORM);
 286                                 self.mins = '-3 -3 -3';
 287                                 self.maxs = '3 3 3';
 288                                 break;
 289                         case PROJECTILE_TAG:
 290                                 loopsound(self, CHAN_PROJECTILE, "weapons/tag_rocket_fly.wav", VOL_BASE, ATTN_NORM);
 291                                 self.mins = '-2 -2 -2';
 292                                 self.maxs = '2 2 2';
 293                                 break;
 294                         case PROJECTILE_GRENADE_BOUNCING:
 295                                 self.mins = '0 0 -3';
 296                                 self.maxs = '0 0 -3';
 297                                 self.move_movetype = MOVETYPE_BOUNCE;
 298                                 self.move_touch = SUB_Null;
 299                                 break;
 300                         case PROJECTILE_SEEKER:
 301                                 self.mins = '-2 -2 -2';
 302                                 self.maxs = '2 2 2';
 303                                 break;
 304                         case PROJECTILE_PORTO_RED:
 305                                 self.colormod = '2 1 1';
 306                                 self.alpha = 0.5;
 307                                 self.move_movetype = MOVETYPE_BOUNCE;
 308                                 self.move_touch = SUB_Null;
 309                                 break;
 310                         case PROJECTILE_PORTO_BLUE:
 311                                 self.colormod = '1 1 2';
 312                                 self.alpha = 0.5;
 313                                 self.move_movetype = MOVETYPE_BOUNCE;
 314                                 self.move_touch = SUB_Null;
 315                                 break;
 316                         case PROJECTILE_HAGAR_BOUNCING:
 317                                 self.move_movetype = MOVETYPE_BOUNCE;
 318                                 self.move_touch = SUB_Null;
 319                                 break;
 320                         default:
 321                                 break;
 322                 }
 323         }
 324
 325         if(self.gravity)
 326         {
 327                 if(self.move_movetype == MOVETYPE_FLY)
 328                         self.move_movetype = MOVETYPE_TOSS;
 329                 if(self.move_movetype == MOVETYPE_BOUNCEMISSILE)
 330                         self.move_movetype = MOVETYPE_BOUNCE;
 331         }
 332         else
 333         {
 334                 if(self.move_movetype == MOVETYPE_TOSS)
 335                         self.move_movetype = MOVETYPE_FLY;
 336                 if(self.move_movetype == MOVETYPE_BOUNCE)
 337                         self.move_movetype = MOVETYPE_BOUNCEMISSILE;
 338         }
 339
 340         if(!(self.count & 0x80))
 341                 InterpolateOrigin_Note();
 342
 343         self.draw = Projectile_Draw;
 344         self.entremove = Ent_RemoveProjectile;
 345 }
 346
 347 void Projectile_Precache()
 348 {
 349         precache_model("models/ebomb.mdl");
 350         precache_model("models/elaser.mdl");
 351         precache_model("models/grenademodel.md3");
 352         precache_model("models/hagarmissile.mdl");
 353         precache_model("models/hlac_bullet.md3");
 354         precache_model("models/laser.mdl");
 355         precache_model("models/plasmatrail.mdl");
 356         precache_model("models/rocket.md3");
 357         precache_model("models/tagrocket.md3");
 358         precache_model("models/tracer.mdl");
 359         precache_sound("weapons/electro_fly.wav");
 360         precache_sound("weapons/rocket_fly.wav");
 361         precache_sound("weapons/tag_rocket_fly.wav");
 362 }