data/qcsrc/client/projectile.qc

   1 .vector iorigin1, iorigin2;
   2 .float spawntime;
   3 .vector trail_oldorigin;
   4 .float trail_oldtime;
   5 .float fade_time, fade_rate;
   6
   7 void SUB_Null()
   8 {
   9 }
  10
  11 void SUB_Stop()
  12 {
  13         self.move_velocity = self.move_avelocity = '0 0 0';
  14         self.move_movetype = MOVETYPE_NONE;
  15 }
  16
  17 .float alphamod;
  18 .float count; // set if clientside projectile
  19 .float cnt; // sound index
  20 .float gravity;
  21 .float snd_looping;
  22 .float silent;
  23 .float traileffect;
  24
  25 void Projectile_DrawTrail(vector to)
  26 {
  27         vector from;
  28         float t0;
  29         from = self.trail_oldorigin;
  30         t0 = self.trail_oldtime;
  31         self.trail_oldorigin = to;
  32         self.trail_oldtime = time;
  33
  34         if (self.traileffect)
  35                 trailparticles(self, self.traileffect, from, to);
  36 }
  37
  38 void Projectile_Draw()
  39 {
  40         vector rot;
  41         vector trailorigin;
  42         float f;
  43         float drawn;
  44         float t;
  45         float a;
  46
  47         f = self.move_flags;
  48
  49         if(self.count & 0x80)
  50         {
  51                 //self.move_flags &~= FL_ONGROUND;
  52                 Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  53                 if(!(self.move_flags & FL_ONGROUND))
  54                         self.angles = vectoangles(self.velocity);
  55         }
  56         else
  57         {
  58                 InterpolateOrigin_Do();
  59         }
  60
  61         if(self.count & 0x80)
  62         {
  63                 drawn = (time >= self.spawntime - 0.02);
  64                 t = max(time, self.spawntime);
  65         }
  66         else
  67         {
  68                 drawn = (self.iflags & IFLAG_VALID);
  69                 t = time;
  70         }
  71
  72         if(!(f & FL_ONGROUND))
  73         {
  74                 rot = '0 0 0';
  75                 switch(self.cnt)
  76                 {
  77                         /*
  78                         case PROJECTILE_GRENADE:
  79                                 rot = '-2000 0 0'; // forward
  80                                 break;
  81                         */
  82                         case PROJECTILE_GRENADE_BOUNCING:
  83                                 rot = '0 -1000 0'; // sideways
  84                                 break;
  85                         case PROJECTILE_HOOKBOMB:
  86                                 rot = '1000 0 0'; // forward
  87                                 break;
  88                         default:
  89                                 break;
  90                 }
  91                 self.angles = AnglesTransform_Multiply(self.angles, rot * (t - self.spawntime));
  92         }
  93
  94         fixedmakevectors(self.angles);
  95
  96         a = 1 - (time - self.fade_time) * self.fade_rate;
  97         if(a <= 0)
  98                 drawn = 0;
  99
 100         trailorigin = self.origin;
 101         switch(self.cnt)
 102         {
 103                 case PROJECTILE_GRENADE:
 104                 case PROJECTILE_GRENADE_BOUNCING:
 105                         trailorigin += v_right * 1 + v_forward * -10;
 106                         break;
 107                 default:
 108                         break;
 109         }
 110         if(drawn)
 111                 Projectile_DrawTrail(trailorigin);
 112         else
 113         {
 114                 self.trail_oldorigin = trailorigin;
 115                 self.trail_oldtime = time;
 116         }
 117
 118         if(!drawn)
 119                 return;
 120
 121         switch(self.cnt)
 122         {
 123                 case PROJECTILE_BULLET_GLOWING:
 124                 case PROJECTILE_BULLET_GLOWING_TRACER:
 125                         R_AddDynamicLight(self.origin, 50 * a, '1 1 0');
 126                         break;
 127                 default:
 128                         break;
 129         }
 130
 131         self.alpha = self.alphamod * a;
 132         self.renderflags = 0;
 133
 134         R_AddEntity(self);
 135 }
 136
 137 void loopsound(entity e, float ch, string samp, float vol, float attn)
 138 {
 139         if(self.silent)
 140                 return;
 141
 142         sound(e, ch, samp, vol, attn);
 143         e.snd_looping = 1;
 144 }
 145
 146 void Ent_RemoveProjectile()
 147 {
 148         if(self.snd_looping)
 149                 sound(self, CHAN_PROJECTILE, "misc/null.wav", VOL_BASE, ATTN_NORM);
 150
 151         if(self.count & 0x80)
 152         {
 153                 tracebox(self.origin, self.mins, self.maxs, self.origin + self.velocity * 0.05, MOVE_NORMAL, self);
 154                 Projectile_DrawTrail(trace_endpos);
 155         }
 156 }
 157
 158 void Ent_Projectile()
 159 {
 160         float f;
 161
 162         // projectile properties:
 163         //   kind (interpolated, or clientside)
 164         //
 165         //   modelindex
 166         //   origin
 167         //   scale
 168         //   if clientside:
 169         //     velocity
 170         //     gravity
 171         //   soundindex (hardcoded list)
 172         //   effects
 173         //
 174         // projectiles don't send angles, because they always follow the velocity
 175
 176         f = ReadByte();
 177         self.count = (f & 0x80);
 178         self.iflags = (self.iflags & IFLAG_INTERNALMASK) | IFLAG_AUTOANGLES | IFLAG_ANGLES;
 179         self.solid = SOLID_TRIGGER;
 180         //self.effects = EF_NOMODELFLAGS;
 181
 182         // this should make collisions with bmodels more exact, but it leads to
 183         // projectiles no longer being able to lie on a bmodel
 184         self.move_nomonsters = MOVE_WORLDONLY;
 185         if(f & 0x40)
 186                 self.move_flags |= FL_ONGROUND;
 187         else
 188                 self.move_flags &~= FL_ONGROUND;
 189
 190         if(!self.move_time)
 191         {
 192                 // for some unknown reason, we don't need to care for
 193                 // sv_gameplayfix_delayprojectiles here.
 194                 self.move_time = time;
 195                 self.spawntime = time;
 196         }
 197         else
 198                 self.move_time = max(self.move_time, time);
 199
 200         if(!(self.count & 0x80))
 201                 InterpolateOrigin_Undo();
 202
 203         if(f & 1)
 204         {
 205                 self.origin_x = ReadCoord();
 206                 self.origin_y = ReadCoord();
 207                 self.origin_z = ReadCoord();
 208                 if(self.count & 0x80)
 209                 {
 210                         self.velocity_x = ReadCoord();
 211                         self.velocity_y = ReadCoord();
 212                         self.velocity_z = ReadCoord();
 213                         self.gravity = ReadCoord();
 214
 215                         self.move_origin = self.origin;
 216                         self.move_velocity = self.velocity;
 217                 }
 218
 219                 if(time == self.spawntime || (self.count & 0x80) || (f & 0x10))
 220                 {
 221                         self.trail_oldorigin = self.origin;
 222                         if(!(self.count & 0x80))
 223                                 InterpolateOrigin_Reset();
 224                 }
 225
 226                 if(f & 0x20)
 227                 {
 228                         self.fade_time = time + ReadByte() * ticrate;
 229                         self.fade_rate = 1 / (ReadByte() * ticrate);
 230                 }
 231                 else
 232                 {
 233                         self.fade_time = 0;
 234                         self.fade_rate = 0;
 235                 }
 236         }
 237
 238         if(f & 2)
 239         {
 240                 self.cnt = ReadByte();
 241
 242                 self.silent = (self.cnt & 0x80);
 243                 self.cnt = (self.cnt & 0x7F);
 244
 245                 self.scale = 1;
 246                 self.traileffect = 0;
 247                 switch(self.cnt)
 248                 {
 249                         case PROJECTILE_ELECTRO: setmodel(self, "models/ebomb.mdl");self.traileffect = particleeffectnum("TR_NEXUIZPLASMA"); break;
 250                         case PROJECTILE_ROCKET: setmodel(self, "models/rocket.md3");self.traileffect = particleeffectnum("TR_ROCKET"); self.scale = 2; break;
 251                         case PROJECTILE_BULLET: setmodel(self, "models/tracer.mdl");self.traileffect = particleeffectnum("tr_bullet"); break;
 252                         case PROJECTILE_BULLET_GLOWING: setmodel(self, "models/tracer.mdl");self.traileffect = particleeffectnum("tr_bullet"); break;
 253                         case PROJECTILE_BULLET_GLOWING_TRACER: setmodel(self, "models/tracer.mdl");self.traileffect = particleeffectnum("tr_rifle"); break;
 254                         case PROJECTILE_CRYLINK: setmodel(self, "models/plasmatrail.mdl");self.traileffect = particleeffectnum("TR_CRYLINKPLASMA"); break;
 255                         case PROJECTILE_CRYLINK_BOUNCING: setmodel(self, "models/plasmatrail.mdl");self.traileffect = particleeffectnum("TR_CRYLINKPLASMA"); break;
 256                         case PROJECTILE_ELECTRO_BEAM: setmodel(self, "models/elaser.mdl");self.traileffect = particleeffectnum("TR_NEXUIZPLASMA"); break;
 257                         case PROJECTILE_GRENADE: setmodel(self, "models/grenademodel.md3");self.traileffect = particleeffectnum("TR_GRENADE"); break;
 258                         case PROJECTILE_GRENADE_BOUNCING: setmodel(self, "models/grenademodel.md3");self.traileffect = particleeffectnum("TR_GRENADE"); break;
 259                         case PROJECTILE_LASER: setmodel(self, "models/laser.mdl");self.traileffect = particleeffectnum(""); break;
 260                         case PROJECTILE_HLAC: setmodel(self, "models/hlac_bullet.md3");self.traileffect = particleeffectnum(""); break;
 261                         case PROJECTILE_PORTO_RED: setmodel(self, "models/grenademodel.md3");self.traileffect = particleeffectnum("TR_WIZSPIKE"); self.scale = 4; break;
 262                         case PROJECTILE_PORTO_BLUE: setmodel(self, "models/grenademodel.md3");self.traileffect = particleeffectnum("TR_WIZSPIKE"); self.scale = 4; break;
 263                         case PROJECTILE_HOOKBOMB: setmodel(self, "models/grenademodel.md3");self.traileffect = particleeffectnum("TR_KNIGHTSPIKE"); break;
 264                         case PROJECTILE_HAGAR: setmodel(self, "models/hagarmissile.mdl");self.traileffect = particleeffectnum("TR_GRENADE"); self.scale = 0.4; break;
 265                         case PROJECTILE_HAGAR_BOUNCING: setmodel(self, "models/hagarmissile.mdl");self.traileffect = particleeffectnum("TR_GRENADE"); self.scale = 0.4; break;
 266                         case PROJECTILE_FIREBALL: self.model = ""; self.modelindex = 0; self.traileffect = particleeffectnum("fireball"); break; // particle effect is good enough
 267                         case PROJECTILE_FIREMINE: self.model = ""; self.modelindex = 0; self.traileffect = particleeffectnum("firemine"); break; // particle effect is good enough
 268                         case PROJECTILE_TAG: setmodel(self, "models/laser.mdl"); self.traileffect = particleeffectnum("TR_ROCKET"); break;
 269                         case PROJECTILE_FLAC: setmodel(self, "models/hagarmissile.mdl"); self.scale = 0.4; self.traileffect = particleeffectnum("TR_ROCKET"); break;
 270                         case PROJECTILE_SEEKER: setmodel(self, "models/tagrocket.md3"); self.scale = 2; self.traileffect = particleeffectnum("TR_ROCKET"); break;
 271                         default:
 272                                 error("Received invalid CSQC projectile, can't work with this!");
 273                                 break;
 274                 }
 275
 276                 self.mins = '0 0 0';
 277                 self.maxs = '0 0 0';
 278                 self.colormod = '0 0 0';
 279                 self.move_touch = SUB_Stop;
 280                 self.move_movetype = MOVETYPE_TOSS;
 281                 self.alphamod = 1;
 282
 283                 switch(self.cnt)
 284                 {
 285                         case PROJECTILE_ELECTRO:
 286                                 // only new engines support sound moving with object
 287                                 loopsound(self, CHAN_PROJECTILE, "weapons/electro_fly.wav", VOL_BASE, ATTN_NORM);
 288                                 self.mins = '0 0 -3';
 289                                 self.maxs = '0 0 -3';
 290                                 self.move_movetype = MOVETYPE_BOUNCE;
 291                                 self.move_touch = SUB_Null;
 292                                 break;
 293                         case PROJECTILE_ROCKET:
 294                                 loopsound(self, CHAN_PROJECTILE, "weapons/rocket_fly.wav", VOL_BASE, ATTN_NORM);
 295                                 self.mins = '-3 -3 -3';
 296                                 self.maxs = '3 3 3';
 297                                 break;
 298                         case PROJECTILE_GRENADE:
 299                                 self.mins = '0 0 -3';
 300                                 self.maxs = '0 0 -3';
 301                                 break;
 302                         case PROJECTILE_GRENADE_BOUNCING:
 303                                 self.mins = '0 0 -3';
 304                                 self.maxs = '0 0 -3';
 305                                 self.move_movetype = MOVETYPE_BOUNCE;
 306                                 self.move_touch = SUB_Null;
 307                                 break;
 308                         case PROJECTILE_PORTO_RED:
 309                                 self.colormod = '2 1 1';
 310                                 self.alphamod = 0.5;
 311                                 self.move_movetype = MOVETYPE_BOUNCE;
 312                                 self.move_touch = SUB_Null;
 313                                 break;
 314                         case PROJECTILE_PORTO_BLUE:
 315                                 self.colormod = '1 1 2';
 316                                 self.alphamod = 0.5;
 317                                 self.move_movetype = MOVETYPE_BOUNCE;
 318                                 self.move_touch = SUB_Null;
 319                                 break;
 320                         case PROJECTILE_HAGAR_BOUNCING:
 321                                 self.move_movetype = MOVETYPE_BOUNCE;
 322                                 self.move_touch = SUB_Null;
 323                                 break;
 324                         case PROJECTILE_CRYLINK_BOUNCING:
 325                                 self.move_movetype = MOVETYPE_BOUNCE;
 326                                 self.move_touch = SUB_Null;
 327                                 break;
 328                         case PROJECTILE_FIREBALL:
 329                                 loopsound(self, CHAN_PROJECTILE, "weapons/fireball_fly2.wav", VOL_BASE, ATTN_NORM);
 330                                 self.mins = '-16 -16 -16';
 331                                 self.maxs = '16 16 16';
 332                                 break;
 333                         case PROJECTILE_FIREMINE:
 334                                 loopsound(self, CHAN_PROJECTILE, "weapons/fireball_fly.wav", VOL_BASE, ATTN_NORM);
 335                                 self.move_movetype = MOVETYPE_BOUNCE;
 336                                 self.move_touch = SUB_Null;
 337                                 self.mins = '-4 -4 -4';
 338                                 self.maxs = '4 4 4';
 339                                 break;
 340                         case PROJECTILE_TAG:
 341                                 loopsound(self, CHAN_PROJECTILE, "weapons/tag_rocket_fly.wav", VOL_BASE, ATTN_NORM);
 342                                 self.mins = '-2 -2 -2';
 343                                 self.maxs = '2 2 2';
 344                                 break;
 345                         case PROJECTILE_FLAC:
 346                                 self.mins = '-2 -2 -2';
 347                                 self.maxs = '2 2 2';
 348                                 break;
 349                         case PROJECTILE_SEEKER:
 350                                 self.mins = '-4 -4 -4';
 351                                 self.maxs = '4 4 4';
 352                                 break;
 353                         default:
 354                                 break;
 355                 }
 356         }
 357
 358         if(self.gravity)
 359         {
 360                 if(self.move_movetype == MOVETYPE_FLY)
 361                         self.move_movetype = MOVETYPE_TOSS;
 362                 if(self.move_movetype == MOVETYPE_BOUNCEMISSILE)
 363                         self.move_movetype = MOVETYPE_BOUNCE;
 364         }
 365         else
 366         {
 367                 if(self.move_movetype == MOVETYPE_TOSS)
 368                         self.move_movetype = MOVETYPE_FLY;
 369                 if(self.move_movetype == MOVETYPE_BOUNCE)
 370                         self.move_movetype = MOVETYPE_BOUNCEMISSILE;
 371         }
 372
 373         if(!(self.count & 0x80))
 374                 InterpolateOrigin_Note();
 375
 376         self.draw = Projectile_Draw;
 377         self.entremove = Ent_RemoveProjectile;
 378 }
 379
 380 void Projectile_Precache()
 381 {
 382         precache_model("models/ebomb.mdl");
 383         precache_model("models/elaser.mdl");
 384         precache_model("models/grenademodel.md3");
 385         precache_model("models/hagarmissile.mdl");
 386         precache_model("models/hlac_bullet.md3");
 387         precache_model("models/laser.mdl");
 388         precache_model("models/plasmatrail.mdl");
 389         precache_model("models/rocket.md3");
 390         precache_model("models/tagrocket.md3");
 391         precache_model("models/tracer.mdl");
 392         precache_sound("weapons/electro_fly.wav");
 393         precache_sound("weapons/rocket_fly.wav");
 394         precache_sound("weapons/fireball_fly.wav");
 395         precache_sound("weapons/fireball_fly2.wav");
 396         precache_sound("weapons/tag_rocket_fly.wav");
 397 }