data/qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------\r
   2 // BEGIN REQUIRED CSQC FUNCTIONS\r
   3 //include "main.qh"\r
   4 \r
   5 void() menu_show_error =\r
   6 {\r
   7         drawstring('0 200', "ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!", '8 8 0', '1 0 0', 1, 0);\r
   8 };\r
   9 \r
  10 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)\r
  11 // Useful for precaching things\r
  12 \r
  13 void() menu_sub_null =\r
  14 {\r
  15 };\r
  16 \r
  17 // let's make this a general data buffer...\r
  18 float databuf;\r
  19 float using_gps;\r
  20 \r
  21 void CSQC_Init(void)\r
  22 {\r
  23         float i;\r
  24         drawfont = 0;\r
  25         menu_visible = FALSE;\r
  26         menu_show = menu_show_error;\r
  27         menu_action = menu_sub_null;\r
  28         using_gps = false;\r
  29         //ctf_temp_1 = "";\r
  30         localcmd("alias order \"cmd order $*\"");\r
  31         //registercmd("ctf_menu");\r
  32         registercmd("ons_map");\r
  33         //registercmd("menu_action");\r
  34         registercmd("sbar_columns_set");\r
  35         registercmd("sbar_columns_help");\r
  36 \r
  37         registercvar("sbar_usecsqc", "1");\r
  38         registercvar("sbar_columns", "ping name | caps returns frags deaths");\r
  39 \r
  40         gametype = 0;\r
  41 \r
  42         gps_start = world;\r
  43 \r
  44         // sbar_fields uses strunzone on the titles!\r
  45         for(i = 0; i < MAX_SBAR_FIELDS; ++i)\r
  46                 sbar_title[i] = strzone("(null)");\r
  47 \r
  48         localcmd(strcat("\nsbar_columns_set ", cvar_string("sbar_columns"), ";\n"));\r
  49 \r
  50         postinit = false;\r
  51 }\r
  52 \r
  53 void PostInit(void)\r
  54 {\r
  55         float i;\r
  56 \r
  57         print(strcat("PostInit\n    maxclients = ", ftos(maxclients), "\n"));\r
  58         databuf = buf_create();\r
  59         for(i = 0; i < maxclients; ++i)\r
  60         {\r
  61                 bufstr_set(databuf, DATABUF_PING + i, "N/A");\r
  62                 bufstr_set(databuf, DATABUF_DEATHS + i, "0");\r
  63                 bufstr_set(databuf, DATABUF_CAPTURES + i, "0");\r
  64                 bufstr_set(databuf, DATABUF_RETURNS + i, "0");\r
  65         }\r
  66 \r
  67         postinit = true;\r
  68 }\r
  69 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)\r
  70 void CSQC_Shutdown(void)\r
  71 {\r
  72         buf_del(databuf);\r
  73 }\r
  74 \r
  75 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function\r
  76 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.\r
  77 void Cmd_Sbar_SetFields(float);\r
  78 void Cmd_Sbar_Help(float);\r
  79 float CSQC_ConsoleCommand(string strMessage)\r
  80 {\r
  81         float argc;\r
  82         // Tokenize String\r
  83         argc = tokenize(strMessage);\r
  84         \r
  85         // Acquire Command\r
  86         local string strCmd;\r
  87         strCmd = argv(0);\r
  88 \r
  89         /*if(strCmd == "ctf_menu") {\r
  90                 ctf_menu_show();\r
  91                 nReturn = true;\r
  92                 } else*/\r
  93         if(strCmd == "ons_map") {\r
  94                 Cmd_ons_map();\r
  95                 return true;\r
  96         } else if(strCmd == "sbar_columns_set") {\r
  97                 Cmd_Sbar_SetFields(argc);\r
  98                 return true;\r
  99         } else if(strCmd == "sbar_columns_help") {\r
 100                 Cmd_Sbar_Help(argc);\r
 101                 return true;\r
 102         }\r
 103         \r
 104         return false;\r
 105 }\r
 106 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.\r
 107 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.\r
 108 // All keys are in ascii.\r
 109 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.\r
 110 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.\r
 111 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.\r
 112 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)\r
 113 {\r
 114         local float bSkipKey;\r
 115         bSkipKey = false;\r
 116         if(menu_visible)\r
 117                 if(menu_action(bInputType, nPrimary, nSecondary))\r
 118                         return TRUE;\r
 119         return bSkipKey;\r
 120 }\r
 121 \r
 122 // END REQUIRED CSQC FUNCTIONS\r
 123 // --------------------------------------------------------------------------\r
 124 \r
 125 // --------------------------------------------------------------------------\r
 126 // BEGIN OPTIONAL CSQC FUNCTIONS\r
 127 void ReadONS()\r
 128 {\r
 129         entity gps;\r
 130         using_gps = true;\r
 131 \r
 132         self.origin_x = ReadCoord();\r
 133         self.origin_y = ReadCoord();\r
 134         self.angles_y = ReadCoord();\r
 135         self.origin_z = self.angles_x = self.angles_z = 0;\r
 136 \r
 137         for(gps = gps_start; gps; gps = gps.chain)\r
 138         {\r
 139                 if(gps == self)\r
 140                         break;\r
 141         }\r
 142         if(!gps)\r
 143         {\r
 144                 self.chain = gps_start;\r
 145                 gps_start = self;\r
 146         }\r
 147 }\r
 148 \r
 149 void RemoveONS()\r
 150 {\r
 151         if(gps_start == self)\r
 152                 gps_start = self.chain;\r
 153         else\r
 154         {\r
 155                 local entity ent;\r
 156                 ent = gps_start;\r
 157                         \r
 158                 while(ent.chain != self && ent.chain != world)\r
 159                         ent = ent.chain;\r
 160                 if(ent.chain == self)\r
 161                         ent.chain = self.chain;\r
 162         }\r
 163 }\r
 164 \r
 165 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.\r
 166 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.\r
 167 void(float bIsNewEntity) CSQC_Ent_Update =\r
 168 {\r
 169         float msg;\r
 170         self.enttype = ReadByte();\r
 171         if(self.enttype == ENT_CLIENT_ENTCS)\r
 172         {\r
 173                 self.sv_entnum = ReadByte()-1;\r
 174 \r
 175                 for(msg = ReadByte(); msg != ENTCS_MSG_END; msg = ReadByte())\r
 176                 {\r
 177                         switch(msg)\r
 178                         {\r
 179                         case ENTCS_MSG_ONS_GPS: ReadONS(); break;\r
 180                         case ENTCS_MSG_ONS_REMOVE: RemoveONS(); break;\r
 181                         default:\r
 182                                 error("unknown ENTCS_MSG type\n");\r
 183                         }\r
 184                 }\r
 185         }\r
 186         else\r
 187                 error("unknown entity type in CSQC_Ent_Update\n");\r
 188         \r
 189 };\r
 190 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.\r
 191 void CSQC_Ent_Remove()\r
 192 {\r
 193         if(self.enttype == ENT_CLIENT_ENTCS)\r
 194         {\r
 195                 if(using_gps) //gametype == GAME_ONSLAUGHT)\r
 196                 {\r
 197                         if(gps_start == self)\r
 198                                 gps_start = self.chain;\r
 199                         else\r
 200                         {\r
 201                                 local entity ent;\r
 202                                 ent = gps_start;\r
 203                         \r
 204                                 while(ent.chain != self && ent.chain != world)\r
 205                                         ent = ent.chain;\r
 206                                 if(ent.chain == self)\r
 207                                         ent.chain = self.chain;\r
 208                         }\r
 209                 }\r
 210         }\r
 211         remove(self);\r
 212 }\r
 213 \r
 214 void Gamemode_Init()\r
 215 {\r
 216         local string mapinfo, infoline;\r
 217         local float len;\r
 218         local float file;\r
 219         local vector mi_min, mi_max;\r
 220 \r
 221         draw_enginesbar = true;\r
 222         gametype = cvar("gametype");\r
 223         if(gametype == GAME_ONSLAUGHT) {\r
 224                 if(!strcasecmp(substring(mapname, 0, 5), "maps/"))\r
 225                         minimapname = substring(mapname, 5, 999);\r
 226                 else\r
 227                         minimapname = mapname;\r
 228                 len = strlen(minimapname);\r
 229                 if(!strcasecmp(substring(minimapname, len-4, 4), ".bsp"))\r
 230                         minimapname = substring(minimapname, 0, len-4);\r
 231                 \r
 232                 mapinfo = strcat("maps/", minimapname, ".info");\r
 233                 minimapname = strzone(strcat("gfx/", minimapname, "_mini.tga"));\r
 234 \r
 235                 mi_min = world.mins;\r
 236                 mi_max = world.maxs;\r
 237                 \r
 238                 file = fopen(mapinfo, FILE_READ);\r
 239                 if(file >= 0) {\r
 240                         while((infoline = fgets(file))) {\r
 241                                 if(!strncasecmp(infoline, "mins", 4)) {\r
 242                                         mi_min = stov(substring(infoline, 5, 999));\r
 243                                 } else if(!strncasecmp(infoline, "maxs", 4)) {\r
 244                                         mi_max = stov(substring(infoline, 5, 999));\r
 245                                 } else if(strncasecmp(infoline, "//", 2)) { // don't print comment-style lines\r
 246                                         print(strcat("mapinfo: ", infoline, "\n"));\r
 247                                 }\r
 248                         }\r
 249                 } else {\r
 250                         print(strcat("^1Error: ^7Mapinfo file '", mapinfo, "' missing! Minimap will be screwed.\n"));\r
 251                 }\r
 252                 fclose(file);\r
 253 \r
 254                 print(strcat("Mins: ", vtos(mi_min), "    Maxs: ", vtos(mi_max), "\n"));\r
 255                 \r
 256                 mi_center = (mi_min + mi_max) * 0.5;\r
 257                 mi_scale = mi_max - mi_min;\r
 258                 \r
 259                 \r
 260                 print(strcat("Using ", minimapname, " as minimap.\n"));\r
 261                 precache_pic(minimapname);\r
 262                 precache_pic("gfx/ons-cp-neutral.tga");\r
 263                 precache_pic("gfx/ons-cp-red.tga");\r
 264                 precache_pic("gfx/ons-cp-blue.tga");\r
 265                 precache_pic("gfx/ons-frame.tga");\r
 266                 precache_pic("gfx/ons-frame-team.tga");\r
 267         } else if(gametype == GAME_KEYHUNT) {\r
 268                 precache_pic("gfx/sb_key_carrying");\r
 269                 precache_pic("gfx/sb_key_carrying_outline");\r
 270                 draw_enginesbar = false;\r
 271         }\r
 272 }\r
 273 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.\r
 274 void CSQC_Parse_StuffCmd(string strMessage)\r
 275 {\r
 276         localcmd(strMessage);\r
 277         // watch for gametype changes!\r
 278         if(gametype != cvar("gametype"))\r
 279         {\r
 280                 Gamemode_Init();\r
 281         }\r
 282 }\r
 283 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.\r
 284 void CSQC_Parse_Print(string strMessage)\r
 285 {\r
 286         print(strMessage);\r
 287 }\r
 288 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.  To execute standard behavior, simply execute cprint with the string.\r
 289 void CSQC_Parse_CenterPrint(string strMessage)\r
 290 {\r
 291         cprint(strMessage);\r
 292 }\r
 293 \r
 294 void CSQC_CheckRevision();\r
 295 void ReadInit()\r
 296 {\r
 297         csqc_revision = ReadShort();\r
 298         maxclients = ReadByte();\r
 299 \r
 300         CSQC_CheckRevision();\r
 301 }\r
 302 \r
 303 void ReadPings()\r
 304 {\r
 305         float plnum, ping;\r
 306         for(plnum = ReadByte(); plnum != 0; plnum = ReadByte())\r
 307         {\r
 308                 ping = ReadShort();\r
 309                 bufstr_set(databuf, DATABUF_PING + plnum-1, ftos(ping));\r
 310         }\r
 311 }\r
 312 \r
 313 void ReadCaptures()\r
 314 {\r
 315         float plnum, caps, mode;\r
 316         mode = ReadByte();\r
 317         caps_team1 = ReadByte();\r
 318         caps_team2 = ReadByte();\r
 319         for(plnum = ReadByte(); plnum != 0; plnum = ReadByte())\r
 320         {\r
 321                 caps = ReadByte();\r
 322                 bufstr_set(databuf, DATABUF_CAPTURES + plnum-1, ftos(caps));\r
 323         }\r
 324 }\r
 325 \r
 326 void ReadDatabuf(float ofs)\r
 327 {\r
 328         float plnum, data;\r
 329         for(plnum = ReadByte(); plnum != 0; plnum = ReadByte())\r
 330         {\r
 331                 data = ReadByte();\r
 332                 bufstr_set(databuf, ofs + plnum-1, ftos(data));\r
 333         }\r
 334 }\r
 335 \r
 336 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.\r
 337 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.\r
 338 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.\r
 339 float CSQC_Parse_TempEntity()\r
 340 {\r
 341         local float bHandled;\r
 342                 bHandled  = true;\r
 343         // Acquire TE ID\r
 344         local float nTEID;\r
 345                 nTEID = ReadByte();\r
 346                 \r
 347         switch(nTEID)\r
 348         {\r
 349                 case TE_CSQC_INIT:\r
 350                         ReadInit();\r
 351                         bHandled = true;\r
 352                         break;\r
 353                 case TE_CSQC_PING:\r
 354                         ReadPings();\r
 355                         bHandled = true;\r
 356                         break;\r
 357                 case TE_CSQC_CAPTURES:\r
 358                         ReadCaptures();\r
 359                         bHandled = true;\r
 360                         break;\r
 361                 case TE_CSQC_RETURNS:\r
 362                         ReadDatabuf(DATABUF_RETURNS);\r
 363                         bHandled = true;\r
 364                         break;\r
 365                 case TE_CSQC_DEATHS:\r
 366                         ReadDatabuf(DATABUF_DEATHS);\r
 367                         bHandled = true;\r
 368                         break;\r
 369                 default:\r
 370                         // No special logic for this temporary entity; return 0 so the engine can handle it\r
 371                         bHandled = false;\r
 372                         break;\r
 373         }\r
 374         \r
 375         if(!postinit)\r
 376                 PostInit();\r
 377                 \r
 378         return bHandled;\r
 379 }\r
 380 \r
 381 // COMMIT-TODO: Update if necessare, before committing\r
 382 float csqc_svn_map[CSQC_REVISION] =\r
 383 {\r
 384         3795,\r
 385 };\r
 386 \r
 387 // COMMIT-TODO: Update if necessare, before committing\r
 388 void CSQC_CheckRevision()\r
 389 {\r
 390         if(csqc_revision == CSQC_REVISION)\r
 391         {\r
 392                 print("^2SVQC and CSQC revisions are compatible.\n");\r
 393         } else if(csqc_revision < CSQC_REVISION) {\r
 394                 print("^1Your csprogs.dat (CSQC) version is newer than the one on the server.\n");\r
 395                 print("^1The last known svn revision for the server's CSQC is: ^7");\r
 396                 print(ftos(csqc_svn_map[csqc_revision])); // don't use strcat, fteqcc loves screwing up arrays...\r
 397                 print("\n");\r
 398         } else if(csqc_revision > CSQC_REVISION) {\r
 399                 print("^1Your csprogs.dat (CSQC) is too old for this server.\n");\r
 400                 print("^1Please update to a newer version.\n");\r
 401         }\r
 402 }\r