data/qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------\r
   2 // BEGIN REQUIRED CSQC FUNCTIONS\r
   3 //include "main.qh"\r
   4 \r
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
   6 \r
   7 void cvar_clientsettemp(string cv, string val)\r
   8 {\r
   9         entity e;\r
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )\r
  11                 if(e.netname == cv)\r
  12                         goto saved;\r
  13         e = spawn();\r
  14         e.classname = "saved_cvar_value";\r
  15         e.netname = strzone(cv);\r
  16         e.message = strzone(cvar_string(cv));\r
  17 :saved\r
  18         cvar_set(cv, val);\r
  19 }\r
  20 \r
  21 void cvar_clientsettemp_restore()\r
  22 {\r
  23         entity e;\r
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )\r
  25                         cvar_set(e.netname, e.message);\r
  26 }\r
  27 \r
  28 void() menu_show_error =\r
  29 {\r
  30         drawstring('0 200 0', "ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!", '8 8 0', '1 0 0', 1, 0);\r
  31 };\r
  32 \r
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)\r
  34 // Useful for precaching things\r
  35 \r
  36 void() menu_sub_null =\r
  37 {\r
  38 };\r
  39 \r
  40 #ifdef USE_FTE\r
  41 float __engine_check;\r
  42 #endif\r
  43 \r
  44 string forcefog;\r
  45 void WaypointSprite_Load();\r
  46 void CSQC_Init(void)\r
  47 {\r
  48 #ifdef USE_FTE\r
  49 #pragma target ID\r
  50         __engine_check = checkextension("DP_SV_WRITEPICTURE");\r
  51         if(!__engine_check)\r
  52         {\r
  53                 print("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n");\r
  54                 localcmd("\ndisconnect\n");\r
  55                 return;\r
  56         }\r
  57 #pragma target FTE\r
  58 #endif\r
  59 \r
  60         float i;\r
  61         CSQC_CheckEngine();\r
  62         dprint_load();\r
  63 \r
  64         binddb = db_create();\r
  65         tempdb = db_create();\r
  66         compressShortVector_init();\r
  67 \r
  68         drawfont = 0;\r
  69         menu_visible = FALSE;\r
  70         menu_show = menu_show_error;\r
  71         menu_action = menu_sub_null;\r
  72 \r
  73         for(i = 0; i < 255; ++i)\r
  74                 if(getplayerkey(i, "viewentity") == "")\r
  75                         break;\r
  76         maxclients = i;\r
  77 \r
  78         //ctf_temp_1 = "";\r
  79         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used\r
  80         //registercmd("ctf_menu");\r
  81         registercmd("ons_map");\r
  82         //registercmd("menu_action");\r
  83 \r
  84         registercmd("+button3");\r
  85         registercmd("-button3");\r
  86         registercmd("+button4");\r
  87         registercmd("-button4");\r
  88 \r
  89 #ifndef CAMERATEST\r
  90         if(isdemo())\r
  91         {\r
  92 #endif\r
  93                 registercmd("+forward");registercmd("-forward");\r
  94                 registercmd("+back");registercmd("-back");\r
  95                 registercmd("+moveup");registercmd("-moveup");\r
  96                 registercmd("+movedown");registercmd("-movedown");\r
  97                 registercmd("+moveright");registercmd("-moveright");\r
  98                 registercmd("+moveleft");registercmd("-moveleft");\r
  99                 registercmd("+roll_right");registercmd("-roll_right");\r
 100                 registercmd("+roll_left");registercmd("-roll_left");\r
 101 #ifndef CAMERATEST\r
 102         }\r
 103 #endif\r
 104         registercvar("sbar_usecsqc", "1");\r
 105         registercvar("sbar_columns", "default", CVAR_SAVE);\r
 106 \r
 107         gametype = 0;\r
 108 \r
 109         // sbar_fields uses strunzone on the titles!\r
 110         for(i = 0; i < MAX_SBAR_FIELDS; ++i)\r
 111                 sbar_title[i] = strzone("(null)");\r
 112 \r
 113         postinit = false;\r
 114 \r
 115         teams = Sort_Spawn();\r
 116         players = Sort_Spawn();\r
 117 \r
 118         GetTeam(COLOR_SPECTATOR, true); // add specs first\r
 119 \r
 120         cvar_clientsettemp("_supports_weaponpriority", "1");\r
 121 \r
 122 \r
 123 \r
 124 \r
 125         cs_project_is_b0rked = TRUE;\r
 126         R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');\r
 127         R_SetView(VF_FOV, '90 90 0');\r
 128         R_SetView(VF_ORIGIN, '0 0 0');\r
 129         R_SetView(VF_ANGLES, '0 0 0');\r
 130         R_SetView(VF_PERSPECTIVE, 1);\r
 131         makevectors('0 0 0');\r
 132         vector v;\r
 133         v = cs_project(v_forward);\r
 134         if(v_x - 320 < +1)\r
 135         if(v_x - 320 > -1)\r
 136         if(v_y - 240 < +1)\r
 137         if(v_y - 240 > -1)\r
 138                 cs_project_is_b0rked = FALSE;\r
 139 \r
 140         RegisterWeapons();\r
 141 \r
 142         WaypointSprite_Load();\r
 143 \r
 144         Projectile_Precache();\r
 145         GibSplash_Precache();\r
 146         Casings_Precache();\r
 147         DamageInfo_Precache();\r
 148 \r
 149         get_mi_min_max_texcoords(1); // try the CLEVER way first\r
 150         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");\r
 151         shortmapname = mi_shortname;\r
 152 \r
 153         if(precache_pic(minimapname) == "")\r
 154         {\r
 155                 // but maybe we have a non-clever minimap\r
 156                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");\r
 157                 if(precache_pic(minimapname) == "")\r
 158                         minimapname = ""; // FAIL\r
 159                 else\r
 160                         get_mi_min_max_texcoords(0); // load new texcoords\r
 161         }\r
 162 \r
 163         mi_center = (mi_min + mi_max) * 0.5;\r
 164         mi_scale = mi_max - mi_min;\r
 165         minimapname = strzone(minimapname);\r
 166 }\r
 167 \r
 168 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)\r
 169 void CSQC_Shutdown(void)\r
 170 {\r
 171 #ifdef USE_FTE\r
 172 #pragma TARGET id\r
 173         if(!__engine_check)\r
 174                 return 0;\r
 175 #pragma TARGET fte\r
 176 #endif\r
 177 \r
 178         remove(teams);\r
 179         remove(players);\r
 180         db_close(binddb);\r
 181         db_close(tempdb);\r
 182 \r
 183         cvar_clientsettemp_restore();\r
 184 \r
 185         if(camera_active)\r
 186                 cvar_set("chase_active",ftos(chase_active_backup));\r
 187 }\r
 188 \r
 189 .float has_team;\r
 190 float SetTeam(entity o, float Team)\r
 191 {\r
 192         entity tm;\r
 193         if(Team == -1) // leave\r
 194         {\r
 195                 if(o.has_team)\r
 196                 {\r
 197                         //print("(DISCONNECT) leave team ", ftos(o.team), "\n");\r
 198                         tm = GetTeam(o.team, false);\r
 199                         tm.team_size -= 1;\r
 200                         o.has_team = 0;\r
 201                         return TRUE;\r
 202                 }\r
 203         }\r
 204         else\r
 205         {\r
 206                 if not(o.has_team)\r
 207                 {\r
 208                         //print("(CONNECT) enter team ", ftos(o.team), "\n");\r
 209                         o.team = Team;\r
 210                         tm = GetTeam(Team, true);\r
 211                         tm.team_size += 1;\r
 212                         o.has_team = 1;\r
 213                         return TRUE;\r
 214                 }\r
 215                 else if(Team != o.team)\r
 216                 {\r
 217                         //print("(CHANGE) leave team ", ftos(o.team), "\n");\r
 218                         tm = GetTeam(o.team, false);\r
 219                         tm.team_size -= 1;\r
 220                         o.team = Team;\r
 221                         //print("(CHANGE) enter team ", ftos(o.team), "\n");\r
 222                         tm = GetTeam(Team, true);\r
 223                         tm.team_size += 1;\r
 224                         return TRUE;\r
 225                 }\r
 226         }\r
 227         return FALSE;\r
 228 }\r
 229 \r
 230 void Playerchecker_Think()\r
 231 {\r
 232         float i;\r
 233         entity e;\r
 234         for(i = 0; i < maxclients; ++i)\r
 235         {\r
 236                 e = playerslots[i];\r
 237                 if(GetPlayerName(i) == "")\r
 238                 {\r
 239                         if(e.sort_prev)\r
 240                         {\r
 241                                 //print("playerchecker: KILL KILL KILL\n");\r
 242                                 // player disconnected\r
 243                                 SetTeam(e, -1);\r
 244                                 RemovePlayer(e);\r
 245                                 e.sort_prev = world;\r
 246                                 //e.gotscores = 0;\r
 247                         }\r
 248                 }\r
 249                 else\r
 250                 {\r
 251                         if not(e.sort_prev)\r
 252                         {\r
 253                                 //print("playerchecker: SPAWN SPAWN SPAWN\n");\r
 254                                 // player connected\r
 255                                 if not(e)\r
 256                                         playerslots[i] = e = spawn();\r
 257                                 e.sv_entnum = i;\r
 258                                 //e.gotscores = 0; // we might already have the scores...\r
 259                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with Sbar_UpdatePlayerTeams\r
 260                                 RegisterPlayer(e);\r
 261                                 Sbar_UpdatePlayerPos(e);\r
 262                         }\r
 263                 }\r
 264         }\r
 265         self.nextthink = time + 0.2;\r
 266 }\r
 267 \r
 268 void Porto_Init();\r
 269 void PostInit(void)\r
 270 {\r
 271         print(strcat("PostInit\n    maxclients = ", ftos(maxclients), "\n"));\r
 272         localcmd(strcat("\nsbar_columns_set ", cvar_string("sbar_columns"), ";\n"));\r
 273 \r
 274         entity playerchecker;\r
 275         playerchecker = spawn();\r
 276         playerchecker.think = Playerchecker_Think;\r
 277         playerchecker.nextthink = time + 0.2;\r
 278 \r
 279         Porto_Init();\r
 280 \r
 281         postinit = true;\r
 282 }\r
 283 \r
 284 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function\r
 285 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.\r
 286 float button_zoom;\r
 287 void Cmd_Sbar_SetFields(float);\r
 288 void Cmd_Sbar_Help(float);\r
 289 float CSQC_ConsoleCommand(string strMessage)\r
 290 {\r
 291         float argc;\r
 292         // Tokenize String\r
 293         //argc = tokenize(strMessage);\r
 294         argc = tokenize_sane(strMessage);\r
 295 \r
 296         // Acquire Command\r
 297         local string strCmd;\r
 298         strCmd = argv(0);\r
 299 \r
 300         if(strCmd == "+button4") { // zoom\r
 301                 // return false, because the message shall be sent to the server anyway (for demos/speccing)\r
 302                 if(ignore_plus_zoom)\r
 303                 {\r
 304                         --ignore_plus_zoom;\r
 305                         return false;\r
 306                 }\r
 307                 button_zoom = 1;\r
 308                 return true;\r
 309         } else if(strCmd == "-button4") { // zoom\r
 310                 if(ignore_minus_zoom)\r
 311                 {\r
 312                         --ignore_minus_zoom;\r
 313                         return false;\r
 314                 }\r
 315                 button_zoom = 0;\r
 316                 return true;\r
 317         } else if(strCmd == "+button3") { // secondary\r
 318                 button_attack2 = 1;\r
 319                 return false;\r
 320         } else if(strCmd == "-button3") { // secondary\r
 321                 button_attack2 = 0;\r
 322                 return false;\r
 323         } else if(strCmd == "+showscores") {\r
 324                 sb_showscores = true;\r
 325                 return true;\r
 326         } else if(strCmd == "-showscores") {\r
 327                 sb_showscores = false;\r
 328                 return true;\r
 329         }\r
 330 \r
 331         if(camera_active)\r
 332         if(strCmd == "+forward" || strCmd == "-back") {\r
 333                 ++camera_direction_x;\r
 334                 return true;\r
 335         } else if(strCmd == "-forward" || strCmd == "+back") {\r
 336                 --camera_direction_x;\r
 337                 return true;\r
 338         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {\r
 339                 --camera_direction_y;\r
 340                 return true;\r
 341         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {\r
 342                 ++camera_direction_y;\r
 343                 return true;\r
 344         } else if(strCmd == "+moveup" || strCmd == "-movedown") {\r
 345                 ++camera_direction_z;\r
 346                 return true;\r
 347         } else if(strCmd == "-moveup" || strCmd == "+movedown") {\r
 348                 --camera_direction_z;\r
 349                 return true;\r
 350         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {\r
 351                 ++camera_roll;\r
 352                 return true;\r
 353         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {\r
 354                 --camera_roll;\r
 355                 return true;\r
 356         }\r
 357 \r
 358         return false;\r
 359 }\r
 360 \r
 361 .vector view_ofs;\r
 362 entity debug_shotorg;\r
 363 void ShotOrg_Draw()\r
 364 {\r
 365         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;\r
 366         self.angles = view_angles;\r
 367         self.angles_x = -self.angles_x;\r
 368         if not(self.cnt)\r
 369                 R_AddEntity(self);\r
 370 }\r
 371 void ShotOrg_Draw2D()\r
 372 {\r
 373         vector coord2d_topleft, coord2d_topright, coord2d;\r
 374         string s;\r
 375         vector fs;\r
 376 \r
 377         s = vtos(self.view_ofs);\r
 378         s = substring(s, 1, strlen(s) - 2);\r
 379         if(tokenize_sane(s) == 3)\r
 380                 s = strcat(argv(0), " ", argv(1), " ", argv(2));\r
 381 \r
 382         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);\r
 383         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);\r
 384 \r
 385         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE));\r
 386 \r
 387         coord2d = coord2d_topleft;\r
 388         if(fs_x < 8)\r
 389         {\r
 390                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;\r
 391                 fs = '8 8 0';\r
 392         }\r
 393         coord2d_y -= fs_y;\r
 394         coord2d_z = 0;\r
 395         drawstring(coord2d, s, fs, '1 1 1', 1, 0);\r
 396 }\r
 397 \r
 398 void ShotOrg_Spawn()\r
 399 {\r
 400         debug_shotorg = spawn();\r
 401         debug_shotorg.draw = ShotOrg_Draw;\r
 402         debug_shotorg.draw2d = ShotOrg_Draw2D;\r
 403         debug_shotorg.renderflags = RF_VIEWMODEL;\r
 404         debug_shotorg.effects = EF_FULLBRIGHT;\r
 405         precache_model("models/shotorg_adjuster.md3");\r
 406         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");\r
 407         debug_shotorg.scale = 2;\r
 408         debug_shotorg.view_ofs = '25 8 -8';\r
 409 }\r
 410 \r
 411 void GameCommand(string msg)\r
 412 {\r
 413         float argc;\r
 414         argc = tokenize_sane(msg);\r
 415 \r
 416         if(argv(0) == "help" || argc == 0)\r
 417         {\r
 418                 print("Usage: sv_cmd COMMAND..., where possible commands are:\n");\r
 419                 print("  settemp cvar value\n");\r
 420                 print("  radar\n");\r
 421                 print("  sbar_columns_set ...\n");\r
 422                 print("  sbar_columns_help\n");\r
 423                 GameCommand_Generic("help");\r
 424         }\r
 425 \r
 426         if(GameCommand_Generic(msg))\r
 427                 return;\r
 428 \r
 429         string cmd;\r
 430         cmd = argv(0);\r
 431         if(cmd == "mv_download") {\r
 432                 Cmd_MapVote_MapDownload(argc);\r
 433         }\r
 434         else if(cmd == "settemp") {\r
 435                 cvar_clientsettemp(argv(1), argv(2));\r
 436         }\r
 437         else if(cmd == "radar") {\r
 438                 ons_showmap = !ons_showmap;\r
 439         }\r
 440         else if(cmd == "sbar_columns_set") {\r
 441                 Cmd_Sbar_SetFields(argc);\r
 442         }\r
 443         else if(cmd == "sbar_columns_help") {\r
 444                 Cmd_Sbar_Help(argc);\r
 445         }\r
 446 #ifdef BLURTEST\r
 447         else if(cmd == "blurtest") {\r
 448                 blurtest_time0 = time;\r
 449                 blurtest_time1 = time + stof(argv(1));\r
 450                 blurtest_radius = stof(argv(2));\r
 451                 blurtest_power = stof(argv(3));\r
 452         }\r
 453 #endif\r
 454         else if(cmd == "shotorg_move") {\r
 455                 if(!debug_shotorg)\r
 456                         ShotOrg_Spawn();\r
 457                 else\r
 458                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));\r
 459                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");\r
 460         }\r
 461         else if(cmd == "shotorg_movez") {\r
 462                 if(!debug_shotorg)\r
 463                         ShotOrg_Spawn();\r
 464                 else\r
 465                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos\r
 466                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");\r
 467         }\r
 468         else if(cmd == "shotorg_set") {\r
 469                 if(!debug_shotorg)\r
 470                         ShotOrg_Spawn();\r
 471                 else\r
 472                         debug_shotorg.view_ofs = stov(argv(1));\r
 473                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");\r
 474         }\r
 475         else if(cmd == "shotorg_setz") {\r
 476                 if(!debug_shotorg)\r
 477                         ShotOrg_Spawn();\r
 478                 else\r
 479                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos\r
 480                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");\r
 481         }\r
 482         else if(cmd == "shotorg_toggle_hide") {\r
 483                 if(debug_shotorg)\r
 484                 {\r
 485                         debug_shotorg.cnt = !debug_shotorg.cnt;\r
 486                 }\r
 487         }\r
 488         else if(cmd == "shotorg_end") {\r
 489                 if(debug_shotorg)\r
 490                 {\r
 491                         print(vtos(debug_shotorg.view_ofs), "\n");\r
 492                         remove(debug_shotorg);\r
 493                         debug_shotorg = world;\r
 494                 }\r
 495                 localcmd("sv_cmd debug_shotorg\n");\r
 496         }\r
 497         else\r
 498         {\r
 499                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");\r
 500         }\r
 501 \r
 502         return;\r
 503 }\r
 504 \r
 505 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.\r
 506 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.\r
 507 // All keys are in ascii.\r
 508 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.\r
 509 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.\r
 510 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.\r
 511 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)\r
 512 {\r
 513         local float bSkipKey;\r
 514         bSkipKey = false;\r
 515 \r
 516         if(menu_visible)\r
 517                 if(menu_action(bInputType, nPrimary, nSecondary))\r
 518                         return TRUE;\r
 519         return bSkipKey;\r
 520 }\r
 521 \r
 522 // END REQUIRED CSQC FUNCTIONS\r
 523 // --------------------------------------------------------------------------\r
 524 \r
 525 // --------------------------------------------------------------------------\r
 526 // BEGIN OPTIONAL CSQC FUNCTIONS\r
 527 void Ent_ReadEntCS()\r
 528 {\r
 529         InterpolateOrigin_Undo();\r
 530 \r
 531         self.classname = "entcs_receiver";\r
 532         self.sv_entnum = ReadByte() - 1;\r
 533         self.origin_x = ReadShort();\r
 534         self.origin_y = ReadShort();\r
 535         self.origin_z = ReadShort();\r
 536         self.angles_y = ReadByte() * 360.0 / 256;\r
 537         self.origin_z = self.angles_x = self.angles_z = 0;\r
 538 \r
 539         InterpolateOrigin_Note();\r
 540 }\r
 541 \r
 542 void Ent_Remove();\r
 543 \r
 544 void Ent_RemovePlayerScore()\r
 545 {\r
 546         float i;\r
 547 \r
 548         if(self.owner)\r
 549         {\r
 550                 SetTeam(self.owner, -1);\r
 551                 self.owner.gotscores = 0;\r
 552                 for(i = 0; i < MAX_SCORE; ++i)\r
 553                         self.owner.(scores[i]) = 0; // clear all scores\r
 554         }\r
 555 }\r
 556 \r
 557 void Ent_ReadPlayerScore()\r
 558 {\r
 559         float i, n;\r
 560         float isNew;\r
 561         entity o;\r
 562 \r
 563         // damnit -.- don't want to go change every single .sv_entnum in sbar.qc AGAIN\r
 564         // (no I've never heard of M-x replace-string, sed, or anything like that)\r
 565         isNew = !self.owner; // workaround for DP bug\r
 566         n = ReadByte()-1;\r
 567 \r
 568 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
 569         if(!isNew && n != self.sv_entnum)\r
 570         {\r
 571                 print("A CSQC entity changed its owner!\n");\r
 572                 isNew = true;\r
 573                 Ent_Remove();\r
 574                 self.enttype = ENT_CLIENT_SCORES;\r
 575         }\r
 576 #endif\r
 577 \r
 578         self.sv_entnum = n;\r
 579 \r
 580         if not(playerslots[self.sv_entnum])\r
 581                 playerslots[self.sv_entnum] = spawn();\r
 582         o = self.owner = playerslots[self.sv_entnum];\r
 583         o.sv_entnum = self.sv_entnum;\r
 584         o.gotscores = 1;\r
 585 \r
 586         //if not(o.sort_prev)\r
 587         //      RegisterPlayer(o);\r
 588         //playerchecker will do this for us later, if it has not already done so\r
 589 \r
 590 #if MAX_SCORE <= 3\r
 591         for(i = 0; i < MAX_SCORE; ++i)\r
 592                 o.(scores[i]) = ReadShort();\r
 593 #else\r
 594         float sf;\r
 595 #if MAX_SCORE <= 8\r
 596         sf = ReadByte();\r
 597 #else\r
 598         sf = ReadShort();\r
 599 #endif\r
 600         float p;\r
 601         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)\r
 602                 if(sf & p)\r
 603                         o.(scores[i]) = ReadShort();\r
 604 #endif\r
 605 \r
 606         if(o.sort_prev)\r
 607                 Sbar_UpdatePlayerPos(o); // if not registered, we cannot do this yet!\r
 608 \r
 609         self.entremove = Ent_RemovePlayerScore;\r
 610 }\r
 611 \r
 612 void Ent_ReadTeamScore()\r
 613 {\r
 614         float i;\r
 615         entity o;\r
 616 \r
 617         self.team = ReadByte();\r
 618         o = self.owner = GetTeam(self.team, true);\r
 619 \r
 620 #if MAX_TEAMSCORE <= 3\r
 621         for(i = 0; i < MAX_TEAMSCORE; ++i)\r
 622                 o.(teamscores[i]) = ReadShort();\r
 623 #else\r
 624         float sf;\r
 625 #if MAX_TEAMSCORE <= 8\r
 626         sf = ReadByte();\r
 627 #else\r
 628         sf = ReadShort();\r
 629 #endif\r
 630         float p;\r
 631         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)\r
 632                 if(sf & p)\r
 633                         o.(teamscores[i]) = ReadShort();\r
 634 #endif\r
 635 \r
 636         Sbar_UpdateTeamPos(o);\r
 637 }\r
 638 \r
 639 void Net_Reset()\r
 640 {\r
 641 }\r
 642 \r
 643 void Ent_ClientData()\r
 644 {\r
 645         float f;\r
 646         float newspectatee_status;\r
 647 \r
 648         f = ReadByte();\r
 649 \r
 650         sb_showscores_force = (f & 1);\r
 651 \r
 652         if(f & 2)\r
 653         {\r
 654                 newspectatee_status = ReadByte();\r
 655                 if(newspectatee_status == player_localentnum)\r
 656                         newspectatee_status = -1; // observing\r
 657         }\r
 658         else\r
 659                 newspectatee_status = 0;\r
 660 \r
 661         spectatorbutton_zoom = (f & 4);\r
 662 \r
 663         if(f & 8)\r
 664         {\r
 665                 angles_held_status = 1;\r
 666                 angles_held_x = ReadAngle();\r
 667                 angles_held_y = ReadAngle();\r
 668                 angles_held_z = 0;\r
 669         }\r
 670         else\r
 671                 angles_held_status = 0;\r
 672 \r
 673         if(newspectatee_status != spectatee_status)\r
 674         {\r
 675                 // clear race stuff\r
 676                 race_laptime = 0;\r
 677                 race_checkpointtime = 0;\r
 678         }\r
 679         spectatee_status = newspectatee_status;\r
 680 }\r
 681 \r
 682 void Ent_Nagger()\r
 683 {\r
 684         float nags, i, j, b, f;\r
 685 \r
 686         nags = ReadByte();\r
 687 \r
 688         if(nags & 128)\r
 689         {\r
 690                 if(vote_called_vote)\r
 691                         strunzone(vote_called_vote);\r
 692                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));\r
 693         }\r
 694 \r
 695         if(nags & 1)\r
 696         {\r
 697                 for(j = 0; j < maxclients; ++j)\r
 698                         if(playerslots[j])\r
 699                                 playerslots[j].ready = 1;\r
 700                 for(i = 1; i <= maxclients; i += 8)\r
 701                 {\r
 702                         f = ReadByte();\r
 703                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)\r
 704                                 if not(f & b)\r
 705                                         if(playerslots[j])\r
 706                                                 playerslots[j].ready = 0;\r
 707                 }\r
 708         }\r
 709 \r
 710         ready_waiting = (nags & 1);\r
 711         ready_waiting_for_me = (nags & 2);\r
 712         vote_waiting = (nags & 4);\r
 713         vote_waiting_for_me = (nags & 8);\r
 714         warmup_stage = (nags & 16);\r
 715 }\r
 716 \r
 717 void Ent_RandomSeed()\r
 718 {\r
 719         float s;\r
 720         prandom_debug();\r
 721         s = ReadShort();\r
 722         psrandom(s);\r
 723 }\r
 724 \r
 725 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.\r
 726 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.\r
 727 void Ent_RadarLink();\r
 728 void Ent_Init();\r
 729 void Ent_ScoresInfo();\r
 730 void(float bIsNewEntity) CSQC_Ent_Update =\r
 731 {\r
 732         float t;\r
 733         float savetime;\r
 734         t = ReadByte();\r
 735 \r
 736         // set up the "time" global for received entities to be correct for interpolation purposes\r
 737         savetime = time;\r
 738         if(servertime)\r
 739         {\r
 740                 time = servertime;\r
 741         }\r
 742         else\r
 743         {\r
 744                 serverprevtime = time;\r
 745                 serverdeltatime = getstatf(STAT_SYS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);\r
 746                 time = serverprevtime + serverdeltatime;\r
 747         }\r
 748 \r
 749 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
 750         if(self.enttype)\r
 751                 if(t != self.enttype)\r
 752                 {\r
 753                         print("A CSQC entity changed its type!\n");\r
 754                         Ent_Remove();\r
 755                 }\r
 756 #endif\r
 757         self.enttype = t;\r
 758         switch(t)\r
 759         {\r
 760                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;\r
 761                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;\r
 762                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;\r
 763                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;\r
 764                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;\r
 765                 case ENT_CLIENT_LASER: Ent_Laser(); break;\r
 766                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;\r
 767                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;\r
 768                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;\r
 769                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;\r
 770                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(); break;\r
 771                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(); break;\r
 772                 case ENT_CLIENT_CASING: Ent_Casing(); break;\r
 773                 case ENT_CLIENT_INIT: Ent_Init(); break;\r
 774                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;\r
 775                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;\r
 776                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;\r
 777                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;\r
 778                 case ENT_CLIENT_WALL: Ent_Wall(); break;\r
 779                 default:\r
 780                         error(strcat("unknown entity type in CSQC_Ent_Update: ", ftos(self.enttype), "\n"));\r
 781                         break;\r
 782         }\r
 783 \r
 784         time = savetime;\r
 785 };\r
 786 // Destructor, but does NOT deallocate the entity by calling remove(). Also\r
 787 // used when an entity changes its type. For an entity that someone interacts\r
 788 // with others, make sure it can no longer do so.\r
 789 void Ent_Remove()\r
 790 {\r
 791         if(self.entremove)\r
 792                 self.entremove();\r
 793 \r
 794         self.enttype = 0;\r
 795         self.classname = "";\r
 796         self.draw = menu_sub_null;\r
 797         self.entremove = menu_sub_null;\r
 798         // TODO possibly set more stuff to defaults\r
 799 }\r
 800 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.\r
 801 void CSQC_Ent_Remove()\r
 802 {\r
 803         if(self.enttype)\r
 804                 Ent_Remove();\r
 805         remove(self);\r
 806 }\r
 807 \r
 808 void Gamemode_Init()\r
 809 {\r
 810         if(gametype == GAME_ONSLAUGHT) {\r
 811                 print(strcat("Using ", minimapname, " as minimap.\n"));\r
 812                 precache_pic("gfx/ons-cp-neutral.tga");\r
 813                 precache_pic("gfx/ons-cp-red.tga");\r
 814                 precache_pic("gfx/ons-cp-blue.tga");\r
 815                 precache_pic("gfx/ons-frame.tga");\r
 816                 precache_pic("gfx/ons-frame-team.tga");\r
 817         } else if(gametype == GAME_KEYHUNT) {\r
 818                 precache_pic("gfx/sb_key_carrying");\r
 819                 precache_pic("gfx/sb_key_carrying_outline");\r
 820         }\r
 821 }\r
 822 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.\r
 823 void CSQC_Parse_StuffCmd(string strMessage)\r
 824 {\r
 825         localcmd(strMessage);\r
 826 }\r
 827 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.\r
 828 void CSQC_Parse_Print(string strMessage)\r
 829 {\r
 830         print(ColorTranslateRGB(strMessage));\r
 831 }\r
 832 \r
 833 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.\r
 834 void CSQC_Parse_CenterPrint(string strMessage)\r
 835 {\r
 836         centerprint(strMessage);\r
 837 }\r
 838 \r
 839 void Fog_Force()\r
 840 {\r
 841         // TODO somehow thwart prvm_globalset client ...\r
 842 \r
 843         if(forcefog != "")\r
 844                 localcmd(strcat("\nfog ", forcefog, "\nr_fog_exp2 0\nr_drawfog 1\n"));\r
 845 }\r
 846 \r
 847 void Gamemode_Init();\r
 848 void Ent_ScoresInfo()\r
 849 {\r
 850         float i;\r
 851         self.classname = "ent_client_scores_info";\r
 852         gametype = ReadByte();\r
 853         for(i = 0; i < MAX_SCORE; ++i)\r
 854         {\r
 855                 scores_label[i] = strzone(ReadString());\r
 856                 scores_flags[i] = ReadByte();\r
 857         }\r
 858         for(i = 0; i < MAX_TEAMSCORE; ++i)\r
 859         {\r
 860                 teamscores_label[i] = strzone(ReadString());\r
 861                 teamscores_flags[i] = ReadByte();\r
 862         }\r
 863         Sbar_InitScores();\r
 864         Gamemode_Init();\r
 865 }\r
 866 \r
 867 void Ent_Init()\r
 868 {\r
 869         float i;\r
 870         self.classname = "ent_client_init";\r
 871 \r
 872         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th\r
 873 \r
 874         for(i = 0; i < 24; ++i)\r
 875                 weaponimpulse[i] = ReadByte() - 1;\r
 876         hook_shotorigin_x = ReadCoord();\r
 877         hook_shotorigin_y = ReadCoord();\r
 878         hook_shotorigin_z = ReadCoord();\r
 879 \r
 880         if(forcefog)\r
 881                 strunzone(forcefog);\r
 882         forcefog = strzone(ReadString());\r
 883 \r
 884         if(!postinit)\r
 885                 PostInit();\r
 886 }\r
 887 \r
 888 string Net_ReadPicture()\r
 889 {\r
 890         string img;\r
 891         if(csqc_flags & CSQC_FLAG_READPICTURE)\r
 892         {\r
 893                 img = ReadPicture();\r
 894                 print(strcat("Got Picture: ", img, "\n"));\r
 895         } else {\r
 896                 img = ReadString();\r
 897                 print(strcat("^3Warning: ^7Couldn't download ", img, ". This is probably because your engine build is outdated.\n"));\r
 898                 float psize, i;\r
 899                 psize = ReadShort();\r
 900                 // Can I be sure that ReadShort is 2 bytes and ReadLong is 4 bytes?\r
 901                 // Because then this could be optimized to first get all 4-byte-groups,\r
 902                 // then the remaining 2, then the remaining 1\r
 903                 for(i = 0; i < psize; ++i)\r
 904                         ReadByte();\r
 905         }\r
 906         return img;\r
 907 }\r
 908 \r
 909 void Net_ReadRace()\r
 910 {\r
 911         float b;\r
 912 \r
 913         b = ReadByte();\r
 914 \r
 915         switch(b)\r
 916         {\r
 917                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:\r
 918                         race_checkpoint = ReadByte();\r
 919                         race_time = ReadShort();\r
 920                         race_previousbesttime = ReadShort();\r
 921                         if(race_previousbestname)\r
 922                                 strunzone(race_previousbestname);\r
 923                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));\r
 924 \r
 925                         race_checkpointtime = time;\r
 926 \r
 927                         if(race_checkpoint == 0)\r
 928                                 race_laptime = time; // valid\r
 929 \r
 930                         break;\r
 931 \r
 932                 case RACE_NET_CHECKPOINT_CLEAR:\r
 933                         race_laptime = 0;\r
 934                         race_checkpointtime = 0;\r
 935                         break;\r
 936 \r
 937                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:\r
 938                         race_laptime = ReadCoord();\r
 939                         race_checkpointtime = -99999;\r
 940                         // fall through\r
 941                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:\r
 942                         race_nextcheckpoint = ReadByte();\r
 943 \r
 944                         race_nextbesttime = ReadShort();\r
 945                         if(race_nextbestname)\r
 946                                 strunzone(race_nextbestname);\r
 947                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));\r
 948                         break;\r
 949 \r
 950                 case RACE_NET_CHECKPOINT_HIT_RACE:\r
 951                         race_mycheckpoint = ReadByte();\r
 952                         race_mycheckpointtime = time;\r
 953                         race_mycheckpointdelta = ReadShort();\r
 954                         race_mycheckpointlapsdelta = ReadByte();\r
 955                         if(race_mycheckpointlapsdelta >= 128)\r
 956                                 race_mycheckpointlapsdelta -= 256;\r
 957                         if(race_mycheckpointenemy)\r
 958                                 strunzone(race_mycheckpointenemy);\r
 959                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));\r
 960                         break;\r
 961 \r
 962                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:\r
 963                         race_othercheckpoint = ReadByte();\r
 964                         race_othercheckpointtime = time;\r
 965                         race_othercheckpointdelta = ReadShort();\r
 966                         race_othercheckpointlapsdelta = ReadByte();\r
 967                         if(race_othercheckpointlapsdelta >= 128)\r
 968                                 race_othercheckpointlapsdelta -= 256;\r
 969                         if(race_othercheckpointenemy)\r
 970                                 strunzone(race_othercheckpointenemy);\r
 971                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));\r
 972                         break;\r
 973         }\r
 974 }\r
 975 \r
 976 void Net_ReadSpawn()\r
 977 {\r
 978         zoomin_effect = 1;\r
 979         current_viewzoom = 0.6;\r
 980 }\r
 981 \r
 982 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.\r
 983 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.\r
 984 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.\r
 985 float CSQC_Parse_TempEntity()\r
 986 {\r
 987         local float bHandled;\r
 988                 bHandled  = true;\r
 989         // Acquire TE ID\r
 990         local float nTEID;\r
 991                 nTEID = ReadByte();\r
 992 \r
 993                 // NOTE: Could just do return instead of break...\r
 994         switch(nTEID)\r
 995         {\r
 996                 case TE_CSQC_PICTURE:\r
 997                         Net_MapVote_Picture();\r
 998                         bHandled = true;\r
 999                         break;\r
1000                 case TE_CSQC_RACE:\r
1001                         Net_ReadRace();\r
1002                         bHandled = true;\r
1003                         break;\r
1004                 case 13: // TE_BEAM\r
1005                         Net_GrapplingHook();\r
1006                         bHandled = true;\r
1007                         break;\r
1008                 case TE_CSQC_SPAWN:\r
1009                         Net_ReadSpawn();\r
1010                         bHandled = true;\r
1011                         break;\r
1012                 case TE_CSQC_ZCURVEPARTICLES:\r
1013                         Net_ReadZCurveParticles();\r
1014                         bHandled = true;\r
1015                         break;\r
1016                 case TE_CSQC_NEXGUNBEAMPARTICLE:\r
1017                         Net_ReadNexgunBeamParticle();\r
1018                         bHandled = true;\r
1019                         break;\r
1020         case TE_CSQC_LIGHTNINGARC:\r
1021             Net_ReadLightningarc();\r
1022             bHandled = true;\r
1023             break;\r
1024                 default:\r
1025                         // No special logic for this temporary entity; return 0 so the engine can handle it\r
1026                         bHandled = false;\r
1027                         break;\r
1028         }\r
1029 \r
1030         return bHandled;\r
1031 }\r
1032 \r
1033 string getcommandkey(string text, string command)\r
1034 {\r
1035         string keys;\r
1036         float n, j, k, l;\r
1037 \r
1038         if (!sbar_showbinds)\r
1039                 return text;\r
1040 \r
1041         keys = db_get(binddb, command);\r
1042         if(csqc_flags & CSQC_FLAG_READPICTURE)\r
1043         {\r
1044                 if (!keys)\r
1045                 {\r
1046                         n = tokenize_insane(findkeysforcommand(command)); // uses '...' strings\r
1047                         for(j = 0; j < n; ++j)\r
1048                         {\r
1049                                 k = stof(argv(j));\r
1050                                 if(k != -1)\r
1051                                 {\r
1052                                         if ("" == keys)\r
1053                                                 keys = keynumtostring(k);\r
1054                                         else\r
1055                                                 keys = strcat(keys, ", ", keynumtostring(k));\r
1056 \r
1057                                         ++l;\r
1058                                         if (sbar_showbinds_limit > 0 && sbar_showbinds_limit >= l) break;\r
1059                                 }\r
1060 \r
1061                         }\r
1062                         db_put(binddb, command, keys);\r
1063                 }\r
1064         }\r
1065 \r
1066         if ("" == keys) {\r
1067                 if (sbar_showbinds > 1)\r
1068                         return strcat(text, " (not bound)");\r
1069                 else\r
1070                         return text;\r
1071         }\r
1072         else if (sbar_showbinds > 1)\r
1073                 return strcat(text, " (", keys, ")");\r
1074         else\r
1075                 return keys;\r
1076 }\r