fix color swapping on big endian of big rle bitmaps
[btb/d2x.git] / configure.ac
1 # -*- mode: shell-script -*-
2
3 define([D2X_MAJOR],0)
4 define([D2X_MINOR],2)
5 define([D2X_MICRO],0)
6
7 AC_INIT(d2x,[D2X_MAJOR.D2X_MINOR.D2X_MICRO],[descent-source@warpcore.org])
8 AC_PREREQ(2.52)
9
10 AC_CANONICAL_BUILD
11 AC_CANONICAL_HOST
12 AC_CANONICAL_TARGET
13
14 AM_INIT_AUTOMAKE([1.6])
15
16 AM_CONFIG_HEADER(conf.h)
17
18 AC_DEFINE_UNQUOTED(D2XMAJOR,D2X_MAJOR,[d2x major version])
19 AC_DEFINE_UNQUOTED(D2XMINOR,D2X_MINOR,[d2x minor version])
20 AC_DEFINE_UNQUOTED(D2XMICRO,D2X_MICRO,[d2x micro version])
21
22 AM_MAINTAINER_MODE
23
24 #kludge to keep autoconf from adding -g -O2
25 CFLAGS=" $CFLAGS"
26
27 AC_PROG_INSTALL
28 AC_PROG_MAKE_SET
29 AC_ISC_POSIX
30 AC_CHECK_TOOL(CC, gcc, :)
31 AC_CHECK_TOOL(RANLIB, ranlib, :)
32 AC_CHECK_TOOL(STRIP, strip, :)
33 AC_CHECK_TOOL(AR, ar, :)
34 AC_PROG_CC
35 AC_PROG_CXX
36 AC_STDC_HEADERS
37 AC_PATH_PROGS(NASM, nasm nasmw, no)
38 AC_C_BIGENDIAN
39
40 case $host_cpu in
41         sparc)
42                 AC_DEFINE(WORDS_NEED_ALIGNMENT,,[Define if your processor needs data to be word-aligned])
43         ;;
44 esac
45
46 case $host_os in
47     cygwin)
48         AC_MSG_WARN([Cygwin found, setting -mno-cygwin])
49         CFLAGS="-mno-cygwin $CFLAGS"
50         MINGW32=yes
51         ;;
52     mingw*)
53         MINGW32=yes
54         ;;
55     darwin*)
56         MACOSX=yes
57         ;;
58     msdos*)
59         MSDOS=yes
60         ;;
61 esac
62
63 AM_CONDITIONAL(MINGW32, test x$MINGW32 = xyes)
64 if test x$MINGW32 = xyes; then
65     GL_LIBS="opengl32 glu32"
66 elif test x$MACOSX = xyes; then
67     GL_LIBS=""
68 else
69     GL_LIBS="GL GLU"
70 fi
71
72 if test x$MACOSX = xyes; then
73     AC_DEFINE(__MACOSX__,,[Define if building on MAC OS X])
74 fi
75 AM_CONDITIONAL(MACOSX, test x$MACOSX = xyes)
76
77 dnl Set $prefix and $exec_prefix to $ac_default_prefix if they are not set
78 test "x$prefix" = "xNONE" && prefix=$ac_default_prefix
79 test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"
80
81 dnl Set default locations to find data files.
82 default_sharepath="$datadir/games/$PACKAGE"
83
84 CFLAGS="-Wall $CFLAGS"
85
86 dnl Enable editor build?
87 AC_ARG_ENABLE(editor,
88     [  --enable-editor         Build editor? (not functional)],,)
89 if test x$enable_editor = xyes; then
90     AC_DEFINE(EDITOR,,[Define if you want to build the editor])
91     D2X_MAIN_SUBDIRS=editor
92 fi
93 AM_CONDITIONAL(EDITOR, test x$enable_editor = xyes)
94
95 dnl Enable macdata build?
96 AC_ARG_ENABLE(macdata,
97     [  --enable-macdata        Build for mac datafiles],,)
98 if test x$enable_macdata = xyes; then
99     AC_DEFINE(MACDATA,,[Define if you want to build for mac datafiles])
100     D2X_FEATURES="macdata ${D2X_FEATURES}"
101 fi
102 AM_CONDITIONAL(MACDATA, test x$enable_macdata = xyes)
103
104 dnl Build with NDEBUG?
105 AC_ARG_ENABLE(debug,
106     [  --disable-debug         Take out debug symbols, Asserts, Int3, etc ],,)
107 if test x$enable_debug = xno; then
108     AC_DEFINE(NDEBUG,,[Define to disable asserts, int3, etc.])
109     CFLAGS="-O2 $CFLAGS"
110 else
111     CFLAGS="-g $CFLAGS"
112     D2X_FEATURES="debug ${D2X_FEATURES}"
113 fi
114
115 dnl Build with RELEASE?
116 AC_ARG_ENABLE(release,
117     [  --enable-release        Release build.  Removes debug/editor things ],,)
118 if test x$enable_release = xyes; then
119     AC_DEFINE(RELEASE,,[Define for a "release" build])
120     D2X_FEATURES="release ${D2X_FEATURES}"
121 fi
122
123 dnl Build without using sdl-joystick ?
124 AC_ARG_ENABLE(linuxjoy,
125     [  --enable-linuxjoy       do not use the SDL Joystick. (eg for MS Sidewinder)],,)
126 if test x$enable_linuxjoy = xyes; then
127     AC_DEFINE(USE_LINUX_JOY,,[define to not use the SDL_Joystick routines.])
128 fi
129 AM_CONDITIONAL(USE_LINUX_JOY, test x$enable_linuxjoy = xyes)
130
131 dnl Build with FAST_FILE_IO?
132 AC_ARG_ENABLE(fastfileio,
133     [  --disable-fastfileio    Disable fast file i/o. ],,)
134 if test x$enable_fastfileio != xno; then
135         if test x$ac_cv_c_bigendian = xyes; then
136                 AC_MSG_WARN([big-endian cpu detected.  disabling fastfileio])
137                 enable_fastfileio="no";
138         fi
139 fi
140 if test x$enable_fastfileio != xno; then
141     AC_DEFINE(FAST_FILE_IO,,[Define for faster i/o on little-endian cpus])
142     D2X_FEATURES="fastfileio ${D2X_FEATURES}"
143 fi
144
145 dnl Build with CONSOLE?
146 AC_ARG_ENABLE(console,
147     [  --enable-console         Enable console (very experimental) ],,)
148 if test x$enable_console = xyes; then
149     AC_DEFINE(CONSOLE,,[Define to enable console])
150     D2X_FEATURES="console ${D2X_FEATURES}"
151 fi
152
153 AC_ARG_WITH(sharepath,
154     [[  --with-sharepath=DIR    Use DIR for shared game data (unix only) [DATADIR/games/d2x]]],
155     sharepath=$withval, sharepath="auto")
156 if test "x$sharepath" = "xauto" -o "x$sharepath" = "xyes" -o "x$sharepath" = "x"; then
157     sharepath="$default_sharepath"
158 fi
159 AC_SUBST(sharepath)
160 eval sharepath=$sharepath
161 AC_DEFINE_UNQUOTED(SHAREPATH, "$sharepath",[Define this to be the shared game directory root])
162
163 # Test for MSDOS
164 if test x$MSDOS = xyes; then
165     CFLAGS="-I \$(top_srcdir)/arch/dos/include $CFLAGS"
166     TARGETS=d2x
167     D2X_ARCH_SUBDIRS=dos
168 else
169
170     CFLAGS="-pipe $CFLAGS"
171
172     dnl Check for SDL
173     AM_PATH_SDL(1.1.0,
174         :,
175         AC_MSG_ERROR(SDL not found. Make sure sdl-config is in your PATH, or specify with --with-sdl-prefix)
176     )
177     CFLAGS="$SDL_CFLAGS $CFLAGS"
178     LIBS="$SDL_LIBS $LIBS"
179
180     TARGETS=d2x-sdl
181     D2X_ARCH_SUBDIRS=sdl
182
183     AC_CHECK_HEADERS(netipx/ipx.h)
184
185   # Check for OpenGL
186     AC_ARG_WITH(opengl,
187         [  --with-opengl           Build OpenGL support ],,)
188     if test x$with_opengl = xyes; then
189         for lib in $GL_LIBS; do
190             AC_CHECK_LIB($lib, main,
191                 OGL_LIBS="${OGL_LIBS} -l$lib",
192                 [AC_MSG_ERROR([$lib not found, --with-opengl cannot be used])
193                     opengl=false],
194                 ${OGL_LIBS}
195             )
196         done
197         AC_DEFINE(OGL,,[Define if you want an OpenGL build])
198         TARGETS=d2x-gl
199         D2X_ARCH_SUBDIRS="ogl ${D2X_ARCH_SUBDIRS}"
200     fi
201     AC_SUBST(OGL_LIBS)
202     AM_CONDITIONAL(USE_OPENGL, test x$with_opengl = xyes)
203
204   # Check for GGI
205     AC_ARG_WITH(ggi,
206         [  --with-ggi              Build GGI support ],,)
207     if test x$with_ggi = xyes; then
208         AC_CHECK_LIB(ggi, ggiInit,
209             GGI_LIBS="-lggi",
210             [AC_MSG_ERROR([GGI not found, GGI version cannot be built]); ggi=false])
211         AC_CHECK_LIB(gii, giiInit,
212             GGI_LIBS="${GGI_LIBS} -lgii",
213             [AC_MSG_ERROR([GII not found, GGI version cannot be built]); ggi=false])
214         AC_DEFINE(GGI,,[Define if you want a GGI build])
215         TARGETS=d2x-ggi
216         D2X_ARCH_SUBDIRS="ggi ${D2X_ARCH_SUBDIRS}"
217     fi
218     AC_SUBST(GGI_LIBS)
219     AM_CONDITIONAL(USE_GGI, test x$with_ggi = xyes)
220
221   # Check for SVGALib
222     AC_ARG_WITH(svga,
223         [  --with-svga             Build SVGALib support ],,)
224     if test x$with_svga = xyes; then
225         AC_CHECK_LIB(vga,vga_getmousetype,
226             SVGA_LIBS="-lvga",
227             [AC_MSG_ERROR([vga not found, SVGALib cannot be built])
228                 svga=false],
229         )
230         AC_CHECK_LIB(vgagl,gl_getcontext,
231             SVGA_LIBS="${SVGA_LIBS} -lvgagl",
232             [AC_MSG_ERROR([vgagl not found, SVGALib cannot be built])
233                 svga=false],
234             -lvga)
235         AC_DEFINE(SVGA,,[Define if you want an SVGALib build])
236         TARGETS=d2x-svga
237         D2X_ARCH_SUBDIRS="svgalib ${D2X_ARCH_SUBDIRS}"
238     fi
239     AC_SUBST(SVGA_LIBS)
240     AM_CONDITIONAL(USE_SVGALIB, test x$with_svga = xyes)
241
242     if test x$MINGW32 = xyes; then
243         D2X_ARCH_SUBDIRS="win32 ${D2X_ARCH_SUBDIRS}"
244     else
245         CFLAGS="-I \$(top_srcdir)/arch/linux/include $CFLAGS"
246         D2X_ARCH_SUBDIRS="linux ${D2X_ARCH_SUBDIRS}"
247     fi
248 fi
249
250 dnl Check for network
251 AC_ARG_ENABLE(network,
252     [  --disable-network       Do not build network/serial support ],,)
253 if test x$enable_network != xno; then
254         if test x$MACOSX = xyes; then
255                 AC_MSG_WARN([OS X detected.  disabling network])
256                 enable_network="no";
257         fi
258 fi
259 if test x$enable_network != xno; then
260     AC_DEFINE(NETWORK,,[Define if you want a network build])
261     D2X_FEATURES="network ${D2X_FEATURES}"
262 fi
263 AM_CONDITIONAL(USE_NETWORK, test x$enable_network != xno)
264
265 dnl Check for assembler
266 AC_ARG_ENABLE(assembler,
267     [  --disable-assembler     Do not use assembler optimization ],,)
268 if test x$enable_assembler != xno; then
269     if test x$NASM = xno; then
270         AC_MSG_WARN([nasm not found. disabling assembler])
271         enable_assembler="no"
272     else
273         NASMFLAGS="-i\$(srcdir)/ $NASMFLAGS"
274         case $host_os in
275             cygwin* | mingw*)
276                 NASMFLAGS="-f win32 $NASMFLAGS"
277                 ;;
278             msdos*)
279                 NASMFLAGS="-f coff $NASMFLAGS"
280                 ;;
281             linux*)
282                 NASMFLAGS="-f elf -d__linux__ $NASMFLAGS"
283                 ;;
284             *)
285                 AC_MSG_WARN([nasm not supported for this OS. disabling assembler])
286                 enable_assembler="no"
287                 ;;
288         esac
289     fi
290 fi
291 if test x$enable_assembler = xno; then
292     AC_DEFINE(NO_ASM,,[Define if you want an assembler free build])
293     D2X_FEATURES="no_asm ${D2X_FEATURES}"
294 fi
295 AM_CONDITIONAL(USE_ASM, test x$enable_assembler != xno)
296
297 AH_BOTTOM([
298         /* General defines */
299 #define VERSION_NAME PACKAGE_STRING
300 #define NMONO 1
301 #define PIGGY_USE_PAGING 1
302 #define NEWDEMO 1
303
304 #ifdef __MACOSX__
305 #define __unix__
306 #endif
307
308 #ifdef __unix__
309 # ifdef GGI
310 #  define GII_INPUT 1
311 #  define GGI_VIDEO 1
312 # else
313 #  ifdef SVGA
314 #   define SVGALIB_INPUT 1
315 #   define SVGALIB_VIDEO 1
316 #  else
317 #   define SDL_INPUT 1
318 #   ifdef OGL
319 #    define SDL_GL_VIDEO 1
320 #   else
321 #    define SDL_VIDEO 1
322 #   endif
323 #  endif
324 # endif
325 #endif
326
327 #ifdef __MINGW32__
328 # define SDL_INPUT 1
329 # ifdef OGL
330 #  define SDL_GL_VIDEO 1
331 # else
332 #  define SDL_VIDEO 1
333 # endif
334 #endif
335         ])
336
337 AM_PROG_AS
338
339 AC_SUBST(D2X_ARCH_SUBDIRS)
340
341 AC_SUBST(D2X_MAIN_SUBDIRS)
342
343 AC_SUBST(TARGETS)
344
345 AC_SUBST(NASMFLAGS)
346
347 AC_SUBST(CFLAGS)
348
349 AC_OUTPUT(
350     Makefile
351     2d/Makefile
352     3d/Makefile
353     arch/Makefile
354     arch/dos/Makefile
355     arch/ggi/Makefile
356     arch/linux/Makefile
357     arch/ogl/Makefile
358     arch/sdl/Makefile
359     arch/svgalib/Makefile
360     arch/win32/Makefile
361     cfile/Makefile
362     iff/Makefile
363     libmve/Makefile
364     main/Makefile
365     main/editor/Makefile
366     maths/Makefile
367     mem/Makefile
368     misc/Makefile
369     texmap/Makefile
370     utilities/Makefile
371     debian/changelog
372     rpm/d2x.spec
373 )
374
375 AC_MSG_RESULT([
376         d2x has been configured successfully.
377
378         Platform(s): $D2X_ARCH_SUBDIRS
379         Features   : $D2X_FEATURES $D2X_MAIN_SUBDIRS
380
381         Shared game data directory (unix only): $sharepath
382         ])