data/qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void() menu_show_error =
  29 {
  30         drawstring('0 200 0', "ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!", '8 8 0', '1 0 0', 1, 0);
  31 };
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void() menu_sub_null =
  37 {
  38 };
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 void WaypointSprite_Load();
  46 void CSQC_Init(void)
  47 {
  48 #ifdef USE_FTE
  49 #pragma target ID
  50         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  51         if(!__engine_check)
  52         {
  53                 print("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n");
  54                 localcmd("\ndisconnect\n");
  55                 return;
  56         }
  57 #pragma target FTE
  58 #endif
  59
  60         check_unacceptable_compiler_bugs();
  61
  62         float i;
  63         CSQC_CheckEngine();
  64
  65         binddb = db_create();
  66         tempdb = db_create();
  67         ClientProgsDB = db_load("client.db");
  68         compressShortVector_init();
  69
  70         drawfont = 0;
  71         menu_visible = FALSE;
  72         menu_show = menu_show_error;
  73         menu_action = menu_sub_null;
  74
  75         for(i = 0; i < 255; ++i)
  76                 if(getplayerkey(i, "viewentity") == "")
  77                         break;
  78         maxclients = i;
  79
  80         //ctf_temp_1 = "";
  81         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
  82         //registercmd("ctf_menu");
  83         registercmd("ons_map");
  84         //registercmd("menu_action");
  85
  86         registercmd("+button3");
  87         registercmd("-button3");
  88         registercmd("+button4");
  89         registercmd("-button4");
  90         registercmd("+showaccuracy");registercmd("-showaccuracy");
  91
  92 #ifndef CAMERATEST
  93         if(isdemo())
  94         {
  95 #endif
  96                 registercmd("+forward");registercmd("-forward");
  97                 registercmd("+back");registercmd("-back");
  98                 registercmd("+moveup");registercmd("-moveup");
  99                 registercmd("+movedown");registercmd("-movedown");
 100                 registercmd("+moveright");registercmd("-moveright");
 101                 registercmd("+moveleft");registercmd("-moveleft");
 102                 registercmd("+roll_right");registercmd("-roll_right");
 103                 registercmd("+roll_left");registercmd("-roll_left");
 104 #ifndef CAMERATEST
 105         }
 106 #endif
 107         registercvar("sbar_usecsqc", "1");
 108         registercvar("sbar_columns", "default", CVAR_SAVE);
 109
 110         gametype = 0;
 111
 112         // sbar_fields uses strunzone on the titles!
 113         for(i = 0; i < MAX_SBAR_FIELDS; ++i)
 114                 sbar_title[i] = strzone("(null)");
 115
 116         postinit = false;
 117
 118         calledhooks = 0;
 119
 120         teams = Sort_Spawn();
 121         players = Sort_Spawn();
 122
 123         GetTeam(COLOR_SPECTATOR, true); // add specs first
 124
 125         cvar_clientsettemp("_supports_weaponpriority", "1");
 126
 127         RegisterWeapons();
 128
 129         WaypointSprite_Load();
 130
 131         Projectile_Precache();
 132         GibSplash_Precache();
 133         Casings_Precache();
 134         DamageInfo_Precache();
 135         Announcer_Precache();
 136         Tuba_Precache();
 137
 138 #ifdef UID
 139         {
 140                 // find the user ID
 141                 string uid;
 142                 registercvar("_cl_userid", "", CVAR_SAVE);
 143                 uid = cvar_string("_cl_userid");
 144                 if(strlen(uid) < 16)
 145                 {
 146                         uid = "";
 147                         for(i = 0; i < 4; ++i)
 148                                 uid = strcat(uid, substring(ftos(floor(10000 + random() * 10000)), 1, -1));
 149                 }
 150                 cvar_set("_cl_userid", uid);
 151                 localcmd(strcat("\ncmd uid ", uid, "\n"));
 152         }
 153 #endif
 154
 155         get_mi_min_max_texcoords(1); // try the CLEVER way first
 156         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 157         shortmapname = mi_shortname;
 158
 159         if(precache_pic(minimapname) == "")
 160         {
 161                 // but maybe we have a non-clever minimap
 162                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 163                 if(precache_pic(minimapname) == "")
 164                         minimapname = ""; // FAIL
 165                 else
 166                         get_mi_min_max_texcoords(0); // load new texcoords
 167         }
 168
 169         mi_center = (mi_min + mi_max) * 0.5;
 170         mi_scale = mi_max - mi_min;
 171         minimapname = strzone(minimapname);
 172 }
 173
 174 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 175 void CSQC_Shutdown(void)
 176 {
 177 #ifdef USE_FTE
 178 #pragma TARGET id
 179         if(!__engine_check)
 180                 return 0;
 181 #pragma TARGET fte
 182 #endif
 183
 184         remove(teams);
 185         remove(players);
 186         db_close(binddb);
 187         db_close(tempdb);
 188         db_save(ClientProgsDB, "client.db");
 189         db_close(ClientProgsDB);
 190
 191         cvar_clientsettemp_restore();
 192
 193         if(camera_active)
 194                 cvar_set("chase_active",ftos(chase_active_backup));
 195
 196         if not(isdemo())
 197         {
 198                 if not(calledhooks & HOOK_START)
 199                         localcmd("\n_cl_hook_gamestart nop;");
 200                 if not(calledhooks & HOOK_END)
 201                         localcmd("\ncl_hook_gameend;");
 202         }
 203 }
 204
 205 .float has_team;
 206 float SetTeam(entity o, float Team)
 207 {
 208         entity tm;
 209         if(teamplay)
 210         {
 211                 switch(Team)
 212                 {
 213                         case -1:
 214                         case COLOR_TEAM1:
 215                         case COLOR_TEAM2:
 216                         case COLOR_TEAM3:
 217                         case COLOR_TEAM4:
 218                                 break;
 219                         default:
 220                                 if(GetTeam(Team, false) == NULL)
 221                                 {
 222                                         print("trying to switch to unsupported team ", ftos(Team), "\n");
 223                                         Team = COLOR_SPECTATOR;
 224                                 }
 225                                 break;
 226                 }
 227         }
 228         else
 229         {
 230                 switch(Team)
 231                 {
 232                         case -1:
 233                         case 0:
 234                                 break;
 235                         default:
 236                                 if(GetTeam(Team, false) == NULL)
 237                                 {
 238                                         print("trying to switch to unsupported team ", ftos(Team), "\n");
 239                                         Team = COLOR_SPECTATOR;
 240                                 }
 241                                 break;
 242                 }
 243         }
 244         if(Team == -1) // leave
 245         {
 246                 if(o.has_team)
 247                 {
 248                         //print("(DISCONNECT) leave team ", ftos(o.team), "\n");
 249                         tm = GetTeam(o.team, false);
 250                         tm.team_size -= 1;
 251                         o.has_team = 0;
 252                         return TRUE;
 253                 }
 254         }
 255         else
 256         {
 257                 if not(o.has_team)
 258                 {
 259                         //print("(CONNECT) enter team ", ftos(o.team), "\n");
 260                         o.team = Team;
 261                         tm = GetTeam(Team, true);
 262                         tm.team_size += 1;
 263                         o.has_team = 1;
 264                         return TRUE;
 265                 }
 266                 else if(Team != o.team)
 267                 {
 268                         //print("(CHANGE) leave team ", ftos(o.team), "\n");
 269                         tm = GetTeam(o.team, false);
 270                         tm.team_size -= 1;
 271                         o.team = Team;
 272                         //print("(CHANGE) enter team ", ftos(o.team), "\n");
 273                         tm = GetTeam(Team, true);
 274                         tm.team_size += 1;
 275                         return TRUE;
 276                 }
 277         }
 278         return FALSE;
 279 }
 280
 281 void Playerchecker_Think()
 282 {
 283         float i;
 284         entity e;
 285         for(i = 0; i < maxclients; ++i)
 286         {
 287                 e = playerslots[i];
 288                 if(GetPlayerName(i) == "")
 289                 {
 290                         if(e.sort_prev)
 291                         {
 292                                 //print("playerchecker: KILL KILL KILL\n");
 293                                 // player disconnected
 294                                 SetTeam(e, -1);
 295                                 RemovePlayer(e);
 296                                 e.sort_prev = world;
 297                                 //e.gotscores = 0;
 298                         }
 299                 }
 300                 else
 301                 {
 302                         if not(e.sort_prev)
 303                         {
 304                                 //print("playerchecker: SPAWN SPAWN SPAWN\n");
 305                                 // player connected
 306                                 if not(e)
 307                                         playerslots[i] = e = spawn();
 308                                 e.sv_entnum = i;
 309                                 e.ping = 0;
 310                                 e.ping_packetloss = 0;
 311                                 e.ping_movementloss = 0;
 312                                 //e.gotscores = 0; // we might already have the scores...
 313                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with Sbar_UpdatePlayerTeams
 314                                 RegisterPlayer(e);
 315                                 Sbar_UpdatePlayerPos(e);
 316                         }
 317                 }
 318         }
 319         self.nextthink = time + 0.2;
 320 }
 321
 322 void Porto_Init();
 323 void TrueAim_Init();
 324 void PostInit(void)
 325 {
 326         print(strcat("PostInit\n    maxclients = ", ftos(maxclients), "\n"));
 327         localcmd(strcat("\nsbar_columns_set ", cvar_string("sbar_columns"), ";\n"));
 328
 329         entity playerchecker;
 330         playerchecker = spawn();
 331         playerchecker.think = Playerchecker_Think;
 332         playerchecker.nextthink = time + 0.2;
 333
 334         Porto_Init();
 335         TrueAim_Init();
 336
 337         postinit = true;
 338 }
 339
 340 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
 341 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 342 float button_zoom;
 343 void Cmd_Sbar_SetFields(float);
 344 void Cmd_Sbar_Help(float);
 345 float CSQC_ConsoleCommand(string strMessage)
 346 {
 347         float argc;
 348         // Tokenize String
 349         //argc = tokenize(strMessage);
 350         argc = tokenize_console(strMessage);
 351
 352         // Acquire Command
 353         local string strCmd;
 354         strCmd = argv(0);
 355
 356         if(strCmd == "+button4") { // zoom
 357                 // return false, because the message shall be sent to the server anyway (for demos/speccing)
 358                 if(ignore_plus_zoom)
 359                 {
 360                         --ignore_plus_zoom;
 361                         return false;
 362                 }
 363                 button_zoom = 1;
 364                 return true;
 365         } else if(strCmd == "-button4") { // zoom
 366                 if(ignore_minus_zoom)
 367                 {
 368                         --ignore_minus_zoom;
 369                         return false;
 370                 }
 371                 button_zoom = 0;
 372                 return true;
 373         } else if(strCmd == "+button3") { // secondary
 374                 button_attack2 = 1;
 375                 return false;
 376         } else if(strCmd == "-button3") { // secondary
 377                 button_attack2 = 0;
 378                 return false;
 379         } else if(strCmd == "+showscores") {
 380                 sb_showscores = true;
 381                 return true;
 382         } else if(strCmd == "-showscores") {
 383                 sb_showscores = false;
 384                 return true;
 385         } else if(strCmd == "+showaccuracy") {
 386                 sb_showaccuracy = true;
 387                 return true;
 388         } else if(strCmd == "-showaccuracy") {
 389                 sb_showaccuracy = false;
 390                 return true;
 391         }
 392
 393         if(camera_active)
 394         if(strCmd == "+forward" || strCmd == "-back") {
 395                 ++camera_direction_x;
 396                 return true;
 397         } else if(strCmd == "-forward" || strCmd == "+back") {
 398                 --camera_direction_x;
 399                 return true;
 400         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 401                 --camera_direction_y;
 402                 return true;
 403         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 404                 ++camera_direction_y;
 405                 return true;
 406         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 407                 ++camera_direction_z;
 408                 return true;
 409         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 410                 --camera_direction_z;
 411                 return true;
 412         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 413                 ++camera_roll;
 414                 return true;
 415         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 416                 --camera_roll;
 417                 return true;
 418         }
 419
 420         return false;
 421 }
 422
 423 .vector view_ofs;
 424 entity debug_shotorg;
 425 void ShotOrg_Draw()
 426 {
 427         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 428         self.angles = view_angles;
 429         self.angles_x = -self.angles_x;
 430         if not(self.cnt)
 431                 R_AddEntity(self);
 432 }
 433 void ShotOrg_Draw2D()
 434 {
 435         vector coord2d_topleft, coord2d_topright, coord2d;
 436         string s;
 437         vector fs;
 438
 439         s = vtos(self.view_ofs);
 440         s = substring(s, 1, strlen(s) - 2);
 441         if(tokenize_console(s) == 3)
 442                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 443
 444         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 445         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 446
 447         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 448
 449         coord2d = coord2d_topleft;
 450         if(fs_x < 8)
 451         {
 452                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 453                 fs = '8 8 0';
 454         }
 455         coord2d_y -= fs_y;
 456         coord2d_z = 0;
 457         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 458 }
 459
 460 void ShotOrg_Spawn()
 461 {
 462         debug_shotorg = spawn();
 463         debug_shotorg.draw = ShotOrg_Draw;
 464         debug_shotorg.draw2d = ShotOrg_Draw2D;
 465         debug_shotorg.renderflags = RF_VIEWMODEL;
 466         debug_shotorg.effects = EF_FULLBRIGHT;
 467         precache_model("models/shotorg_adjuster.md3");
 468         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 469         debug_shotorg.scale = 2;
 470         debug_shotorg.view_ofs = '25 8 -8';
 471 }
 472
 473 void DrawDebugModel()
 474 {
 475         if(time - floor(time) > 0.5)
 476         {
 477                 PolyDrawModel(self);
 478         }
 479         else
 480         {
 481                 self.renderflags = 0;
 482                 R_AddEntity(self);
 483         }
 484 }
 485
 486 void GameCommand(string msg)
 487 {
 488         string s;
 489         float argc;
 490         entity e;
 491         argc = tokenize_console(msg);
 492
 493         if(argv(0) == "help" || argc == 0)
 494         {
 495                 print("Usage: cl_cmd COMMAND..., where possible commands are:\n");
 496                 print("  settemp cvar value\n");
 497                 print("  radar\n");
 498                 print("  sbar_columns_set ...\n");
 499                 print("  sbar_columns_help\n");
 500                 GameCommand_Generic("help");
 501                 return;
 502         }
 503
 504         if(GameCommand_Generic(msg))
 505                 return;
 506
 507         string cmd;
 508         cmd = argv(0);
 509         if(cmd == "mv_download") {
 510                 Cmd_MapVote_MapDownload(argc);
 511         }
 512         else if(cmd == "settemp") {
 513                 cvar_clientsettemp(argv(1), argv(2));
 514         }
 515         else if(cmd == "radar") {
 516                 ons_showmap = !ons_showmap;
 517         }
 518         else if(cmd == "sbar_columns_set") {
 519                 Cmd_Sbar_SetFields(argc);
 520         }
 521         else if(cmd == "sbar_columns_help") {
 522                 Cmd_Sbar_Help(argc);
 523         }
 524 #ifdef BLURTEST
 525         else if(cmd == "blurtest") {
 526                 blurtest_time0 = time;
 527                 blurtest_time1 = time + stof(argv(1));
 528                 blurtest_radius = stof(argv(2));
 529                 blurtest_power = stof(argv(3));
 530         }
 531 #endif
 532         else if(cmd == "shotorg_move") {
 533                 if(!debug_shotorg)
 534                         ShotOrg_Spawn();
 535                 else
 536                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 537                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 538         }
 539         else if(cmd == "shotorg_movez") {
 540                 if(!debug_shotorg)
 541                         ShotOrg_Spawn();
 542                 else
 543                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 544                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 545         }
 546         else if(cmd == "shotorg_set") {
 547                 if(!debug_shotorg)
 548                         ShotOrg_Spawn();
 549                 else
 550                         debug_shotorg.view_ofs = stov(argv(1));
 551                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 552         }
 553         else if(cmd == "shotorg_setz") {
 554                 if(!debug_shotorg)
 555                         ShotOrg_Spawn();
 556                 else
 557                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 558                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 559         }
 560         else if(cmd == "shotorg_toggle_hide") {
 561                 if(debug_shotorg)
 562                 {
 563                         debug_shotorg.cnt = !debug_shotorg.cnt;
 564                 }
 565         }
 566         else if(cmd == "shotorg_end") {
 567                 if(debug_shotorg)
 568                 {
 569                         print(vtos(debug_shotorg.view_ofs), "\n");
 570                         remove(debug_shotorg);
 571                         debug_shotorg = world;
 572                 }
 573                 localcmd("sv_cmd debug_shotorg\n");
 574         }
 575         else if(cmd == "sendcvar") {
 576                 s = cvar_string(argv(1));
 577                 if(argv(1) == "cl_weaponpriority")
 578                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 579                 else if(substring(argv(1), 0, 17) == "cl_weaponpriority" && strlen(argv(1)) == 18)
 580                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 581                 localcmd("cmd sentcvar ", argv(1), " \"", s, "\"\n");
 582         }
 583         else if(cmd == "spawn") {
 584                 s = argv(1);
 585                 e = spawn();
 586                 precache_model(s);
 587                 setmodel(e, s);
 588                 setorigin(e, view_origin);
 589                 e.angles = view_angles;
 590                 e.draw = DrawDebugModel;
 591                 e.classname = "debugmodel";
 592         }
 593         else
 594         {
 595                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 596         }
 597
 598         return;
 599 }
 600
 601 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 602 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 603 // All keys are in ascii.
 604 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 605 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 606 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 607 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 608 {
 609         local float bSkipKey;
 610         bSkipKey = false;
 611
 612         if(menu_visible)
 613                 if(menu_action(bInputType, nPrimary, nSecondary))
 614                         return TRUE;
 615         return bSkipKey;
 616 }
 617
 618 // END REQUIRED CSQC FUNCTIONS
 619 // --------------------------------------------------------------------------
 620
 621 // --------------------------------------------------------------------------
 622 // BEGIN OPTIONAL CSQC FUNCTIONS
 623 void Ent_ReadEntCS()
 624 {
 625         InterpolateOrigin_Undo();
 626
 627         self.classname = "entcs_receiver";
 628         self.sv_entnum = ReadByte() - 1;
 629         self.origin_x = ReadShort();
 630         self.origin_y = ReadShort();
 631         self.origin_z = ReadShort();
 632         self.angles_y = ReadByte() * 360.0 / 256;
 633         self.origin_z = self.angles_x = self.angles_z = 0;
 634
 635         InterpolateOrigin_Note();
 636 }
 637
 638 void Ent_Remove();
 639
 640 void Ent_RemovePlayerScore()
 641 {
 642         float i;
 643
 644         if(self.owner)
 645         {
 646                 SetTeam(self.owner, -1);
 647                 self.owner.gotscores = 0;
 648                 for(i = 0; i < MAX_SCORE; ++i)
 649                         self.owner.(scores[i]) = 0; // clear all scores
 650         }
 651 }
 652
 653 void Ent_ReadPlayerScore()
 654 {
 655         float i, n;
 656         float isNew;
 657         entity o;
 658
 659         // damnit -.- don't want to go change every single .sv_entnum in sbar.qc AGAIN
 660         // (no I've never heard of M-x replace-string, sed, or anything like that)
 661         isNew = !self.owner; // workaround for DP bug
 662         n = ReadByte()-1;
 663
 664 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 665         if(!isNew && n != self.sv_entnum)
 666         {
 667                 print("A CSQC entity changed its owner!\n");
 668                 isNew = true;
 669                 Ent_Remove();
 670                 self.enttype = ENT_CLIENT_SCORES;
 671         }
 672 #endif
 673
 674         self.sv_entnum = n;
 675
 676         if not(playerslots[self.sv_entnum])
 677                 playerslots[self.sv_entnum] = spawn();
 678         o = self.owner = playerslots[self.sv_entnum];
 679         o.sv_entnum = self.sv_entnum;
 680         o.gotscores = 1;
 681
 682         //if not(o.sort_prev)
 683         //      RegisterPlayer(o);
 684         //playerchecker will do this for us later, if it has not already done so
 685
 686         float sf, lf;
 687 #if MAX_SCORE <= 8
 688         sf = ReadByte();
 689         lf = ReadByte();
 690 #else
 691         sf = ReadShort();
 692         lf = ReadShort();
 693 #endif
 694         float p;
 695         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 696                 if(sf & p)
 697                 {
 698                         if(lf & p)
 699                                 o.(scores[i]) = ReadInt24_t();
 700                         else
 701                                 o.(scores[i]) = ReadChar();
 702                 }
 703
 704         if(o.sort_prev)
 705                 Sbar_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 706
 707         self.entremove = Ent_RemovePlayerScore;
 708 }
 709
 710 void Ent_ReadTeamScore()
 711 {
 712         float i;
 713         entity o;
 714
 715         self.team = ReadByte();
 716         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 717
 718         float sf, lf;
 719 #if MAX_TEAMSCORE <= 8
 720         sf = ReadByte();
 721         lf = ReadByte();
 722 #else
 723         sf = ReadShort();
 724         lf = ReadShort();
 725 #endif
 726         float p;
 727         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 728                 if(sf & p)
 729                 {
 730                         if(lf & p)
 731                                 o.(teamscores[i]) = ReadInt24_t();
 732                         else
 733                                 o.(teamscores[i]) = ReadChar();
 734                 }
 735
 736         Sbar_UpdateTeamPos(o);
 737 }
 738
 739 void Net_Reset()
 740 {
 741 }
 742
 743 void Ent_ClientData()
 744 {
 745         float f;
 746         float newspectatee_status;
 747
 748         f = ReadByte();
 749
 750         sb_showscores_force = (f & 1);
 751
 752         if(f & 2)
 753         {
 754                 newspectatee_status = ReadByte();
 755                 if(newspectatee_status == player_localentnum)
 756                         newspectatee_status = -1; // observing
 757         }
 758         else
 759                 newspectatee_status = 0;
 760
 761         spectatorbutton_zoom = (f & 4);
 762
 763         if(f & 8)
 764         {
 765                 angles_held_status = 1;
 766                 angles_held_x = ReadAngle();
 767                 angles_held_y = ReadAngle();
 768                 angles_held_z = 0;
 769         }
 770         else
 771                 angles_held_status = 0;
 772
 773         if(newspectatee_status != spectatee_status)
 774         {
 775                 float i;
 776                 // clear the weapon accuracy stats
 777                 for(i = WEP_FIRST; i <= WEP_LAST; ++i) {
 778                         weapon_hits[i] = 0;
 779                         weapon_fired[i] = 0;
 780                 }
 781
 782                 // clear race stuff
 783                 race_laptime = 0;
 784                 race_checkpointtime = 0;
 785         }
 786         spectatee_status = newspectatee_status;
 787 }
 788
 789 void Ent_Nagger()
 790 {
 791         float nags, i, j, b, f;
 792
 793         nags = ReadByte();
 794
 795         if(nags & 128)
 796         {
 797                 if(vote_called_vote)
 798                         strunzone(vote_called_vote);
 799                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 800         }
 801
 802         if(nags & 1)
 803         {
 804                 for(j = 0; j < maxclients; ++j)
 805                         if(playerslots[j])
 806                                 playerslots[j].ready = 1;
 807                 for(i = 1; i <= maxclients; i += 8)
 808                 {
 809                         f = ReadByte();
 810                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 811                                 if not(f & b)
 812                                         if(playerslots[j])
 813                                                 playerslots[j].ready = 0;
 814                 }
 815         }
 816
 817         ready_waiting = (nags & 1);
 818         ready_waiting_for_me = (nags & 2);
 819         vote_waiting = (nags & 4);
 820         vote_waiting_for_me = (nags & 8);
 821         warmup_stage = (nags & 16);
 822 }
 823
 824 void Ent_RandomSeed()
 825 {
 826         float s;
 827         prandom_debug();
 828         s = ReadShort();
 829         psrandom(s);
 830 }
 831
 832 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 833 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 834 void Ent_RadarLink();
 835 void Ent_Init();
 836 void Ent_ScoresInfo();
 837 void(float bIsNewEntity) CSQC_Ent_Update =
 838 {
 839         float t;
 840         float savetime;
 841         t = ReadByte();
 842
 843         // set up the "time" global for received entities to be correct for interpolation purposes
 844         savetime = time;
 845         if(servertime)
 846         {
 847                 time = servertime;
 848         }
 849         else
 850         {
 851                 serverprevtime = time;
 852                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 853                 time = serverprevtime + serverdeltatime;
 854         }
 855
 856 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 857         if(self.enttype)
 858                 if(t != self.enttype)
 859                 {
 860                         print("A CSQC entity changed its type!\n");
 861                         Ent_Remove();
 862                         bIsNewEntity = 1;
 863                 }
 864 #endif
 865         self.enttype = t;
 866         switch(t)
 867         {
 868                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 869                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 870                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 871                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 872                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 873                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 874                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 875                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 876                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 877                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 878                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 879                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 880                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 881                 case ENT_CLIENT_INIT: Ent_Init(); break;
 882                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 883                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 884                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 885                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 886                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 887                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 888                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 889                 default:
 890                         error(strcat("unknown entity type in CSQC_Ent_Update: ", ftos(self.enttype), "\n"));
 891                         break;
 892         }
 893
 894         time = savetime;
 895 };
 896 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 897 // used when an entity changes its type. For an entity that someone interacts
 898 // with others, make sure it can no longer do so.
 899 void Ent_Remove()
 900 {
 901         if(self.entremove)
 902                 self.entremove();
 903
 904         self.enttype = 0;
 905         self.classname = "";
 906         self.draw = menu_sub_null;
 907         self.entremove = menu_sub_null;
 908         // TODO possibly set more stuff to defaults
 909 }
 910 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 911 void CSQC_Ent_Remove()
 912 {
 913         if(self.enttype)
 914                 Ent_Remove();
 915         remove(self);
 916 }
 917
 918 void Gamemode_Init()
 919 {
 920         if(gametype == GAME_ONSLAUGHT) {
 921                 print(strcat("Using ", minimapname, " as minimap.\n"));
 922                 precache_pic("gfx/ons-cp-neutral.tga");
 923                 precache_pic("gfx/ons-cp-red.tga");
 924                 precache_pic("gfx/ons-cp-blue.tga");
 925                 precache_pic("gfx/ons-frame.tga");
 926                 precache_pic("gfx/ons-frame-team.tga");
 927         } else if(gametype == GAME_KEYHUNT) {
 928                 precache_pic("gfx/sb_key_carrying");
 929                 precache_pic("gfx/sb_key_carrying_outline");
 930         }
 931
 932         if not(isdemo())
 933         {
 934                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), ";");
 935                 calledhooks |= HOOK_START;
 936         }
 937 }
 938 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 939 void CSQC_Parse_StuffCmd(string strMessage)
 940 {
 941         localcmd(strMessage);
 942 }
 943 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 944 void CSQC_Parse_Print(string strMessage)
 945 {
 946         print(ColorTranslateRGB(strMessage));
 947 }
 948
 949 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
 950 void CSQC_Parse_CenterPrint(string strMessage)
 951 {
 952         centerprint(strMessage);
 953 }
 954
 955 string notranslate_fogcmd1 = "\nfog ";
 956 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 957 void Fog_Force()
 958 {
 959         // TODO somehow thwart prvm_globalset client ...
 960
 961         if(forcefog != "")
 962                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
 963 }
 964
 965 void Gamemode_Init();
 966 void Ent_ScoresInfo()
 967 {
 968         float i;
 969         self.classname = "ent_client_scores_info";
 970         gametype = ReadByte();
 971         for(i = 0; i < MAX_SCORE; ++i)
 972         {
 973                 scores_label[i] = strzone(ReadString());
 974                 scores_flags[i] = ReadByte();
 975         }
 976         for(i = 0; i < MAX_TEAMSCORE; ++i)
 977         {
 978                 teamscores_label[i] = strzone(ReadString());
 979                 teamscores_flags[i] = ReadByte();
 980         }
 981         Sbar_InitScores();
 982         Gamemode_Init();
 983 }
 984
 985 void Ent_Init()
 986 {
 987         self.classname = "ent_client_init";
 988
 989         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 990
 991         hook_shotorigin_x = ReadCoord();
 992         hook_shotorigin_y = ReadCoord();
 993         hook_shotorigin_z = ReadCoord();
 994
 995         if(forcefog)
 996                 strunzone(forcefog);
 997         forcefog = strzone(ReadString());
 998
 999         armorblockpercent = ReadByte() / 255.0;
1000
1001         g_weaponswitchdelay = ReadByte() / 255.0;
1002
1003         if(!postinit)
1004                 PostInit();
1005 }
1006
1007 void Net_ReadRace()
1008 {
1009         float b;
1010
1011         b = ReadByte();
1012
1013         switch(b)
1014         {
1015                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1016                         race_checkpoint = ReadByte();
1017                         race_time = ReadInt24_t();
1018                         race_previousbesttime = ReadInt24_t();
1019                         if(race_previousbestname)
1020                                 strunzone(race_previousbestname);
1021                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1022
1023                         race_checkpointtime = time;
1024
1025                         if(race_checkpoint == 0 || race_checkpoint == 254)
1026                         {
1027                                 race_penaltyaccumulator = 0;
1028                                 race_laptime = time; // valid
1029                         }
1030
1031                         break;
1032
1033                 case RACE_NET_CHECKPOINT_CLEAR:
1034                         race_laptime = 0;
1035                         race_checkpointtime = 0;
1036                         break;
1037
1038                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1039                         race_laptime = ReadCoord();
1040                         race_checkpointtime = -99999;
1041                         // fall through
1042                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1043                         race_nextcheckpoint = ReadByte();
1044
1045                         race_nextbesttime = ReadInt24_t();
1046                         if(race_nextbestname)
1047                                 strunzone(race_nextbestname);
1048                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1049                         break;
1050
1051                 case RACE_NET_CHECKPOINT_HIT_RACE:
1052                         race_mycheckpoint = ReadByte();
1053                         race_mycheckpointtime = time;
1054                         race_mycheckpointdelta = ReadInt24_t();
1055                         race_mycheckpointlapsdelta = ReadByte();
1056                         if(race_mycheckpointlapsdelta >= 128)
1057                                 race_mycheckpointlapsdelta -= 256;
1058                         if(race_mycheckpointenemy)
1059                                 strunzone(race_mycheckpointenemy);
1060                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1061                         break;
1062
1063                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1064                         race_othercheckpoint = ReadByte();
1065                         race_othercheckpointtime = time;
1066                         race_othercheckpointdelta = ReadInt24_t();
1067                         race_othercheckpointlapsdelta = ReadByte();
1068                         if(race_othercheckpointlapsdelta >= 128)
1069                                 race_othercheckpointlapsdelta -= 256;
1070                         if(race_othercheckpointenemy)
1071                                 strunzone(race_othercheckpointenemy);
1072                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1073                         break;
1074
1075                 case RACE_NET_PENALTY_RACE:
1076                         race_penaltyeventtime = time;
1077                         race_penaltytime = ReadShort();
1078                         //race_penaltyaccumulator += race_penaltytime;
1079                         if(race_penaltyreason)
1080                                 strunzone(race_penaltyreason);
1081                         race_penaltyreason = strzone(ReadString());
1082                         break;
1083
1084                 case RACE_NET_PENALTY_QUALIFYING:
1085                         race_penaltyeventtime = time;
1086                         race_penaltytime = ReadShort();
1087                         race_penaltyaccumulator += race_penaltytime;
1088                         if(race_penaltyreason)
1089                                 strunzone(race_penaltyreason);
1090                         race_penaltyreason = strzone(ReadString());
1091                         break;
1092
1093                 case RACE_NET_SERVER_RECORD:
1094                         race_server_record = ReadInt24_t();
1095                         break;
1096                 case RACE_NET_SPEED_AWARD:
1097                         race_speedaward = ReadInt24_t();
1098                         if(race_speedaward_holder)
1099                                 strunzone(race_speedaward_holder);
1100                         race_speedaward_holder = strzone(ReadString());
1101                         break;
1102                 case RACE_NET_SPEED_AWARD_BEST:
1103                         race_speedaward_alltimebest = ReadInt24_t();
1104                         if(race_speedaward_alltimebest_holder)
1105                                 strunzone(race_speedaward_alltimebest_holder);
1106                         race_speedaward_alltimebest_holder = strzone(ReadString());
1107                         break;
1108                 case RACE_NET_SERVER_RANKINGS:
1109                         float pos, prevpos, del;
1110                         pos = ReadShort();
1111                         prevpos = ReadShort();
1112                         del = ReadShort();
1113
1114                         // move other rankings out of the way
1115                         float i;
1116                         if (prevpos) {
1117                                 for (i=prevpos-1;i>pos-1;--i) {
1118                                         grecordtime[i] = grecordtime[i-1];
1119                                         if(grecordholder[i])
1120                                                 strunzone(grecordholder[i]);
1121                                         grecordholder[i] = strzone(grecordholder[i-1]);
1122                                 }
1123                         } else if (del) { // a record has been deleted by the admin
1124                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1125                                         if (i == RANKINGS_CNT-1) { // clear out last record
1126                                                 grecordtime[i] = 0;
1127                                                 if (grecordholder[i])
1128                                                         strunzone(grecordholder[i]);
1129                                                 grecordholder[i] = string_null;
1130                                         }
1131                                         else {
1132                                                 grecordtime[i] = grecordtime[i+1];
1133                                                 if (grecordholder[i])
1134                                                         strunzone(grecordholder[i]);
1135                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1136                                         }
1137                                 }
1138                         } else { // player has no ranked record yet
1139                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1140                                         grecordtime[i] = grecordtime[i-1];
1141                                         if(grecordholder[i])
1142                                                 strunzone(grecordholder[i]);
1143                                         grecordholder[i] = strzone(grecordholder[i-1]);
1144                                 }
1145                         }
1146
1147                         // store new ranking
1148                         if(grecordholder[pos-1] != "")
1149                                 strunzone(grecordholder[pos-1]);
1150                         grecordholder[pos-1] = strzone(ReadString());
1151                         grecordtime[pos-1] = ReadInt24_t();
1152                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1153                                 race_myrank = pos;
1154                         break;
1155                 case RACE_NET_SERVER_STATUS:
1156                         race_status = ReadShort();
1157                         if(race_status_name)
1158                                 strunzone(race_status_name);
1159                         race_status_name = strzone(ReadString());
1160         }
1161 }
1162
1163 void Net_ReadSpawn()
1164 {
1165         zoomin_effect = 1;
1166         current_viewzoom = 0.6;
1167 }
1168
1169 void Net_TeamNagger()
1170 {
1171         teamnagger = 1;
1172 }
1173
1174 void Net_ReadPingPLReport()
1175 {
1176         float e, pi, pl, ml;
1177         e = ReadByte();
1178         pi = ReadShort();
1179         pl = ReadByte();
1180         ml = ReadByte();
1181         if not(playerslots[e])
1182                 return;
1183         playerslots[e].ping = pi;
1184         playerslots[e].ping_packetloss = pl / 255.0;
1185         playerslots[e].ping_movementloss = ml / 255.0;
1186 }
1187
1188 void Net_VoteDialog(float highlight) {
1189         if(highlight) {
1190                 vote_highlighted = ReadShort();
1191                 return;
1192         }
1193
1194         vote_yescount = ReadShort();
1195         vote_nocount = ReadShort();
1196         vote_needed = ReadShort();
1197         vote_active = 1;
1198 }
1199
1200 void Net_VoteDialogReset() {
1201         vote_active = 0;
1202 }
1203
1204 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1205 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1206 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1207 float CSQC_Parse_TempEntity()
1208 {
1209         local float bHandled;
1210                 bHandled  = true;
1211         // Acquire TE ID
1212         local float nTEID;
1213                 nTEID = ReadByte();
1214
1215                 // NOTE: Could just do return instead of break...
1216         switch(nTEID)
1217         {
1218                 case TE_CSQC_PICTURE:
1219                         Net_MapVote_Picture();
1220                         bHandled = true;
1221                         break;
1222                 case TE_CSQC_RACE:
1223                         Net_ReadRace();
1224                         bHandled = true;
1225                         break;
1226                 case 13: // TE_BEAM
1227                         Net_GrapplingHook();
1228                         bHandled = true;
1229                         break;
1230                 case TE_CSQC_SPAWN:
1231                         Net_ReadSpawn();
1232                         bHandled = true;
1233                         break;
1234                 case TE_CSQC_ZCURVEPARTICLES:
1235                         Net_ReadZCurveParticles();
1236                         bHandled = true;
1237                         break;
1238                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1239                         Net_ReadNexgunBeamParticle();
1240                         bHandled = true;
1241                         break;
1242                 case TE_CSQC_TEAMNAGGER:
1243                         Net_TeamNagger();
1244                         bHandled = true;
1245                         break;
1246                 case TE_CSQC_VOTE:
1247                         Net_VoteDialog(ReadByte());
1248                         bHandled = true;
1249                         break;
1250                 case TE_CSQC_VOTERESET:
1251                         Net_VoteDialogReset();
1252                         bHandled = true;
1253                         break;
1254         case TE_CSQC_LIGHTNINGARC:
1255             Net_ReadLightningarc();
1256             bHandled = true;
1257             break;
1258         case TE_CSQC_PINGPLREPORT:
1259             Net_ReadPingPLReport();
1260             bHandled = true;
1261             break;
1262                 default:
1263                         // No special logic for this temporary entity; return 0 so the engine can handle it
1264                         bHandled = false;
1265                         break;
1266         }
1267
1268         return bHandled;
1269 }
1270
1271 string getcommandkey(string text, string command)
1272 {
1273         string keys;
1274         float n, j, k, l;
1275
1276         if (!sbar_showbinds)
1277                 return text;
1278
1279         keys = db_get(binddb, command);
1280         if (!keys)
1281         {
1282                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1283                 for(j = 0; j < n; ++j)
1284                 {
1285                         k = stof(argv(j));
1286                         if(k != -1)
1287                         {
1288                                 if ("" == keys)
1289                                         keys = keynumtostring(k);
1290                                 else
1291                                         keys = strcat(keys, ", ", keynumtostring(k));
1292
1293                                 ++l;
1294                                 if (sbar_showbinds_limit > 0 && sbar_showbinds_limit >= l) break;
1295                         }
1296
1297                 }
1298                 db_put(binddb, command, keys);
1299         }
1300
1301         if ("" == keys) {
1302                 if (sbar_showbinds > 1)
1303                         return strcat(text, " (not bound)");
1304                 else
1305                         return text;
1306         }
1307         else if (sbar_showbinds > 1)
1308                 return strcat(text, " (", keys, ")");
1309         else
1310                 return keys;
1311 }