data/qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------\r
   2 // BEGIN REQUIRED CSQC FUNCTIONS\r
   3 //include "main.qh"\r
   4 \r
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
   6 \r
   7 void cvar_clientsettemp(string cv, string val)\r
   8 {\r
   9         entity e;\r
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )\r
  11                 if(e.netname == cv)\r
  12                         goto saved;\r
  13         e = spawn();\r
  14         e.classname = "saved_cvar_value";\r
  15         e.netname = strzone(cv);\r
  16         e.message = strzone(cvar_string(cv));\r
  17 :saved\r
  18         cvar_set(cv, val);\r
  19 }\r
  20 \r
  21 void cvar_clientsettemp_restore()\r
  22 {\r
  23         entity e;\r
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )\r
  25                         cvar_set(e.netname, e.message);\r
  26 }\r
  27 \r
  28 void() menu_show_error =\r
  29 {\r
  30         drawstring('0 200 0', "ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!", '8 8 0', '1 0 0', 1, 0);\r
  31 };\r
  32 \r
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)\r
  34 // Useful for precaching things\r
  35 \r
  36 void() menu_sub_null =\r
  37 {\r
  38 };\r
  39 \r
  40 #ifdef USE_FTE\r
  41 float __engine_check;\r
  42 #endif\r
  43 \r
  44 string config_get(string key, string defaultvalue)\r
  45 {\r
  46         string s;\r
  47         s = db_get(configdb, strcat("/s/", key));\r
  48         if(s == "")\r
  49                 return defaultvalue;\r
  50         else\r
  51                 return db_get(configdb, strcat("/v/", key));\r
  52 }\r
  53 \r
  54 string forcefog;\r
  55 void WaypointSprite_Load();\r
  56 void CSQC_Init(void)\r
  57 {\r
  58 #ifdef USE_FTE\r
  59 #pragma target ID\r
  60         __engine_check = checkextension("DP_SV_WRITEPICTURE");\r
  61         if(!__engine_check)\r
  62         {\r
  63                 print("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n");\r
  64                 localcmd("\ndisconnect\n");\r
  65                 return;\r
  66         }\r
  67 #pragma target FTE\r
  68 #endif\r
  69         \r
  70         float i;\r
  71         CSQC_CheckEngine();\r
  72         dprint_load();\r
  73 \r
  74         configdb = db_create();\r
  75         binddb = db_create();\r
  76         tempdb = db_create();\r
  77         compressShortVector_init();\r
  78 \r
  79         drawfont = 0;\r
  80         menu_visible = FALSE;\r
  81         menu_show = menu_show_error;\r
  82         menu_action = menu_sub_null;\r
  83         maxclients = 255; // we later get the real maxclients to speed up stuff\r
  84         //ctf_temp_1 = "";\r
  85         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used\r
  86         //registercmd("ctf_menu");\r
  87         registercmd("ons_map");\r
  88         //registercmd("menu_action");\r
  89         registercmd("sbar_columns_set");\r
  90         registercmd("sbar_columns_help");\r
  91 \r
  92         registercmd("+button3");\r
  93         registercmd("-button3");\r
  94         registercmd("+button4");\r
  95         registercmd("-button4");\r
  96 \r
  97         registercvar("sbar_usecsqc", "1");\r
  98         registercvar("sbar_columns", "default", CVAR_SAVE);\r
  99 \r
 100         gametype = 0;\r
 101 \r
 102         // sbar_fields uses strunzone on the titles!\r
 103         for(i = 0; i < MAX_SBAR_FIELDS; ++i)\r
 104                 sbar_title[i] = strzone("(null)");\r
 105 \r
 106         postinit = false;\r
 107 \r
 108         teams = Sort_Spawn();\r
 109         players = Sort_Spawn();\r
 110         \r
 111         GetTeam(COLOR_SPECTATOR, true); // add specs first\r
 112 \r
 113         cvar_clientsettemp("_supports_weaponpriority", "1");\r
 114 \r
 115 \r
 116 \r
 117 \r
 118         cs_project_is_b0rked = TRUE;\r
 119         R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');\r
 120         R_SetView(VF_FOV, '90 90 0');\r
 121         R_SetView(VF_ORIGIN, '0 0 0');\r
 122         R_SetView(VF_ANGLES, '0 0 0');\r
 123         R_SetView(VF_PERSPECTIVE, 1);\r
 124         makevectors('0 0 0');\r
 125         vector v;\r
 126         v = cs_project(v_forward);\r
 127         if(v_x - 320 < +1)\r
 128         if(v_x - 320 > -1)\r
 129         if(v_y - 240 < +1)\r
 130         if(v_y - 240 > -1)\r
 131                 cs_project_is_b0rked = FALSE;\r
 132 \r
 133         WaypointSprite_Load();\r
 134 \r
 135         Projectile_Precache();\r
 136         GibSplash_Precache();\r
 137 }\r
 138 \r
 139 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)\r
 140 void CSQC_Shutdown(void)\r
 141 {\r
 142 #ifdef USE_FTE\r
 143 #pragma TARGET id\r
 144         if(!__engine_check)\r
 145                 return 0;\r
 146 #pragma TARGET fte\r
 147 #endif\r
 148 \r
 149         remove(teams);\r
 150         remove(players);\r
 151         db_close(configdb);\r
 152         db_close(binddb);\r
 153         db_close(tempdb);\r
 154 \r
 155         cvar_clientsettemp_restore();\r
 156 }\r
 157 \r
 158 .float has_team;\r
 159 float SetTeam(entity o, float Team)\r
 160 {\r
 161         entity tm;\r
 162         if(Team == -1) // leave\r
 163         {\r
 164                 if(o.has_team)\r
 165                 {\r
 166                         //print("(DISCONNECT) leave team ", ftos(o.team), "\n");\r
 167                         tm = GetTeam(o.team, false);\r
 168                         tm.team_size -= 1;\r
 169                         o.has_team = 0;\r
 170                         return TRUE;\r
 171                 }\r
 172         }\r
 173         else\r
 174         {\r
 175                 if not(o.has_team)\r
 176                 {\r
 177                         //print("(CONNECT) enter team ", ftos(o.team), "\n");\r
 178                         o.team = Team;\r
 179                         tm = GetTeam(Team, true);\r
 180                         tm.team_size += 1;\r
 181                         o.has_team = 1;\r
 182                         return TRUE;\r
 183                 }\r
 184                 else if(Team != o.team)\r
 185                 {\r
 186                         //print("(CHANGE) leave team ", ftos(o.team), "\n");\r
 187                         tm = GetTeam(o.team, false);\r
 188                         tm.team_size -= 1;\r
 189                         o.team = Team;\r
 190                         //print("(CHANGE) enter team ", ftos(o.team), "\n");\r
 191                         tm = GetTeam(Team, true);\r
 192                         tm.team_size += 1;\r
 193                         return TRUE;\r
 194                 }\r
 195         }\r
 196         return FALSE;\r
 197 }\r
 198 \r
 199 void Playerchecker_Think()\r
 200 {\r
 201         float i;\r
 202         entity e;\r
 203         for(i = 0; i < maxclients; ++i)\r
 204         {\r
 205                 e = playerslots[i];\r
 206                 if(GetPlayerName(i) == "")\r
 207                 {\r
 208                         if(e.sort_prev)\r
 209                         {\r
 210                                 //print("playerchecker: KILL KILL KILL\n");\r
 211                                 // player disconnected\r
 212                                 SetTeam(e, -1);\r
 213                                 RemovePlayer(e);\r
 214                                 e.sort_prev = world;\r
 215                                 //e.gotscores = 0;\r
 216                         }\r
 217                 }\r
 218                 else\r
 219                 {\r
 220                         if not(e.sort_prev)\r
 221                         {\r
 222                                 //print("playerchecker: SPAWN SPAWN SPAWN\n");\r
 223                                 // player connected\r
 224                                 if not(e)\r
 225                                         playerslots[i] = e = spawn();\r
 226                                 e.sv_entnum = i;\r
 227                                 //e.gotscores = 0; // we might already have the scores...\r
 228                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with Sbar_UpdatePlayerTeams\r
 229                                 RegisterPlayer(e);\r
 230                                 Sbar_UpdatePlayerPos(e);\r
 231                         }\r
 232                 }\r
 233         }\r
 234         self.nextthink = time + 0.2;\r
 235 }\r
 236 \r
 237 void Porto_Init();\r
 238 void PostInit(void)\r
 239 {\r
 240         print(strcat("PostInit\n    maxclients = ", ftos(maxclients), "\n"));\r
 241         localcmd(strcat("\nsbar_columns_set ", cvar_string("sbar_columns"), ";\n"));\r
 242 \r
 243         entity playerchecker;\r
 244         playerchecker = spawn();\r
 245         playerchecker.think = Playerchecker_Think;\r
 246         playerchecker.nextthink = time + 0.2;\r
 247 \r
 248         Porto_Init();\r
 249 \r
 250         postinit = true;\r
 251 }\r
 252 \r
 253 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function\r
 254 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.\r
 255 float button_zoom;\r
 256 void Cmd_Sbar_SetFields(float);\r
 257 void Cmd_Sbar_Help(float);\r
 258 float CSQC_ConsoleCommand(string strMessage)\r
 259 {\r
 260         float argc;\r
 261         // Tokenize String\r
 262         //argc = tokenize(strMessage);\r
 263         argc = tokenize_sane(strMessage);\r
 264         \r
 265         // Acquire Command\r
 266         local string strCmd;\r
 267         strCmd = argv(0);\r
 268 \r
 269         if(strCmd == "+button4") { // zoom\r
 270                 // return false, because the message shall be sent to the server anyway (for demos/speccing)\r
 271                 if(ignore_plus_zoom)\r
 272                 {\r
 273                         --ignore_plus_zoom;\r
 274                         return false;\r
 275                 }\r
 276                 button_zoom = 1;\r
 277                 return true;\r
 278         } else if(strCmd == "-button4") { // zoom\r
 279                 if(ignore_minus_zoom)\r
 280                 {\r
 281                         --ignore_minus_zoom;\r
 282                         return false;\r
 283                 }\r
 284                 button_zoom = 0;\r
 285                 return true;\r
 286         } else if(strCmd == "+button3") { // secondary\r
 287                 button_attack2 = 1;\r
 288                 return false;\r
 289         } else if(strCmd == "-button3") { // secondary\r
 290                 button_attack2 = 0;\r
 291                 return false;\r
 292         } else if(strCmd == "+showscores") {\r
 293                 sb_showscores = true;\r
 294                 return true;\r
 295         } else if(strCmd == "-showscores") {\r
 296                 sb_showscores = false;\r
 297                 return true;\r
 298         }\r
 299         \r
 300         return false;\r
 301 }\r
 302 \r
 303 float GameCommand(string msg)\r
 304 {\r
 305         float argc;\r
 306         argc = tokenize_sane(msg);\r
 307         string cmd;\r
 308         cmd = argv(0);\r
 309         if(cmd == "mv_download") {\r
 310                 Cmd_MapVote_MapDownload(argc);\r
 311                 return true;\r
 312         }\r
 313         else if(cmd == "settemp") {\r
 314                 cvar_clientsettemp(argv(1), argv(2));\r
 315         }\r
 316         else if(cmd == "radar") {\r
 317                 ons_showmap = !ons_showmap;\r
 318         }\r
 319         else if(cmd == "sbar_columns_set") {\r
 320                 Cmd_Sbar_SetFields(argc);\r
 321         }\r
 322         else if(cmd == "sbar_columns_help") {\r
 323                 Cmd_Sbar_Help(argc);\r
 324         }\r
 325 #ifdef BLURTEST\r
 326         else if(cmd == "blurtest") {\r
 327                 blurtest_time0 = time;\r
 328                 blurtest_time1 = time + stof(argv(1));\r
 329                 blurtest_radius = stof(argv(2));\r
 330                 blurtest_power = stof(argv(3));\r
 331         }\r
 332 #endif\r
 333         \r
 334         return false;\r
 335 }\r
 336 \r
 337 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.\r
 338 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.\r
 339 // All keys are in ascii.\r
 340 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.\r
 341 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.\r
 342 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.\r
 343 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)\r
 344 {\r
 345         local float bSkipKey;\r
 346         bSkipKey = false;\r
 347         \r
 348         if(menu_visible)\r
 349                 if(menu_action(bInputType, nPrimary, nSecondary))\r
 350                         return TRUE;\r
 351         return bSkipKey;\r
 352 }\r
 353 \r
 354 // END REQUIRED CSQC FUNCTIONS\r
 355 // --------------------------------------------------------------------------\r
 356 \r
 357 // --------------------------------------------------------------------------\r
 358 // BEGIN OPTIONAL CSQC FUNCTIONS\r
 359 void Ent_ReadEntCS()\r
 360 {\r
 361         InterpolateOrigin_Undo();\r
 362 \r
 363         self.classname = "entcs_receiver";\r
 364         self.sv_entnum = ReadByte() - 1;\r
 365         self.origin_x = ReadShort();\r
 366         self.origin_y = ReadShort();\r
 367         self.origin_z = ReadShort();\r
 368         self.angles_y = ReadByte() * 360.0 / 256;\r
 369         self.origin_z = self.angles_x = self.angles_z = 0;\r
 370 \r
 371         InterpolateOrigin_Note();\r
 372 }\r
 373 \r
 374 void Ent_RemoveEntCS()\r
 375 {\r
 376 }\r
 377 \r
 378 void Ent_Remove();\r
 379 void Ent_ReadPlayerScore()\r
 380 {\r
 381         float i, n;\r
 382         float isNew;\r
 383         entity o;\r
 384 \r
 385         // damnit -.- don't want to go change every single .sv_entnum in sbar.qc AGAIN\r
 386         // (no I've never heard of M-x replace-string, sed, or anything like that)\r
 387         isNew = !self.owner; // workaround for DP bug\r
 388         n = ReadByte()-1;\r
 389 \r
 390 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
 391         if(!isNew && n != self.sv_entnum)\r
 392         {\r
 393                 print("A CSQC entity changed its owner!\n");\r
 394                 isNew = true;\r
 395                 Ent_Remove();\r
 396                 self.enttype = ENT_CLIENT_SCORES;\r
 397         }\r
 398 #endif\r
 399 \r
 400         self.sv_entnum = n;\r
 401 \r
 402         if not(playerslots[self.sv_entnum])\r
 403                 playerslots[self.sv_entnum] = spawn();\r
 404         o = self.owner = playerslots[self.sv_entnum];\r
 405         o.sv_entnum = self.sv_entnum;\r
 406         o.gotscores = 1;\r
 407 \r
 408         //if not(o.sort_prev)\r
 409         //      RegisterPlayer(o);\r
 410         //playerchecker will do this for us later, if it has not already done so\r
 411 \r
 412 #if MAX_SCORE <= 3\r
 413         for(i = 0; i < MAX_SCORE; ++i)\r
 414                 o.(scores[i]) = ReadShort();\r
 415 #else\r
 416         float sf;\r
 417 #if MAX_SCORE <= 8\r
 418         sf = ReadByte();\r
 419 #else\r
 420         sf = ReadShort();\r
 421 #endif\r
 422         float p;\r
 423         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)\r
 424                 if(sf & p)\r
 425                         o.(scores[i]) = ReadShort();\r
 426 #endif\r
 427 \r
 428         if(o.sort_prev)\r
 429                 Sbar_UpdatePlayerPos(o); // if not registered, we cannot do this yet!\r
 430 }\r
 431 \r
 432 void Ent_ReadTeamScore()\r
 433 {\r
 434         float i;\r
 435         entity o;\r
 436         \r
 437         self.team = ReadByte();\r
 438         o = self.owner = GetTeam(self.team, true);\r
 439 \r
 440 #if MAX_TEAMSCORE <= 3\r
 441         for(i = 0; i < MAX_TEAMSCORE; ++i)\r
 442                 o.(teamscores[i]) = ReadShort();\r
 443 #else\r
 444         float sf;\r
 445 #if MAX_TEAMSCORE <= 8\r
 446         sf = ReadByte();\r
 447 #else\r
 448         sf = ReadShort();\r
 449 #endif\r
 450         float p;\r
 451         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)\r
 452                 if(sf & p)\r
 453                         o.(teamscores[i]) = ReadShort();\r
 454 #endif\r
 455 \r
 456         Sbar_UpdateTeamPos(o);\r
 457 }\r
 458 \r
 459 void Ent_Nagger()\r
 460 {\r
 461         float nags;\r
 462 \r
 463         nags = ReadByte();\r
 464 \r
 465         if(nags & 128)\r
 466         {\r
 467                 if(vote_called_vote)\r
 468                         strunzone(vote_called_vote);\r
 469                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));\r
 470         }\r
 471 \r
 472         ready_waiting = (nags & 1);\r
 473         ready_waiting_for_me = (nags & 2);\r
 474         vote_waiting = (nags & 4);\r
 475         vote_waiting_for_me = (nags & 8);\r
 476 }\r
 477 \r
 478 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.\r
 479 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.\r
 480 void Ent_RadarLink();\r
 481 void(float bIsNewEntity) CSQC_Ent_Update =\r
 482 {\r
 483         float t;\r
 484         float savetime;\r
 485         t = ReadByte();\r
 486 \r
 487         // set up the "time" global for received entities to be correct for interpolation purposes\r
 488         savetime = time;\r
 489         if(servertime)\r
 490                 time = servertime;\r
 491 \r
 492 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
 493         if(self.enttype)\r
 494                 if(t != self.enttype)\r
 495                 {\r
 496                         print("A CSQC entity changed its type!\n");\r
 497                         Ent_Remove();\r
 498                 }\r
 499 #endif\r
 500         self.enttype = t;\r
 501         if(self.enttype == ENT_CLIENT_ENTCS)\r
 502                 Ent_ReadEntCS();\r
 503         else if(self.enttype == ENT_CLIENT_SCORES)\r
 504                 Ent_ReadPlayerScore();\r
 505         else if(self.enttype == ENT_CLIENT_TEAMSCORES)\r
 506                 Ent_ReadTeamScore();\r
 507         else if(self.enttype == ENT_CLIENT_POINTPARTICLES)\r
 508                 Ent_PointParticles();\r
 509         else if(self.enttype == ENT_CLIENT_RAINSNOW)\r
 510                 Ent_RainOrSnow();\r
 511         else if(self.enttype == ENT_CLIENT_LASER)\r
 512                 Ent_Laser();\r
 513         else if(self.enttype == ENT_CLIENT_NAGGER)\r
 514                 Ent_Nagger();\r
 515         else if(self.enttype == ENT_CLIENT_WAYPOINT)\r
 516                 Ent_WaypointSprite();\r
 517         else if(self.enttype == ENT_CLIENT_RADARLINK)\r
 518                 Ent_RadarLink();\r
 519         else if(self.enttype == ENT_CLIENT_PROJECTILE)\r
 520                 Ent_Projectile();\r
 521         else if(self.enttype == ENT_CLIENT_GIBSPLASH)\r
 522                 Ent_GibSplash();\r
 523         else if(self.enttype == ENT_CLIENT_DAMAGEINFO)\r
 524                 Ent_DamageInfo();\r
 525         else\r
 526                 error(strcat("unknown entity type in CSQC_Ent_Update: ", ftos(self.enttype), "\n"));\r
 527         \r
 528         time = savetime;\r
 529 };\r
 530 // Destructor, but does NOT deallocate the entity by calling remove(). Also\r
 531 // used when an entity changes its type. For an entity that someone interacts\r
 532 // with others, make sure it can no longer do so.\r
 533 void Ent_Remove()\r
 534 {\r
 535         float i;\r
 536         if(self.enttype == ENT_CLIENT_ENTCS)\r
 537         {\r
 538                 Ent_RemoveEntCS();\r
 539         } else if(self.enttype == ENT_CLIENT_SCORES)\r
 540         {\r
 541                 if(self.owner)\r
 542                 {\r
 543                         SetTeam(self.owner, -1);\r
 544                         self.owner.gotscores = 0;\r
 545                         for(i = 0; i < MAX_SCORE; ++i)\r
 546                                 self.owner.(scores[i]) = 0; // clear all scores\r
 547                 }\r
 548         } else if(self.enttype == ENT_CLIENT_TEAMSCORES)\r
 549         {\r
 550                 /*\r
 551                 if(self.owner)\r
 552                         RemoveTeam(self.owner);\r
 553                 */\r
 554                 // we don't NEED to remove them... they won't display anyway\r
 555                 // plus, svqc never does this anyway\r
 556         } else if(self.enttype == ENT_CLIENT_POINTPARTICLES)\r
 557         {\r
 558                 Ent_PointParticles_Remove();\r
 559         }\r
 560         else if(self.enttype == ENT_CLIENT_WAYPOINT)\r
 561                 Ent_RemoveWaypointSprite();\r
 562         else if(self.enttype == ENT_CLIENT_PROJECTILE)\r
 563                 Ent_RemoveProjectile();\r
 564 \r
 565         self.enttype = 0;\r
 566         self.classname = "";\r
 567         self.draw = menu_sub_null;\r
 568         // TODO possibly set more stuff to defaults\r
 569 }\r
 570 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.\r
 571 void CSQC_Ent_Remove()\r
 572 {\r
 573         if(self.enttype)\r
 574                 Ent_Remove();\r
 575         remove(self);\r
 576 }\r
 577 \r
 578 void Gamemode_Init()\r
 579 {\r
 580         get_mi_min_max_texcoords(1); // try the CLEVER way first\r
 581         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");\r
 582         shortmapname = mi_shortname;\r
 583 \r
 584         if(precache_pic(minimapname) == "")\r
 585         {\r
 586                 // but maybe we have a non-clever minimap\r
 587                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");\r
 588                 if(precache_pic(minimapname) == "")\r
 589                         minimapname = ""; // FAIL\r
 590                 else\r
 591                         get_mi_min_max_texcoords(0); // load new texcoords\r
 592         }\r
 593 \r
 594         mi_center = (mi_min + mi_max) * 0.5;\r
 595         mi_scale = mi_max - mi_min;\r
 596         minimapname = strzone(minimapname);\r
 597 \r
 598         if(gametype == GAME_ONSLAUGHT) {\r
 599                 print(strcat("Using ", minimapname, " as minimap.\n"));\r
 600                 precache_pic("gfx/ons-cp-neutral.tga");\r
 601                 precache_pic("gfx/ons-cp-red.tga");\r
 602                 precache_pic("gfx/ons-cp-blue.tga");\r
 603                 precache_pic("gfx/ons-frame.tga");\r
 604                 precache_pic("gfx/ons-frame-team.tga");\r
 605         } else if(gametype == GAME_KEYHUNT) {\r
 606                 precache_pic("gfx/sb_key_carrying");\r
 607                 precache_pic("gfx/sb_key_carrying_outline");\r
 608         }\r
 609 }\r
 610 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.\r
 611 void CSQC_Parse_StuffCmd(string strMessage)\r
 612 {\r
 613         localcmd(strMessage);\r
 614 }\r
 615 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.\r
 616 void CSQC_Parse_Print(string strMessage)\r
 617 {\r
 618         print(ColorTranslateRGB(strMessage));\r
 619 }\r
 620 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.  To execute standard behavior, simply execute cprint with the string.\r
 621 void CSQC_Parse_CenterPrint(string strMessage)\r
 622 {\r
 623         cprint(ColorTranslateRGB(strMessage));\r
 624 }\r
 625 \r
 626 void CSQC_CheckRevision();\r
 627 \r
 628 void Fog_Force()\r
 629 {\r
 630         // TODO somehow thwart prvm_globalset client ...\r
 631 \r
 632         if(forcefog != "")\r
 633                 localcmd(strcat("\nfog ", forcefog, "\nr_fog_exp2 0\nr_drawfog 1\n"));\r
 634 }\r
 635 \r
 636 void Net_ReadFog()\r
 637 {\r
 638         if(forcefog)\r
 639                 strunzone(forcefog);\r
 640         ReadCoord(); // ignore fog interval\r
 641         forcefog = strzone(ReadString());\r
 642 }\r
 643 \r
 644 void Gamemode_Init();\r
 645 void Net_ReadScoresInfo()\r
 646 {\r
 647         float i;\r
 648         gametype = ReadByte();\r
 649         for(i = 0; i < MAX_SCORE; ++i)\r
 650         {\r
 651                 scores_label[i] = strzone(ReadString());\r
 652                 scores_flags[i] = ReadByte();\r
 653         }\r
 654         for(i = 0; i < MAX_TEAMSCORE; ++i)\r
 655         {\r
 656                 teamscores_label[i] = strzone(ReadString());\r
 657                 teamscores_flags[i] = ReadByte();\r
 658         }\r
 659         Sbar_InitScores();\r
 660         Gamemode_Init();\r
 661 }\r
 662 \r
 663 void Net_ReadInit()\r
 664 {\r
 665         float i;\r
 666         csqc_revision = ReadShort();\r
 667         maxclients = ReadByte();\r
 668         for(i = 0; i < 24; ++i)\r
 669                 weaponimpulse[i] = ReadByte() - 1;\r
 670         hook_shotorigin_x = ReadCoord();\r
 671         hook_shotorigin_y = ReadCoord();\r
 672         hook_shotorigin_z = ReadCoord();\r
 673         CSQC_CheckRevision();\r
 674 }\r
 675 \r
 676 string Net_ReadPicture()\r
 677 {\r
 678         string img;\r
 679         if(csqc_flags & CSQC_FLAG_READPICTURE)\r
 680         {\r
 681                 img = ReadPicture();\r
 682                 print(strcat("Got Picture: ", img, "\n"));\r
 683         } else {\r
 684                 img = ReadString();\r
 685                 print(strcat("^3Warning: ^7Couldn't download ", img, ". This is probably because your engine build is outdated.\n"));\r
 686                 float psize, i;\r
 687                 psize = ReadShort();\r
 688                 // Can I be sure that ReadShort is 2 bytes and ReadLong is 4 bytes?\r
 689                 // Because then this could be optimized to first get all 4-byte-groups,\r
 690                 // then the remaining 2, then the remaining 1\r
 691                 for(i = 0; i < psize; ++i)\r
 692                         ReadByte();\r
 693         }\r
 694         return img;\r
 695 }\r
 696 \r
 697 void Net_Config()\r
 698 {\r
 699         string key, value;\r
 700         key = ReadString();\r
 701         value = ReadString();\r
 702         db_put(configdb, strcat("/v/", key), value);\r
 703         db_put(configdb, strcat("/s/", key), "1");\r
 704 }\r
 705 \r
 706 void Net_ReadRace()\r
 707 {\r
 708         float b;\r
 709 \r
 710         b = ReadByte();\r
 711 \r
 712         switch(b)\r
 713         {\r
 714                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:\r
 715                         race_checkpoint = ReadByte();\r
 716                         race_time = ReadShort();\r
 717                         race_previousbesttime = ReadShort();\r
 718                         if(race_previousbestname)\r
 719                                 strunzone(race_previousbestname);\r
 720                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));\r
 721 \r
 722                         race_checkpointtime = time;\r
 723 \r
 724                         if(race_checkpoint == 0)\r
 725                                 race_laptime = time; // valid\r
 726 \r
 727                         break;\r
 728 \r
 729                 case RACE_NET_CHECKPOINT_CLEAR:\r
 730                         race_laptime = 0;\r
 731                         race_checkpointtime = 0;\r
 732                         break;\r
 733 \r
 734                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:\r
 735                         race_laptime = ReadCoord();\r
 736                         race_checkpointtime = -99999;\r
 737                         // fall through\r
 738                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:\r
 739                         race_nextcheckpoint = ReadByte();\r
 740 \r
 741                         race_nextbesttime = ReadShort();\r
 742                         if(race_nextbestname)\r
 743                                 strunzone(race_nextbestname);\r
 744                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));\r
 745                         break;\r
 746 \r
 747                 case RACE_NET_CHECKPOINT_HIT_RACE:\r
 748                         race_mycheckpoint = ReadByte();\r
 749                         race_mycheckpointtime = time;\r
 750                         race_mycheckpointdelta = ReadShort();\r
 751                         race_mycheckpointlapsdelta = ReadByte();\r
 752                         if(race_mycheckpointlapsdelta >= 128)\r
 753                                 race_mycheckpointlapsdelta -= 256;\r
 754                         if(race_mycheckpointenemy)\r
 755                                 strunzone(race_mycheckpointenemy);\r
 756                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));\r
 757                         break;\r
 758 \r
 759                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:\r
 760                         race_othercheckpoint = ReadByte();\r
 761                         race_othercheckpointtime = time;\r
 762                         race_othercheckpointdelta = ReadShort();\r
 763                         race_othercheckpointlapsdelta = ReadByte();\r
 764                         if(race_othercheckpointlapsdelta >= 128)\r
 765                                 race_othercheckpointlapsdelta -= 256;\r
 766                         if(race_othercheckpointenemy)\r
 767                                 strunzone(race_othercheckpointenemy);\r
 768                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));\r
 769                         break;\r
 770         }\r
 771 }\r
 772 \r
 773 void Net_ReadForceScoreboard()\r
 774 {\r
 775         sb_showscores_force = ReadByte();\r
 776 }\r
 777 \r
 778 void Net_Reset()\r
 779 {\r
 780         float i;\r
 781         race_laptime = 0;\r
 782         race_checkpointtime = 0;\r
 783         for(i = 0; i < 24; ++i)\r
 784                 angles_held_status[i] = 0;\r
 785 }\r
 786 \r
 787 void Net_ReadSpectating()\r
 788 {\r
 789         float newspectatee_status;\r
 790         newspectatee_status = ReadByte();\r
 791         if(newspectatee_status == player_localentnum)\r
 792                 newspectatee_status = -1; // observing\r
 793         if(newspectatee_status != spectatee_status)\r
 794                 Net_Reset();\r
 795         spectatee_status = newspectatee_status;\r
 796 }\r
 797 \r
 798 void Net_ReadZoomNotify()\r
 799 {\r
 800         spectatorbutton_zoom = ReadByte();\r
 801 }\r
 802 \r
 803 void Net_ReadSpawn()\r
 804 {\r
 805         zoomin_effect = 1;\r
 806         current_viewzoom = 0.6;\r
 807 }\r
 808 \r
 809 void Net_ReadWarmupStage()\r
 810 {\r
 811         warmup_stage = ReadByte();\r
 812 }\r
 813 \r
 814 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.\r
 815 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.\r
 816 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.\r
 817 void Net_ReadHoldAngles();\r
 818 float CSQC_Parse_TempEntity()\r
 819 {\r
 820         local float bHandled;\r
 821                 bHandled  = true;\r
 822         // Acquire TE ID\r
 823         local float nTEID;\r
 824                 nTEID = ReadByte();\r
 825 \r
 826                 // NOTE: Could just do return instead of break...\r
 827         switch(nTEID)\r
 828         {\r
 829                 case TE_CSQC_INIT:\r
 830                         Net_ReadInit();\r
 831                         bHandled = true;\r
 832                         break;\r
 833                 case TE_CSQC_MAPVOTE:\r
 834                         Net_Mapvote();\r
 835                         bHandled = true;\r
 836                         break;\r
 837                 case TE_CSQC_CONFIG:\r
 838                         Net_Config();\r
 839                         bHandled = true;\r
 840                         break;\r
 841                 case TE_CSQC_SCORESINFO:\r
 842                         Net_ReadScoresInfo();\r
 843                         bHandled = true;\r
 844                         break;\r
 845                 case TE_CSQC_RACE:\r
 846                         Net_ReadRace();\r
 847                         bHandled = true;\r
 848                         break;\r
 849                 case TE_CSQC_FORCESCOREBOARD:\r
 850                         Net_ReadForceScoreboard();\r
 851                         bHandled = true;\r
 852                         break;\r
 853                 case TE_CSQC_SPECTATING:\r
 854                         Net_ReadSpectating();\r
 855                         bHandled = true;\r
 856                         break;\r
 857                 case 13: // TE_BEAM\r
 858                         Net_GrapplingHook();\r
 859                         bHandled = true;\r
 860                         break;\r
 861                 case TE_CSQC_SPAWN:\r
 862                         Net_ReadSpawn();\r
 863                         bHandled = true;\r
 864                         break;\r
 865                 case TE_CSQC_ZOOMNOTIFY:\r
 866                         Net_ReadZoomNotify();\r
 867                         bHandled = true;\r
 868                         break;\r
 869                 case TE_CSQC_HOLDANGLES:\r
 870                         Net_ReadHoldAngles();\r
 871                         bHandled = true;\r
 872                         break;\r
 873                 case TE_CSQC_WARMUP:\r
 874                         Net_ReadWarmupStage();\r
 875                         bHandled = true;\r
 876                         break;\r
 877                 case TE_CSQC_FOG:\r
 878                         Net_ReadFog();\r
 879                         bHandled = true;\r
 880                         break;\r
 881                 default:\r
 882                         // No special logic for this temporary entity; return 0 so the engine can handle it\r
 883                         bHandled = false;\r
 884                         break;\r
 885         }\r
 886         \r
 887         if(!postinit)\r
 888                 PostInit();\r
 889                 \r
 890         return bHandled;\r
 891 }\r
 892 \r
 893 // COMMIT-TODO: Update if necessare, before committing\r
 894 void CSQC_CheckRevision()\r
 895 {\r
 896         if(csqc_revision == CSQC_REVISION)\r
 897         {\r
 898                 print("^2SVQC and CSQC revisions are compatible.\n");\r
 899         } else if(csqc_revision < CSQC_REVISION) {\r
 900                 print("^1Your csprogs.dat (CSQC) version is newer than the one on the server.\n");\r
 901         } else if(csqc_revision > CSQC_REVISION) {\r
 902                 print("^1Your csprogs.dat (CSQC) is too old for this server.\n");\r
 903                 print("^1Please update to a newer version.\n");\r
 904         }\r
 905 }\r
 906 \r
 907 string getcommandkey(string text, string command)\r
 908 {\r
 909         string keys;\r
 910         float n, j, k, l;\r
 911 \r
 912         if (!sbar_showbinds)\r
 913                 return text;\r
 914 \r
 915         keys = db_get(binddb, command);\r
 916         if(csqc_flags & CSQC_FLAG_READPICTURE)\r
 917         {\r
 918                 if (!keys) \r
 919                 {\r
 920                         n = tokenize_insane(findkeysforcommand(command)); // uses '...' strings\r
 921                         for(j = 0; j < n; ++j)\r
 922                         {\r
 923                                 k = stof(argv(j));\r
 924                                 if(k != -1) \r
 925                                 {\r
 926                                         if ("" == keys)\r
 927                                                 keys = keynumtostring(k);\r
 928                                         else\r
 929                                                 keys = strcat(keys, ", ", keynumtostring(k));\r
 930 \r
 931                                         ++l;\r
 932                                         if (sbar_showbinds_limit > 0 && sbar_showbinds_limit >= l) break;\r
 933                                 }\r
 934                         \r
 935                         }\r
 936                         db_put(binddb, command, keys);\r
 937                 }\r
 938         }\r
 939         \r
 940         if ("" == keys) {\r
 941                 if (sbar_showbinds > 1)\r
 942                         return strcat(text, " (not bound)");\r
 943                 else\r
 944                         return text;\r
 945         }\r
 946         else if (sbar_showbinds > 1)\r
 947                 return strcat(text, " (", keys, ")");\r
 948         else\r
 949                 return keys;\r
 950 }\r