data/qcsrc/client/View.qc

   1 #define spider_rocket_icon "gfx/spiderbot/rocket_ico.tga"
   2 #define spider_rocket_targ "gfx/spiderbot/target.tga"
   3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
   4 #define rkt_size 32
   5 #define rld_size_x 256
   6 #define rld_size_y 16
   7
   8 void CSQC_WAKIZASHI_HUD();
   9
  10 entity porto;
  11 vector polyline[16];
  12 float trace_dphitcontents;
  13 float trace_networkentity;
  14 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
  15 float DPCONTENTS_SOLID = 1; // blocks player movement
  16 float DPCONTENTS_BODY = 32; // blocks player movement
  17 float DPCONTENTS_CORPSE = 64; // blocks player movement
  18 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  19 void Porto_Draw()
  20 {
  21         vector p, dir, ang, q, nextdir;
  22         float idx, portal_number, portal1_idx;
  23
  24         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  25                 return;
  26         if(intermission == 1)
  27                 return;
  28         if(intermission == 2)
  29                 return;
  30         if (getstati(STAT_HEALTH) <= 0)
  31                 return;
  32
  33         dir = view_forward;
  34
  35         if(angles_held_status)
  36         {
  37                 makevectors(angles_held);
  38                 dir = v_forward;
  39         }
  40
  41         p = view_origin;
  42
  43         polyline[0] = p;
  44         idx = 1;
  45         portal_number = 0;
  46         nextdir = dir;
  47
  48         for(;;)
  49         {
  50                 dir = nextdir;
  51                 traceline(p, p + 65536 * dir, TRUE, porto);
  52                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  53                         return;
  54                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  55                 p = trace_endpos;
  56                 polyline[idx] = p;
  57                 ++idx;
  58                 if(idx >= 16)
  59                         return;
  60                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  61                         continue;
  62                 ++portal_number;
  63                 ang = vectoangles2(trace_plane_normal, dir);
  64                 ang_x = -ang_x;
  65                 makevectors(ang);
  66                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  67                         return;
  68                 if(portal_number == 1)
  69                         portal1_idx = idx;
  70                 if(portal_number >= 2)
  71                         break;
  72         }
  73
  74         while(idx >= 2)
  75         {
  76                 p = polyline[idx-2];
  77                 q = polyline[idx-1];
  78                 if(idx == 2)
  79                         p = p - view_up * 16;
  80                 if(idx-1 >= portal1_idx)
  81                 {
  82                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL);
  83                 }
  84                 else
  85                 {
  86                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL);
  87                 }
  88                 --idx;
  89         }
  90 }
  91
  92 /**
  93  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  94  *
  95  * TODO: Use a better solution where a common shared entitiy is used that contains
  96  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  97  * and STAT_FRAGLIMIT to be auto-sent)
  98  */
  99 void CheckForGamestartChange() {
 100         float startTime;
 101         startTime = getstatf(STAT_GAMESTARTTIME);
 102         if (previous_game_starttime != startTime) {
 103                 if ((time + 5.0) < startTime) {
 104                         //if connecting to server while restart was active don't always play prepareforbattle
 105                         sound(self, CHAN_VOICE, strcat("announcer/", cvar_string("cl_announcer"), "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
 106                 }
 107                 if (time < startTime) {
 108                         restartAnnouncer = spawn();
 109                         restartAnnouncer.think = restartAnnouncer_Think;
 110                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 111                 }
 112         }
 113         previous_game_starttime = startTime;
 114 }
 115
 116 void Porto_Init()
 117 {
 118         porto = spawn();
 119         porto.classname = "porto";
 120         porto.draw = Porto_Draw;
 121         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 122 }
 123
 124 float drawtime;
 125 float avgspeed;
 126 vector GetCurrentFov(float fov)
 127 {
 128         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 129
 130         zoomsensitivity = cvar("cl_zoomsensitivity");
 131         zoomfactor = cvar("cl_zoomfactor");
 132         if(zoomfactor < 1 || zoomfactor > 16)
 133                 zoomfactor = 2.5;
 134         zoomspeed = cvar("cl_zoomspeed");
 135         if(zoomspeed >= 0)
 136                 if(zoomspeed < 0.5 || zoomspeed > 16)
 137                         zoomspeed = 3.5;
 138
 139         zoomdir = button_zoom;
 140         if(getstati(STAT_ACTIVEWEAPON) == WEP_NEX) // do NOT use switchweapon here
 141                 zoomdir += button_attack2;
 142         if(spectatee_status > 0 || isdemo())
 143         {
 144                 if(spectatorbutton_zoom)
 145                         zoomdir = 0 + !zoomdir;
 146                 // do not even THINK about removing this 0
 147                 // _I_ know what I am doing
 148                 // fteqcc does not
 149         }
 150
 151         if(zoomdir)
 152                 zoomin_effect = 0;
 153
 154         if(zoomin_effect || camera_active)
 155         {
 156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 157         }
 158         else
 159         {
 160                 if(zoomspeed < 0) // instant zoom
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / zoomfactor;
 164                         else
 165                                 current_viewzoom = 1;
 166                 }
 167                 else
 168                 {
 169                         if(zoomdir)
 170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 171                         else
 172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 173                 }
 174         }
 175
 176         if(almost_equals(current_viewzoom, 1))
 177                 current_zoomfraction = 0;
 178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 179                 current_zoomfraction = 1;
 180         else
 181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 182
 183         if(zoomsensitivity < 1)
 184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 185         else
 186                 setsensitivityscale(1);
 187
 188         velocityzoom = bound(0, drawframetime / max(0.000000001, cvar_or("cl_velocityzoomtime", 0.3)), 1);
 189         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 190         velocityzoom = exp(float2range11(avgspeed * -cvar_or("cl_velocityzoom", 0) / 1) * 1);
 191
 192         //print(ftos(avgspeed), " avgspeed, ", ftos(cvar_or("cl_velocityzoom", 0)), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 193
 194         float frustumx, frustumy, fovx, fovy;
 195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 199
 200         return '1 0 0' * fovx + '0 1 0' * fovy;
 201 }
 202
 203 // this function must match W_SetupShot!
 204 float zoomscript_caught;
 205
 206 vector wcross_origin;
 207 float wcross_scale_prev, wcross_alpha_prev;
 208 vector wcross_color_prev;
 209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 210 vector wcross_color_goal_prev;
 211 float wcross_changedonetime;
 212
 213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 215 float wcross_name_changestarttime, wcross_name_changedonetime;
 216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 217 entity trueaim;
 218 entity trueaim_rifle;
 219
 220 #define SHOTTYPE_HITTEAM 1
 221 #define SHOTTYPE_HITOBSTRUCTION 2
 222 #define SHOTTYPE_HITWORLD 3
 223 #define SHOTTYPE_HITENEMY 4
 224
 225 void TrueAim_Init()
 226 {
 227         trueaim = spawn();
 228         trueaim.classname = "trueaim";
 229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230         trueaim_rifle = spawn();
 231         trueaim_rifle.classname = "trueaim_rifle";
 232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 233 }
 234
 235 float EnemyHitCheck()
 236 {
 237         float t;
 238         wcross_origin = project_3d_to_2d(trace_endpos);
 239         wcross_origin_z = 0;
 240         if(trace_networkentity < 1)
 241                 return SHOTTYPE_HITWORLD;
 242         if(trace_networkentity > maxclients)
 243                 return SHOTTYPE_HITWORLD;
 244         t = GetPlayerColor(trace_networkentity - 1);
 245         if(teamplay)
 246                 if(t == myteam)
 247                         return SHOTTYPE_HITTEAM;
 248         if(t == COLOR_SPECTATOR)
 249                 return SHOTTYPE_HITWORLD;
 250         return SHOTTYPE_HITENEMY;
 251 }
 252
 253 float TrueAimCheck()
 254 {
 255         float nudge = 1; // added to traceline target and subtracted from result
 256         vector vecs, trueaimpoint, w_shotorg;
 257         vector mi, ma, dv;
 258         float shottype;
 259         entity ta;
 260         float mv;
 261
 262         mi = ma = '0 0 0';
 263         ta = trueaim;
 264         mv = MOVE_NOMONSTERS;
 265
 266         switch(activeweapon)
 267         {
 268                 case WEP_TUBA: // no aim
 269                 case WEP_PORTO: // shoots from eye
 270                 case WEP_HOOK: // no trueaim
 271                 case WEP_GRENADE_LAUNCHER: // toss curve
 272                         return SHOTTYPE_HITWORLD;
 273                 case WEP_NEX:
 274                 case WEP_MINSTANEX:
 275                         mv = MOVE_NORMAL;
 276                         break;
 277                 case WEP_CAMPINGRIFLE:
 278                         ta = trueaim_rifle;
 279                         mv = MOVE_NORMAL;
 280                         if(zoomscript_caught)
 281                         {
 282                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 283                                 return EnemyHitCheck();
 284                         }
 285                         break;
 286                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 287                         mi = '-3 -3 -3';
 288                         ma = '3 3 3';
 289                         break;
 290                 case WEP_FIREBALL: // projectile has a size!
 291                         mi = '-16 -16 -16';
 292                         ma = '16 16 16';
 293                         break;
 294                 case WEP_ELECTRO: // projectile has a size!
 295                         mi = '0 0 -3';
 296                         ma = '0 0 -3';
 297                         break;
 298         }
 299
 300         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 301
 302         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 303         trueaimpoint = trace_endpos;
 304
 305         if(vecs_x > 0)
 306                 vecs_y = -vecs_y;
 307         else
 308                 vecs = '0 0 0';
 309
 310         dv = view_right * vecs_y + view_up * vecs_z;
 311         w_shotorg = view_origin + dv;
 312
 313         // now move the vecs forward as much as requested if possible
 314         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 315         w_shotorg = trace_endpos - view_forward * nudge;
 316
 317         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 318         shottype = EnemyHitCheck();
 319         if(shottype != SHOTTYPE_HITWORLD)
 320                 return shottype;
 321
 322 #if 0
 323         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 324         // or rather, I know why, but see no fix
 325         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 326                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 327                 return SHOTTYPE_HITOBSTRUCTION;
 328 #endif
 329
 330         return SHOTTYPE_HITWORLD;
 331 }
 332
 333 void CSQC_common_hud(void);
 334
 335 void CSQC_kh_hud(void);
 336 void CSQC_ctf_hud(void);
 337 void PostInit(void);
 338 void CSQC_Demo_Camera();
 339 float Sbar_WouldDrawScoreboard ();
 340 float view_set;
 341 float camera_mode;
 342 string NextFrameCommand;
 343 void CSQC_spider_HUD();
 344 void CSQC_UpdateView(float w, float h)
 345 {
 346         entity e;
 347         float fov;
 348         float f, i, j;
 349         vector v;
 350
 351         WaypointSprite_Load();
 352
 353         if(spectatee_status)
 354                 myteam = GetPlayerColor(spectatee_status - 1);
 355         else
 356                 myteam = GetPlayerColor(player_localentnum - 1);
 357
 358         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 359
 360         // Render the Scene
 361         if(!intermission || !view_set)
 362         {
 363                 view_origin = pmove_org + '0 0 1' * getstati(STAT_VIEWHEIGHT);
 364                 view_angles = input_angles;
 365                 makevectors(view_angles);
 366                 view_forward = v_forward;
 367                 view_right = v_right;
 368                 view_up = v_up;
 369                 view_set = 1;
 370         }
 371
 372         vid_width = w;
 373         vid_height = h;
 374
 375 #ifdef BLURTEST
 376         if(time > blurtest_time0 && time < blurtest_time1)
 377         {
 378                 float r, t;
 379
 380                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 381                 r = t * blurtest_radius;
 382                 f = 1 / pow(t, blurtest_power) - 1;
 383
 384                 cvar_set("r_glsl_postprocess", "1");
 385                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 386         }
 387         else
 388         {
 389                 cvar_set("r_glsl_postprocess", "0");
 390                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 391         }
 392 #endif
 393
 394         Fog_Force();
 395
 396         drawframetime = max(0.000001, time - drawtime);
 397         drawtime = time;
 398
 399         // watch for gametype changes here...
 400         // in ParseStuffCMD the cmd isn't executed yet :/
 401         // might even be better to add the gametype to TE_CSQC_INIT...?
 402         if(!postinit)
 403                 PostInit();
 404
 405         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 406                 if(calledhooks & HOOK_START)
 407                 {
 408                         localcmd("\ncl_hook_gameend;");
 409                         calledhooks |= HOOK_END;
 410                 }
 411
 412         CheckForGamestartChange();
 413         serverAnnouncer();
 414         maptimeAnnouncer();
 415         carrierAnnouncer();
 416
 417         fov = cvar("fov");
 418         if(button_zoom || fov <= 59.5)
 419         {
 420                 if(!zoomscript_caught)
 421                 {
 422                         localcmd("+button4\n");
 423                         zoomscript_caught = 1;
 424                         ignore_plus_zoom += 1;
 425                 }
 426         }
 427         else
 428         {
 429                 if(zoomscript_caught)
 430                 {
 431                         localcmd("-button4\n");
 432                         zoomscript_caught = 0;
 433                         ignore_minus_zoom += 1;
 434                 }
 435         }
 436
 437         sbar_alpha_fg = cvar("sbar_alpha_fg" ) * (1 - cvar("_menu_alpha"));
 438         sbar_currentammo = cvar("sbar_showcurrentammo");
 439         sbar_hudselector = cvar("sbar_hudselector");
 440         sbar_accuracy_hud = cvar_or("sbar_accuracy_hud", 1);
 441         ColorTranslateMode = cvar("cl_stripcolorcodes");
 442         activeweapon = getstati(STAT_SWITCHWEAPON);
 443         f = cvar("teamplay");
 444         if(f != teamplay)
 445         {
 446                 teamplay = f;
 447                 Sbar_InitScores();
 448         }
 449
 450         if(last_weapon != activeweapon) {
 451                 weapontime = time;
 452                 last_weapon = activeweapon;
 453         }
 454
 455         // ALWAYS Clear Current Scene First
 456         R_ClearScene();
 457
 458         // Assign Standard Viewflags
 459         // Draw the World (and sky)
 460         R_SetView(VF_DRAWWORLD, 1);
 461
 462         // Set the console size vars
 463         vid_conwidth = cvar("vid_conwidth");
 464         vid_conheight = cvar("vid_conheight");
 465         vid_pixelheight = cvar("vid_pixelheight");
 466
 467         R_SetView(VF_FOV, GetCurrentFov(fov));
 468
 469         // Camera for demo playback
 470         if(camera_active)
 471         {
 472                 if(cvar("camera_enable"))
 473                         CSQC_Demo_Camera();
 474                 else
 475                 {
 476                         cvar_set("chase_active", ftos(chase_active_backup));
 477                         cvar_set("cl_demo_mousegrab", "0");
 478                         camera_active = FALSE;
 479                 }
 480         }
 481 #ifdef CAMERATEST
 482         else if(cvar("camera_enable"))
 483 #else
 484         else if(cvar("camera_enable") && isdemo())
 485 #endif
 486         {
 487                 // Enable required Darkplaces cvars
 488                 chase_active_backup = cvar("chase_active");
 489                 cvar_set("chase_active", "2");
 490                 cvar_set("cl_demo_mousegrab", "1");
 491                 camera_active = TRUE;
 492                 camera_mode = FALSE;
 493         }
 494
 495         // Draw the Crosshair
 496         float scoreboard_active;
 497         scoreboard_active = Sbar_WouldDrawScoreboard();
 498         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 499
 500         // Draw the Engine Status Bar (the default Quake HUD)
 501         R_SetView(VF_DRAWENGINESBAR, 0);
 502
 503         // fetch this one only once per frame
 504         sbar_showbinds = cvar("sbar_showbinds");
 505         sbar_showbinds_limit = cvar("sbar_showbinds_limit");
 506
 507         // Update the mouse position
 508         /*
 509            mousepos_x = vid_conwidth;
 510            mousepos_y = vid_conheight;
 511            mousepos = mousepos*0.5 + getmousepos();
 512          */
 513
 514         e = self;
 515         for(self = world; (self = nextent(self)); )
 516                 if(self.draw)
 517                         self.draw();
 518         self = e;
 519
 520         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 521         R_RenderScene();
 522
 523         // now switch to 2D drawing mode by calling a 2D drawing function
 524         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 525         // next R_RenderScene call
 526         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 527
 528         // Draw the mouse cursor
 529         // NOTE: drawpic must happen after R_RenderScene for some reason
 530         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
 531         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
 532         //self = edict_num(player_localnum);
 533         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
 534         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
 535         // as long as the ctf part isn't in, this is useless
 536         if(menu_visible)
 537                 menu_show();
 538
 539         /*if(gametype == GAME_CTF)
 540           {
 541           ctf_view();
 542           } else */
 543
 544         // draw 2D entities
 545         e = self;
 546         for(self = world; (self = nextent(self)); )
 547                 if(self.draw2d)
 548                         self.draw2d();
 549         self = e;
 550
 551         // draw radar
 552         if(
 553                         ons_showmap
 554                         ||
 555                         (
 556                          !scoreboard_active
 557                          &&
 558                          cvar_string("cl_teamradar") != "0"
 559                          &&
 560                          (
 561                           cvar("cl_teamradar") == 2
 562                           ||
 563                           teamplay
 564                          )
 565                         )
 566           )
 567                 teamradar_view();
 568
 569         // draw sbar
 570         if(cvar("r_letterbox") == 0) {
 571                 if (cvar("cl_showpressedkeys")) { // draw pressed keys when spectating and playing
 572                         if(spectatee_status > 0 || cvar("cl_showpressedkeys") >= 2)
 573                                 Sbar_DrawPressedKeys();
 574                 }
 575
 576                 if (cvar("cl_showspeed"))
 577                         Sbar_ShowSpeed();
 578                 if (cvar("cl_showacceleration"))
 579                         Sbar_ShowAcceleration();
 580
 581                 Sbar_DrawCenterPrint(); // draw centerprint messages even if viewsize >= 120
 582         }
 583
 584         float hud;
 585         hud = getstati(STAT_HUD);
 586         if(hud == HUD_SPIDERBOT)
 587         {
 588                 CSQC_spider_HUD();
 589         }
 590         else if(hud == HUD_WAKIZASHI)
 591         CSQC_WAKIZASHI_HUD();
 592         else
 593         {
 594                 if(cvar("r_letterbox") == 0)
 595                         if(cvar("viewsize") < 120)
 596                                 CSQC_common_hud();
 597
 598                 // crosshair goes VERY LAST
 599                 if(!scoreboard_active && !ons_showmap && !camera_active) {
 600                         // TrueAim check
 601                         float shottype;
 602                         float bullets, ring_scale;
 603                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 604                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 605                         wcross_origin_z = 0;
 606                         if(cvar("crosshair_hittest"))
 607                         {
 608                                 vector wcross_oldorigin;
 609                                 wcross_oldorigin = wcross_origin;
 610                                 shottype = TrueAimCheck();
 611                                 if(shottype == SHOTTYPE_HITWORLD)
 612                                 {
 613                                         v = wcross_origin - wcross_oldorigin;
 614                                         v_x /= vid_conwidth;
 615                                         v_y /= vid_conheight;
 616                                         if(vlen(v) > 0.01)
 617                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 618                                 }
 619                                 if(!cvar("crosshair_hittest_showimpact"))
 620                                         wcross_origin = wcross_oldorigin;
 621                         }
 622                         else
 623                                 shottype = SHOTTYPE_HITWORLD;
 624
 625                         string wcross_style;
 626                         wcross_style = cvar_string("crosshair");
 627
 628                         if (wcross_style != "0") {
 629                                 vector wcross_color, wcross_size;
 630                                 string wcross_wep, wcross_name;
 631                                 float wcross_alpha, wcross_scale, wcross_blur, wcross_resolution;
 632
 633                                 wcross_color_x = cvar("crosshair_color_red");
 634                                 wcross_color_y = cvar("crosshair_color_green");
 635                                 wcross_color_z = cvar("crosshair_color_blue");
 636                                 wcross_alpha = cvar("crosshair_color_alpha");
 637                                 wcross_resolution = cvar("crosshair_size");
 638                                 if (cvar("crosshair_per_weapon")) {
 639                                         e = get_weaponinfo(activeweapon);
 640                                         if (e && e.netname != "")
 641                                         {
 642                                                 wcross_wep = e.netname;
 643                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 644                                                 if(wcross_style == "")
 645                                                         wcross_style = e.netname;
 646
 647                                                 if(!cvar("crosshair_color_override"))
 648                                                 {
 649                                                         wcross_color_x = cvar(strcat("crosshair_", wcross_wep, "_color_red"));
 650                                                         wcross_color_y = cvar(strcat("crosshair_", wcross_wep, "_color_green"));
 651                                                         wcross_color_z = cvar(strcat("crosshair_", wcross_wep, "_color_blue"));
 652                                                 }
 653
 654                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_color_alpha"));
 655                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 656                                         }
 657                                 }
 658
 659                                 wcross_name = strcat("gfx/crosshair", wcross_style);
 660
 661                                 if(cvar("crosshair_effect_scalefade"))
 662                                 {
 663                                         wcross_scale = wcross_resolution;
 664                                         wcross_resolution = 1;
 665                                 }
 666                                 else
 667                                 {
 668                                         wcross_scale = 1;
 669                                 }
 670
 671                                 if(shottype == SHOTTYPE_HITENEMY)
 672                                         wcross_scale *= cvar("crosshair_hittest"); // is not queried if hittest is 0
 673                                 if(shottype == SHOTTYPE_HITTEAM)
 674                                         wcross_scale /= cvar("crosshair_hittest"); // is not queried if hittest is 0
 675
 676                                 f = cvar("crosshair_effect_speed");
 677                                 if(f < 0)
 678                                         f *= -2 * g_weaponswitchdelay;
 679                                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 680                                 {
 681                                         wcross_changedonetime = time + f;
 682                                 }
 683                                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 684                                 {
 685                                         wcross_name_changestarttime = time;
 686                                         wcross_name_changedonetime = time + f;
 687                                         if(wcross_name_goal_prev_prev)
 688                                                 strunzone(wcross_name_goal_prev_prev);
 689                                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
 690                                         wcross_name_goal_prev = strzone(wcross_name);
 691                                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 692                                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 693                                         wcross_resolution_goal_prev = wcross_resolution;
 694                                 }
 695
 696                                 wcross_scale_goal_prev = wcross_scale;
 697                                 wcross_alpha_goal_prev = wcross_alpha;
 698                                 wcross_color_goal_prev = wcross_color;
 699
 700                                 if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && cvar("crosshair_hittest_blur") && !cvar("chase_active")))
 701                                 {
 702                                         wcross_blur = 1;
 703                                         wcross_alpha *= 0.75;
 704                                 }
 705                                 else
 706                                         wcross_blur = 0;
 707                                 // *_prev is at time-frametime
 708                                 // * is at wcross_changedonetime+f
 709                                 // what do we have at time?
 710                                 if(time < wcross_changedonetime)
 711                                 {
 712                                         f = frametime / (wcross_changedonetime - time + frametime);
 713                                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 714                                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 715                                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 716                                 }
 717
 718                                 wcross_scale_prev = wcross_scale;
 719                                 wcross_alpha_prev = wcross_alpha;
 720                                 wcross_color_prev = wcross_color;
 721
 722                                 wcross_scale *= 1 - cvar("_menu_alpha");
 723                                 wcross_alpha *= 1 - cvar("_menu_alpha");
 724
 725                                 // ring around crosshair representing bullets left in camping rifle clip
 726                                 if (activeweapon == WEP_CAMPINGRIFLE)
 727                                 {
 728                                         ring_scale = cvar("crosshair_campingrifle_ring_size");
 729                                         bullets = bound(0, getstati(STAT_BULLETS_LOADED), 8);
 730                                 }
 731                                 else
 732                                         bullets = 0;
 733
 734 #define CROSSHAIR_DRAW_RING(i,j,sz,wcross_name,wcross_alpha) \
 735                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x * ring_scale + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y * ring_scale + j * wcross_blur)), strcat("gfx/hud/rifle_ring_", ftos(bullets)), sz * wcross_size * ring_scale, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 736
 737 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 738                                 do \
 739                                 { \
 740                                         if(wcross_blur > 0) \
 741                                         { \
 742                                                 for(i = -2; i <= 2; ++i) \
 743                                                         for(j = -2; j <= 2; ++j) \
 744                                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
 745                                         } \
 746                                         else \
 747                                         { \
 748                                                 M(0,0,sz,wcross_name,wcross_alpha); \
 749                                         } \
 750                                 } \
 751                                 while(0)
 752
 753 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
 754                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 755
 756 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 757                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 758
 759                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 760                                 {
 761                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 762                                         wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 763                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 764                                         f = 1 - f;
 765                                 }
 766                                 else
 767                                 {
 768                                         f = 1;
 769                                 }
 770
 771                                 wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
 772                                 if(bullets)
 773                                 {
 774                                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_RING, wcross_resolution, wcross_name, wcross_alpha);
 775                                 }
 776                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 777                                 wcross_name_alpha_goal_prev = f;
 778                         }
 779                 }
 780                 else
 781                 {
 782                         wcross_scale_prev = 0;
 783                         wcross_alpha_prev = 0;
 784                         wcross_scale_goal_prev = 0;
 785                         wcross_alpha_goal_prev = 0;
 786                         wcross_changedonetime = 0;
 787                         if(wcross_name_goal_prev)
 788                                 strunzone(wcross_name_goal_prev);
 789                         wcross_name_goal_prev = string_null;
 790                         if(wcross_name_goal_prev_prev)
 791                                 strunzone(wcross_name_goal_prev_prev);
 792                         wcross_name_goal_prev_prev = string_null;
 793                         wcross_name_changestarttime = 0;
 794                         wcross_name_changedonetime = 0;
 795                         wcross_name_alpha_goal_prev = 0;
 796                         wcross_name_alpha_goal_prev_prev = 0;
 797                         wcross_resolution_goal_prev = 0;
 798                         wcross_resolution_goal_prev_prev = 0;
 799                 }
 800         }
 801
 802         if(NextFrameCommand)
 803         {
 804                 localcmd("\n", NextFrameCommand, "\n");
 805                 NextFrameCommand = string_null;
 806         }
 807
 808         // we must do this check AFTER a frame was rendered, or it won't work
 809         if(cs_project_is_b0rked == 0)
 810         {
 811                 string w0, h0;
 812                 w0 = cvar_string("vid_conwidth");
 813                 h0 = cvar_string("vid_conheight");
 814                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
 815                 //R_SetView(VF_FOV, '90 90 0');
 816                 R_SetView(VF_ORIGIN, '0 0 0');
 817                 R_SetView(VF_ANGLES, '0 0 0');
 818                 R_SetView(VF_PERSPECTIVE, 1);
 819                 makevectors('0 0 0');
 820                 vector v1, v2;
 821                 cvar_set("vid_conwidth", "800");
 822                 cvar_set("vid_conheight", "600");
 823                 v1 = cs_project(v_forward);
 824                 cvar_set("vid_conwidth", "640");
 825                 cvar_set("vid_conheight", "480");
 826                 v2 = cs_project(v_forward);
 827                 if(v1 == v2)
 828                         cs_project_is_b0rked = 1;
 829                 else
 830                         cs_project_is_b0rked = -1;
 831                 cvar_set("vid_conwidth", w0);
 832                 cvar_set("vid_conheight", h0);
 833         }
 834
 835         // be safe against triggerbots until everyone has the fixed engine
 836         // this call is meant to overwrite the trace globals by something
 837         // unsuspicious
 838         traceline('0 0 0', '0 0 0', MOVE_WORLDONLY, world);
 839 }
 840
 841 void Sbar_Draw();
 842 void CSQC_spider_HUD()
 843 {
 844         float rockets,reload,heat,hp,shield,i;
 845         vector p,pp;
 846
 847     p = drawgetimagesize(SPIDER_CROSS);
 848     p_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
 849     p_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
 850     drawpic('0.5 0 0' * (vid_conwidth - p_x) + '0 0.5 0' * (vid_conheight - p_y), SPIDER_CROSS, p, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
 851
 852     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
 853         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
 854         heat    = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
 855         rockets =     getstati(STAT_VEHICLESTAT_AMMO2);
 856         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD2), 1);
 857
 858         // Draw health bar
 859         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
 860         p = p + '0 1 0' * vid_conheight - '0 32 0';
 861         //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
 862         drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
 863         p_y += 8;
 864         drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
 865         p_x += 256 * hp;
 866         drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
 867
 868         // Draw minigun heat indicator
 869         p = '0.5 0 0' * (vid_conwidth - 256);
 870         p = p + '0 1 0' * vid_conheight - '0 34  0';
 871         drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
 872         p_x += 256 * (1-heat);
 873         drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
 874
 875         // Draw rocket icons for loaded/empty tubes.
 876         pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
 877         pp += '0 1 0' * vid_conheight - '0 64 0';
 878         for(i = 0; i < 8; ++i)
 879         {
 880                 p = pp + '1 0 0' * (rkt_size * i);
 881                 if(rockets == 8)
 882                 {
 883                         if(floor(reload * 8) == i)
 884                         {
 885                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
 886                         }
 887                         else if(i < reload * 8)
 888                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
 889                         else
 890                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
 891                 }
 892                 else
 893                 {
 894                         if(i < rockets)
 895                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
 896                         else
 897                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
 898                 }
 899         }
 900
 901         if (sb_showscores)
 902         {
 903                 Sbar_DrawScoreboard();
 904                 Sbar_DrawCenterPrint();
 905         }
 906
 907 }
 908
 909 void CSQC_WAKIZASHI_HUD()
 910 {
 911         // 0--1 floats. 1 = 100%, 0.6 = 50%.
 912         float health, shield, energy, rockets;
 913
 914         vector p;
 915
 916     p = drawgetimagesize(SPIDER_CROSS);
 917     p_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
 918     p_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
 919     drawpic('0.5 0 0' * (vid_conwidth - p_x) + '0 0.5 0' * (vid_conheight - p_y), SPIDER_CROSS, p, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
 920
 921 /*
 922 const float STAT_VEHICLESTAT_HEALTH  = 60;
 923 const float STAT_VEHICLESTAT_SHIELD  = 61;
 924 const float STAT_VEHICLESTAT_ENERGY  = 62;
 925 const float STAT_VEHICLESTAT_AMMO1   = 63;
 926 const float STAT_VEHICLESTAT_RELAOD1 = 64;
 927 const float STAT_VEHICLESTAT_AMMO2   = 65;
 928 const float STAT_VEHICLESTAT_RELOAD2 = 66;
 929 */
 930     health  = min(getstatf(STAT_VEHICLESTAT_HEALTH),  1);
 931         shield  = min(getstatf(STAT_VEHICLESTAT_SHIELD),  1);
 932         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
 933         rockets = bound(0,getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
 934
 935
 936         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
 937         p = p + '0 1 0' * vid_conheight - '0 32 0';
 938
 939         // Draw health bar
 940         p_y += 8;
 941         drawfill(p, '256 0 0' * health + '0 8 0' , '0 0.7 0', 0.75, DRAWFLAG_NORMAL);
 942         p_x += 256 * health;
 943         drawfill(p, '256 0 0' * (1 - health) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
 944
 945         // Draw shiled bar
 946         p_x -= 256 * health;
 947         p_y += 4;
 948         drawfill(p, '256 0 0' * shield + '0 4 0' , '0.25 0.25 1', 0.5, DRAWFLAG_NORMAL);
 949
 950         // Draw energy
 951         //p_x -= 256 * health;
 952         p_y -= 8;
 953         drawfill(p, '256 0 0' * energy + '0 4 0' , '1 1 1', 0.75, DRAWFLAG_NORMAL);
 954
 955         // Draw rockets bar
 956         p_y += 12;
 957         drawfill(p, '256 0 0' * rockets + '0 4 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
 958
 959
 960         /*
 961         // Draw energy bar
 962         p = '0.5 0 0' * (vid_conwidth - 256);
 963         p = p + '0 1 0' * vid_conheight - '0 34  0';
 964         drawfill(p, '256 0 0' * (1 - energy) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
 965         p_x += 256 * (1 - energy);
 966         drawfill(p, '256 0 0' * energy  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
 967
 968         // Draw rockets bar
 969         p_y += 8;
 970         drawfill(p, '256 0 0' * rockets + '0 8 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
 971         p_x += 256 * health;
 972         drawfill(p, '256 0 0' * (1 - rockets) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
 973     */
 974
 975
 976         if (sb_showscores)
 977         {
 978                 Sbar_DrawScoreboard();
 979                 Sbar_DrawCenterPrint();
 980         }
 981
 982 }
 983
 984
 985 void CSQC_common_hud(void)
 986 {
 987         // Sbar_SortFrags(); done in Sbar_Draw
 988         float hud;
 989         hud = getstati(STAT_HUD);
 990
 991         //hud = 10;
 992         switch(hud)
 993         {
 994                 case HUD_NORMAL:
 995                         Sbar_Draw();
 996                         break;
 997
 998                 case HUD_SPIDERBOT:
 999                         CSQC_spider_HUD();
1000                         break;
1001
1002                 case HUD_WAKIZASHI:
1003                         CSQC_WAKIZASHI_HUD();
1004                         break;
1005         }
1006 }
1007
1008
1009 // following vectors must be global to allow seamless switching between camera modes
1010 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1011 void CSQC_Demo_Camera()
1012 {
1013         float speed, attenuation, dimensions;
1014         vector tmp, delta;
1015
1016         if( cvar("camera_reset") || !camera_mode )
1017         {
1018                 camera_offset = '0 0 0';
1019                 current_angles = '0 0 0';
1020                 camera_direction = '0 0 0';
1021                 camera_offset_z += 30;
1022                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1023                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1024                 current_origin = view_origin;
1025                 current_camera_offset  = camera_offset;
1026                 cvar_set("camera_reset", "0");
1027                 camera_mode = CAMERA_CHASE;
1028         }
1029
1030         // Camera angles
1031         if( camera_roll )
1032                 mouse_angles_z += camera_roll * cvar("camera_speed_roll");
1033
1034         if(cvar("camera_look_player"))
1035         {
1036                 local vector dir;
1037                 local float n;
1038
1039                 dir = normalize(view_origin - current_position);
1040                 n = mouse_angles_z;
1041                 mouse_angles = vectoangles(dir);
1042                 mouse_angles_x = mouse_angles_x * -1;
1043                 mouse_angles_z = n;
1044         }
1045         else
1046         {
1047                 tmp = getmousepos() * 0.1;
1048                 if(vlen(tmp)>cvar("camera_mouse_treshold"))
1049                 {
1050                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1051                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1052                 }
1053         }
1054
1055         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1056         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1057         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1058         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1059
1060         // Fix difference when angles don't have the same sign
1061         delta = '0 0 0';
1062         if(mouse_angles_y < -60 && current_angles_y > 60)
1063                 delta = '0 360 0';
1064         if(mouse_angles_y > 60 && current_angles_y < -60)
1065                 delta = '0 -360 0';
1066
1067         if(cvar("camera_look_player"))
1068                 attenuation = cvar("camera_look_attenuation");
1069         else
1070                 attenuation = cvar("camera_speed_attenuation");
1071
1072         attenuation = 1 / max(1, attenuation);
1073         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1074
1075         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1076         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1077         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1078         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1079
1080         // Camera position
1081         tmp = '0 0 0';
1082         dimensions = 0;
1083
1084         if( camera_direction_x )
1085         {
1086                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1087                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1088                 if( cvar("camera_forward_follows") && !cvar("camera_look_player") )
1089                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1090                 ++dimensions;
1091         }
1092
1093         if( camera_direction_y )
1094         {
1095                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1096                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1097                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1098                 ++dimensions;
1099         }
1100
1101         if( camera_direction_z )
1102         {
1103                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1104                 ++dimensions;
1105         }
1106
1107         if(cvar("camera_free"))
1108                 speed = cvar("camera_speed_free");
1109         else
1110                 speed = cvar("camera_speed_chase");
1111
1112         if(dimensions)
1113         {
1114                 speed = speed * sqrt(1 / dimensions);
1115                 camera_offset += tmp * speed;
1116         }
1117
1118         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1119
1120         // Camera modes
1121         if( cvar("camera_free") )
1122         {
1123                 if ( camera_mode == CAMERA_CHASE )
1124                 {
1125                         current_camera_offset = current_origin + current_camera_offset;
1126                         camera_offset = current_origin + camera_offset;
1127                 }
1128
1129                 camera_mode = CAMERA_FREE;
1130                 current_position = current_camera_offset;
1131         }
1132         else
1133         {
1134                 if ( camera_mode == CAMERA_FREE )
1135                 {
1136                         current_origin = view_origin;
1137                         camera_offset = camera_offset - current_origin;
1138                         current_camera_offset = current_camera_offset - current_origin;
1139                 }
1140
1141                 camera_mode = CAMERA_CHASE;
1142
1143                 if(cvar("camera_chase_smoothly"))
1144                         current_origin += (view_origin - current_origin) * attenuation;
1145                 else
1146                         current_origin = view_origin;
1147
1148                 current_position = current_origin + current_camera_offset;
1149         }
1150
1151         R_SetView(VF_ANGLES, current_angles);
1152         R_SetView(VF_ORIGIN, current_position);
1153 }