Enable global structs for mine saving functions
[btb/d2x.git] / configure.ac
1 # -*- mode: shell-script -*-
2
3 define([D2X_MAJOR],0)
4 define([D2X_MINOR],2)
5 define([D2X_MICRO],6)
6
7 AC_INIT(d2x,[D2X_MAJOR.D2X_MINOR.D2X_MICRO],[descent-source@warpcore.org])
8 AC_PREREQ(2.52)
9
10 AC_CANONICAL_BUILD
11 AC_CANONICAL_HOST
12 AC_CANONICAL_TARGET
13
14 AC_EXEEXT
15 AC_OBJEXT
16
17 AM_INIT_AUTOMAKE([1.6])
18
19 AM_CONFIG_HEADER(conf.h)
20
21 AC_DEFINE_UNQUOTED(D2XMAJOR,D2X_MAJOR,[d2x major version])
22 AC_DEFINE_UNQUOTED(D2XMINOR,D2X_MINOR,[d2x minor version])
23 AC_DEFINE_UNQUOTED(D2XMICRO,D2X_MICRO,[d2x micro version])
24
25 AM_MAINTAINER_MODE
26
27 #kludge to keep autoconf from adding -g -O2
28 CFLAGS=" $CFLAGS"
29
30 AC_PROG_INSTALL
31 AC_PROG_MAKE_SET
32 AC_ISC_POSIX
33 AC_CHECK_TOOL(CC, gcc, :)
34 AC_CHECK_TOOL(RANLIB, ranlib, :)
35 AC_CHECK_TOOL(STRIP, strip, :)
36 AC_CHECK_TOOL(AR, ar, :)
37 AC_PROG_CC
38 AC_PROG_CXX
39 AC_STDC_HEADERS
40 AC_PATH_PROGS(NASM, nasm nasmw, no)
41 AC_C_BIGENDIAN
42
43 case $host_cpu in
44         sparc)
45                 AC_DEFINE(WORDS_NEED_ALIGNMENT,,[Define if your processor needs data to be word-aligned])
46         ;;
47 esac
48
49 case $host_os in
50     cygwin)
51         AC_MSG_WARN([Cygwin found, setting -mno-cygwin])
52         CFLAGS="-mno-cygwin $CFLAGS"
53         MINGW32=yes
54         ;;
55     mingw*)
56         MINGW32=yes
57         ;;
58     darwin*)
59         MACOSX=yes
60         CFLAGS="-no-cpp-precomp $CFLAGS"
61         ;;
62     msdos*)
63         MSDOS=yes
64         ;;
65 esac
66
67 AC_CHECK_DECLS(nanosleep,,,[#include <time.h>])
68 AC_CHECK_TYPES([struct timespec, struct timeval],,,[#include <sys/time.h>])
69
70 AM_CONDITIONAL(MINGW32, test x$MINGW32 = xyes)
71 if test x$MINGW32 = xyes; then
72     GL_LIBS="opengl32 glu32"
73 elif test x$MACOSX = xyes; then
74     GL_LIBS=""
75 else
76     GL_LIBS="GL GLU"
77 fi
78
79 AM_CONDITIONAL(MACOSX, test x$MACOSX = xyes)
80
81 dnl Set $prefix and $exec_prefix to $ac_default_prefix if they are not set
82 test "x$prefix" = "xNONE" && prefix=$ac_default_prefix
83 test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"
84
85 dnl Set default locations to find data files.
86 default_sharepath="$datadir/games/$PACKAGE"
87
88 CFLAGS="-Wall -Wno-char-subscripts $CFLAGS"
89
90 dnl Enable editor build?
91 AC_ARG_ENABLE(editor,
92     [  --enable-editor         Build editor? (not functional)],,)
93 if test x$enable_editor = xyes; then
94     AC_DEFINE(EDITOR,,[Define if you want to build the editor])
95     D2X_MAIN_SUBDIRS=editor
96 fi
97 AM_CONDITIONAL(EDITOR, test x$enable_editor = xyes)
98
99 dnl Enable macdata build?
100 AC_ARG_ENABLE(macdata,
101     [  --enable-macdata        Build for mac datafiles],,)
102 if test x$enable_macdata = xyes; then
103     AC_DEFINE(MACDATA,,[Define if you want to build for mac datafiles])
104     D2X_FEATURES="macdata ${D2X_FEATURES}"
105 fi
106 AM_CONDITIONAL(MACDATA, test x$enable_macdata = xyes)
107
108 dnl Build with NDEBUG?
109 AC_ARG_ENABLE(debug,
110     [  --disable-debug         Take out debug symbols, Asserts, Int3, etc ],,)
111 if test x$enable_debug = xno; then
112     AC_DEFINE(NDEBUG,,[Define to disable asserts, int3, etc.])
113     CFLAGS="-O2 $CFLAGS"
114 else
115     CFLAGS="-g $CFLAGS"
116     D2X_FEATURES="debug ${D2X_FEATURES}"
117 fi
118
119 dnl Build with RELEASE?
120 AC_ARG_ENABLE(release,
121     [  --enable-release        Release build.  Removes debug/editor things ],,)
122 if test x$enable_release = xyes; then
123     AC_DEFINE(RELEASE,,[Define for a "release" build])
124     D2X_FEATURES="release ${D2X_FEATURES}"
125 fi
126
127 dnl Build without using sdl-joystick ?
128 AC_ARG_ENABLE(linuxjoy,
129     [  --enable-linuxjoy       do not use the SDL Joystick. (eg for MS Sidewinder)],,)
130 if test x$enable_linuxjoy = xyes; then
131     AC_DEFINE(USE_LINUX_JOY,,[define to not use the SDL_Joystick routines.])
132     D2X_FEATURES="linuxjoy ${D2X_FEATURES}"
133 fi
134 AM_CONDITIONAL(USE_LINUX_JOY, test x$enable_linuxjoy = xyes)
135
136 dnl Build with FAST_FILE_IO?
137 AC_ARG_ENABLE(fastfileio,
138     [  --disable-fastfileio    Disable fast file i/o. ],,)
139 if test x$enable_fastfileio != xno; then
140         if test x$ac_cv_c_bigendian = xyes; then
141                 AC_MSG_WARN([big-endian cpu detected.  disabling fastfileio])
142                 enable_fastfileio="no";
143         fi
144 fi
145 if test x$enable_fastfileio != xno; then
146     AC_DEFINE(FAST_FILE_IO,,[Define for faster i/o on little-endian cpus])
147     D2X_FEATURES="fastfileio ${D2X_FEATURES}"
148 fi
149
150 dnl Build with CONSOLE?
151 AC_ARG_ENABLE(console,
152     [  --enable-console        Enable console (experimental) ],,)
153 if test x$enable_console = xyes; then
154     AC_DEFINE(CONSOLE,,[Define to enable console])
155     D2X_SUBDIRS=console
156 fi
157 AM_CONDITIONAL(CONSOLE, test x$enable_console = xyes)
158
159 AC_ARG_WITH(sharepath,
160     [[  --with-sharepath=DIR    Use DIR for shared game data (unix only) [DATADIR/games/d2x]]],
161     sharepath=$withval, sharepath="auto")
162 if test "x$sharepath" = "xauto" -o "x$sharepath" = "xyes" -o "x$sharepath" = "x"; then
163     sharepath="$default_sharepath"
164 fi
165 AC_SUBST(sharepath)
166 eval sharepath=$sharepath
167 AC_DEFINE_UNQUOTED(SHAREPATH, "$sharepath",[Define this to be the shared game directory root])
168
169 # Test for MSDOS
170 if test x$MSDOS = xyes; then
171     CFLAGS="-I \$(top_srcdir)/arch/dos/include $CFLAGS"
172     TARGETS=d2x
173     D2X_ARCH_SUBDIRS=dos
174 else
175
176     CFLAGS="-pipe $CFLAGS"
177
178     dnl Check for SDL
179     AM_PATH_SDL(1.1.0,
180         :,
181         AC_MSG_ERROR(SDL not found. Make sure sdl-config is in your PATH, or specify with --with-sdl-prefix)
182     )
183     CFLAGS="$SDL_CFLAGS $CFLAGS"
184     LIBS="$SDL_LIBS $LIBS"
185
186     TARGETS=d2x-sdl
187     D2X_ARCH_SUBDIRS=sdl
188
189     AC_CHECK_HEADERS(netipx/ipx.h)
190
191   # Check for SDL_image
192     AC_CHECK_LIB(SDL_image, IMG_ReadXPMFromArray,
193         LIBS="-lSDL_image $LIBS"
194         AC_DEFINE(SDL_IMAGE,,[Define if you have the SDL_image library]))
195
196   # Check for libpng
197     have_libpng=no
198     #PKG_CHECK_MODULES(LIBPNG, libpng,
199     #   AC_DEFINE(HAVE_LIBPNG,,[Define if you have libpng])
200     #   have_libpng=yes
201     #   LIBS="$LIBPNG_LIBS $LIBS",
202     #   AC_MSG_WARN([libpng not found. disabling png replacement texture support])
203 #)
204     AM_CONDITIONAL(USE_LIBPNG, test x$have_libpng = xyes)
205
206   # Check for PhysicsFS
207     AC_CHECK_HEADERS(physfs.h, , [AC_MSG_ERROR([physfs.h required])])
208     AC_CHECK_LIB(physfs, PHYSFS_init, LIBS="-lphysfs $LIBS",
209                  [AC_MSG_ERROR([physfs library required])])
210
211   # Check for OpenGL
212     AC_ARG_WITH(opengl,
213         [  --with-opengl           Build OpenGL support ],,)
214     if test x$with_opengl = xyes; then
215         for lib in $GL_LIBS; do
216             AC_CHECK_LIB($lib, main,
217                 OGL_LIBS="${OGL_LIBS} -l$lib",
218                 [AC_MSG_ERROR([$lib not found, --with-opengl cannot be used])
219                     opengl=false],
220                 ${OGL_LIBS}
221             )
222         done
223         AC_DEFINE(OGL,,[Define if you want an OpenGL build])
224         TARGETS=d2x-gl
225         D2X_ARCH_SUBDIRS="ogl ${D2X_ARCH_SUBDIRS}"
226     fi
227     AC_SUBST(OGL_LIBS)
228     AM_CONDITIONAL(USE_OPENGL, test x$with_opengl = xyes)
229
230   # Check for GGI
231     AC_ARG_WITH(ggi,
232         [  --with-ggi              Build GGI support ],,)
233     if test x$with_ggi = xyes; then
234         AC_CHECK_LIB(ggi, ggiInit,
235             GGI_LIBS="-lggi",
236             [AC_MSG_ERROR([GGI not found, GGI version cannot be built]); ggi=false])
237         AC_CHECK_LIB(gii, giiInit,
238             GGI_LIBS="${GGI_LIBS} -lgii",
239             [AC_MSG_ERROR([GII not found, GGI version cannot be built]); ggi=false])
240         AC_DEFINE(GGI,,[Define if you want a GGI build])
241         TARGETS=d2x-ggi
242         D2X_ARCH_SUBDIRS="ggi ${D2X_ARCH_SUBDIRS}"
243     fi
244     AC_SUBST(GGI_LIBS)
245     AM_CONDITIONAL(USE_GGI, test x$with_ggi = xyes)
246
247   # Check for SVGALib
248     AC_ARG_WITH(svga,
249         [  --with-svga             Build SVGALib support ],,)
250     if test x$with_svga = xyes; then
251         AC_CHECK_LIB(vga,vga_getmousetype,
252             SVGA_LIBS="-lvga",
253             [AC_MSG_ERROR([vga not found, SVGALib cannot be built])
254                 svga=false],
255         )
256         AC_CHECK_LIB(vgagl,gl_getcontext,
257             SVGA_LIBS="${SVGA_LIBS} -lvgagl",
258             [AC_MSG_ERROR([vgagl not found, SVGALib cannot be built])
259                 svga=false],
260             -lvga)
261         AC_DEFINE(SVGA,,[Define if you want an SVGALib build])
262         TARGETS=d2x-svga
263         D2X_ARCH_SUBDIRS="svgalib ${D2X_ARCH_SUBDIRS}"
264     fi
265     AC_SUBST(SVGA_LIBS)
266     AM_CONDITIONAL(USE_SVGALIB, test x$with_svga = xyes)
267
268     if test x$MINGW32 = xyes; then
269         D2X_ARCH_SUBDIRS="win32 ${D2X_ARCH_SUBDIRS}"
270     else
271         CFLAGS="-I \$(top_srcdir)/arch/linux/include $CFLAGS"
272         D2X_ARCH_SUBDIRS="linux ${D2X_ARCH_SUBDIRS}"
273     fi
274 fi
275
276 dnl Check for network
277 AC_ARG_ENABLE(network,
278     [  --disable-network       Do not build network/serial support ],,)
279 if test x$enable_network != xno; then
280     case $host_os in
281         cygwin* | mingw* | msdos* | linux*)
282             enable_native_ipx="yes";
283            ;;
284        *)
285             AC_MSG_WARN([d2x does not support native ipx on this host.  disabling native ipx])
286             enable_native_ipx="no";
287             ;;
288     esac
289         case $host_os in
290                 cygwin* | mingw* | msdos*)
291                         enable_kalinix="no";
292                         ;;
293         esac
294     case $host_os in
295         *solaris*)
296             AC_CHECK_LIB(socket, socket, LIBS="${LIBS} -lsocket",
297                 [AC_MSG_ERROR(socket lib required for net support on solaris not found)])
298             AC_CHECK_LIB(nsl, inet_addr, LIBS="${LIBS} -lnsl",
299                 [AC_MSG_ERROR(nsl lib required for net support on solaris not found)])          
300            ;;
301     esac
302 fi
303 AC_ARG_ENABLE(kalinix,
304     [  --disable-kalinix       Disable the KaliNix driver (unix-only)],,)
305 if test x$enable_network != xno; then
306     if test x$enable_native_ipx != xno; then
307         D2X_FEATURES="ipx ${D2X_FEATURES}"
308         AC_DEFINE(NATIVE_IPX,,[Define to use the IPX support of the OS])
309     fi
310     if test x$enable_kalinix != xno; then
311         D2X_FEATURES="kalinix ${D2X_FEATURES}"
312         AC_DEFINE(KALINIX,,[Define to enable use of the KaliNix driver])
313     fi
314     AC_DEFINE(NETWORK,,[Define if you want a network build])
315     D2X_FEATURES="network ${D2X_FEATURES}"
316 fi
317 AM_CONDITIONAL(USE_NETWORK, test x$enable_network != xno)
318 AM_CONDITIONAL(USE_NATIVE_IPX, test x$enable_native_ipx != xno)
319 AM_CONDITIONAL(USE_KALINIX, test x$enable_kalinix != xno)
320
321 dnl Check for assembler
322 AC_ARG_ENABLE(assembler,
323     [  --disable-assembler     Do not use assembler optimization ],,)
324 if test x$enable_assembler != xno; then
325     if test x$NASM = xno; then
326         AC_MSG_WARN([nasm not found. disabling assembler])
327         enable_assembler="no"
328     else
329         NASMFLAGS="-i\$(srcdir)/ $NASMFLAGS"
330         case $host_os in
331             cygwin* | mingw*)
332                 NASMFLAGS="-f win32 $NASMFLAGS"
333                 ;;
334             msdos*)
335                 NASMFLAGS="-f coff $NASMFLAGS"
336                 ;;
337                         linux* | freebsd*)
338                                 NASMFLAGS="-f elf -d__ELF__ $NASMFLAGS"
339                 ;;
340             *)
341                 AC_MSG_WARN([nasm not supported for this OS. disabling assembler])
342                 enable_assembler="no"
343                 ;;
344         esac
345     fi
346 fi
347 if test x$enable_assembler = xno; then
348     AC_DEFINE(NO_ASM,,[Define if you want an assembler free build])
349     D2X_FEATURES="no_asm ${D2X_FEATURES}"
350 fi
351 AM_CONDITIONAL(USE_ASM, test x$enable_assembler != xno)
352
353 AH_BOTTOM([
354         /* General defines */
355 #ifndef PACKAGE_STRING
356 #define PACKAGE_STRING PACKAGE " " VERSION
357 #endif
358 #define VERSION_NAME PACKAGE_STRING
359 #define NMONO 1
360 #define PIGGY_USE_PAGING 1
361 #define NEWDEMO 1
362
363 #if defined(__APPLE__) && defined(__MACH__)
364 #define __unix__ /* since we're doing a unix-style compilation... */
365 #endif
366
367 #ifdef __unix__
368 # ifdef GGI
369 #  define GII_INPUT 1
370 #  define GGI_VIDEO 1
371 # else
372 #  ifdef SVGA
373 #   define SVGALIB_INPUT 1
374 #   define SVGALIB_VIDEO 1
375 #  else
376 #   define SDL_INPUT 1
377 #   ifdef OGL
378 #    define SDL_GL_VIDEO 1
379 #   else
380 #    define SDL_VIDEO 1
381 #   endif
382 #  endif
383 # endif
384 #endif
385
386 #ifdef _WIN32
387 # define SDL_INPUT 1
388 # ifdef OGL
389 #  define SDL_GL_VIDEO 1
390 # else
391 #  define SDL_VIDEO 1
392 # endif
393 #endif
394         ])
395
396 TARGETS="$TARGETS$ac_cv_exeext"
397
398 AM_PROG_AS
399
400 AC_SUBST(D2X_SUBDIRS)
401
402 AC_SUBST(D2X_ARCH_SUBDIRS)
403
404 AC_SUBST(D2X_MAIN_SUBDIRS)
405
406 AC_SUBST(TARGETS)
407
408 AC_SUBST(NASMFLAGS)
409
410 AC_SUBST(CFLAGS)
411
412 AC_OUTPUT(
413     Makefile
414     2d/Makefile
415     3d/Makefile
416     arch/Makefile
417     arch/dos/Makefile
418     arch/ggi/Makefile
419     arch/linux/Makefile
420     arch/ogl/Makefile
421     arch/sdl/Makefile
422     arch/svgalib/Makefile
423     arch/win32/Makefile
424     console/Makefile
425     iff/Makefile
426     libmve/Makefile
427     main/Makefile
428     main/editor/Makefile
429     maths/Makefile
430     mem/Makefile
431     misc/Makefile
432     texmap/Makefile
433     utilities/Makefile
434     debian/changelog
435     rpm/d2x.spec
436 )
437
438 AC_MSG_RESULT([
439         d2x has been configured successfully.
440
441         Platform(s): $D2X_ARCH_SUBDIRS
442         Features   : $D2X_FEATURES $D2X_SUBDIRS $D2X_MAIN_SUBDIRS
443
444         Shared game data directory (unix only): $sharepath
445         ])