increment version number, add some news
[btb/d2x.git] / configure.ac
1 # -*- mode: shell-script -*-
2
3 define([D2X_MAJOR],0)
4 define([D2X_MINOR],2)
5 define([D2X_MICRO],6)
6
7 AC_INIT(d2x,[D2X_MAJOR.D2X_MINOR.D2X_MICRO],[descent-source@warpcore.org])
8 AC_PREREQ(2.52)
9
10 AC_CANONICAL_BUILD
11 AC_CANONICAL_HOST
12 AC_CANONICAL_TARGET
13
14 AM_INIT_AUTOMAKE([1.6])
15
16 AM_CONFIG_HEADER(conf.h)
17
18 AC_DEFINE_UNQUOTED(D2XMAJOR,D2X_MAJOR,[d2x major version])
19 AC_DEFINE_UNQUOTED(D2XMINOR,D2X_MINOR,[d2x minor version])
20 AC_DEFINE_UNQUOTED(D2XMICRO,D2X_MICRO,[d2x micro version])
21
22 AM_MAINTAINER_MODE
23
24 #kludge to keep autoconf from adding -g -O2
25 CFLAGS=" $CFLAGS"
26
27 AC_PROG_INSTALL
28 AC_PROG_MAKE_SET
29 AC_ISC_POSIX
30 AC_CHECK_TOOL(CC, gcc, :)
31 AC_CHECK_TOOL(RANLIB, ranlib, :)
32 AC_CHECK_TOOL(STRIP, strip, :)
33 AC_CHECK_TOOL(AR, ar, :)
34 AC_PROG_CC
35 AC_PROG_CXX
36 AC_STDC_HEADERS
37 AC_PATH_PROGS(NASM, nasm nasmw, no)
38 AC_C_BIGENDIAN
39
40 case $host_cpu in
41         sparc)
42                 AC_DEFINE(WORDS_NEED_ALIGNMENT,,[Define if your processor needs data to be word-aligned])
43         ;;
44 esac
45
46 build_macosx_bundle=no
47 build_simple_bundle=no
48
49 case $host_os in
50     cygwin)
51         AC_MSG_WARN([Cygwin found, setting -mno-cygwin])
52         CFLAGS="-mno-cygwin $CFLAGS"
53         MINGW32=yes
54         ;;
55     mingw*)
56         MINGW32=yes
57         ;;
58     darwin*)
59         MACOSX=yes
60         AC_MSG_RESULT(Mac OS X/Darwin; Mac OS X bundle)
61         build_macosx_bundle=yes
62         DATADIR='EXE>>../Resources'
63         #SCOREDIR='/Library/Preferences/KoboDeluxe/scores'
64         #CONFIGDIR='HOME>>Library/Preferences'
65         #CONFIGFILE='KoboDeluxe Preferences'
66         MATHLIB=""
67         ;;
68     msdos*)
69         MSDOS=yes
70         ;;
71 esac
72
73 AC_CHECK_DECLS(nanosleep,,,[#include <time.h>])
74 AC_CHECK_TYPES([struct timespec, struct timeval],,,[#include <sys/time.h>])
75
76 AM_CONDITIONAL(MINGW32, test x$MINGW32 = xyes)
77 if test x$MINGW32 = xyes; then
78     GL_LIBS="opengl32 glu32"
79 elif test x$MACOSX = xyes; then
80     GL_LIBS=""
81 else
82     GL_LIBS="GL GLU"
83 fi
84
85 AM_CONDITIONAL(MACOSX, test x$MACOSX = xyes)
86 AM_CONDITIONAL(BUILD_MACOSX_BUNDLE, test x$build_macosx_bundle = xyes)
87 AM_CONDITIONAL(BUILD_SIMPLE_BUNDLE, test x$build_simple_bundle = xyes)
88
89 dnl Set $prefix and $exec_prefix to $ac_default_prefix if they are not set
90 test "x$prefix" = "xNONE" && prefix=$ac_default_prefix
91 test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"
92
93 dnl Set default locations to find data files.
94 default_sharepath="$datadir/games/$PACKAGE"
95
96 CFLAGS="-Wall $CFLAGS"
97
98 dnl Enable editor build?
99 AC_ARG_ENABLE(editor,
100     [  --enable-editor         Build editor? (not functional)],,)
101 if test x$enable_editor = xyes; then
102     AC_DEFINE(EDITOR,,[Define if you want to build the editor])
103     D2X_MAIN_SUBDIRS=editor
104 fi
105 AM_CONDITIONAL(EDITOR, test x$enable_editor = xyes)
106
107 dnl Enable macdata build?
108 AC_ARG_ENABLE(macdata,
109     [  --enable-macdata        Build for mac datafiles],,)
110 if test x$enable_macdata = xyes; then
111     AC_DEFINE(MACDATA,,[Define if you want to build for mac datafiles])
112     D2X_FEATURES="macdata ${D2X_FEATURES}"
113 fi
114 AM_CONDITIONAL(MACDATA, test x$enable_macdata = xyes)
115
116 dnl Build with NDEBUG?
117 AC_ARG_ENABLE(debug,
118     [  --disable-debug         Take out debug symbols, Asserts, Int3, etc ],,)
119 if test x$enable_debug = xno; then
120     AC_DEFINE(NDEBUG,,[Define to disable asserts, int3, etc.])
121     CFLAGS="-O2 $CFLAGS"
122 else
123     CFLAGS="-g $CFLAGS"
124     D2X_FEATURES="debug ${D2X_FEATURES}"
125 fi
126
127 dnl Build with RELEASE?
128 AC_ARG_ENABLE(release,
129     [  --enable-release        Release build.  Removes debug/editor things ],,)
130 if test x$enable_release = xyes; then
131     AC_DEFINE(RELEASE,,[Define for a "release" build])
132     D2X_FEATURES="release ${D2X_FEATURES}"
133 fi
134
135 dnl Build without using sdl-joystick ?
136 AC_ARG_ENABLE(linuxjoy,
137     [  --enable-linuxjoy       do not use the SDL Joystick. (eg for MS Sidewinder)],,)
138 if test x$enable_linuxjoy = xyes; then
139     AC_DEFINE(USE_LINUX_JOY,,[define to not use the SDL_Joystick routines.])
140 fi
141 AM_CONDITIONAL(USE_LINUX_JOY, test x$enable_linuxjoy = xyes)
142
143 dnl Build with FAST_FILE_IO?
144 AC_ARG_ENABLE(fastfileio,
145     [  --disable-fastfileio    Disable fast file i/o. ],,)
146 if test x$enable_fastfileio != xno; then
147         if test x$ac_cv_c_bigendian = xyes; then
148                 AC_MSG_WARN([big-endian cpu detected.  disabling fastfileio])
149                 enable_fastfileio="no";
150         fi
151 fi
152 if test x$enable_fastfileio != xno; then
153     AC_DEFINE(FAST_FILE_IO,,[Define for faster i/o on little-endian cpus])
154     D2X_FEATURES="fastfileio ${D2X_FEATURES}"
155 fi
156
157 dnl Build with CONSOLE?
158 AC_ARG_ENABLE(console,
159     [  --enable-console        Enable console (experimental) ],,)
160 if test x$enable_console = xyes; then
161     AC_DEFINE(CONSOLE,,[Define to enable console])
162     D2X_SUBDIRS=console
163 fi
164 AM_CONDITIONAL(CONSOLE, test x$enable_console = xyes)
165
166 AC_ARG_WITH(sharepath,
167     [[  --with-sharepath=DIR    Use DIR for shared game data (unix only) [DATADIR/games/d2x]]],
168     sharepath=$withval, sharepath="auto")
169 if test "x$sharepath" = "xauto" -o "x$sharepath" = "xyes" -o "x$sharepath" = "x"; then
170     sharepath="$default_sharepath"
171 fi
172 AC_SUBST(sharepath)
173 eval sharepath=$sharepath
174 AC_DEFINE_UNQUOTED(SHAREPATH, "$sharepath",[Define this to be the shared game directory root])
175
176 # Test for MSDOS
177 if test x$MSDOS = xyes; then
178     CFLAGS="-I \$(top_srcdir)/arch/dos/include $CFLAGS"
179     TARGETS=d2x
180     D2X_ARCH_SUBDIRS=dos
181 else
182
183     CFLAGS="-pipe $CFLAGS"
184
185     dnl Check for SDL
186     AM_PATH_SDL(1.1.0,
187         :,
188         AC_MSG_ERROR(SDL not found. Make sure sdl-config is in your PATH, or specify with --with-sdl-prefix)
189     )
190     CFLAGS="$SDL_CFLAGS $CFLAGS"
191     LIBS="$SDL_LIBS $LIBS"
192
193     TARGETS=d2x-sdl
194     D2X_ARCH_SUBDIRS=sdl
195
196     AC_CHECK_HEADERS(netipx/ipx.h)
197
198   # Check for SDL_image
199         AC_CHECK_LIB(SDL_image, IMG_ReadXPMFromArray,
200                 LIBS="-lSDL_image $LIBS"
201                 AC_DEFINE(SDL_IMAGE,,[Define if you have the SDL_image library]))
202
203   # Check for OpenGL
204     AC_ARG_WITH(opengl,
205         [  --with-opengl           Build OpenGL support ],,)
206     if test x$with_opengl = xyes; then
207         for lib in $GL_LIBS; do
208             AC_CHECK_LIB($lib, main,
209                 OGL_LIBS="${OGL_LIBS} -l$lib",
210                 [AC_MSG_ERROR([$lib not found, --with-opengl cannot be used])
211                     opengl=false],
212                 ${OGL_LIBS}
213             )
214         done
215         AC_DEFINE(OGL,,[Define if you want an OpenGL build])
216         TARGETS=d2x-gl
217         D2X_ARCH_SUBDIRS="ogl ${D2X_ARCH_SUBDIRS}"
218     fi
219     AC_SUBST(OGL_LIBS)
220     AM_CONDITIONAL(USE_OPENGL, test x$with_opengl = xyes)
221
222   # Check for GGI
223     AC_ARG_WITH(ggi,
224         [  --with-ggi              Build GGI support ],,)
225     if test x$with_ggi = xyes; then
226         AC_CHECK_LIB(ggi, ggiInit,
227             GGI_LIBS="-lggi",
228             [AC_MSG_ERROR([GGI not found, GGI version cannot be built]); ggi=false])
229         AC_CHECK_LIB(gii, giiInit,
230             GGI_LIBS="${GGI_LIBS} -lgii",
231             [AC_MSG_ERROR([GII not found, GGI version cannot be built]); ggi=false])
232         AC_DEFINE(GGI,,[Define if you want a GGI build])
233         TARGETS=d2x-ggi
234         D2X_ARCH_SUBDIRS="ggi ${D2X_ARCH_SUBDIRS}"
235     fi
236     AC_SUBST(GGI_LIBS)
237     AM_CONDITIONAL(USE_GGI, test x$with_ggi = xyes)
238
239   # Check for SVGALib
240     AC_ARG_WITH(svga,
241         [  --with-svga             Build SVGALib support ],,)
242     if test x$with_svga = xyes; then
243         AC_CHECK_LIB(vga,vga_getmousetype,
244             SVGA_LIBS="-lvga",
245             [AC_MSG_ERROR([vga not found, SVGALib cannot be built])
246                 svga=false],
247         )
248         AC_CHECK_LIB(vgagl,gl_getcontext,
249             SVGA_LIBS="${SVGA_LIBS} -lvgagl",
250             [AC_MSG_ERROR([vgagl not found, SVGALib cannot be built])
251                 svga=false],
252             -lvga)
253         AC_DEFINE(SVGA,,[Define if you want an SVGALib build])
254         TARGETS=d2x-svga
255         D2X_ARCH_SUBDIRS="svgalib ${D2X_ARCH_SUBDIRS}"
256     fi
257     AC_SUBST(SVGA_LIBS)
258     AM_CONDITIONAL(USE_SVGALIB, test x$with_svga = xyes)
259
260     if test x$MINGW32 = xyes; then
261         D2X_ARCH_SUBDIRS="win32 ${D2X_ARCH_SUBDIRS}"
262     else
263         CFLAGS="-I \$(top_srcdir)/arch/linux/include $CFLAGS"
264         D2X_ARCH_SUBDIRS="linux ${D2X_ARCH_SUBDIRS}"
265     fi
266 fi
267
268 dnl Check for network
269 AC_ARG_ENABLE(network,
270     [  --disable-network       Do not build network/serial support ],,)
271 if test x$enable_network != xno; then
272     case $host_os in
273         cygwin* | mingw* | msdos* | linux*)
274             enable_native_ipx="yes";
275            ;;
276        *)
277             AC_MSG_WARN([d2x doesn't support native ipx on this host.  disabling native ipx])
278             enable_native_ipx="no";
279             ;;
280     esac
281     case $host_os in
282         *solaris*)
283             AC_CHECK_LIB(socket, socket, LIBS="${LIBS} -lsocket",
284                 [AC_MSG_ERROR(socket lib required for net support on solaris not found)])
285             AC_CHECK_LIB(nsl, inet_addr, LIBS="${LIBS} -lnsl",
286                 [AC_MSG_ERROR(nsl lib required for net support on solaris not found)])          
287            ;;
288     esac
289 fi
290 if test x$enable_network != xno; then
291     if test x$enable_native_ipx != xno; then
292         D2X_FEATURES="ipx ${D2X_FEATURES}"
293         AC_DEFINE(NATIVE_IPX,,[Define to use the IPX support of the OS])
294     fi
295     AC_DEFINE(NETWORK,,[Define if you want a network build])
296     D2X_FEATURES="network ${D2X_FEATURES}"
297 fi
298 AM_CONDITIONAL(USE_NETWORK, test x$enable_network != xno)
299 AM_CONDITIONAL(USE_NATIVE_IPX, test x$enable_native_ipx != xno)
300
301 dnl Check for assembler
302 AC_ARG_ENABLE(assembler,
303     [  --disable-assembler     Do not use assembler optimization ],,)
304 if test x$enable_assembler != xno; then
305     if test x$NASM = xno; then
306         AC_MSG_WARN([nasm not found. disabling assembler])
307         enable_assembler="no"
308     else
309         NASMFLAGS="-i\$(srcdir)/ $NASMFLAGS"
310         case $host_os in
311             cygwin* | mingw*)
312                 NASMFLAGS="-f win32 $NASMFLAGS"
313                 ;;
314             msdos*)
315                 NASMFLAGS="-f coff $NASMFLAGS"
316                 ;;
317             linux*)
318                 NASMFLAGS="-f elf -d__linux__ $NASMFLAGS"
319                 ;;
320             *)
321                 AC_MSG_WARN([nasm not supported for this OS. disabling assembler])
322                 enable_assembler="no"
323                 ;;
324         esac
325     fi
326 fi
327 if test x$enable_assembler = xno; then
328     AC_DEFINE(NO_ASM,,[Define if you want an assembler free build])
329     D2X_FEATURES="no_asm ${D2X_FEATURES}"
330 fi
331 AM_CONDITIONAL(USE_ASM, test x$enable_assembler != xno)
332
333 AH_BOTTOM([
334         /* General defines */
335 #ifndef PACKAGE_STRING
336 #define PACKAGE_STRING PACKAGE " " VERSION
337 #endif
338 #define VERSION_NAME PACKAGE_STRING
339 #define NMONO 1
340 #define PIGGY_USE_PAGING 1
341 #define NEWDEMO 1
342
343 #if defined(__APPLE__) && defined(__MACH__)
344 #define __unix__
345 #endif
346
347 #ifdef __unix__
348 # ifdef GGI
349 #  define GII_INPUT 1
350 #  define GGI_VIDEO 1
351 # else
352 #  ifdef SVGA
353 #   define SVGALIB_INPUT 1
354 #   define SVGALIB_VIDEO 1
355 #  else
356 #   define SDL_INPUT 1
357 #   ifdef OGL
358 #    define SDL_GL_VIDEO 1
359 #   else
360 #    define SDL_VIDEO 1
361 #   endif
362 #  endif
363 # endif
364 #endif
365
366 #ifdef __MINGW32__
367 # define SDL_INPUT 1
368 # ifdef OGL
369 #  define SDL_GL_VIDEO 1
370 # else
371 #  define SDL_VIDEO 1
372 # endif
373 #endif
374         ])
375
376 AM_PROG_AS
377
378 AC_SUBST(D2X_SUBDIRS)
379
380 AC_SUBST(D2X_ARCH_SUBDIRS)
381
382 AC_SUBST(D2X_MAIN_SUBDIRS)
383
384 AC_SUBST(TARGETS)
385
386 AC_SUBST(NASMFLAGS)
387
388 AC_SUBST(CFLAGS)
389
390 AC_OUTPUT(
391     Makefile
392     2d/Makefile
393     3d/Makefile
394     arch/Makefile
395     arch/dos/Makefile
396     arch/ggi/Makefile
397     arch/linux/Makefile
398     arch/ogl/Makefile
399     arch/sdl/Makefile
400     arch/svgalib/Makefile
401     arch/win32/Makefile
402     cfile/Makefile
403     console/Makefile
404     iff/Makefile
405     libmve/Makefile
406     main/Makefile
407     main/editor/Makefile
408     maths/Makefile
409     mem/Makefile
410     misc/Makefile
411     texmap/Makefile
412     utilities/Makefile
413     debian/changelog
414     rpm/d2x.spec
415     Info.plist
416 )
417
418 AC_MSG_RESULT([
419         d2x has been configured successfully.
420
421         Platform(s): $D2X_ARCH_SUBDIRS
422         Features   : $D2X_FEATURES $D2X_SUBDIRS $D2X_MAIN_SUBDIRS
423
424         Shared game data directory (unix only): $sharepath
425         ])