data/qcsrc/client/mapvoting.qc

   1 float mv_num_maps;
   2
   3 float mv_active;
   4 string mv_maps[MAPVOTE_COUNT];
   5 string mv_pics[MAPVOTE_COUNT];
   6 string mv_pk3[MAPVOTE_COUNT];
   7 float mv_preview[MAPVOTE_COUNT];
   8 float mv_votes[MAPVOTE_COUNT];
   9 entity mv_pk3list;
  10 float mv_abstain;
  11 float mv_ownvote;
  12 float mv_detail;
  13 float mv_timeout;
  14 float mv_maps_mask;
  15
  16 string MapVote_FormatMapItem(float id, string map, float count, float maxwidth)
  17 {
  18         string pre, post;
  19         pre = strcat(ftos(id+1), ". ");
  20         if(mv_detail)
  21         {
  22                 if(count == 1)
  23                         post = strcat(" (1 vote)");
  24                 else
  25                         post = strcat(" (", ftos(count), " votes)");
  26         }
  27         else
  28                 post = "";
  29         maxwidth -= stringwidth(pre, FALSE) + stringwidth(post, FALSE);
  30         map = textShortenToWidth(map, maxwidth, stringwidth_nocolors);
  31         return strcat(pre, map, post);
  32 }
  33
  34 vector MapVote_RGB(float id)
  35 {
  36         if(id == mv_ownvote)
  37                 return '1 1 0';
  38         else
  39                 return '1 1 1';
  40 }
  41
  42 void MapVote_DrawMapItem(vector pos, float isize, float tsize, string map, string pic, float count, float id)
  43 {
  44         vector img_size;
  45         vector rgb;
  46         string label;
  47         float text_size;
  48
  49         isize -= sbar_fontsize_y; // respect the text when calculating the image size
  50
  51         rgb = MapVote_RGB(id);
  52
  53         img_size_y = isize;
  54         img_size_x = isize / 0.75; // 4:3 x can be stretched easily, height is defined in isize
  55
  56         drawfont = sbar_font;
  57         pos_y = pos_y + img_size_y;
  58
  59         label = MapVote_FormatMapItem(id, map, count, tsize / sbar_fontsize_x);
  60
  61         text_size = stringwidth(label, false) * sbar_fontsize_x;
  62
  63         pos_x -= text_size*0.5;
  64         drawstring(pos, label, sbar_fontsize, rgb, 1, DRAWFLAG_NORMAL);
  65
  66         pos_x = pos_x + text_size*0.5 - img_size_x*0.5;
  67         pos_y = pos_y - img_size_y;
  68
  69         pos += sbar_border_thickness * '1 1 0';
  70         img_size -= (sbar_border_thickness * 2) * '1 1 0';
  71         if(pic == "")
  72         {
  73                 drawfill(pos, img_size, '.5 .5 .5', .7, DRAWFLAG_NORMAL);
  74         }
  75         else
  76         {
  77                 drawpic(pos, pic, img_size, '1 1 1', 1, DRAWFLAG_NORMAL);
  78         }
  79
  80         drawpic(pos + '1 0 0', strcat("gfx/hud/num_", ftos(id+1)), (img_size_y / 5) * '1 1 0', '1 1 1', 0.6, DRAWFLAG_NORMAL);
  81
  82         if(id == mv_ownvote || pic == "")
  83         {
  84                 drawborderlines(sbar_border_thickness, pos, img_size, rgb, 1, DRAWFLAG_NORMAL);
  85                 drawpic(pos + '1 0 0', strcat("gfx/hud/num_", ftos(id+1)), (img_size_y / 5) * '1 1 0', rgb, 0.6, DRAWFLAG_NORMAL);
  86         }
  87         else
  88         {
  89                 drawborderlines(sbar_border_thickness, pos, img_size, '0 0 0', 1, DRAWFLAG_NORMAL);
  90                 drawpic(pos + '1 0 0', strcat("gfx/hud/num_", ftos(id+1)), (img_size_y / 5) * '1 1 0', '1 1 1', 0.6, DRAWFLAG_NORMAL);
  91         }
  92 }
  93
  94 void MapVote_DrawAbstain(vector pos, float isize, float tsize, float count, float id)
  95 {
  96         vector rgb;
  97         float text_size;
  98         string label;
  99
 100         rgb = MapVote_RGB(id);
 101
 102         drawfont = sbar_font;
 103         pos_y = pos_y + sbar_fontsize_y;
 104
 105         label = MapVote_FormatMapItem(id, "Don't care", count, tsize / sbar_fontsize_x);
 106
 107         text_size = stringwidth(label, false) * sbar_fontsize_x;
 108
 109         pos_x -= text_size*0.5;
 110         drawstring(pos, label, sbar_fontsize, rgb, 1, DRAWFLAG_NORMAL);
 111 }
 112
 113 vector MapVote_GridVec(vector gridspec, float i, float m)
 114 {
 115         float r;
 116         r = mod(i, m);
 117         return
 118                 '1 0 0' * (gridspec_x * r)
 119                 +
 120                 '0 1 0' * (gridspec_y * (i - r) / m);
 121 }
 122
 123 void MapVote_Draw()
 124 {
 125         string map;
 126         float i, tmp;
 127         vector pos;
 128         float isize;
 129         float center;
 130         float columns, rows;
 131         float tsize;
 132         vector dist;
 133
 134         if(!mv_active)
 135                 return;
 136
 137         center = (vid_conwidth - 1)/2;
 138         xmin = vid_conwidth*0.05; // 5% border must suffice
 139         xmax = vid_conwidth - xmin;
 140         ymin = 20;
 141         i = cvar("con_chatpos"); //*cvar("con_chatsize");
 142         if(i < 0)
 143                 ymax = vid_conheight + (i - cvar("con_chat")) * cvar("con_chatsize");
 144         if(i >= 0 || ymax < (vid_conheight*0.5))
 145                 ymax = vid_conheight - ymin;
 146
 147         drawfont = sbar_bigfont;
 148         sbar_fontsize = Sbar_GetFontsize("sbar_fontsize");
 149
 150         pos_y = ymin;
 151         pos_z = 0;
 152         pos_x = center - stringwidth("Vote for a map", false) * 0.5 * 24;
 153         drawstring(pos, "Vote for a map", '24 24 0', '1 1 1', 1, DRAWFLAG_NORMAL);
 154         pos_y += 26;
 155
 156         i = ceil(max(0, mv_timeout - time));
 157         map = strcat(ftos(i), " seconds left");
 158         pos_x = center - stringwidth(map, false) * 0.5 * 16;
 159         drawstring(pos, map, '16 16 0', '0 1 0', 1, DRAWFLAG_NORMAL);
 160         pos_y += 22;
 161         pos_x = xmin;
 162
 163         drawfont = sbar_font;
 164
 165         // base for multi-column stuff...
 166         ymin = pos_y;
 167         if(mv_abstain)
 168                 mv_num_maps -= 1;
 169
 170         if(mv_num_maps > 3)
 171         {
 172                 columns = 3;
 173         } else {
 174                 columns = mv_num_maps;
 175         }
 176         rows = ceil(mv_num_maps / columns);
 177
 178         dist_x = (xmax - xmin) / columns;
 179         dist_y = (ymax - pos_y) / rows;
 180         tsize = dist_x - 10;
 181         isize = min(dist_y - 10, 0.75 * tsize);
 182
 183         pos_x += (xmax - xmin) / (2 * columns);
 184         pos_y += (dist_y - isize) / 2;
 185         ymax -= isize;
 186         for(i = 0; i < mv_num_maps; ++i)
 187         {
 188                 tmp = mv_votes[i]; // FTEQCC bug: too many array accesses in the function call screw it up
 189                 if(tmp < 0)
 190                         continue;
 191                 map = mv_maps[i];
 192                 if(mv_preview[i])
 193                         MapVote_DrawMapItem(pos + MapVote_GridVec(dist, i, columns), isize, tsize, map, mv_pics[i], tmp, i);
 194                 else
 195                         MapVote_DrawMapItem(pos + MapVote_GridVec(dist, i, columns), isize, tsize, map, "", tmp, i);
 196         }
 197
 198         if(mv_abstain)
 199                 ++mv_num_maps;
 200
 201         if(mv_abstain && i < mv_num_maps) {
 202                 tmp = mv_votes[i];
 203                 pos_y = ymax + isize - sbar_fontsize_y;
 204                 pos_x = (xmax+xmin)*0.5;
 205                 MapVote_DrawAbstain(pos, isize, xmax - xmin, tmp, i);
 206         }
 207 }
 208
 209 void Cmd_MapVote_MapDownload(float argc)
 210 {
 211         float id;
 212         entity pak;
 213
 214         if(argc != 2 || !mv_pk3list)
 215         {
 216                 print("mv_mapdownload: ^3You're not supposed to use this command on your own!\n");
 217                 return;
 218         }
 219
 220         id = stof(argv(1));
 221         for(pak = mv_pk3list; pak; pak = pak.chain)
 222                 if(pak.sv_entnum == id)
 223                         break;
 224
 225         if(!pak || pak.sv_entnum != id) {
 226                 print("^1Error:^7 Couldn't find pak index.\n");
 227                 return;
 228         }
 229
 230         //print(strcat("^3Adding: ", ftos(id), " - ", pak.message, " - "));
 231
 232         if(PreviewExists(pak.message))
 233         {
 234                 mv_preview[id] = true;
 235                 //print("^2Found...\n");
 236                 return;
 237         } else {
 238                 print("Requesting preview...\n");
 239                 localcmd(strcat("\ncmd mv_getpic ", ftos(id), "\n"));
 240         }
 241 }
 242
 243 void MapVote_CheckPK3(string pic, string pk3, float id)
 244 {
 245         entity pak;
 246         pak = spawn();
 247         pak.netname = pk3;
 248         pak.message = pic;
 249         pak.sv_entnum = id;
 250
 251         pak.chain = mv_pk3list;
 252         mv_pk3list = pak;
 253
 254         if(pk3 != "")
 255         {
 256                 localcmd(strcat("\ncurl --pak ", pk3, "; wait; cl_cmd mv_download ", ftos(id), "\n"));
 257         }
 258         else
 259         {
 260                 Cmd_MapVote_MapDownload(tokenize_console(strcat("mv_download ", ftos(id))));
 261         }
 262 }
 263
 264 void MapVote_CheckPic(string pic, string pk3, float id)
 265 {
 266         // never try to retrieve a pic for the "don't care" 'map'
 267         if(mv_abstain && id == mv_num_maps - 1)
 268                 return;
 269
 270         if(PreviewExists(pic))
 271         {
 272                 mv_preview[id] = true;
 273                 return;
 274         }
 275         MapVote_CheckPK3(pic, pk3, id);
 276 }
 277
 278 void MapVote_Init()
 279 {
 280         float i, power;
 281         string map, pk3, ssdir;
 282
 283         precache_sound ("misc/invshot.wav");
 284
 285         registercmd("+showscores");
 286         registercmd("-showscores");
 287
 288         mv_active = 1;
 289
 290         ssdir = ReadString();
 291
 292         mv_num_maps = min(MAPVOTE_COUNT, ReadByte());
 293         mv_abstain = ReadByte();
 294         if(mv_abstain)
 295                 mv_abstain = 1; // must be 1 for bool-true, makes stuff easier
 296         mv_detail = ReadByte();
 297
 298         mv_ownvote = -1;
 299         mv_timeout = ReadCoord();
 300
 301         if(mv_num_maps <= 8)
 302                 mv_maps_mask = ReadByte();
 303         else
 304                 mv_maps_mask = ReadShort();
 305
 306         // Assume mv_pk3list is NULL, there should only be 1 mapvote per round
 307         mv_pk3list = NULL; // I'm still paranoid!
 308
 309         for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 310         {
 311                 mv_votes[i] = 0;
 312
 313                 if(mv_maps_mask & power)
 314                 {
 315                         map = strzone(ReadString());
 316                         pk3 = strzone(ReadString());
 317                         mv_maps[i] = map;
 318                         mv_pk3[i] = pk3;
 319                         map = strzone(strcat(ssdir, "/", map));
 320                         mv_pics[i] = map;
 321
 322                         mv_preview[i] = false;
 323
 324                         //print(strcat("RECV: ", map, " in ", pk3, "\n"));
 325                         MapVote_CheckPic(map, pk3, i);
 326                 }
 327                 else
 328                 {
 329                         mv_maps[i] = strzone("if-you-see-this-the-code-is-broken");
 330                         mv_pk3[i] = strzone("if-you-see-this-the-code-is-broken");
 331                         mv_pics[i] = strzone("if-you-see-this-the-code-is-broken");
 332                         mv_preview[i] = false;
 333                 }
 334         }
 335
 336         // do we NEED this, or can we handle key presses directly in CSQC?
 337         localcmd("\nin_bind 7 1 \"impulse 1\"; in_bind 7 2 \"impulse 2\"; in_bind 7 3 \"impulse 3\"; in_bind 7 4 \"impulse 4\"; in_bind 7 5 \"impulse 5\"; in_bind 7 6 \"impulse 6\"; in_bind 7 7 \"impulse 7\"; in_bind 7 8 \"impulse 8\"; in_bind 7 9 \"impulse 9\"; in_bind 7 0 \"impulse 10\"; in_bind 7 KP_1 \"impulse 1\"; in_bind 7 KP_2 \"impulse 2\"; in_bind 7 KP_3 \"impulse 3\"; in_bind 7 KP_4 \"impulse 4\"; in_bind 7 KP_5 \"impulse 5\"; in_bind 7 KP_6 \"impulse 6\"; in_bind 7 KP_7 \"impulse 7\"; in_bind 7 KP_8 \"impulse 8\"; in_bind 7 KP_9 \"impulse 9\"; in_bind 7 KP_0 \"impulse 10\"; in_bindmap 7 0\n");
 338 }
 339
 340 void MapVote_UpdateMask()
 341 {
 342         float i, power;
 343         float oldmask;
 344
 345         oldmask = mv_maps_mask;
 346         if(mv_num_maps <= 8)
 347                 mv_maps_mask = ReadByte();
 348         else
 349                 mv_maps_mask = ReadShort();
 350
 351         if(oldmask & mv_maps_mask != oldmask)
 352                 if(oldmask & mv_maps_mask == mv_maps_mask)
 353                          sound(world, CHAN_AUTO, "misc_invshot.wav", VOL_BASE, ATTN_NONE);
 354
 355         // remove votes that no longer apply
 356         for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 357                 if not(mv_maps_mask & power)
 358                         mv_votes[i] = -1;
 359 }
 360
 361 void MapVote_UpdateVotes()
 362 {
 363         float i, power;
 364         for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 365         {
 366                 if(mv_maps_mask & power)
 367                 {
 368                         if(mv_detail)
 369                                 mv_votes[i] = ReadByte();
 370                         else
 371                                 mv_votes[i] = 0;
 372                 }
 373                 else
 374                         mv_votes[i] = -1;
 375         }
 376
 377         mv_ownvote = ReadByte()-1;
 378 }
 379
 380 void Ent_MapVote()
 381 {
 382         float sf;
 383
 384         sf = ReadByte();
 385
 386         if(sf & 1)
 387                 MapVote_Init();
 388
 389         if(sf & 2)
 390                 MapVote_UpdateMask();
 391
 392         if(sf & 4)
 393                 MapVote_UpdateVotes();
 394 }
 395
 396 void Net_MapVote_Picture()
 397 {
 398         float type;
 399         type = ReadByte();
 400         mv_preview[type] = true;
 401         mv_pics[type] = strzone(ReadPicture());
 402 }