data/qcsrc/client/View.qc

   1 #define spider_rocket_icon "gfx/spiderbot/rocket_ico.tga"
   2 #define spider_rocket_targ "gfx/spiderbot/target.tga"
   3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
   4 #define rkt_size 32
   5 #define rld_size_x 256
   6 #define rld_size_y 16
   7
   8 void CSQC_WAKIZASHI_HUD();
   9
  10 entity porto;
  11 vector polyline[16];
  12 float trace_dphitcontents;
  13 float trace_networkentity;
  14 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
  15 float DPCONTENTS_SOLID = 1; // blocks player movement
  16 float DPCONTENTS_BODY = 32; // blocks player movement
  17 float DPCONTENTS_CORPSE = 64; // blocks player movement
  18 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  19 void Porto_Draw()
  20 {
  21         vector p, dir, ang, q, nextdir;
  22         float idx, portal_number, portal1_idx;
  23
  24         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  25                 return;
  26         if(intermission == 1)
  27                 return;
  28         if(intermission == 2)
  29                 return;
  30         if (getstati(STAT_HEALTH) <= 0)
  31                 return;
  32
  33         dir = view_forward;
  34
  35         if(angles_held_status)
  36         {
  37                 makevectors(angles_held);
  38                 dir = v_forward;
  39         }
  40
  41         p = view_origin;
  42
  43         polyline[0] = p;
  44         idx = 1;
  45         portal_number = 0;
  46         nextdir = dir;
  47
  48         for(;;)
  49         {
  50                 dir = nextdir;
  51                 traceline(p, p + 65536 * dir, TRUE, porto);
  52                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  53                         return;
  54                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  55                 p = trace_endpos;
  56                 polyline[idx] = p;
  57                 ++idx;
  58                 if(idx >= 16)
  59                         return;
  60                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  61                         continue;
  62                 ++portal_number;
  63                 ang = vectoangles2(trace_plane_normal, dir);
  64                 ang_x = -ang_x;
  65                 makevectors(ang);
  66                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  67                         return;
  68                 if(portal_number == 1)
  69                         portal1_idx = idx;
  70                 if(portal_number >= 2)
  71                         break;
  72         }
  73
  74         while(idx >= 2)
  75         {
  76                 p = polyline[idx-2];
  77                 q = polyline[idx-1];
  78                 if(idx == 2)
  79                         p = p - view_up * 16;
  80                 if(idx-1 >= portal1_idx)
  81                 {
  82                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL);
  83                 }
  84                 else
  85                 {
  86                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL);
  87                 }
  88                 --idx;
  89         }
  90 }
  91
  92 /**
  93  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  94  *
  95  * TODO: Use a better solution where a common shared entitiy is used that contains
  96  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  97  * and STAT_FRAGLIMIT to be auto-sent)
  98  */
  99 void CheckForGamestartChange() {
 100         float startTime;
 101         startTime = getstatf(STAT_GAMESTARTTIME);
 102         if (previous_game_starttime != startTime) {
 103                 if ((time + 5.0) < startTime) {
 104                         //if connecting to server while restart was active don't always play prepareforbattle
 105                         sound(self, CHAN_VOICE, "announcer/robotic/prepareforbattle.wav", VOL_BASEVOICE, ATTN_NONE);
 106                 }
 107                 if (time < startTime) {
 108                         restartAnnouncer = spawn();
 109                         restartAnnouncer.think = restartAnnouncer_Think;
 110                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 111                 }
 112         }
 113         previous_game_starttime = startTime;
 114 }
 115
 116 void Porto_Init()
 117 {
 118         porto = spawn();
 119         porto.classname = "porto";
 120         porto.draw = Porto_Draw;
 121         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 122 }
 123
 124 float drawtime;
 125 float avgspeed;
 126 vector GetCurrentFov(float fov)
 127 {
 128         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 129
 130         zoomsensitivity = cvar("cl_zoomsensitivity");
 131         zoomfactor = cvar("cl_zoomfactor");
 132         if(zoomfactor < 1 || zoomfactor > 16)
 133                 zoomfactor = 2.5;
 134         zoomspeed = cvar("cl_zoomspeed");
 135         if(zoomspeed >= 0)
 136                 if(zoomspeed < 0.5 || zoomspeed > 16)
 137                         zoomspeed = 3.5;
 138
 139         zoomdir = button_zoom;
 140         if(getstati(STAT_ACTIVEWEAPON) == WEP_NEX) // do NOT use switchweapon here
 141                 zoomdir += button_attack2;
 142         if(spectatee_status > 0 || isdemo())
 143         {
 144                 if(spectatorbutton_zoom)
 145                         zoomdir = 0 + !zoomdir;
 146                 // do not even THINK about removing this 0
 147                 // _I_ know what I am doing
 148                 // fteqcc does not
 149         }
 150
 151         if(zoomdir)
 152                 zoomin_effect = 0;
 153
 154         if(zoomin_effect || camera_active)
 155         {
 156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 157         }
 158         else
 159         {
 160                 if(zoomspeed < 0) // instant zoom
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / zoomfactor;
 164                         else
 165                                 current_viewzoom = 1;
 166                 }
 167                 else
 168                 {
 169                         if(zoomdir)
 170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 171                         else
 172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 173                 }
 174         }
 175
 176         if(almost_equals(current_viewzoom, 1))
 177                 current_zoomfraction = 0;
 178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 179                 current_zoomfraction = 1;
 180         else
 181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 182
 183         if(zoomsensitivity < 1)
 184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 185         else
 186                 setsensitivityscale(1);
 187
 188         velocityzoom = bound(0, drawframetime / max(0.000000001, cvar_or("cl_velocityzoomtime", 0.3)), 1);
 189         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 190         velocityzoom = exp(float2range11(avgspeed * -cvar_or("cl_velocityzoom", 0) / 1) * 1);
 191
 192         //print(ftos(avgspeed), " avgspeed, ", ftos(cvar_or("cl_velocityzoom", 0)), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 193
 194         float frustumx, frustumy, fovx, fovy;
 195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 199
 200         return '1 0 0' * fovx + '0 1 0' * fovy;
 201 }
 202
 203 // this function must match W_SetupShot!
 204 float zoomscript_caught;
 205
 206 vector wcross_origin;
 207 float wcross_scale_prev, wcross_alpha_prev;
 208 vector wcross_color_prev;
 209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 210 vector wcross_color_goal_prev;
 211 float wcross_changedonetime;
 212
 213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 215 float wcross_name_changestarttime, wcross_name_changedonetime;
 216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 217 entity trueaim;
 218 entity trueaim_rifle;
 219
 220 #define SHOTTYPE_HITTEAM 1
 221 #define SHOTTYPE_HITOBSTRUCTION 2
 222 #define SHOTTYPE_HITWORLD 3
 223 #define SHOTTYPE_HITENEMY 4
 224
 225 void TrueAim_Init()
 226 {
 227         trueaim = spawn();
 228         trueaim.classname = "trueaim";
 229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230         trueaim_rifle = spawn();
 231         trueaim_rifle.classname = "trueaim_rifle";
 232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 233 }
 234
 235 float EnemyHitCheck()
 236 {
 237         float t;
 238         wcross_origin = project_3d_to_2d(trace_endpos);
 239         wcross_origin_z = 0;
 240         if(trace_networkentity < 1)
 241                 return SHOTTYPE_HITWORLD;
 242         if(trace_networkentity > maxclients)
 243                 return SHOTTYPE_HITWORLD;
 244         t = GetPlayerColor(trace_networkentity - 1);
 245         if(teamplay)
 246                 if(t == myteam)
 247                         return SHOTTYPE_HITTEAM;
 248         if(t == COLOR_SPECTATOR)
 249                 return SHOTTYPE_HITWORLD;
 250         return SHOTTYPE_HITENEMY;
 251 }
 252
 253 float TrueAimCheck()
 254 {
 255         float nudge = 1; // added to traceline target and subtracted from result
 256         vector vecs, trueaimpoint, w_shotorg;
 257         vector mi, ma, dv;
 258         float shottype;
 259         entity ta;
 260         float mv;
 261
 262         mi = ma = '0 0 0';
 263         ta = trueaim;
 264         mv = MOVE_NOMONSTERS;
 265
 266         switch(activeweapon)
 267         {
 268                 case WEP_TUBA: // no aim
 269                 case WEP_PORTO: // shoots from eye
 270                 case WEP_HOOK: // no trueaim
 271                 case WEP_GRENADE_LAUNCHER: // toss curve
 272                         return SHOTTYPE_HITWORLD;
 273                 case WEP_NEX:
 274                 case WEP_MINSTANEX:
 275                         mv = MOVE_NORMAL;
 276                         break;
 277                 case WEP_CAMPINGRIFLE:
 278                         ta = trueaim_rifle;
 279                         mv = MOVE_NORMAL;
 280                         if(zoomscript_caught)
 281                         {
 282                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 283                                 return EnemyHitCheck();
 284                         }
 285                         break;
 286                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 287                         mi = '-3 -3 -3';
 288                         ma = '3 3 3';
 289                         break;
 290                 case WEP_FIREBALL: // projectile has a size!
 291                         mi = '-16 -16 -16';
 292                         ma = '16 16 16';
 293                         break;
 294                 case WEP_ELECTRO: // projectile has a size!
 295                         mi = '0 0 -3';
 296                         ma = '0 0 -3';
 297                         break;
 298         }
 299
 300         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 301
 302         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 303         trueaimpoint = trace_endpos;
 304
 305         if(vecs_x > 0)
 306                 vecs_y = -vecs_y;
 307         else
 308                 vecs = '0 0 0';
 309
 310         dv = view_right * vecs_y + view_up * vecs_z;
 311         w_shotorg = view_origin + dv;
 312
 313         // now move the vecs forward as much as requested if possible
 314         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 315         w_shotorg = trace_endpos - view_forward * nudge;
 316
 317         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 318         shottype = EnemyHitCheck();
 319         if(shottype != SHOTTYPE_HITWORLD)
 320                 return shottype;
 321
 322 #if 0
 323         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 324         // or rather, I know why, but see no fix
 325         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 326                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 327                 return SHOTTYPE_HITOBSTRUCTION;
 328 #endif
 329
 330         return SHOTTYPE_HITWORLD;
 331 }
 332
 333 void CSQC_common_hud(void);
 334
 335 void CSQC_kh_hud(void);
 336 void CSQC_ctf_hud(void);
 337 void PostInit(void);
 338 void CSQC_Demo_Camera();
 339 float Sbar_WouldDrawScoreboard ();
 340 float view_set;
 341 float camera_mode;
 342 string NextFrameCommand;
 343 void CSQC_spider_HUD();
 344 void CSQC_UpdateView(float w, float h)
 345 {
 346         entity e;
 347         float fov;
 348         float f, i, j;
 349         vector v;
 350
 351         dprint_load();
 352         WaypointSprite_Load();
 353
 354         if(spectatee_status)
 355                 myteam = GetPlayerColor(spectatee_status - 1);
 356         else
 357                 myteam = GetPlayerColor(player_localentnum - 1);
 358
 359         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 360
 361         // Render the Scene
 362         if(!intermission || !view_set)
 363         {
 364                 view_origin = pmove_org + '0 0 1' * getstati(STAT_VIEWHEIGHT);
 365                 view_angles = input_angles;
 366                 makevectors(view_angles);
 367                 view_forward = v_forward;
 368                 view_right = v_right;
 369                 view_up = v_up;
 370                 view_set = 1;
 371         }
 372
 373         vid_width = w;
 374         vid_height = h;
 375
 376 #ifdef BLURTEST
 377         if(time > blurtest_time0 && time < blurtest_time1)
 378         {
 379                 float r, t;
 380
 381                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 382                 r = t * blurtest_radius;
 383                 f = 1 / pow(t, blurtest_power) - 1;
 384
 385                 cvar_set("r_glsl_postprocess", "1");
 386                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 387         }
 388         else
 389         {
 390                 cvar_set("r_glsl_postprocess", "0");
 391                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 392         }
 393 #endif
 394
 395         Fog_Force();
 396
 397         drawframetime = max(0.000001, time - drawtime);
 398         drawtime = time;
 399
 400         // watch for gametype changes here...
 401         // in ParseStuffCMD the cmd isn't executed yet :/
 402         // might even be better to add the gametype to TE_CSQC_INIT...?
 403         if(!postinit)
 404                 PostInit();
 405
 406         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 407                 if(calledhooks & HOOK_START)
 408                 {
 409                         localcmd("\ncl_hook_gameend;");
 410                         calledhooks |= HOOK_END;
 411                 }
 412
 413         CheckForGamestartChange();
 414         maptimeAnnouncer();
 415
 416         fov = cvar("fov");
 417         if(button_zoom || fov <= 59.5)
 418         {
 419                 if(!zoomscript_caught)
 420                 {
 421                         localcmd("+button4\n");
 422                         zoomscript_caught = 1;
 423                         ignore_plus_zoom += 1;
 424                 }
 425         }
 426         else
 427         {
 428                 if(zoomscript_caught)
 429                 {
 430                         localcmd("-button4\n");
 431                         zoomscript_caught = 0;
 432                         ignore_minus_zoom += 1;
 433                 }
 434         }
 435
 436         sbar_alpha_fg = cvar("sbar_alpha_fg" ) * (1 - cvar("_menu_alpha"));
 437         sbar_currentammo = cvar("sbar_showcurrentammo");
 438         sbar_hudselector = cvar("sbar_hudselector");
 439         sbar_accuracy_hud = cvar_or("sbar_accuracy_hud", 1);
 440         ColorTranslateMode = cvar("cl_stripcolorcodes");
 441         activeweapon = getstati(STAT_SWITCHWEAPON);
 442         f = cvar("teamplay");
 443         if(f != teamplay)
 444         {
 445                 teamplay = f;
 446                 Sbar_InitScores();
 447         }
 448
 449         if(last_weapon != activeweapon) {
 450                 weapontime = time;
 451                 last_weapon = activeweapon;
 452         }
 453
 454         // ALWAYS Clear Current Scene First
 455         R_ClearScene();
 456
 457         // Assign Standard Viewflags
 458         // Draw the World (and sky)
 459         R_SetView(VF_DRAWWORLD, 1);
 460
 461         // Set the console size vars
 462         vid_conwidth = cvar("vid_conwidth");
 463         vid_conheight = cvar("vid_conheight");
 464         vid_pixelheight = cvar("vid_pixelheight");
 465
 466         R_SetView(VF_FOV, GetCurrentFov(fov));
 467
 468         // Camera for demo playback
 469         if(camera_active)
 470         {
 471                 if(cvar("camera_enable"))
 472                         CSQC_Demo_Camera();
 473                 else
 474                 {
 475                         cvar_set("chase_active", ftos(chase_active_backup));
 476                         cvar_set("cl_demo_mousegrab", "0");
 477                         camera_active = FALSE;
 478                 }
 479         }
 480 #ifdef CAMERATEST
 481         else if(cvar("camera_enable"))
 482 #else
 483         else if(cvar("camera_enable") && isdemo())
 484 #endif
 485         {
 486                 // Enable required Darkplaces cvars
 487                 chase_active_backup = cvar("chase_active");
 488                 cvar_set("chase_active", "2");
 489                 cvar_set("cl_demo_mousegrab", "1");
 490                 camera_active = TRUE;
 491                 camera_mode = FALSE;
 492         }
 493
 494         // Draw the Crosshair
 495         float scoreboard_active;
 496         scoreboard_active = Sbar_WouldDrawScoreboard();
 497         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 498
 499         // Draw the Engine Status Bar (the default Quake HUD)
 500         R_SetView(VF_DRAWENGINESBAR, 0);
 501
 502         // fetch this one only once per frame
 503         sbar_showbinds = cvar("sbar_showbinds");
 504         sbar_showbinds_limit = cvar("sbar_showbinds_limit");
 505
 506         // Update the mouse position
 507         /*
 508            mousepos_x = vid_conwidth;
 509            mousepos_y = vid_conheight;
 510            mousepos = mousepos*0.5 + getmousepos();
 511          */
 512
 513         e = self;
 514         for(self = world; (self = nextent(self)); )
 515                 if(self.draw)
 516                         self.draw();
 517         self = e;
 518
 519         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 520         R_RenderScene();
 521
 522         // now switch to 2D drawing mode by calling a 2D drawing function
 523         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 524         // next R_RenderScene call
 525         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 526
 527         // Draw the mouse cursor
 528         // NOTE: drawpic must happen after R_RenderScene for some reason
 529         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
 530         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
 531         //self = edict_num(player_localnum);
 532         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
 533         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
 534         // as long as the ctf part isn't in, this is useless
 535         if(menu_visible)
 536                 menu_show();
 537
 538         /*if(gametype == GAME_CTF)
 539           {
 540           ctf_view();
 541           } else */
 542
 543         // draw 2D entities
 544         e = self;
 545         for(self = world; (self = nextent(self)); )
 546                 if(self.draw2d)
 547                         self.draw2d();
 548         self = e;
 549
 550         // draw radar
 551         if(
 552                         ons_showmap
 553                         ||
 554                         (
 555                          !scoreboard_active
 556                          &&
 557                          cvar_string("cl_teamradar") != "0"
 558                          &&
 559                          (
 560                           cvar("cl_teamradar") == 2
 561                           ||
 562                           teamplay
 563                          )
 564                         )
 565           )
 566                 teamradar_view();
 567
 568         // draw sbar
 569         if(cvar("r_letterbox") == 0) {
 570                 if (cvar("cl_showpressedkeys")) { // draw pressed keys when spectating and playing
 571                         if(spectatee_status > 0 || cvar("cl_showpressedkeys") >= 2)
 572                                 Sbar_DrawPressedKeys();
 573                 }
 574
 575                 if (cvar("cl_showspeed"))
 576                         Sbar_ShowSpeed();
 577                 if (cvar("cl_showacceleration"))
 578                         Sbar_ShowAcceleration();
 579
 580                 Sbar_DrawCenterPrint(); // draw centerprint messages even if viewsize >= 120
 581         }
 582
 583         float hud;
 584         hud = getstati(STAT_HUD);
 585         if(hud == HUD_SPIDERBOT)
 586         {
 587                 CSQC_spider_HUD();
 588         }
 589         else if(hud == HUD_WAKIZASHI)
 590         CSQC_WAKIZASHI_HUD();
 591         else
 592         {
 593                 if(cvar("r_letterbox") == 0)
 594                         if(cvar("viewsize") < 120)
 595                                 CSQC_common_hud();
 596
 597                 // crosshair goes VERY LAST
 598                 if(!scoreboard_active && !ons_showmap && !camera_active) {
 599                         // TrueAim check
 600                         float shottype;
 601                         float bullets, ring_scale;
 602                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 603                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 604                         wcross_origin_z = 0;
 605                         if(cvar("crosshair_hittest"))
 606                         {
 607                                 vector wcross_oldorigin;
 608                                 wcross_oldorigin = wcross_origin;
 609                                 shottype = TrueAimCheck();
 610                                 if(shottype == SHOTTYPE_HITWORLD)
 611                                 {
 612                                         v = wcross_origin - wcross_oldorigin;
 613                                         v_x /= vid_conwidth;
 614                                         v_y /= vid_conheight;
 615                                         if(vlen(v) > 0.01)
 616                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 617                                 }
 618                                 if(!cvar("crosshair_hittest_showimpact"))
 619                                         wcross_origin = wcross_oldorigin;
 620                         }
 621                         else
 622                                 shottype = SHOTTYPE_HITWORLD;
 623
 624                         string wcross_style;
 625                         wcross_style = cvar_string("crosshair");
 626
 627                         if (wcross_style != "0") {
 628                                 vector wcross_color, wcross_size;
 629                                 string wcross_wep, wcross_name;
 630                                 float wcross_alpha, wcross_scale, wcross_blur, wcross_resolution;
 631
 632                                 wcross_color_x = cvar("crosshair_color_red");
 633                                 wcross_color_y = cvar("crosshair_color_green");
 634                                 wcross_color_z = cvar("crosshair_color_blue");
 635                                 wcross_alpha = cvar("crosshair_color_alpha");
 636                                 wcross_resolution = cvar("crosshair_size");
 637                                 if (cvar("crosshair_per_weapon")) {
 638                                         e = get_weaponinfo(activeweapon);
 639                                         if (e && e.netname != "")
 640                                         {
 641                                                 wcross_wep = e.netname;
 642                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 643                                                 if(wcross_style == "")
 644                                                         wcross_style = e.netname;
 645
 646                                                 if(!cvar("crosshair_color_override"))
 647                                                 {
 648                                                         wcross_color_x = cvar(strcat("crosshair_", wcross_wep, "_color_red"));
 649                                                         wcross_color_y = cvar(strcat("crosshair_", wcross_wep, "_color_green"));
 650                                                         wcross_color_z = cvar(strcat("crosshair_", wcross_wep, "_color_blue"));
 651                                                 }
 652
 653                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_color_alpha"));
 654                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 655                                         }
 656                                 }
 657
 658                                 wcross_name = strcat("gfx/crosshair", wcross_style);
 659
 660                                 if(cvar("crosshair_effect_scalefade"))
 661                                 {
 662                                         wcross_scale = wcross_resolution;
 663                                         wcross_resolution = 1;
 664                                 }
 665                                 else
 666                                 {
 667                                         wcross_scale = 1;
 668                                 }
 669
 670                                 if(shottype == SHOTTYPE_HITENEMY)
 671                                         wcross_scale *= cvar("crosshair_hittest"); // is not queried if hittest is 0
 672                                 if(shottype == SHOTTYPE_HITTEAM)
 673                                         wcross_scale /= cvar("crosshair_hittest"); // is not queried if hittest is 0
 674
 675                                 f = cvar("crosshair_effect_speed");
 676                                 if(f < 0)
 677                                         f *= -2 * g_weaponswitchdelay;
 678                                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 679                                 {
 680                                         wcross_changedonetime = time + f;
 681                                 }
 682                                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 683                                 {
 684                                         wcross_name_changestarttime = time;
 685                                         wcross_name_changedonetime = time + f;
 686                                         if(wcross_name_goal_prev_prev)
 687                                                 strunzone(wcross_name_goal_prev_prev);
 688                                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
 689                                         wcross_name_goal_prev = strzone(wcross_name);
 690                                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 691                                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 692                                         wcross_resolution_goal_prev = wcross_resolution;
 693                                 }
 694
 695                                 wcross_scale_goal_prev = wcross_scale;
 696                                 wcross_alpha_goal_prev = wcross_alpha;
 697                                 wcross_color_goal_prev = wcross_color;
 698
 699                                 if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && cvar("crosshair_hittest_blur") && !cvar("chase_active")))
 700                                 {
 701                                         wcross_blur = 1;
 702                                         wcross_alpha *= 0.75;
 703                                 }
 704                                 else
 705                                         wcross_blur = 0;
 706                                 // *_prev is at time-frametime
 707                                 // * is at wcross_changedonetime+f
 708                                 // what do we have at time?
 709                                 if(time < wcross_changedonetime)
 710                                 {
 711                                         f = frametime / (wcross_changedonetime - time + frametime);
 712                                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 713                                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 714                                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 715                                 }
 716
 717                                 wcross_scale_prev = wcross_scale;
 718                                 wcross_alpha_prev = wcross_alpha;
 719                                 wcross_color_prev = wcross_color;
 720
 721                                 wcross_scale *= 1 - cvar("_menu_alpha");
 722                                 wcross_alpha *= 1 - cvar("_menu_alpha");
 723
 724                                 wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
 725
 726                                 // ring around crosshair representing bullets left in camping rifle clip
 727                                 if (activeweapon == WEP_CAMPINGRIFLE)
 728                                 {
 729                                         ring_scale = cvar("crosshair_campingrifle_ring_size");
 730                                         bullets = bound(0, getstati(STAT_BULLETS_LOADED), 8);
 731                                 }
 732                                 else
 733                                         bullets = 0;
 734
 735 #define CROSSHAIR_DRAW_RING(i,j,sz,wcross_name,wcross_alpha) \
 736                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x * ring_scale + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y * ring_scale + j * wcross_blur)), strcat("gfx/hud/rifle_ring_", ftos(bullets)), sz * wcross_size * ring_scale, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 737
 738 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 739                                 do \
 740                                 { \
 741                                         if(wcross_blur > 0) \
 742                                         { \
 743                                                 for(i = -2; i <= 2; ++i) \
 744                                                         for(j = -2; j <= 2; ++j) \
 745                                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
 746                                         } \
 747                                         else \
 748                                         { \
 749                                                 M(0,0,sz,wcross_name,wcross_alpha); \
 750                                         } \
 751                                 } \
 752                                 while(0)
 753
 754 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
 755                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 756
 757 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 758                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 759
 760                                 if(bullets)
 761                                 {
 762                                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_RING, wcross_resolution, wcross_name, wcross_alpha);
 763                                 }
 764
 765                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 766                                 {
 767                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 768                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 769                                         f = 1 - f;
 770                                 }
 771                                 else
 772                                 {
 773                                         f = 1;
 774                                 }
 775                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 776                                 wcross_name_alpha_goal_prev = f;
 777                         }
 778                 }
 779                 else
 780                 {
 781                         wcross_scale_prev = 0;
 782                         wcross_alpha_prev = 0;
 783                         wcross_scale_goal_prev = 0;
 784                         wcross_alpha_goal_prev = 0;
 785                         wcross_changedonetime = 0;
 786                         if(wcross_name_goal_prev)
 787                                 strunzone(wcross_name_goal_prev);
 788                         wcross_name_goal_prev = string_null;
 789                         if(wcross_name_goal_prev_prev)
 790                                 strunzone(wcross_name_goal_prev_prev);
 791                         wcross_name_goal_prev_prev = string_null;
 792                         wcross_name_changestarttime = 0;
 793                         wcross_name_changedonetime = 0;
 794                         wcross_name_alpha_goal_prev = 0;
 795                         wcross_name_alpha_goal_prev_prev = 0;
 796                         wcross_resolution_goal_prev = 0;
 797                         wcross_resolution_goal_prev_prev = 0;
 798                 }
 799         }
 800
 801         if(NextFrameCommand)
 802         {
 803                 localcmd("\n", NextFrameCommand, "\n");
 804                 NextFrameCommand = string_null;
 805         }
 806
 807         // we must do this check AFTER a frame was rendered, or it won't work
 808         if(cs_project_is_b0rked == 0)
 809         {
 810                 string w0, h0;
 811                 w0 = cvar_string("vid_conwidth");
 812                 h0 = cvar_string("vid_conheight");
 813                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
 814                 //R_SetView(VF_FOV, '90 90 0');
 815                 R_SetView(VF_ORIGIN, '0 0 0');
 816                 R_SetView(VF_ANGLES, '0 0 0');
 817                 R_SetView(VF_PERSPECTIVE, 1);
 818                 makevectors('0 0 0');
 819                 vector v1, v2;
 820                 cvar_set("vid_conwidth", "800");
 821                 cvar_set("vid_conheight", "600");
 822                 v1 = cs_project(v_forward);
 823                 cvar_set("vid_conwidth", "640");
 824                 cvar_set("vid_conheight", "480");
 825                 v2 = cs_project(v_forward);
 826                 if(v1 == v2)
 827                         cs_project_is_b0rked = 1;
 828                 else
 829                         cs_project_is_b0rked = -1;
 830                 cvar_set("vid_conwidth", w0);
 831                 cvar_set("vid_conheight", h0);
 832         }
 833
 834         // be safe against triggerbots until everyone has the fixed engine
 835         // this call is meant to overwrite the trace globals by something
 836         // unsuspicious
 837         traceline('0 0 0', '0 0 0', MOVE_WORLDONLY, world);
 838 }
 839
 840 void Sbar_Draw();
 841 void CSQC_spider_HUD()
 842 {
 843         float rockets,reload,heat,hp,shield,i;
 844         vector p,pp;
 845
 846     p = drawgetimagesize(SPIDER_CROSS);
 847     p_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
 848     p_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
 849     drawpic('0.5 0 0' * (vid_conwidth - p_x) + '0 0.5 0' * (vid_conheight - p_y), SPIDER_CROSS, p, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
 850
 851     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
 852         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
 853         heat    = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
 854         rockets =     getstati(STAT_VEHICLESTAT_AMMO2);
 855         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD2), 1);
 856
 857         // Draw health bar
 858         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
 859         p = p + '0 1 0' * vid_conheight - '0 32 0';
 860         //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
 861         drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
 862         p_y += 8;
 863         drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
 864         p_x += 256 * hp;
 865         drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
 866
 867         // Draw minigun heat indicator
 868         p = '0.5 0 0' * (vid_conwidth - 256);
 869         p = p + '0 1 0' * vid_conheight - '0 34  0';
 870         drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
 871         p_x += 256 * (1-heat);
 872         drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
 873
 874         // Draw rocket icons for loaded/empty tubes.
 875         pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
 876         pp += '0 1 0' * vid_conheight - '0 64 0';
 877         for(i = 0; i < 8; ++i)
 878         {
 879                 p = pp + '1 0 0' * (rkt_size * i);
 880                 if(rockets == 8)
 881                 {
 882                         if(floor(reload * 8) == i)
 883                         {
 884                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
 885                         }
 886                         else if(i < reload * 8)
 887                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
 888                         else
 889                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
 890                 }
 891                 else
 892                 {
 893                         if(i < rockets)
 894                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
 895                         else
 896                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
 897                 }
 898         }
 899
 900         if (sb_showscores)
 901         {
 902                 Sbar_DrawScoreboard();
 903                 Sbar_DrawCenterPrint();
 904         }
 905
 906 }
 907
 908 void CSQC_WAKIZASHI_HUD()
 909 {
 910         // 0--1 floats. 1 = 100%, 0.6 = 50%.
 911         float health, shield, energy, rockets;
 912
 913         vector p;
 914
 915     p = drawgetimagesize(SPIDER_CROSS);
 916     p_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
 917     p_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
 918     drawpic('0.5 0 0' * (vid_conwidth - p_x) + '0 0.5 0' * (vid_conheight - p_y), SPIDER_CROSS, p, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
 919
 920 /*
 921 const float STAT_VEHICLESTAT_HEALTH  = 60;
 922 const float STAT_VEHICLESTAT_SHIELD  = 61;
 923 const float STAT_VEHICLESTAT_ENERGY  = 62;
 924 const float STAT_VEHICLESTAT_AMMO1   = 63;
 925 const float STAT_VEHICLESTAT_RELAOD1 = 64;
 926 const float STAT_VEHICLESTAT_AMMO2   = 65;
 927 const float STAT_VEHICLESTAT_RELOAD2 = 66;
 928 */
 929     health  = min(getstatf(STAT_VEHICLESTAT_HEALTH),  1);
 930         shield  = min(getstatf(STAT_VEHICLESTAT_SHIELD),  1);
 931         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
 932         rockets = bound(0,getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
 933
 934
 935         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
 936         p = p + '0 1 0' * vid_conheight - '0 32 0';
 937
 938         // Draw health bar
 939         p_y += 8;
 940         drawfill(p, '256 0 0' * health + '0 8 0' , '0 0.7 0', 0.75, DRAWFLAG_NORMAL);
 941         p_x += 256 * health;
 942         drawfill(p, '256 0 0' * (1 - health) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
 943
 944         // Draw shiled bar
 945         p_x -= 256 * health;
 946         p_y += 4;
 947         drawfill(p, '256 0 0' * shield + '0 4 0' , '0.25 0.25 1', 0.5, DRAWFLAG_NORMAL);
 948
 949         // Draw energy
 950         //p_x -= 256 * health;
 951         p_y -= 8;
 952         drawfill(p, '256 0 0' * energy + '0 4 0' , '1 1 1', 0.75, DRAWFLAG_NORMAL);
 953
 954         // Draw rockets bar
 955         p_y += 12;
 956         drawfill(p, '256 0 0' * rockets + '0 4 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
 957
 958
 959         /*
 960         // Draw energy bar
 961         p = '0.5 0 0' * (vid_conwidth - 256);
 962         p = p + '0 1 0' * vid_conheight - '0 34  0';
 963         drawfill(p, '256 0 0' * (1 - energy) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
 964         p_x += 256 * (1 - energy);
 965         drawfill(p, '256 0 0' * energy  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
 966
 967         // Draw rockets bar
 968         p_y += 8;
 969         drawfill(p, '256 0 0' * rockets + '0 8 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
 970         p_x += 256 * health;
 971         drawfill(p, '256 0 0' * (1 - rockets) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
 972     */
 973
 974
 975         if (sb_showscores)
 976         {
 977                 Sbar_DrawScoreboard();
 978                 Sbar_DrawCenterPrint();
 979         }
 980
 981 }
 982
 983
 984 void CSQC_common_hud(void)
 985 {
 986         // Sbar_SortFrags(); done in Sbar_Draw
 987         float hud;
 988         hud = getstati(STAT_HUD);
 989
 990         //hud = 10;
 991         switch(hud)
 992         {
 993                 case HUD_NORMAL:
 994                         Sbar_Draw();
 995                         break;
 996
 997                 case HUD_SPIDERBOT:
 998                         CSQC_spider_HUD();
 999                         break;
1000
1001                 case HUD_WAKIZASHI:
1002                         CSQC_WAKIZASHI_HUD();
1003                         break;
1004         }
1005 }
1006
1007
1008 // following vectors must be global to allow seamless switching between camera modes
1009 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1010 void CSQC_Demo_Camera()
1011 {
1012         float speed, attenuation, dimensions;
1013         vector tmp, delta;
1014
1015         if( cvar("camera_reset") || !camera_mode )
1016         {
1017                 camera_offset = '0 0 0';
1018                 current_angles = '0 0 0';
1019                 camera_direction = '0 0 0';
1020                 camera_offset_z += 30;
1021                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1022                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1023                 current_origin = view_origin;
1024                 current_camera_offset  = camera_offset;
1025                 cvar_set("camera_reset", "0");
1026                 camera_mode = CAMERA_CHASE;
1027         }
1028
1029         // Camera angles
1030         if( camera_roll )
1031                 mouse_angles_z += camera_roll * cvar("camera_speed_roll");
1032
1033         if(cvar("camera_look_player"))
1034         {
1035                 local vector dir;
1036                 local float n;
1037
1038                 dir = normalize(view_origin - current_position);
1039                 n = mouse_angles_z;
1040                 mouse_angles = vectoangles(dir);
1041                 mouse_angles_x = mouse_angles_x * -1;
1042                 mouse_angles_z = n;
1043         }
1044         else
1045         {
1046                 tmp = getmousepos() * 0.1;
1047                 if(vlen(tmp)>cvar("camera_mouse_treshold"))
1048                 {
1049                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1050                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1051                 }
1052         }
1053
1054         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1055         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1056         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1057         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1058
1059         // Fix difference when angles don't have the same sign
1060         delta = '0 0 0';
1061         if(mouse_angles_y < -60 && current_angles_y > 60)
1062                 delta = '0 360 0';
1063         if(mouse_angles_y > 60 && current_angles_y < -60)
1064                 delta = '0 -360 0';
1065
1066         if(cvar("camera_look_player"))
1067                 attenuation = cvar("camera_look_attenuation");
1068         else
1069                 attenuation = cvar("camera_speed_attenuation");
1070
1071         attenuation = 1 / max(1, attenuation);
1072         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1073
1074         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1075         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1076         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1077         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1078
1079         // Camera position
1080         tmp = '0 0 0';
1081         dimensions = 0;
1082
1083         if( camera_direction_x )
1084         {
1085                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1086                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1087                 if( cvar("camera_forward_follows") && !cvar("camera_look_player") )
1088                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1089                 ++dimensions;
1090         }
1091
1092         if( camera_direction_y )
1093         {
1094                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1095                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1096                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1097                 ++dimensions;
1098         }
1099
1100         if( camera_direction_z )
1101         {
1102                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1103                 ++dimensions;
1104         }
1105
1106         if(cvar("camera_free"))
1107                 speed = cvar("camera_speed_free");
1108         else
1109                 speed = cvar("camera_speed_chase");
1110
1111         if(dimensions)
1112         {
1113                 speed = speed * sqrt(1 / dimensions);
1114                 camera_offset += tmp * speed;
1115         }
1116
1117         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1118
1119         // Camera modes
1120         if( cvar("camera_free") )
1121         {
1122                 if ( camera_mode == CAMERA_CHASE )
1123                 {
1124                         current_camera_offset = current_origin + current_camera_offset;
1125                         camera_offset = current_origin + camera_offset;
1126                 }
1127
1128                 camera_mode = CAMERA_FREE;
1129                 current_position = current_camera_offset;
1130         }
1131         else
1132         {
1133                 if ( camera_mode == CAMERA_FREE )
1134                 {
1135                         current_origin = view_origin;
1136                         camera_offset = camera_offset - current_origin;
1137                         current_camera_offset = current_camera_offset - current_origin;
1138                 }
1139
1140                 camera_mode = CAMERA_CHASE;
1141
1142                 if(cvar("camera_chase_smoothly"))
1143                         current_origin += (view_origin - current_origin) * attenuation;
1144                 else
1145                         current_origin = view_origin;
1146
1147                 current_position = current_origin + current_camera_offset;
1148         }
1149
1150         R_SetView(VF_ANGLES, current_angles);
1151         R_SetView(VF_ORIGIN, current_position);
1152 }