configure.ac

   1 # -*- mode: shell-script -*-
   2
   3 define([D2X_MAJOR],0)
   4 define([D2X_MINOR],2)
   5 define([D2X_MICRO],4)
   6
   7 AC_INIT(d2x,[D2X_MAJOR.D2X_MINOR.D2X_MICRO],[descent-source@warpcore.org])
   8 AC_PREREQ(2.52)
   9
  10 AC_CANONICAL_BUILD
  11 AC_CANONICAL_HOST
  12 AC_CANONICAL_TARGET
  13
  14 AM_INIT_AUTOMAKE([1.6])
  15
  16 AM_CONFIG_HEADER(conf.h)
  17
  18 AC_DEFINE_UNQUOTED(D2XMAJOR,D2X_MAJOR,[d2x major version])
  19 AC_DEFINE_UNQUOTED(D2XMINOR,D2X_MINOR,[d2x minor version])
  20 AC_DEFINE_UNQUOTED(D2XMICRO,D2X_MICRO,[d2x micro version])
  21
  22 AM_MAINTAINER_MODE
  23
  24 #kludge to keep autoconf from adding -g -O2
  25 CFLAGS=" $CFLAGS"
  26
  27 AC_PROG_INSTALL
  28 AC_PROG_MAKE_SET
  29 AC_ISC_POSIX
  30 AC_CHECK_TOOL(CC, gcc, :)
  31 AC_CHECK_TOOL(RANLIB, ranlib, :)
  32 AC_CHECK_TOOL(STRIP, strip, :)
  33 AC_CHECK_TOOL(AR, ar, :)
  34 AC_PROG_CC
  35 AC_PROG_CXX
  36 AC_STDC_HEADERS
  37 AC_PATH_PROGS(NASM, nasm nasmw, no)
  38 AC_C_BIGENDIAN
  39
  40 case $host_cpu in
  41         sparc)
  42                 AC_DEFINE(WORDS_NEED_ALIGNMENT,,[Define if your processor needs data to be word-aligned])
  43         ;;
  44 esac
  45
  46 build_macosx_bundle=no
  47 build_simple_bundle=no
  48
  49 case $host_os in
  50     cygwin)
  51         AC_MSG_WARN([Cygwin found, setting -mno-cygwin])
  52         CFLAGS="-mno-cygwin $CFLAGS"
  53         MINGW32=yes
  54         ;;
  55     mingw*)
  56         MINGW32=yes
  57         ;;
  58     darwin*)
  59         MACOSX=yes
  60         AC_MSG_RESULT(Mac OS X/Darwin; Mac OS X bundle)
  61         build_macosx_bundle=yes
  62         DATADIR='EXE>>../Resources'
  63         #SCOREDIR='/Library/Preferences/KoboDeluxe/scores'
  64         #CONFIGDIR='HOME>>Library/Preferences'
  65         #CONFIGFILE='KoboDeluxe Preferences'
  66         MATHLIB=""
  67         ;;
  68     msdos*)
  69         MSDOS=yes
  70         ;;
  71 esac
  72
  73 AC_CHECK_DECLS(nanosleep,,,[#include <time.h>])
  74 AC_CHECK_TYPES(struct timespec)
  75
  76 AM_CONDITIONAL(MINGW32, test x$MINGW32 = xyes)
  77 if test x$MINGW32 = xyes; then
  78     GL_LIBS="opengl32 glu32"
  79 elif test x$MACOSX = xyes; then
  80     GL_LIBS=""
  81 else
  82     GL_LIBS="GL GLU"
  83 fi
  84
  85 AM_CONDITIONAL(MACOSX, test x$MACOSX = xyes)
  86 AM_CONDITIONAL(BUILD_MACOSX_BUNDLE, test x$build_macosx_bundle = xyes)
  87 AM_CONDITIONAL(BUILD_SIMPLE_BUNDLE, test x$build_simple_bundle = xyes)
  88
  89 dnl Set $prefix and $exec_prefix to $ac_default_prefix if they are not set
  90 test "x$prefix" = "xNONE" && prefix=$ac_default_prefix
  91 test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"
  92
  93 dnl Set default locations to find data files.
  94 default_sharepath="$datadir/games/$PACKAGE"
  95
  96 CFLAGS="-Wall $CFLAGS"
  97
  98 dnl Enable editor build?
  99 AC_ARG_ENABLE(editor,
 100     [  --enable-editor         Build editor? (not functional)],,)
 101 if test x$enable_editor = xyes; then
 102     AC_DEFINE(EDITOR,,[Define if you want to build the editor])
 103     D2X_MAIN_SUBDIRS=editor
 104 fi
 105 AM_CONDITIONAL(EDITOR, test x$enable_editor = xyes)
 106
 107 dnl Enable macdata build?
 108 AC_ARG_ENABLE(macdata,
 109     [  --enable-macdata        Build for mac datafiles],,)
 110 if test x$enable_macdata = xyes; then
 111     AC_DEFINE(MACDATA,,[Define if you want to build for mac datafiles])
 112     D2X_FEATURES="macdata ${D2X_FEATURES}"
 113 fi
 114 AM_CONDITIONAL(MACDATA, test x$enable_macdata = xyes)
 115
 116 dnl Build with NDEBUG?
 117 AC_ARG_ENABLE(debug,
 118     [  --disable-debug         Take out debug symbols, Asserts, Int3, etc ],,)
 119 if test x$enable_debug = xno; then
 120     AC_DEFINE(NDEBUG,,[Define to disable asserts, int3, etc.])
 121     CFLAGS="-O2 $CFLAGS"
 122 else
 123     CFLAGS="-g $CFLAGS"
 124     D2X_FEATURES="debug ${D2X_FEATURES}"
 125 fi
 126
 127 dnl Build with RELEASE?
 128 AC_ARG_ENABLE(release,
 129     [  --enable-release        Release build.  Removes debug/editor things ],,)
 130 if test x$enable_release = xyes; then
 131     AC_DEFINE(RELEASE,,[Define for a "release" build])
 132     D2X_FEATURES="release ${D2X_FEATURES}"
 133 fi
 134
 135 dnl Build without using sdl-joystick ?
 136 AC_ARG_ENABLE(linuxjoy,
 137     [  --enable-linuxjoy       do not use the SDL Joystick. (eg for MS Sidewinder)],,)
 138 if test x$enable_linuxjoy = xyes; then
 139     AC_DEFINE(USE_LINUX_JOY,,[define to not use the SDL_Joystick routines.])
 140 fi
 141 AM_CONDITIONAL(USE_LINUX_JOY, test x$enable_linuxjoy = xyes)
 142
 143 dnl Build with FAST_FILE_IO?
 144 AC_ARG_ENABLE(fastfileio,
 145     [  --disable-fastfileio    Disable fast file i/o. ],,)
 146 if test x$enable_fastfileio != xno; then
 147         if test x$ac_cv_c_bigendian = xyes; then
 148                 AC_MSG_WARN([big-endian cpu detected.  disabling fastfileio])
 149                 enable_fastfileio="no";
 150         fi
 151 fi
 152 if test x$enable_fastfileio != xno; then
 153     AC_DEFINE(FAST_FILE_IO,,[Define for faster i/o on little-endian cpus])
 154     D2X_FEATURES="fastfileio ${D2X_FEATURES}"
 155 fi
 156
 157 AC_ARG_WITH(sharepath,
 158     [[  --with-sharepath=DIR    Use DIR for shared game data (unix only) [DATADIR/games/d2x]]],
 159     sharepath=$withval, sharepath="auto")
 160 if test "x$sharepath" = "xauto" -o "x$sharepath" = "xyes" -o "x$sharepath" = "x"; then
 161     sharepath="$default_sharepath"
 162 fi
 163 AC_SUBST(sharepath)
 164 eval sharepath=$sharepath
 165 AC_DEFINE_UNQUOTED(SHAREPATH, "$sharepath",[Define this to be the shared game directory root])
 166
 167 # Test for MSDOS
 168 if test x$MSDOS = xyes; then
 169     CFLAGS="-I \$(top_srcdir)/arch/dos/include $CFLAGS"
 170     TARGETS=d2x
 171     D2X_ARCH_SUBDIRS=dos
 172 else
 173
 174     CFLAGS="-pipe $CFLAGS"
 175
 176     dnl Check for SDL
 177     AM_PATH_SDL(1.1.0,
 178         :,
 179         AC_MSG_ERROR(SDL not found. Make sure sdl-config is in your PATH, or specify with --with-sdl-prefix)
 180     )
 181     CFLAGS="$SDL_CFLAGS $CFLAGS"
 182     LIBS="$SDL_LIBS $LIBS"
 183
 184     TARGETS=d2x-sdl
 185     D2X_ARCH_SUBDIRS=sdl
 186
 187     AC_CHECK_HEADERS(netipx/ipx.h)
 188
 189   # Check for SDL_image
 190         AC_CHECK_LIB(SDL_image, IMG_ReadXPMFromArray,
 191                 LIBS="-lSDL_image $LIBS"
 192                 AC_DEFINE(SDL_IMAGE,,[Define if you have the SDL_image library]))
 193
 194   # Check for OpenGL
 195     AC_ARG_WITH(opengl,
 196         [  --with-opengl           Build OpenGL support ],,)
 197     if test x$with_opengl = xyes; then
 198         for lib in $GL_LIBS; do
 199             AC_CHECK_LIB($lib, main,
 200                 OGL_LIBS="${OGL_LIBS} -l$lib",
 201                 [AC_MSG_ERROR([$lib not found, --with-opengl cannot be used])
 202                     opengl=false],
 203                 ${OGL_LIBS}
 204             )
 205         done
 206         AC_DEFINE(OGL,,[Define if you want an OpenGL build])
 207         TARGETS=d2x-gl
 208         D2X_ARCH_SUBDIRS="ogl ${D2X_ARCH_SUBDIRS}"
 209     fi
 210     AC_SUBST(OGL_LIBS)
 211     AM_CONDITIONAL(USE_OPENGL, test x$with_opengl = xyes)
 212
 213   # Check for GGI
 214     AC_ARG_WITH(ggi,
 215         [  --with-ggi              Build GGI support ],,)
 216     if test x$with_ggi = xyes; then
 217         AC_CHECK_LIB(ggi, ggiInit,
 218             GGI_LIBS="-lggi",
 219             [AC_MSG_ERROR([GGI not found, GGI version cannot be built]); ggi=false])
 220         AC_CHECK_LIB(gii, giiInit,
 221             GGI_LIBS="${GGI_LIBS} -lgii",
 222             [AC_MSG_ERROR([GII not found, GGI version cannot be built]); ggi=false])
 223         AC_DEFINE(GGI,,[Define if you want a GGI build])
 224         TARGETS=d2x-ggi
 225         D2X_ARCH_SUBDIRS="ggi ${D2X_ARCH_SUBDIRS}"
 226     fi
 227     AC_SUBST(GGI_LIBS)
 228     AM_CONDITIONAL(USE_GGI, test x$with_ggi = xyes)
 229
 230   # Check for SVGALib
 231     AC_ARG_WITH(svga,
 232         [  --with-svga             Build SVGALib support ],,)
 233     if test x$with_svga = xyes; then
 234         AC_CHECK_LIB(vga,vga_getmousetype,
 235             SVGA_LIBS="-lvga",
 236             [AC_MSG_ERROR([vga not found, SVGALib cannot be built])
 237                 svga=false],
 238         )
 239         AC_CHECK_LIB(vgagl,gl_getcontext,
 240             SVGA_LIBS="${SVGA_LIBS} -lvgagl",
 241             [AC_MSG_ERROR([vgagl not found, SVGALib cannot be built])
 242                 svga=false],
 243             -lvga)
 244         AC_DEFINE(SVGA,,[Define if you want an SVGALib build])
 245         TARGETS=d2x-svga
 246         D2X_ARCH_SUBDIRS="svgalib ${D2X_ARCH_SUBDIRS}"
 247     fi
 248     AC_SUBST(SVGA_LIBS)
 249     AM_CONDITIONAL(USE_SVGALIB, test x$with_svga = xyes)
 250
 251     if test x$MINGW32 = xyes; then
 252         D2X_ARCH_SUBDIRS="win32 ${D2X_ARCH_SUBDIRS}"
 253     else
 254         CFLAGS="-I \$(top_srcdir)/arch/linux/include $CFLAGS"
 255         D2X_ARCH_SUBDIRS="linux ${D2X_ARCH_SUBDIRS}"
 256     fi
 257 fi
 258
 259 dnl Check for network
 260 AC_ARG_ENABLE(network,
 261     [  --disable-network       Do not build network/serial support ],,)
 262 if test x$enable_network != xno; then
 263         if test x$MACOSX = xyes; then
 264                 AC_MSG_WARN([OS X detected.  disabling network])
 265                 enable_network="no";
 266         fi
 267 fi
 268 if test x$enable_network != xno; then
 269     AC_DEFINE(NETWORK,,[Define if you want a network build])
 270     D2X_FEATURES="network ${D2X_FEATURES}"
 271 fi
 272 AM_CONDITIONAL(USE_NETWORK, test x$enable_network != xno)
 273
 274 dnl Check for assembler
 275 AC_ARG_ENABLE(assembler,
 276     [  --disable-assembler     Do not use assembler optimization ],,)
 277 if test x$enable_assembler != xno; then
 278     if test x$NASM = xno; then
 279         AC_MSG_WARN([nasm not found. disabling assembler])
 280         enable_assembler="no"
 281     else
 282         NASMFLAGS="-i\$(srcdir)/ $NASMFLAGS"
 283         case $host_os in
 284             cygwin* | mingw*)
 285                 NASMFLAGS="-f win32 $NASMFLAGS"
 286                 ;;
 287             msdos*)
 288                 NASMFLAGS="-f coff $NASMFLAGS"
 289                 ;;
 290             linux*)
 291                 NASMFLAGS="-f elf -d__linux__ $NASMFLAGS"
 292                 ;;
 293             *)
 294                 AC_MSG_WARN([nasm not supported for this OS. disabling assembler])
 295                 enable_assembler="no"
 296                 ;;
 297         esac
 298     fi
 299 fi
 300 if test x$enable_assembler = xno; then
 301     AC_DEFINE(NO_ASM,,[Define if you want an assembler free build])
 302     D2X_FEATURES="no_asm ${D2X_FEATURES}"
 303 fi
 304 AM_CONDITIONAL(USE_ASM, test x$enable_assembler != xno)
 305
 306 AH_BOTTOM([
 307         /* General defines */
 308 #ifndef PACKAGE_STRING
 309 #define PACKAGE_STRING PACKAGE " " VERSION
 310 #endif
 311 #define VERSION_NAME PACKAGE_STRING
 312 #define NMONO 1
 313 #define PIGGY_USE_PAGING 1
 314 #define NEWDEMO 1
 315
 316 #if defined(__APPLE__) && defined(__MACH__)
 317 #define __unix__
 318 #endif
 319
 320 #ifdef __unix__
 321 # ifdef GGI
 322 #  define GII_INPUT 1
 323 #  define GGI_VIDEO 1
 324 # else
 325 #  ifdef SVGA
 326 #   define SVGALIB_INPUT 1
 327 #   define SVGALIB_VIDEO 1
 328 #  else
 329 #   define SDL_INPUT 1
 330 #   ifdef OGL
 331 #    define SDL_GL_VIDEO 1
 332 #   else
 333 #    define SDL_VIDEO 1
 334 #   endif
 335 #  endif
 336 # endif
 337 #endif
 338
 339 #ifdef __MINGW32__
 340 # define SDL_INPUT 1
 341 # ifdef OGL
 342 #  define SDL_GL_VIDEO 1
 343 # else
 344 #  define SDL_VIDEO 1
 345 # endif
 346 #endif
 347         ])
 348
 349 AM_PROG_AS
 350
 351 AC_SUBST(D2X_ARCH_SUBDIRS)
 352
 353 AC_SUBST(D2X_MAIN_SUBDIRS)
 354
 355 AC_SUBST(TARGETS)
 356
 357 AC_SUBST(NASMFLAGS)
 358
 359 AC_SUBST(CFLAGS)
 360
 361 AC_OUTPUT(
 362     Makefile
 363     2d/Makefile
 364     3d/Makefile
 365     arch/Makefile
 366     arch/dos/Makefile
 367     arch/ggi/Makefile
 368     arch/linux/Makefile
 369     arch/ogl/Makefile
 370     arch/sdl/Makefile
 371     arch/svgalib/Makefile
 372     arch/win32/Makefile
 373     cfile/Makefile
 374     console/Makefile
 375     iff/Makefile
 376     libmve/Makefile
 377     main/Makefile
 378     main/editor/Makefile
 379     maths/Makefile
 380     mem/Makefile
 381     misc/Makefile
 382     texmap/Makefile
 383     utilities/Makefile
 384     debian/changelog
 385     rpm/d2x.spec
 386     Info.plist
 387 )
 388
 389 AC_MSG_RESULT([
 390         d2x has been configured successfully.
 391
 392         Platform(s): $D2X_ARCH_SUBDIRS
 393         Features   : $D2X_FEATURES $D2X_MAIN_SUBDIRS
 394
 395         Shared game data directory (unix only): $sharepath
 396         ])